usearch 2.8.7 → 2.8.9

package/objc/USearchObjective.mm

@@ -1,299 +0,0 @@
-#import "USearchObjective.h"
-
-#pragma clang diagnostic push
-#pragma clang diagnostic ignored "-Wdocumentation"
-#import <usearch/index_dense.hpp>
-#pragma clang diagnostic pop
-
-using namespace unum::usearch;
-using namespace unum;
-
-using distance_t = distance_punned_t;
-using add_result_t = typename index_dense_t::add_result_t;
-using labeling_result_t = typename index_dense_t::labeling_result_t;
-using search_result_t = typename index_dense_t::search_result_t;
-using shared_index_dense_t = std::shared_ptr<index_dense_t>;
-
-static_assert(std::is_same<USearchKey, index_dense_t::vector_key_t>::value, "Type mismatch between Objective-C and C++");
-
-metric_kind_t to_native_metric(USearchMetric m) {
-    switch (m) {
-        case USearchMetricIP:
-            return metric_kind_t::ip_k;
-
-        case USearchMetricCos:
-            return metric_kind_t::cos_k;
-
-        case USearchMetricL2sq:
-            return metric_kind_t::l2sq_k;
-
-        case USearchMetricHamming:
-            return metric_kind_t::hamming_k;
-
-        case USearchMetricHaversine:
-            return metric_kind_t::haversine_k;
-
-        case USearchMetricDivergence:
-            return metric_kind_t::divergence_k;
-
-        case USearchMetricJaccard:
-            return metric_kind_t::jaccard_k;
-
-        case USearchMetricPearson:
-            return metric_kind_t::pearson_k;
-
-        case USearchMetricSorensen:
-            return metric_kind_t::sorensen_k;
-
-        case USearchMetricTanimoto:
-            return metric_kind_t::tanimoto_k;
-
-        default:
-            return metric_kind_t::unknown_k;
-    }
-}
-
-scalar_kind_t to_native_scalar(USearchScalar m) {
-    switch (m) {
-        case USearchScalarI8:
-            return scalar_kind_t::i8_k;
-
-        case USearchScalarF16:
-            return scalar_kind_t::f16_k;
-
-        case USearchScalarF32:
-            return scalar_kind_t::f32_k;
-
-        case USearchScalarF64:
-            return scalar_kind_t::f64_k;
-
-        default:
-            return scalar_kind_t::unknown_k;
-    }
-}
-
-@interface USearchIndex ()
-
-@property (readonly) shared_index_dense_t native;
-
-- (instancetype)initWithIndex:(shared_index_dense_t)native;
-
-@end
-
-@implementation USearchIndex
-
-- (instancetype)initWithIndex:(shared_index_dense_t)native {
-    self = [super init];
-    _native = native;
-    return self;
-}
-
-- (Boolean)isEmpty {
-    return _native->size() != 0;
-}
-
-- (UInt32)dimensions {
-    return static_cast<UInt32>(_native->dimensions());
-}
-
-- (UInt32)connectivity {
-    return static_cast<UInt32>(_native->connectivity());
-}
-
-- (UInt32)length {
-    return static_cast<UInt32>(_native->size());
-}
-
-- (UInt32)capacity {
-    return static_cast<UInt32>(_native->capacity());
-}
-
-- (UInt32)expansionAdd {
-    return static_cast<UInt32>(_native->expansion_add());
-}
-
-- (UInt32)expansionSearch {
-    return static_cast<UInt32>(_native->expansion_search());
-}
-
-+ (instancetype)make:(USearchMetric)metricKind dimensions:(UInt32)dimensions connectivity:(UInt32)connectivity quantization:(USearchScalar)quantization {
-    std::size_t dims = static_cast<std::size_t>(dimensions);
-
-    index_config_t config(static_cast<std::size_t>(connectivity));
-    metric_punned_t metric(dims, to_native_metric(metricKind), to_native_scalar(quantization));
-    shared_index_dense_t ptr = std::make_shared<index_dense_t>(index_dense_t::make(metric, config));
-    return [[USearchIndex alloc] initWithIndex:ptr];
-}
-
-- (void)addSingle:(USearchKey)key
-           vector:(Float32 const *_Nonnull)vector {
-    add_result_t result = _native->add(key, vector);
-
-    if (!result) {
-        @throw [NSException exceptionWithName:@"Can't add to index"
-                                       reason:[NSString stringWithUTF8String:result.error.release()]
-                                     userInfo:nil];
-    }
-}
-
-- (UInt32)searchSingle:(Float32 const *_Nonnull)vector
-                 count:(UInt32)wanted
-                  keys:(USearchKey *_Nullable)keys
-             distances:(Float32 *_Nullable)distances {
-    search_result_t result = _native->search(vector, static_cast<std::size_t>(wanted));
-
-    if (!result) {
-        @throw [NSException exceptionWithName:@"Can't find in index"
-                                       reason:[NSString stringWithUTF8String:result.error.release()]
-                                     userInfo:nil];
-    }
-
-    std::size_t found = result.dump_to(keys, distances);
-    return static_cast<UInt32>(found);
-}
-
-- (void)addDouble:(USearchKey)key
-           vector:(Float64 const *_Nonnull)vector {
-    add_result_t result = _native->add(key, (f64_t const *)vector);
-
-    if (!result) {
-        @throw [NSException exceptionWithName:@"Can't add to index"
-                                       reason:[NSString stringWithUTF8String:result.error.release()]
-                                     userInfo:nil];
-    }
-}
-
-- (UInt32)searchDouble:(Float64 const *_Nonnull)vector
-                 count:(UInt32)wanted
-                  keys:(USearchKey *_Nullable)keys
-             distances:(Float32 *_Nullable)distances {
-    search_result_t result = _native->search((f64_t const *)vector, static_cast<std::size_t>(wanted));
-
-    if (!result) {
-        @throw [NSException exceptionWithName:@"Can't find in index"
-                                       reason:[NSString stringWithUTF8String:result.error.release()]
-                                     userInfo:nil];
-    }
-
-    std::size_t found = result.dump_to(keys, distances);
-    return static_cast<UInt32>(found);
-}
-
-- (void)addHalf:(USearchKey)key
-         vector:(void const *_Nonnull)vector {
-    add_result_t result = _native->add(key, (f16_t const *)vector);
-
-    if (!result) {
-        @throw [NSException exceptionWithName:@"Can't add to index"
-                                       reason:[NSString stringWithUTF8String:result.error.release()]
-                                     userInfo:nil];
-    }
-}
-
-- (UInt32)searchHalf:(void const *_Nonnull)vector
-               count:(UInt32)wanted
-                keys:(USearchKey *_Nullable)keys
-           distances:(Float32 *_Nullable)distances {
-    search_result_t result = _native->search((f16_t const *)vector, static_cast<std::size_t>(wanted));
-
-    if (!result) {
-        @throw [NSException exceptionWithName:@"Can't find in index"
-                                       reason:[NSString stringWithUTF8String:result.error.release()]
-                                     userInfo:nil];
-    }
-
-    std::size_t found = result.dump_to(keys, distances);
-    return static_cast<UInt32>(found);
-}
-
-- (void)clear {
-    _native->clear();
-}
-
-- (void)reserve:(UInt32)count {
-    _native->reserve(static_cast<std::size_t>(count));
-}
-
-- (Boolean)contains:(USearchKey)key {
-    return _native->contains(key);
-}
-
-- (UInt32)count:(USearchKey)key {
-    return _native->count(key);
-}
-
-- (void)remove:(USearchKey)key {
-    labeling_result_t result = _native->remove(key);
-
-    if (!result) {
-        @throw [NSException exceptionWithName:@"Can't remove an entry"
-                                       reason:[NSString stringWithUTF8String:result.error.release()]
-                                     userInfo:nil];
-    }
-}
-
-- (void)rename:(USearchKey)key to:(USearchKey)to {
-    labeling_result_t result = _native->rename(key, to);
-
-    if (!result) {
-        @throw [NSException exceptionWithName:@"Can't rename the entry"
-                                       reason:[NSString stringWithUTF8String:result.error.release()]
-                                     userInfo:nil];
-    }
-}
-
-- (void)save:(NSString *)path {
-    char const *path_c = [path UTF8String];
-
-    if (!path_c) {
-        @throw [NSException exceptionWithName:@"Can't save to disk"
-                                       reason:@"The path must be convertible to UTF8"
-                                     userInfo:nil];
-    }
-
-    serialization_result_t result = _native->save(path_c);
-
-    if (!result) {
-        @throw [NSException exceptionWithName:@"Can't save to disk"
-                                       reason:[NSString stringWithUTF8String:result.error.release()]
-                                     userInfo:nil];
-    }
-}
-
-- (void)load:(NSString *)path {
-    char const *path_c = [path UTF8String];
-
-    if (!path_c) {
-        @throw [NSException exceptionWithName:@"Can't load from disk"
-                                       reason:@"The path must be convertible to UTF8"
-                                     userInfo:nil];
-    }
-
-    serialization_result_t result = _native->load(path_c);
-
-    if (!result) {
-        @throw [NSException exceptionWithName:@"Can't load from disk"
-                                       reason:[NSString stringWithUTF8String:result.error.release()]
-                                     userInfo:nil];
-    }
-}
-
-- (void)view:(NSString *)path {
-    char const *path_c = [path UTF8String];
-
-    if (!path_c) {
-        @throw [NSException exceptionWithName:@"Can't view from disk"
-                                       reason:@"The path must be convertible to UTF8"
-                                     userInfo:nil];
-    }
-
-    serialization_result_t result = _native->view(path_c);
-
-    if (!result) {
-        @throw [NSException exceptionWithName:@"Can't view from disk"
-                                       reason:[NSString stringWithUTF8String:result.error.release()]
-                                     userInfo:nil];
-    }
-}
-
-@end

