iris-pex-embedded-python 2.3.16__py3-none-any.whl → 2.3.18__py3-none-any.whl

grongier/iris/Grongier/PEX/BusinessOperation.cls

@@ -0,0 +1,33 @@
+/* Copyright (c) 2021 by InterSystems Corporation.
+   Cambridge, Massachusetts, U.S.A.  All rights reserved.
+   Confidential property of InterSystems Corporation. */
+
+Class Grongier.PEX.BusinessOperation Extends (Ens.BusinessOperation, Grongier.PEX.Common) [ Inheritance = right, ProcedureBlock, System = 4 ]
+{
+
+Parameter SETTINGS = "%classname:Python BusinessOperation,%module:Python BusinessOperation,%settings:Python BusinessOperation,%classpaths:Python BusinessOperation";
+
+Method OnMessage(request As %Library.Persistent, Output response As %Library.Persistent) As %Status
+{
+	set tSC = $$$OK
+	try {
+		set response = ..%class."_dispatch_on_message"(request)
+	} catch ex {
+		set tSC = ex.AsStatus()
+	}
+	quit tSC
+}
+
+Method OnKeepalive(pStatus As %Status = {$$$OK}) As %Status
+{
+	set tSC = $$$OK
+	try {
+		$$$ThrowOnError(##super(pStatus))
+		do ..%class."on_keepalive"()
+	} catch ex {
+		set tSC = ex.AsStatus()
+	}
+	quit tSC
+}
+
+}

grongier/iris/Grongier/PEX/BusinessProcess.cls

@@ -0,0 +1,100 @@
+/* Copyright (c) 2021 by InterSystems Corporation.
+   Cambridge, Massachusetts, U.S.A.  All rights reserved.
+   Confidential property of InterSystems Corporation. */
+
+Class Grongier.PEX.BusinessProcess Extends (Ens.BusinessProcess, Grongier.PEX.Common) [ Inheritance = right, ProcedureBlock, System = 4 ]
+{
+
+Parameter SETTINGS = "%classname:Python BusinessProcess,%module:Python BusinessProcess,%settings:Python BusinessProcess,%classpaths:Python BusinessProcess";
+
+Property persistentProperties As array Of %String(MAXLEN = "");
+
+Method dispatchReply(response)
+{
+	set tSC = ..Reply(response)
+	if $$$ISERR(tSC) throw ##class(%Exception.StatusException).CreateFromStatus(tSC)
+	quit
+}
+
+Method dispatchSetTimer(timeout, completionKey)
+{
+	set tSC = ..SetTimer(timeout,$g(completionKey))
+	if $$$ISERR(tSC) throw ##class(%Exception.StatusException).CreateFromStatus(tSC)
+	quit
+}
+
+Method OnRequest(request As %Persistent, Output response As %Persistent) As %Status
+{
+	set tSC = $$$OK
+	try {
+		set response = ..%class."_dispatch_on_request"($this,request)
+	} catch ex {
+		set tSC = ex.AsStatus()
+	}
+	quit tSC
+}
+
+/// Handle a 'Response'
+Method OnResponse(request As %Persistent, Output response As %Persistent, callRequest As %Persistent, callResponse As %Persistent, pCompletionKey As %String) As %Status
+{
+	set tSC = $$$OK
+	try {
+		set response = ..%class."_dispatch_on_response"($this,request,response,callRequest,callResponse,pCompletionKey)
+	} catch ex {
+		set tSC = ex.AsStatus()
+	}
+	quit tSC
+}
+
+Method OnComplete(request As %Library.Persistent, ByRef response As %Library.Persistent) As %Status
+{
+	set tSC = $$$OK
+	try {
+		set tSC = ..Connect() quit:$$$ISERR(tSC)
+		set response = ..%class."_dispatch_on_complete"($this,request,response)
+	} catch ex {
+		set tSC = ex.AsStatus()
+	}
+	quit tSC
+}
+
+Method getPersistentProperty(name)
+{
+	quit ..persistentProperties.GetAt(name)
+}
+
+Method setPersistentProperty(name, value)
+{
+	quit ..persistentProperties.SetAt(value,name)
+}
+
+Storage Default
+{
+<Data name="BusinessProcessDefaultData1">
+<Subscript>"BusinessProcess"</Subscript>
+<Value name="1">
+<Value>%classpaths</Value>
+</Value>
+<Value name="2">
+<Value>%classname</Value>
+</Value>
+<Value name="3">
+<Value>%module</Value>
+</Value>
+<Value name="4">
+<Value>%settings</Value>
+</Value>
+<Value name="5">
+<Value>%class</Value>
+</Value>
+</Data>
+<Data name="persistentProperties">
+<Attribute>persistentProperties</Attribute>
+<Structure>subnode</Structure>
+<Subscript>"Grongier.PEX.BusinessProcess.persistentProperties"</Subscript>
+</Data>
+<DefaultData>BusinessProcessDefaultData1</DefaultData>
+<Type>%Storage.Persistent</Type>
+}
+
+}

grongier/iris/Grongier/PEX/BusinessService.cls

@@ -0,0 +1,33 @@
+/* Copyright (c) 2021 by InterSystems Corporation.
+   Cambridge, Massachusetts, U.S.A.  All rights reserved.
+   Confidential property of InterSystems Corporation. */
+
+Class Grongier.PEX.BusinessService Extends (Ens.BusinessService, Grongier.PEX.Common) [ Inheritance = right, ProcedureBlock, System = 4 ]
+{
+
+Parameter SETTINGS = "%classname:Python BusinessService,%module:Python BusinessService,%settings:Python BusinessService,%classpaths:Python BusinessService";
+
+Method dispatchProcessInput(pInput As %RegisteredObject) As %RegisteredObject
+{
+	
+	quit ..%class."on_process_input"(pInput)
+}
+
+Method OnProcessInput(request As %RegisteredObject, Output response As %RegisteredObject) As %Status
+{
+	set tSC = $$$OK
+	try {
+		try {
+			set ..%class."_wait_for_next_call_interval" = ..%WaitForNextCallInterval
+		} catch {}
+		set response = ..%class."_dispatch_on_process_input"(request)
+		try {
+			set ..%WaitForNextCallInterval = ..%class."_wait_for_next_call_interval"
+		} catch {}
+	} catch ex {
+		set tSC = ex.AsStatus()
+	}
+	quit tSC
+}
+
+}

grongier/iris/Grongier/PEX/Common.cls

@@ -0,0 +1,133 @@
+/* Copyright (c) 2021 by InterSystems Corporation.
+   Cambridge, Massachusetts, U.S.A.  All rights reserved.
+   Confidential property of InterSystems Corporation. */
+
+Include Ensemble
+
+Class Grongier.PEX.Common [ Abstract, ClassType = "", ProcedureBlock, System = 4 ]
+{
+
+/// One or more Classpaths (separated by '|' character) needed in addition to the ones configured in the Java Gateway Service
+Property %classpaths As %String(MAXLEN = "");
+
+Property %classname As %String(MAXLEN = "");
+
+Property %module As %String(MAXLEN = "");
+
+Property %settings As %String(MAXLEN = "");
+
+/// Instance of class
+Property %class As %SYS.Python;
+
+/// Get Class
+Method GetClass() As %SYS.Python
+{
+	Return ..%class
+}
+
+/// Get Classname
+Method GetClassname() As %String
+{
+	Return ..%classname
+}
+
+/// Get Classname
+Method GetModule() As %String
+{
+	Return ..%module
+}
+
+Method OnInit() As %Status
+{
+	set tSC = $$$OK
+	try {
+        $$$ThrowOnError(..Connect())
+		do ..%class."_dispatch_on_init"($this)
+	} catch ex {
+		set tSC = ex.AsStatus()
+	}
+	quit tSC
+}
+
+Method Connect() As %Status
+{
+	set tSC = $$$OK
+	try {
+		
+		set container = $this
+		
+		//set classpass
+		if ..%classpaths '="" {
+			set delimiter = $s($system.Version.GetOS()="Windows":";",1:":")
+			set extraClasspaths = $tr(container.%classpaths,delimiter,"|")
+			for i=1:1:$l(extraClasspaths,"|") {
+				set onePath = $p(extraClasspaths,"|",i)
+				if onePath?1"$$IRISHOME"1P.E set onePath = $e($system.Util.InstallDirectory(),1,*-1)_$e(onePath,11,*)
+				if onePath'="" do ##class(Grongier.PEX.Python).SetClassPath(onePath)
+			}
+		}
+		if $isObject(..%class)=0 {
+			set ..%class = ##class(Grongier.PEX.Python).GetInstanceFromModuleClassName(..%module,..%classname)
+		}
+		;
+		if ..%Extends("Grongier.PEX.InboundAdapter") || ..%Extends("Grongier.PEX.OutboundAdapter") {
+			do ..%class."_set_iris_handles"($this,..BusinessHost)
+		} elseif $this.%Extends("Grongier.PEX.BusinessProcess") {
+			do ..%class."_set_iris_handles"($this,$$$NULLOREF)
+		} else {
+			do ..%class."_set_iris_handles"($this,..Adapter)
+		}
+		;
+		do ..SetPropertyValues()
+		;
+		try {
+			do ..%class."_dispatch_on_connected"($this)
+		} catch ex {
+			$$$LOGWARNING(ex.DisplayString())
+		}
+		;
+	} catch ex {
+		set msg = $System.Status.GetOneStatusText(ex.AsStatus(),1)
+		set tSC = $$$ERROR($$$EnsErrGeneral,msg)
+	}
+	quit tSC
+}
+
+Method OnTearDown() As %Status
+{
+	set tSC = $$$OK
+    do ..%class."_dispatch_on_tear_down"()
+	quit tSC
+}
+
+Method SetPropertyValues()
+{
+	set remoteSettings = $tr(..%settings,$c(13))
+	for i=1:1:$l(remoteSettings,$c(10)) {
+		set oneLine = $p(remoteSettings,$c(10),i)
+		set property = $p(oneLine,"=",1) continue:property=""
+		set value = $p(oneLine,"=",2,*)
+		try {
+			set $property(..%class,property) = value
+		} catch ex {
+			$$$LOGWARNING(ex.DisplayString())
+		}
+	}
+	quit
+}
+
+Method dispatchSendRequestSync(target, request, timeout, description) As %String
+{
+	set tSC = ..SendRequestSync(target,request,.objResponse,timeout,description)
+	if $$$ISERR(tSC) throw ##class(%Exception.StatusException).CreateFromStatus(tSC)
+	quit $g(objResponse)
+}
+
+Method dispatchSendRequestAsync(target, request, description)
+{
+	set tSC = ..SendRequestAsync(target,request,description)
+	if $$$ISERR(tSC) throw ##class(%Exception.StatusException).CreateFromStatus(tSC)
+	quit
+}
+
+}

