testexecutor-ui 0.6.1__py3-none-any.whl

testexecutor/ui/InstructionWidget.qml

@@ -0,0 +1,185 @@
+/*
+ * Copyright 2020 Direkt, Australia
+ * Copyright 2021 Direkt Embedded Pty Ltd
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ * http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ */
+
+import QtQuick
+import QtQuick.Controls
+import QtQuick.Layouts
+
+Item {
+    id: instructionWidget
+    width: parent.width
+    height: parent.height
+    property var color: "yellow"
+    property var proportion: {"header": 0.1, "textHeight": 0.05, "control": 0.1}
+    property var model
+    property var control_enabled: controlEnabled()
+
+    Binding {
+        target: model
+        property: "enabled"
+        value: instructionWidget.enabled
+    }
+
+    Rectangle {
+        id: rectangleBase
+        width: parent.width
+        height: parent.height
+        color: "#f4f2f2"
+        Layout.fillHeight: true
+        Layout.fillWidth: true
+        Layout.alignment: Qt.AlignLeft | Qt.AlignTop
+
+        GridLayout {
+            id: userInput
+            anchors.fill: parent
+            transformOrigin: Item.Center
+            Layout.fillWidth: true
+            flow: Grid.LeftToRight
+            rows: 2
+            columns: 2
+
+            Item {
+                Layout.fillHeight: true
+                Layout.fillWidth: true
+                Layout.columnSpan: 2
+                Rectangle {
+                    id: rectangleText
+                    anchors.fill: parent
+                    color: backColour(model)
+                    ColumnLayout {
+                        id: instructionBox
+                        anchors.fill: parent
+                        spacing: 4
+                        TextEdit {
+                            id: instructionTitle
+                            visible: (Boolean(model) && model.instructionTitle) ? true : false
+                            Layout.preferredHeight: parent.height * proportion.header
+                            Layout.minimumHeight: 0
+                            Layout.maximumHeight: parent.height * proportion.header * 2
+                            Layout.fillWidth: true
+                            clip: true
+                            text: model ? model.instructionTitle : ""
+                            textFormat: Text.AutoText
+                            font.pixelSize: parent.height * proportion.header * 0.9
+                            wrapMode: TextEdit.Wrap
+                            readOnly: true
+                            selectByMouse: true
+                        }
+                        ScrollView {
+                            Layout.fillHeight: true
+                            Layout.fillWidth: true
+                            TextArea {
+                                id: userInstruct
+                                text: model ? model.instructionText : ""
+                                textFormat: Text.AutoText
+                                font.pixelSize: instructionBox.height * proportion.textHeight
+                                color: instructionTitle.color
+                                leftPadding: instructionPadding(model)
+                                rightPadding: instructionPadding(model)
+                                topPadding: instructionPadding(model)
+                                bottomPadding: instructionPadding(model)
+                                wrapMode: TextArea.WordWrap
+                                readOnly: true
+                                selectByMouse: true
+                            }
+                        }
+                    }
+                }
+            }
+
+            Item {
+                Layout.fillWidth: true
+                Layout.preferredHeight: parent.height * proportion.control
+                Layout.minimumHeight: 30
+                Layout.maximumHeight: 100
+                Button {
+                    anchors.fill: parent
+                    id: leftButton
+                    text: model ? model.control.leftButton.text : ""
+                    enabled: model ? model.control.leftButton.enabled : false
+                    font.pixelSize: parent.height * 0.7
+                    onClicked: {
+                        onControlClick(model.control.leftButton.text)
+                    }
+                    contentItem: Text {
+                        text: leftButton.text
+                        font: leftButton.font
+                        opacity: enabled ? 1.0 : 0.3
+                        horizontalAlignment: Text.AlignHCenter
+                        verticalAlignment: Text.AlignVCenter
+                        elide: Text.ElideNone
+                        clip: true
+                    }
+                }
+            }
+
+            Item {
+                Layout.fillWidth: true
+                Layout.preferredHeight: parent.height * proportion.control
+                Layout.minimumHeight: 30
+                Layout.maximumHeight: 100
+                Button {
+                    id: rightButton
+                    anchors.fill: parent
+                    text: model ? model.control.rightButton.text : ""
+                    enabled: model ? model.control.rightButton.enabled : false
+                    antialiasing: true
+                    transformOrigin: Item.Right
+                    checkable: false
+                    checked: false
+                    highlighted: true
+                    font.pixelSize: parent.height * 0.7
+                    onClicked: onControlClick(model.control.rightButton.text)
+                    contentItem: Text {
+                        text: rightButton.text
+                        font: rightButton.font
+                        opacity: enabled ? 1.0 : 0.3
+                        horizontalAlignment: Text.AlignHCenter
+                        verticalAlignment: Text.AlignVCenter
+                        elide: Text.ElideNone
+                        clip: true
+                    }
+                }
+            }
+        }
+    }
+    function onControlClick(control) {
+        model.control.onControl(control)
+    }
+    function backColour(model) {
+        var colour = rectangleBase.color
+        if (Boolean(model) && model.instructionTitle === "ERROR" ) {
+            colour = instructionWidget.color
+        } else if (Boolean(model) && model.enabled && model.instructionText) {
+            colour = instructionWidget.color
+        }
+        return (colour)
+    }
+    function instructionPadding(model) {
+        var padding = 4
+        if (Boolean(model) && model.enabled && model.instructionText) {
+            var instruction = model.instructionText.toLowerCase()
+            if (instruction.includes("html")) {
+                padding = 0
+            }
+        }
+        return (padding)
+    }
+    function controlEnabled() {
+        return (model && (model.control.rightButton.enabled || model.control.leftButton.enabled))
+    }
+}

