testexecutor-ui 0.6.1__py3-none-any.whl

testexecutor/ui/ResultItem.qml

@@ -0,0 +1,199 @@
+/*
+ * Copyright 2020 Direkt, Australia
+ * Copyright 2021 Direkt Embedded Pty Ltd
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ * http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ */
+
+import QtQuick
+import QtQuick.Layouts
+import QtQuick.Controls
+
+Item {
+    id: resultItem
+    width: parent ? parent.width : 100
+    height: 40
+    clip: true
+    property var config: ResultItemConfig{}
+
+    Rectangle {
+        id: resultRectangle
+        color: config.color
+        border.width: 3
+        border.color: config.border.color
+        anchors.fill: parent
+
+        RowLayout {
+            id: resultsRow
+            spacing: 1.5
+            anchors.fill: parent
+
+            Rectangle {
+                id: nameRectangle
+                Layout.preferredWidth: parent.width * config.proportion.name
+                color: config.name.color
+                Layout.fillHeight: true
+
+                Text {
+                    id: resultName
+                    color: config.name.text.color
+                    text: Boolean(test) ? test.name : ""
+                    verticalAlignment: Text.AlignVCenter
+                    font.pixelSize: parent.height / 1.2
+                    anchors.rightMargin: 2
+                    anchors.fill: parent
+                    clip: false
+                    horizontalAlignment: Text.AlignRight
+                }
+            }
+
+            Rectangle {
+                id: feedbackRectangle
+                color: config.feedback.color
+                border.color: config.feedback.border.color
+                Layout.fillHeight: true
+                Layout.fillWidth: true
+                Rectangle {
+                    height: parent.height
+                    width: Boolean(test) ? parent.width * test.progress : 0
+                    color: Boolean(test) && test.progress === 1 ? "transparent" : config.feedback.progress.color
+                    opacity: 0.5
+                }
+                Text {
+                    id: feedback
+                    color: Boolean(test) && test.progress < 1 ? config.feedback.text.color.default : config.feedback.text.color.progress
+                    text: Boolean(test) ? test.feedback : ""
+                    verticalAlignment: Text.AlignTop
+                    clip: true
+                    font.pixelSize: parent.height / 1.2
+                    anchors.rightMargin: 0
+                    anchors.leftMargin: 3
+                    anchors.fill: parent
+                }
+            }
+
+            Rectangle {
+                id: timeRectangle
+                Layout.preferredWidth: parent.width * config.proportion.time
+                Layout.maximumWidth: parent.width * 0.3
+                color: config.time.color
+                Layout.fillHeight: true
+                Timer {
+                    interval: 1000
+                    running: (state === "Running") && Boolean(test) && (test.progress < 1)
+                    repeat: true
+                    onTriggered: {
+                        test.duration = test.duration + 1
+                    }
+                }
+                Text {
+                    id: timeProgress
+                    color: config.time.text.color
+                    text: Boolean(test) ? formatTime(test.duration) : ""
+                    verticalAlignment: Text.AlignVCenter
+                    horizontalAlignment: Text.AlignRight
+                    font.pixelSize: parent.height / 1.2
+                    anchors.rightMargin: 0
+                    anchors.fill: parent
+                    clip: true
+                }
+            }
+        }
+        ToolTip {
+            visible: test && test.name ? resultMouseArea.containsMouse : false
+            timeout: 3000
+            delay: 500
+            contentItem:
+                Row {
+                    Rectangle {
+                        Text {
+                            text: resultName.text
+                            font.pixelSize: resultRectangle.height
+                            font.weight: Font.Bold
+                            color: resultName.color
+                            rightPadding: 5
+                            leftPadding: 10
+                        }
+                        color: nameRectangle.color
+                        width: childrenRect.width
+                        height: childrenRect.height
+                    }
+                    Rectangle {
+                        Text {
+                            text: feedback.text ? feedback.text:"  "
+                            font.pixelSize: resultRectangle.height
+                            font.weight: Font.Bold
+                            color: feedback.color
+                            rightPadding: 5
+                            leftPadding: 5
+                        }
+                        color: feedbackRectangle.color
+                        width: childrenRect.width
+                        height: childrenRect.height
+                    }
+                    Rectangle {
+                        Text {
+                            text: timeProgress.text
+                            font.pixelSize: resultRectangle.height
+                            font.weight: Font.Bold
+                            color: timeProgress.color
+                            rightPadding: 10
+                            leftPadding: 5
+                        }
+                        color: timeRectangle.color
+                        width: childrenRect.width
+                        height: childrenRect.height
+                    }
+                }
+        }
+        MouseArea {
+            id: resultMouseArea
+            anchors.fill: parent
+            hoverEnabled: true
+        }
+    }
+    state: test ? test.result : "Running"
+    states: [
+        State {
+            name: "Running"
+            PropertyChanges { target: feedbackRectangle; color: "#e5e2e2"  }
+        },
+        State {
+            name: "Pass"
+            PropertyChanges { target: feedbackRectangle; color: "green"  }
+        },
+        State {
+            name: "Fail"
+            PropertyChanges { target: feedbackRectangle; color: "red"  }
+        }
+    ]
+
+    function formatTime(timeInSeconds) {
+        var pad = function(num, size) { return ('000' + num).slice(size * -1); },
+        time = parseFloat(timeInSeconds).toFixed(3),
+        hours = Math.floor(time / 60 / 60),
+        minutes = Math.floor(time / 60) % 60,
+        seconds = Math.floor(time - minutes * 60),
+        milliseconds = time.slice(-3);
+
+        var s = pad(seconds, 2);
+        if (timeInSeconds >= 60*60) {
+            s = pad(hours, 2) + ':' + pad(minutes, 2) + ':' + pad(seconds, 2)
+        } else if (timeInSeconds >= 60){
+            s = pad(minutes, 2) + ':' + pad(seconds, 2)
+        }
+
+        return s;
+    }
+}
+