grongier/iris/Grongier/PEX/Director.cls

@@ -0,0 +1,15 @@
+/* Copyright (c) 2021 by InterSystems Corporation.
+   Cambridge, Massachusetts, U.S.A.  All rights reserved.
+   Confidential property of InterSystems Corporation. */
+
+Class Grongier.PEX.Director [ Inheritance = right, ProcedureBlock, System = 4 ]
+{
+
+ClassMethod dispatchCreateBusinessService(pTargetDispatchName As %String) As Ens.BusinessService
+{
+	set tSC = ##class(Ens.Director).CreateBusinessService(pTargetDispatchName,.service)
+	if $$$ISERR(tSC) throw ##class(%Exception.StatusException).CreateFromStatus(tSC)
+	quit service
+}
+
+}

grongier/iris/Grongier/PEX/Duplex/Operation.cls

@@ -0,0 +1,27 @@
+Class Grongier.PEX.DuplexOperation Extends Grongier.PEX.PrivateSessionDuplex
+{
+
+ClassMethod OnBusinessType(pItem As Ens.Config.Item) As %Integer
+{
+    Quit $$$eHostTypeOperation
+}
+
+XData MessageMap
+{
+<MapItems>
+<MapItem MessageType="Ens.Request"><Method>OnMessage</Method></MapItem>
+</MapItems>
+}
+
+Method OnMessage(request As %Library.Persistent, Output response As %Library.Persistent) As %Status
+{
+	set tSC = $$$OK
+	try {
+		set response = ..%class."_dispatch_on_message"(request)
+	} catch ex {
+		set tSC = ex.AsStatus()
+	}
+	quit tSC
+}
+
+}