testexecutor/ui/KeyValueItem.qml

@@ -0,0 +1,194 @@
+/*
+ * Copyright 2020 Direkt, Australia
+ * Copyright 2021 Direkt Embedded Pty Ltd
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ * http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ */
+
+import QtQuick
+import QtQuick.Layouts
+import QtQuick.Controls
+
+Item {
+    id: keyValueItem
+    width:parent.width
+    height: 40
+    clip: true
+    property var config: KeyValueItemConfig {}
+
+    Binding {
+        target: model.value
+        property: "value"
+        value: valueIsArray() ? comboControl.currentText : identifier.text
+    }
+
+    Rectangle {
+        id: rectangle
+        width: parent.width
+        color: config.color
+        border.width: 1
+        border.color: config.border.color
+        anchors.fill: parent
+
+        RowLayout {
+            id: row
+            height: parent.height
+            spacing: 1.5
+            anchors.fill: parent
+
+            Rectangle {
+                id: keyLabelRectangle
+                Layout.preferredWidth: parent.width * config.proportion.name
+                color: config.name.color
+                Layout.alignment: Qt.AlignLeft | Qt.AlignTop
+                border.color: config.name.border.color
+                border.width: 1
+                Layout.fillHeight: true
+
+                Text {
+                    id: identifierName
+                    color: config.name.text.color
+                    text: value.label
+                    verticalAlignment: Text.AlignVCenter
+                    anchors.rightMargin: 2
+                    anchors.fill: parent
+                    font.pixelSize: parent.height * 0.7
+                    minimumPixelSize: 10
+                    elide: Text.ElideLeft
+                    horizontalAlignment: Text.AlignRight
+                    ToolTip {
+                        visible: identifierName.truncated ? mouseArea.containsMouse : false
+                        timeout: 3000
+                        delay: 500
+                        contentItem:
+                            Column {
+                                Text {
+                                    text: identifierName.text
+                                    font.pixelSize: identifier.height
+                                    font.weight: Font.ExtraBold
+                                }
+                            }
+                    }
+                    MouseArea {
+                        id: mouseArea
+                        anchors.fill: parent
+                        hoverEnabled: true
+                    }
+                }
+            }
+
+            Rectangle {
+                id: valueRectangle
+                Layout.fillHeight: true
+                color: config.value.color
+                Layout.fillWidth: true
+                border.width: 1
+                border.color: config.value.border.color
+                ComboBox {
+                    id: comboControl
+                    implicitHeight: parent.height
+                    height: parent.height * 1.2
+                    width: parent.width
+                    font.pixelSize: parent.height * 0.85
+                    model: possibles
+                    visible: valueIsArray()
+                    bottomPadding: height * 0.3
+                    leftPadding: 2
+                    rightPadding: 0
+                    contentItem: Text {
+                        leftPadding: 0
+                        rightPadding: comboControl.indicator ? comboControl.indicator.width + comboControl.spacing : 0
+                        text: comboControl.displayText
+                        font: comboControl.font
+                        verticalAlignment: Text.AlignVCenter
+                        elide: Text.ElideRight
+                    }
+                    ToolTip {
+                        visible: comboControl.currentText ? comboControl.hovered : false
+                        timeout: 3000
+                        delay: 500
+                        contentItem:
+                            Column {
+                                Text {
+                                    text: comboControl.currentText
+                                    font.pixelSize: identifier.height
+                                    font.weight: Font.ExtraBold
+                                }
+                            }
+                    }
+
+                    delegate: ItemDelegate {
+                        width: comboControl.width
+                        contentItem: Text {
+                            text: modelData
+                            font: comboControl.font
+                            elide: Text.ElideRight
+                            verticalAlignment: Text.AlignVCenter
+                            padding: 0
+                        }
+                        highlighted: comboControl.highlightedIndex === index
+                    }
+                    background: Rectangle {
+                        border.width: 1
+                        border.color: config.value.border.color
+                    }
+                }
+
+                TextInput {
+                    id: identifier
+                    text: value.value
+                    color: config.value.text.color
+                    visible: !valueIsArray()
+                    activeFocusOnPress: false
+                    autoScroll: true
+                    clip: true
+                    font.pixelSize: parent.height / 1.2
+                    anchors.rightMargin: 0
+                    anchors.leftMargin: 3
+                    anchors.fill: parent
+                    ToolTip {
+                        visible: parent.text ? identifierMouseArea.containsMouse : false
+                        timeout: 3000
+                        delay: 500
+                        contentItem:
+                            Column {
+                                Text {
+                                    text: identifier.text
+                                    font.pixelSize: identifier.height
+                                    font.weight: Font.ExtraBold
+                                }
+                            }
+                    }
+                    MouseArea {
+                        id: identifierMouseArea
+                        anchors.fill: parent
+                        hoverEnabled: true
+                    }
+                }
+            }
+        }
+    }
+
+    Component.onCompleted: parseConfigStr()
+
+    function valueIsArray() {
+        return (possibles.length > 1) ? true : false;
+    }
+    function parseConfigStr() {
+        if (typeof contextKeyValueItemConfig !== "undefined") {
+            var json = JSON.parse(contextKeyValueItemConfig)
+            keyValueItem.config = json
+        }
+    }
+}
+