package/objc/include/USearchObjective.h

@@ -1,154 +0,0 @@
-#pragma once
-
-#import <Foundation/Foundation.h>
-
-NS_ASSUME_NONNULL_BEGIN
-
-typedef NS_ENUM(NSUInteger, USearchScalar) {
-    USearchScalarF32,
-    USearchScalarF16,
-    USearchScalarF64,
-    USearchScalarI8,
-    USearchScalarB1
-};
-
-typedef NS_ENUM(NSUInteger, USearchMetric) {
-    USearchMetricUnknown,
-    USearchMetricIP,
-    USearchMetricCos,
-    USearchMetricL2sq,
-    USearchMetricPearson,
-    USearchMetricHaversine,
-    USearchMetricDivergence,
-    USearchMetricJaccard,
-    USearchMetricHamming,
-    USearchMetricTanimoto,
-    USearchMetricSorensen
-};
-
-typedef UInt64 USearchKey;
-
-API_AVAILABLE(ios(13.0), macos(10.15), tvos(13.0), watchos(6.0))
-@interface USearchIndex : NSObject
-
-@property (readonly) UInt32 dimensions;
-@property (readonly) UInt32 connectivity;
-@property (readonly) UInt32 expansionAdd;
-@property (readonly) UInt32 expansionSearch;
-
-@property (readonly) UInt32 length;
-@property (readonly) UInt32 capacity;
-@property (readonly) Boolean isEmpty;
-
-- (instancetype)init NS_UNAVAILABLE;
-
-/**
- * @brief Initializes a new index.
- * @param metric The distance function to compare the dis-similarity of vectors.
- * @param dimensions The number of dimensions planned for this index.
- * @param connectivity Number of connections per node in the proximity graph.
- * Higher connectivity improves quantization, increases memory usage, and reduces construction speed.
- * @param quantization Quantization of internal vector representations. Lower quantization means higher speed.
- */
-+ (instancetype)make:(USearchMetric)metric dimensions:(UInt32)dimensions connectivity:(UInt32)connectivity quantization:(USearchScalar)quantization NS_SWIFT_NAME(make(metric:dimensions:connectivity:quantization:));
-
-/**
- * @brief Pre-allocates space in the index for the given number of vectors.
- */
-- (void)reserve:(UInt32)count NS_SWIFT_NAME(reserve(_:));
-
-/**
- * @brief Adds a labeled vector to the index.
- * @param vector Single-precision vector.
- */
-- (void)addSingle:(USearchKey)key
-           vector:(Float32 const *_Nonnull)vector NS_SWIFT_NAME(addSingle(key:vector:));
-
-/**
- * @brief Approximate nearest neighbors search.
- * @param vector Single-precision query vector.
- * @param count Upper limit on the number of matches to retrieve.
- * @param keys Optional output buffer for keys of approximate neighbors.
- * @param distances Optional output buffer for (increasing) distances to approximate neighbors.
- * @return Number of matches exported to `keys` and `distances`.
- */
-- (UInt32)searchSingle:(Float32 const *_Nonnull)vector
-                 count:(UInt32)count
-                  keys:(USearchKey *_Nullable)keys
-             distances:(Float32 *_Nullable)distances NS_SWIFT_NAME(searchSingle(vector:count:keys:distances:));
-
-/**
- * @brief Adds a labeled vector to the index.
- * @param vector Double-precision vector.
- */
-- (void)addDouble:(USearchKey)key
-           vector:(Float64 const *_Nonnull)vector NS_SWIFT_NAME(addDouble(key:vector:));
-
-/**
- * @brief Approximate nearest neighbors search.
- * @param vector Double-precision query vector.
- * @param count Upper limit on the number of matches to retrieve.
- * @param keys Optional output buffer for keys of approximate neighbors.
- * @param distances Optional output buffer for (increasing) distances to approximate neighbors.
- * @return Number of matches exported to `keys` and `distances`.
- */
-- (UInt32)searchDouble:(Float64 const *_Nonnull)vector
-                 count:(UInt32)count
-                  keys:(USearchKey *_Nullable)keys
-             distances:(Float32 *_Nullable)distances NS_SWIFT_NAME(searchDouble(vector:count:keys:distances:));
-
-/**
- * @brief Adds a labeled vector to the index.
- * @param vector Half-precision vector.
- */
-- (void)addHalf:(USearchKey)key
-         vector:(void const *_Nonnull)vector NS_SWIFT_NAME(addHalf(key:vector:));
-
-/**
- * @brief Approximate nearest neighbors search.
- * @param vector Half-precision query vector.
- * @param count Upper limit on the number of matches to retrieve.
- * @param keys Optional output buffer for keys of approximate neighbors.
- * @param distances Optional output buffer for (increasing) distances to approximate neighbors.
- * @return Number of matches exported to `keys` and `distances`.
- */
-- (UInt32)searchHalf:(void const *_Nonnull)vector
-               count:(UInt32)count
-                keys:(USearchKey *_Nullable)keys
-           distances:(Float32 *_Nullable)distances NS_SWIFT_NAME(searchHalf(vector:count:keys:distances:));
-
-
-- (Boolean)contains:(USearchKey)key NS_SWIFT_NAME(contains(key:));
-
-- (UInt32)count:(USearchKey)key NS_SWIFT_NAME(count(key:));
-
-- (void)remove:(USearchKey)key NS_SWIFT_NAME(remove(key:));
-
-- (void)rename:(USearchKey)key to:(USearchKey)key NS_SWIFT_NAME(rename(from:to:));
-
-
-/**
- * @brief Saves pre-constructed index to disk.
- */
-- (void)save:(NSString *)path NS_SWIFT_NAME(save(path:));
-
-/**
- * @brief Loads a pre-constructed index from index.
- */
-- (void)load:(NSString *)path NS_SWIFT_NAME(load(path:));
-
-/**
- * @brief Views a pre-constructed index from disk without loading it into RAM.
- *        Allows working with larger-than memory indexes and saving scarce
- *        memory on device in read-only workloads.
- */
-- (void)view:(NSString *)path NS_SWIFT_NAME(view(path:));
-
-/**
- * @brief Removes all the data from index, while preserving the settings.
- */
-- (void)clear NS_SWIFT_NAME(clear());
-
-@end
-
-NS_ASSUME_NONNULL_END