grongier/iris/Grongier/PEX/Duplex/Process.cls

@@ -0,0 +1,211 @@
+/* Copyright (c) 2022 by InterSystems Corporation.
+   Cambridge, Massachusetts, U.S.A.  All rights reserved.
+   Confidential property of InterSystems Corporation. */
+
+Class Grongier.PEX.DuplexProcess Extends Grongier.PEX.BusinessProcess [ ClassType = persistent, ProcedureBlock, System = 4 ]
+{
+
+/// Domain for Text localization
+Parameter DOMAIN = "PrivateSession";
+
+/// The Duplex Service name. This property is set at runtime after receiving the primary request
+Property ServiceDuplexName As %String;
+
+/// Indicates if a given ConfigItem is in private session or not
+Property %IsInPrivateSession As array Of %Boolean(STORAGEDEFAULT = "list");
+
+/// This method is always called asynchronously ONCE at the beginning of the process
+Method OnRequest(pRequest As %Library.Persistent, Output pResponse As Ens.Response) As %Status
+{
+	#dim tSC As %Status = $$$OK
+	try {
+		If $IsObject(pRequest)&&($classname(pRequest)="Grongier.PEX.PrivateSession.Message.Start") {
+			Set tSC=..Reply(##class(Grongier.PEX.PrivateSession.Message.Ack).%New()) Quit:$$$ISERR(tSC)
+			Set ..ServiceDuplexName = ..%PrimaryRequestHeader.SourceConfigName
+			Do ..IsInPrivateSessionSet(..ServiceDuplexName,1)
+			Set tSC=..SendRequestAsync(..ServiceDuplexName,##class(Grongier.PEX.PrivateSession.Message.Poll).%New(),1) Quit:$$$ISERR(tSC)
+			Set tSC=..OnPrivateSessionStarted(..ServiceDuplexName,0) Quit:$$$ISERR(tSC)
+		} Else {
+			Set tSC=..OnDocument(..%PrimaryRequestHeader.SourceConfigName,pRequest)
+		}
+	} catch {
+		Set tSC=$$$EnsSystemError
+	}
+	Quit tSC
+}
+
+/// Handle a 'Response'
+Method OnResponse(request As %Library.Persistent, ByRef response As %Library.Persistent, callrequest As %Library.Persistent, callresponse As %Library.Persistent, pCompletionKey As %String) As %Status
+{
+	#dim tSC As %Status = $$$OK
+	#dim tSourceConfigName, tOneConfigName As %String
+	try {
+		; get the SourceConfigName of this message
+		Set tSourceConfigName=..%CurrentResponseHeader.SourceConfigName
+		; handle SessionStop message
+		If $IsObject(callresponse)&&($classname(callresponse)="Grongier.PEX.PrivateSession.Message.Ack") {
+			Do ..IsInPrivateSessionSet(tSourceConfigName,1)
+			Set tSC=..SendRequestAsync(tSourceConfigName,##class(Grongier.PEX.PrivateSession.Message.Poll).%New(),1) Quit:$$$ISERR(tSC)
+			Set tSC=..OnPrivateSessionStarted(tSourceConfigName,1) Quit:$$$ISERR(tSC)
+			Quit
+		}
+		; handle SessionStop message
+		If $IsObject(callresponse)&&($classname(callresponse)="Grongier.PEX.PrivateSession.Message.Stop") {
+			Set tSC=..UnRegisterPrivateSession(tSourceConfigName) Quit:$$$ISERR(tSC)
+			Set tSC=..OnPrivateSessionStopped(tSourceConfigName,0,callresponse.AttachedMessage) Quit:$$$ISERR(tSC)
+			Quit
+		}
+		; send poll request again back to the same ConfigItem if this this is in response to a poll request
+		If $IsObject(callrequest)&&($classname(callrequest)="Grongier.PEX.PrivateSession.Message.Poll") {
+			If ..IsInPrivateSession(tSourceConfigName) {
+				Set tSC=..SendRequestAsync(tSourceConfigName,##class(Grongier.PEX.PrivateSession.Message.Poll).%New(),1) If $$$ISERR(tSC)
+			}
+		}
+		; call OnDocument
+		Set tSC=..OnDocument(tSourceConfigName,callresponse) Quit:$$$ISERR(tSC)
+	} catch {
+		Set tSC=$$$EnsSystemError
+	}
+	Quit tSC
+}
+
+Method StartPrivateSession(pDuplexConfigName As %String = "") As %Status
+{
+	#dim tSC As %Status = $$$OK
+	try {
+		If pDuplexConfigName="" Set tSC=$$$EnsError($$$EnsErrGeneral,"Duplex configuration name is missing") Quit
+		If ..IsInPrivateSession(pDuplexConfigName) Quit
+		Set tSC=..SendRequestAsync(pDuplexConfigName,##class(Grongier.PEX.PrivateSession.Message.Start).%New()) Quit:$$$ISERR(tSC)
+	} catch {
+		Set tSC=$$$EnsSystemError
+	}
+	Quit tSC
+}
+
+Method StopPrivateSession(pDuplexConfigName As %String = "", pAttachedMessage As %Persistent = "") As %Status
+{
+	#dim tSC As %Status = $$$OK
+	try {
+		If pDuplexConfigName="" Set tSC=$$$EnsError($$$EnsErrGeneral,"Duplex configuration name is missing") Quit
+		If '..IsInPrivateSession(pDuplexConfigName) Quit
+		Set tSC=..SendRequestAsync(pDuplexConfigName,##class(Grongier.PEX.PrivateSession.Message.Stop).%New(pAttachedMessage),0) Quit:$$$ISERR(tSC)
+		Set tSC=..UnRegisterPrivateSession(pDuplexConfigName)
+		Set tSC=..OnPrivateSessionStopped(pDuplexConfigName,1) Quit:$$$ISERR(tSC)
+	} catch {
+		Set tSC=$$$EnsSystemError
+	}
+	Quit tSC
+}
+
+Method StopAllPrivateSessions(pAttachedMessage As %Persistent = "") As %Status
+{
+	#dim tSC As %Status = $$$OK
+	#dim tItem As %String
+	try {
+		Set tItem="" For  {
+			Set tItem=..%IsInPrivateSession.Next(tItem) Quit:tItem=""
+			Set tSC=..StopPrivateSession(tItem,pAttachedMessage) Quit:$$$ISERR(tSC)
+		}
+	} catch {
+		Set tSC=$$$EnsSystemError
+	}
+	Quit tSC
+}
+
+Method UnRegisterPrivateSession(pDuplexConfigName As %String) As %String
+{
+	#dim tSC As %Status = $$$OK
+	try {
+		For i=..%MasterPendingResponses.Count():-1:1 {
+			Set tRequestHeader=##class(Ens.MessageHeader).%OpenId($li(..%MasterPendingResponses.GetAt(i),1))
+			If $IsObject(tRequestHeader),tRequestHeader.TargetConfigName=pDuplexConfigName,tRequestHeader.MessageBodyClassName="Grongier.PEX.PrivateSession.Message.Poll" {
+				Do ..%MasterPendingResponses.RemoveAt(i)
+			}
+		}
+		Do ..IsInPrivateSessionSet(pDuplexConfigName,0)
+	} catch {
+		Set tSC=$$$EnsSystemError
+	}
+	Quit tSC
+}
+
+Method IsInPrivateSessionSet(pDuplexConfigName As %String, pInPrivateSession As %Boolean)
+{
+	If pInPrivateSession {
+		Do ..%IsInPrivateSession.SetAt(1,pDuplexConfigName)
+	} Else {
+		Do ..%IsInPrivateSession.RemoveAt(pDuplexConfigName)
+	}
+	Quit
+}
+
+Method IsInPrivateSession(pDuplexConfigName As %String) As %Boolean
+{
+	If pDuplexConfigName="" Quit 0
+	Quit ..%IsInPrivateSession.IsDefined(pDuplexConfigName)
+}
+
+Method OnDocument(pSourceConfigName As %String, pInput As %Library.Persistent) As %Status
+{
+	set tSC = $$$OK
+	try {
+		set response = ..%class."_dispatch_on_document"($this,pSourceConfigName,pInput)
+	} catch ex {
+		set tSC = ex.AsStatus()
+	}
+	quit tSC
+}
+
+Method OnPrivateSessionStarted(pSourceConfigName As %String, pSelfGenerated As %Boolean) As %Status
+{
+	set tSC = $$$OK
+	try {
+		set response = ..%class."_dispatch_on_private_session_started"($this,pSourceConfigName,pSelfGenerated)
+	} catch ex {
+		set tSC = ex.AsStatus()
+	}
+	quit tSC
+}
+
+Method OnPrivateSessionStopped(pSourceConfigName As %String, pSelfGenerated As %Boolean, pAttachedMessage As %Persistent = "") As %Status
+{
+	set tSC = $$$OK
+	try {
+		set response = ..%class."_dispatch_on_private_session_stopped"($this,pSourceConfigName,pSelfGenerated,pAttachedMessage)
+	} catch ex {
+		set tSC = ex.AsStatus()
+	}
+	quit tSC
+}
+
+Storage Default
+{
+<Data name="ProcessDefaultData">
+<Subscript>"Process"</Subscript>
+<Value name="1">
+<Value>ServiceDuplexName</Value>
+</Value>
+<Value name="2">
+<Value>%IsInPrivateSession</Value>
+</Value>
+<Value name="3">
+<Value>%classpaths</Value>
+</Value>
+<Value name="4">
+<Value>%classname</Value>
+</Value>
+<Value name="5">
+<Value>%module</Value>
+</Value>
+<Value name="6">
+<Value>%settings</Value>
+</Value>
+<Value name="7">
+<Value>%class</Value>
+</Value>
+</Data>
+<DefaultData>ProcessDefaultData</DefaultData>
+<Type>%Storage.Persistent</Type>
+}
+
+}

grongier/iris/Grongier/PEX/Duplex/Service.cls

@@ -0,0 +1,9 @@
+Class Grongier.PEX.DuplexService Extends Grongier.PEX.PrivateSessionDuplex
+{
+
+ClassMethod OnBusinessType(pItem As Ens.Config.Item) As %Integer
+{
+    Quit $$$eHostTypeService
+}
+
+}

grongier/iris/Grongier/PEX/InboundAdapter.cls

@@ -0,0 +1,22 @@
+/* Copyright (c) 2021 by InterSystems Corporation.
+   Cambridge, Massachusetts, U.S.A.  All rights reserved.
+   Confidential property of InterSystems Corporation. */
+
+Class Grongier.PEX.InboundAdapter Extends (Ens.InboundAdapter, Grongier.PEX.Common) [ Inheritance = right, ProcedureBlock, System = 4 ]
+{
+
+Parameter SETTINGS = "%classname:Python InboundAdapter,%module:Python InboundAdapter,%settings:Python InboundAdapter,%classpaths:Python InboundAdapter";
+
+Method OnTask() As %Status
+{
+	set tSC = $$$OK
+	try {
+		$$$ThrowOnError(..Connect())
+		do ..%class."on_task"()
+	} catch ex {
+		set tSC = ex.AsStatus()
+	}
+	quit tSC
+}
+
+}