testexecutor/ui/KeyValueItemConfig.qml

@@ -0,0 +1,41 @@
+/*
+ * Copyright 2020 Direkt, Australia
+ * Copyright 2021 Direkt Embedded Pty Ltd
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ * http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ */
+
+import QtQuick
+
+Item {
+    /*
+     * Define the proportions for the widths of the test result items.
+     * The feedback area is not defined and will fill any remaining area.
+     */
+    property var proportion: {
+        "name": 0.3
+        // value fill remaining space
+    }
+    property var color: "#605b5b"
+    property var border: {"color": "#00000000"}
+    property var name: {
+        "color": "#00000000",
+        "text": {"color": "#e5e2e2"},
+        "border": {"color": "#00000000"},
+    }
+    property var value: {
+        "color": "#ffffff",
+        "border": {"color": "#b9e5e2e2"},
+        "text": {"color": "black"}
+    }
+}

testexecutor/ui/KeyValueList.qml

@@ -0,0 +1,49 @@
+/*
+ * Copyright 2020 Direkt, Australia
+ * Copyright 2021 Direkt Embedded Pty Ltd
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ * http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ */
+
+import QtQuick
+
+Item {
+    id: keyValueList
+    width: 400
+    clip: true
+    property var keyvalues
+    property int viewableCount: -1
+    property var itemConfig
+
+    Rectangle {
+        id: keyValueRectangle
+        anchors.fill: parent
+
+        ListView {
+            id: keyValueListView
+            clip: true
+            snapMode: ListView.NoSnap
+            boundsBehavior: Flickable.StopAtBounds
+            anchors.fill: parent
+            delegate: KeyValueItem {
+                height: (viewableCount <= 0) ? (keyValueListView.height / keyValueListView.count) : (keyValueListView.height / viewableCount)
+                Component.onCompleted: {
+                    if (keyValueList.itemConfig) {
+                        config = keyValueList.itemConfig
+                    }
+                }
+            }
+            model: keyvalues
+        }
+    }
+}