testexecutor/ui/ResultItemConfig.qml

@@ -0,0 +1,46 @@
+/*
+ * Copyright 2020 Direkt, Australia
+ * Copyright 2021 Direkt Embedded Pty Ltd
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ * http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ */
+
+import QtQuick
+
+Item {
+    /*
+     * Define the proportions for the widths of the test result items.
+     * The feedback area is not defined and will fill any remaining area.
+     */
+    property var proportion: {
+        "name": 0.3,
+        // feedback fill remaining space
+        "time": 0.2
+    }
+    property var color: "#605b5b"
+    property var border: {"color": "#00000000"}
+    property var name: {
+        "color": "#00000000",
+        "text": {"color": "#e5e2e2"}
+    }
+    property var feedback: {
+        "color": "#8e8a8a",
+        "border": {"color": "#b9e5e2e2"},
+        "text": {"color": {"default": "black", "progress": "#e5e2e2"}},
+        "progress": {"color": "green"}
+    }
+    property var time: {
+        "color": "#00000000",
+        "text": {"color": "#e5e2e2"}
+    }
+}

testexecutor/ui/ResultList.qml

@@ -0,0 +1,58 @@
+/*
+ * Copyright 2020 Direkt, Australia
+ * Copyright 2021 Direkt Embedded Pty Ltd
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ * http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ */
+
+import QtQuick
+import QtQuick.Controls
+
+Item {
+    id: resultList
+    width: 600
+    clip: true
+    property var results
+    property int viewableCount: -1
+    property var itemConfig
+    property var color: "#e5e2e2"
+
+    Rectangle {
+        id: resultListRectangle
+        color: color
+        anchors.fill: parent
+
+        ListView {
+            id: resultListView
+            spacing: 1
+            snapMode: ListView.NoSnap
+            boundsBehavior: Flickable.StopAtBounds
+            currentIndex: results ? results.currentTestIndex : 0
+            highlightFollowsCurrentItem: true
+            anchors.fill: parent
+            delegate: ResultItem {
+                height: (viewableCount <= 0) ? (resultListView.height / resultListView.count) : (resultListView.height / viewableCount)
+                Component.onCompleted: {
+                    if (results.currentTestIndex === -1) {
+                        resultListView.positionViewAtEnd();
+                    }
+                    if (resultList.itemConfig) {
+                        config = resultList.itemConfig
+                    }
+                }
+            }
+            model: results
+            ScrollBar.vertical: ScrollBar {}
+        }
+    }
+}

testexecutor/ui/TestSuiteConfig.qml