testexecutor/ui/MultiTestWidget.qml

@@ -0,0 +1,48 @@
+/*
+ * Copyright 2020 Direkt, Australia
+ * Copyright 2021 Direkt Embedded Pty Ltd
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ * http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ */
+
+import QtQuick
+
+Item {
+    property var test_suites
+    anchors.fill: parent
+    Row {
+        id: suiteRows
+        spacing: 2
+        clip: false
+        anchors.fill: parent
+        Repeater {
+            id: testSuiteRepeater
+            anchors.fill: parent
+            model: test_suites
+            delegate: TestSuiteController {
+                tswModel: model
+                cntrlModel: model.testsuite.controller
+                width: parent.width / testSuiteRepeater.count - 1
+                height: parent.height
+                Component.onCompleted: {
+                    if (app_model.config) {
+                        var json = JSON.parse(app_model.config)
+                        config = json
+                        controllerConfig = json.controller
+                    }
+                    about = app_model.about
+                }
+            }
+        }
+    }
+}

testexecutor/ui/MultiTestWindow.qml

@@ -0,0 +1,88 @@
+/*
+ * Copyright 2020 Direkt, Australia
+ * Copyright 2021 Direkt Embedded Pty Ltd
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ * http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ */
+
+import QtQuick
+import QtQuick.Controls
+import QtQuick.Dialogs
+
+ApplicationWindow {
+    id: application
+    title: (app_model) ? app_model.title : "Test Executor"
+    visible: true
+    width: 1200
+    height: 800
+    visibility: (app_model && app_model.visibility) ? app_model.visibility : "Maximized"
+    MultiTestWidget {
+        test_suites: model_list
+    }
+    onClosing: function(close) {
+        if (model_list.active_suites) {
+            close.accepted = false
+            if (Boolean(app_model) && app_model.allowAbort) {
+                activeSuitesDialog.open()
+            } else {
+                closeToolTip.open()
+            }
+        } else {
+            app_model.abortAll(true)
+            close.accepted = true
+        }
+    }
+
+    ToolTip {
+        id: closeToolTip
+        timeout: 2000
+        background: Rectangle {
+            border.color: "red"
+            color: "yellow"
+        }
+        contentItem:
+            Column {
+                Text {
+                    text: (app_model) ? app_model.closeHeading : "There Are Still Tests Running"
+                    font.pixelSize: application.height * 0.03
+                    font.weight: Font.ExtraBold
+                }
+                Text {
+                    text: (app_model) ? app_model.closeText : "Stop all suites if you want to quit"
+                    font.pixelSize: application.height * 0.03
+                    font.weight: Font.ExtraBold
+                }
+            }
+    }
+
+    Dialog {
+        id: activeSuitesDialog
+        title: (app_model) ? app_model.closeHeading : "There Are Still Tests Running"
+        Label {
+            id: label
+            text: (app_model) ? app_model.closeText : "Do you want to abort all tests?"
+            font.pixelSize: application.width * 0.02 > 11 ? application.width * 0.02:11
+        }
+        font.pixelSize: application.width * 0.02 > 11 ? application.width * 0.02:11
+        standardButtons: Dialog.Yes | Dialog.No
+        onAccepted: {
+            app_model.abortAll(false)
+            app_model.abortAll(false)
+        }
+        width: label.width * 1.05
+        x: (parent.width - width) / 2
+        y: (parent.height - height) / 2
+        implicitWidth: width
+    }
+}
+