@@ -0,0 +1,95 @@
+/*
+ * Copyright 2020 Direkt, Australia
+ * Copyright 2021 Direkt Embedded Pty Ltd
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ * http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ */
+
+import QtQuick
+
+/*
+ * A qml item which acts as the default configuration for the test suite widget.
+ * If the inheriting model wants to override this model they can do so by forcefully setting the config property
+ * of the TestSuiteWidget.qml file with equivalent json string. Note the full json needs to be set or some aspects
+ * of the UI will fail due to missing configuration.
+ */
+Item {
+    /*
+     * Configuration variables set dependent on the state of the suite.
+     * idle.color is set in idle and end states if suite does not have a 'pass' or 'fail' state. If it does then the
+     *            pass or fail colours will be used.
+     * ready.color is set when suite is ready to start
+     * running.color is set when suite state is starting or running
+     * stopped.color is set when the suite is stopping or stopped state
+     */
+    property var states: {
+      "idle": { "color": {"default": "lightgray", "pass": "green", "fail": "red"}, "button": {"text": "Clear"} },
+      "ready": { "color": "gray", "button": {"text": "Clear"}},
+      "running": { "color": "gray", "button": {"text": "Stop"}},
+      "stopped": { "color": "orange", "button": {"text": "Clear"}},
+    }
+    /*
+     * Define the proportions for the height of the test suite widget.
+     * The results area is not defined and will fill any remaining area.
+     */
+    property var proportion: {
+      "title": 0.1,
+      "identification": 0.25,
+      "input": 0.05,
+      "instructions": 0.4,
+      // results takes remaining space
+      "status": 0.04
+    }
+
+    /*
+     * viewableCount: The number of test results to be visible. Effects height of each test result, dependent on
+     *                proportion values set.
+     * color: Background color when no items in list
+     * item: Set to false here, in order to use default config from ResultItemConfig.
+     *       User should define it to an equivalent json to ResultItemConfig it they want to override the default.
+     */
+    property var results: {
+      "viewableCount": 8,
+      "color": "#e5e2e2",
+      "item": false
+    }
+
+    /*
+     * color: Background color when no items in list
+     * item: Set to false here, in order to use default config from KeyValueItemConfig.
+     *       User should define it to an equivalent json to KeyValueItemConfig it they want to override the default.
+     */
+    property var identification: {
+      "color": "#e5e2e2",
+      "item": false
+    }
+
+    /*
+     * allow_focus: allow for the input to automatically get focus when the instruction becomes active
+     */
+    property var input: {
+      "allow_focus": true
+    }
+
+    /*
+     * color: Background color when instruction text is not html
+     * proportion:
+     *    header: Proportion of text box dedicated to header if there is one
+     *    text: Proportion of text box the main instruction text height will be
+     *    control: Proportion of instruction box the control buttons are in height
+     */
+    property var instructions: {
+      "color": {"default": "#f4f2f2", "active": "yellow"},
+      "proportion": {"header": 0.1, "textHeight": 0.07, "control": 0.02}
+    }
+}

testexecutor/ui/TestSuiteController.qml

@@ -0,0 +1,54 @@
+/*
+ * Copyright 2020 Sipke Vriend, Australia
+ * Copyright 2021 Direkt Embedded Pty Ltd
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ * http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ */
+
+import QtQuick
+import QtQuick.Controls
+import QtQuick.Layouts
+import QtQuick.Window
+import QtQuick.Dialogs
+import "./selector"
+
+Item {
+    id: testSuiteController
+    property alias tswModel: testSuiteWidget.tswModel
+    property alias cntrlModel: suiteSelector.cntrlModel
+    property alias duration: testSuiteWidget.duration
+    property alias config: testSuiteWidget.config
+    property alias about: testSuiteWidget.about
+    property alias controllerConfig: suiteSelector.config
+    property var useController: tswModel && Boolean(tswModel.testsuite.controller)
+    width: 600
+    height: 600
+    RowLayout {
+        id: rowLayout
+        anchors.fill: parent
+
+        SuiteSelector {
+            id: suiteSelector
+            Layout.fillHeight: true
+            Layout.fillWidth: true
+            visible: useController
+        }
+        TestSuiteWidget {
+            id: testSuiteWidget
+            Layout.minimumWidth: 0
+            Layout.preferredWidth:  useController ? parent.width * 0.5 : parent.width
+            Layout.maximumWidth:  useController ? 400 : parent.width
+            Layout.fillHeight: true
+        }
+    }
+}