ts-wasms 2.0.0 → 3.0.0

package/out/gleam/highlights.scm

@@ -0,0 +1,137 @@
+; Punctuation
+[
+  "("
+  ")"
+  "["
+  "]"
+  "{"
+  "}"
+  "<<"
+  ">>"
+] @punctuation.bracket
+[
+  "."
+  ","
+  ;; Controversial -- maybe some are operators?
+  ":"
+  "#"
+  "="
+  "->"
+  ".."
+  "-"
+  "<-"
+] @punctuation.delimiter
+
+; Variables
+(identifier) @variable
+(discard) @comment.unused
+
+; Comments
+(module_comment) @comment
+(statement_comment) @comment
+(comment) @comment
+
+; Constants
+(constant
+  name: (identifier) @constant)
+
+; "Properties"
+; Assumed to be intended to refer to a name for a field; something that comes
+; before ":" or after "."
+; e.g. record field names, tuple indices, names for named arguments, etc
+(label) @property
+(tuple_access
+  index: (integer) @property)
+
+; Modules
+(module) @module
+(import alias: (identifier) @module)
+(remote_type_identifier
+  module: (identifier) @module)
+(remote_constructor_name
+  module: (identifier) @module)
+
+; Functions
+(unqualified_import (identifier) @function)
+(unqualified_import "type" (type_identifier) @type)
+(unqualified_import (type_identifier) @constructor)
+(function
+  name: (identifier) @function)
+(external_function
+  name: (identifier) @function)
+(function_parameter
+  name: (identifier) @variable.parameter)
+((function_call
+   function: (identifier) @function)
+ (#is-not? local))
+((binary_expression
+   operator: "|>"
+   right: (identifier) @function)
+ (#is-not? local))
+
+; TODO: `#is-not? local` applies to entire patterns but ideally it would accept
+; a capture to check as a local. This needs to be suggested upstream. Until this
+; is a part of the CLI's highlighter we can't distinguish between function calls
+; on modules and accesses of record fields.
+(function_call function: (field_access field: (label) @function)) ; Ideally this pattern would be removed,
+((field_access
+  record: (identifier) @module)
+  ; field: (label) @function)                                     ; this line would be uncommented,
+ (#is-not? local))                                                ; and this line would be `(#is-not? local @module)`.
+
+; Attributes
+(attribute
+  "@" @attribute
+  name: (identifier) @attribute)
+
+(attribute_value (identifier) @constant)
+
+; Type names
+(remote_type_identifier) @type
+(type_identifier) @type
+
+; Data constructors
+(constructor_name) @constructor
+
+; Literals
+(string) @string
+(escape_sequence) @string.escape
+((escape_sequence) @warning
+ ; Deprecated in v0.33.0-rc2:
+ (#eq? @warning "\\e"))
+(bit_array_segment_option) @function.builtin
+(integer) @number
+(float) @number
+
+; Reserved identifiers
+; TODO: when tree-sitter supports `#any-of?` in the Rust bindings,
+; refactor this to use `#any-of?` rather than `#match?`
+((identifier) @error
+ (#any-of? @error "auto" "delegate" "derive" "else" "implement" "macro" "test"))
+
+; Keywords
+[
+  (visibility_modifier) ; "pub"
+  (opacity_modifier) ; "opaque"
+  "as"
+  "assert"
+  "case"
+  "const"
+  "echo"
+  ; DEPRECATED: 'external' was removed in v0.30.
+  "external"
+  "fn"
+  "if"
+  "import"
+  "let"
+  "panic"
+  "todo"
+  "type"
+  "use"
+] @keyword
+
+; Operators
+(binary_expression
+  operator: _ @operator)
+(boolean_negation "!" @operator)
+(integer_negation "-" @operator)

package/out/gleam/indents.scm

@@ -0,0 +1,28 @@
+; Gleam indents similar to Rust and JavaScript
+[
+  (anonymous_function)
+  (assert)
+  (case)
+  (case_clause)
+  (constant)
+  (external_function)
+  (function)
+  (let)
+  (list)
+  (type_definition)
+  (type_alias)
+  (todo)
+  (tuple)
+  (unqualified_imports)
+] @indent.begin
+
+[
+  ")"
+  "]"
+  "}"
+] @indent.end @indent.branch
+
+; Gleam pipelines are not indented, but other binary expression chains are
+((binary_expression
+  operator: _ @_operator) @indent.begin
+  (#not-eq? @_operator "|>"))

package/out/gleam/injections.scm

@@ -0,0 +1,3 @@
+((doc_comment_content) @injection.content
+ (#set! injection.language "markdown")
+ (#set! injection.combined))

package/out/gleam/locals.scm

@@ -0,0 +1,17 @@
+; Scopes
+(block) @local.scope
+
+(function) @local.scope
+
+(case_clause) @local.scope
+
+; Definitions
+(let pattern: (identifier) @local.definition)
+(function_parameter name: (identifier) @local.definition)
+(list_pattern (identifier) @local.definition)
+(list_pattern assign: (identifier) @local.definition)
+(tuple_pattern (identifier) @local.definition)
+(record_pattern_argument pattern: (identifier) @local.definition)
+
+; References
+(identifier) @local.reference

package/out/gleam/tags.scm

@@ -0,0 +1,41 @@
+; Modules
+(module) @name @reference.module
+(import alias: (identifier) @name) @reference.module
+(remote_type_identifier
+  module: (identifier) @name) @reference.module
+((field_access
+  record: (identifier) @name)
+ (#is-not? local)) @reference.module
+
+; Functions
+(function
+  name: (identifier) @name) @definition.function
+(external_function
+  name: (identifier) @name) @definition.function
+(unqualified_import (identifier) @name) @reference.function
+((function_call
+   function: (identifier) @name) @reference.function
+ (#is-not? local))
+((field_access
+  record: (identifier) @ignore
+  field: (label) @name)
+ (#is-not? local)) @reference.function
+((binary_expression
+   operator: "|>"
+   right: (identifier) @name)
+ (#is-not? local)) @reference.function
+
+; Types
+(type_definition
+  (type_name
+    name: (type_identifier) @name)) @definition.type
+(type_definition
+  (data_constructors
+    (data_constructor
+      name: (constructor_name) @name))) @definition.constructor
+(external_type
+  (type_name
+    name: (type_identifier) @name)) @definition.type
+
+(type_identifier) @name @reference.type
+(constructor_name) @name @reference.constructor

package/out/glsl/folds.scm

@@ -0,0 +1 @@
+; inherits: c

package/out/glsl/highlights.scm

@@ -0,0 +1,115 @@
+"break" @keyword
+"case" @keyword
+"const" @keyword
+"continue" @keyword
+"default" @keyword
+"do" @keyword
+"else" @keyword
+"enum" @keyword
+"extern" @keyword
+"for" @keyword
+"if" @keyword
+"inline" @keyword
+"return" @keyword
+"sizeof" @keyword
+"static" @keyword
+"struct" @keyword
+"switch" @keyword
+"typedef" @keyword
+"union" @keyword
+"volatile" @keyword
+"while" @keyword
+
+"#define" @keyword
+"#elif" @keyword
+"#else" @keyword
+"#endif" @keyword
+"#if" @keyword
+"#ifdef" @keyword
+"#ifndef" @keyword
+"#include" @keyword
+(preproc_directive) @keyword
+
+"--" @operator
+"-" @operator
+"-=" @operator
+"->" @operator
+"=" @operator
+"!=" @operator
+"*" @operator
+"&" @operator
+"&&" @operator
+"+" @operator
+"++" @operator
+"+=" @operator
+"<" @operator
+"==" @operator
+">" @operator
+"||" @operator
+
+"." @delimiter
+";" @delimiter
+
+(string_literal) @string
+(system_lib_string) @string
+
+(null) @constant
+(number_literal) @number
+(char_literal) @number
+
+(call_expression
+  function: (identifier) @function)
+(call_expression
+  function: (field_expression
+    field: (field_identifier) @function))
+(function_declarator
+  declarator: (identifier) @function)
+(preproc_function_def
+  name: (identifier) @function.special)
+
+(field_identifier) @property
+(statement_identifier) @label
+(type_identifier) @type
+(primitive_type) @type
+(sized_type_specifier) @type
+
+((identifier) @constant
+ (#match? @constant "^[A-Z][A-Z\\d_]*$"))
+
+(identifier) @variable
+
+(comment) @comment
+; inherits: c
+[
+  "in"
+  "out"
+  "inout"
+  "uniform"
+  "shared"
+  "layout"
+  "attribute"
+  "varying"
+  "buffer"
+  "coherent"
+  "readonly"
+  "writeonly"
+  "precision"
+  "highp"
+  "mediump"
+  "lowp"
+  "centroid"
+  "sample"
+  "patch"
+  "smooth"
+  "flat"
+  "noperspective"
+  "invariant"
+  "precise"
+] @type.qualifier
+
+"subroutine" @keyword.function
+
+(extension_storage_class) @keyword.storage
+
+((identifier) @variable.builtin
+  (#lua-match? @variable.builtin "^gl_"))

package/out/glsl/indents.scm

@@ -0,0 +1 @@
+; inherits: c

package/out/glsl/injections.scm

@@ -0,0 +1 @@
+; inherits: c

package/out/glsl/locals.scm

@@ -0,0 +1 @@
+; inherits: c

package/out/godot_resource/folds.scm

@@ -0,0 +1 @@
+(section) @fold

package/out/godot_resource/highlights.scm

@@ -0,0 +1,49 @@
+(identifier) @variable
+
+(section
+  (identifier) @tag)
+
+(section
+  [
+    "["
+    "]"
+  ] @tag.delimiter)
+
+(attribute
+  (identifier) @tag.attribute)
+
+(property
+  (path) @property)
+
+(constructor
+  (identifier) @constructor)
+
+(string) @string
+
+(integer) @number
+
+(float) @number.float
+
+[
+  (true)
+  (false)
+] @boolean
+
+(null) @constant.builtin
+
+(array
+  [
+    "["
+    "]"
+  ] @punctuation.bracket)
+
+[
+  "("
+  ")"
+  "{"
+  "}"
+] @punctuation.bracket
+
+"=" @operator
+
+(comment) @comment @spell

package/out/godot_resource/injections.scm

@@ -0,0 +1,2 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))

package/out/godot_resource/locals.scm

@@ -0,0 +1 @@
+(section) @local.scope

package/out/kdl/folds.scm

@@ -0,0 +1,8 @@
+; Folds
+
+[
+  (node)
+  (node_children)
+  (string)
+  (multi_line_comment)
+] @fold

package/out/kdl/highlights.scm

@@ -0,0 +1,58 @@
+; Types
+
+(node (identifier) @type)
+
+(type) @type
+
+(annotation_type) @type.builtin
+
+; Properties
+
+(prop (identifier) @property)
+
+; Variables
+
+(identifier) @variable
+
+; Operators
+[
+ "="
+ "+"
+ "-"
+] @operator
+
+; Literals
+
+(string) @string
+
+(escape) @string.escape
+
+(number) @number
+
+(number (decimal) @float)
+(number (exponent) @float)
+
+(boolean) @boolean
+
+"null" @constant.builtin
+
+; Punctuation
+
+["{" "}"] @punctuation.bracket
+
+["(" ")"] @punctuation.bracket
+
+[
+  ";"
+] @punctuation.delimiter
+
+; Comments
+
+[
+  (single_line_comment)
+  (multi_line_comment)
+] @comment @spell
+
+(node (node_comment) (#set! "priority" 105)) @comment
+(node (node_field (node_field_comment) (#set! "priority" 105)) @comment)
+(node_children (node_children_comment) (#set! "priority" 105)) @comment

package/out/kdl/indents.scm

@@ -0,0 +1,7 @@
+(node (node_children) @indent)
+
+"}" @indent_end
+
+[ "{" "}" ] @branch
+
+[ "(" ")" ] @branch

package/out/kdl/injections.scm

@@ -0,0 +1,4 @@
+[
+  (single_line_comment)
+  (multi_line_comment)
+] @comment

package/out/kdl/locals.scm

@@ -0,0 +1,10 @@
+(document) @scope
+(node (node_children) @scope)
+(node_children (node) @scope)
+
+(identifier) @reference
+
+(node_field) @definition.field
+
+(node (identifier) @definition.type)
+(type) @definition.type

package/out/liquid/highlights.scm

@@ -0,0 +1,119 @@
+([
+  "{{"
+  "}}"
+  "{{-"
+  "-}}"
+  "{%"
+  "%}"
+  "{%-"
+  "-%}"
+  ] @tag.delimiter
+ (#set! priority 101))
+
+
+([
+  "]"
+  "["
+  ")"
+  "("
+  ] @punctuation.bracket
+ (#set! priority 101))
+
+([
+  ","
+  "."
+  ] @punctuation.delimiter
+ (#set! priority 101))
+
+
+([
+  "as"
+  "assign"
+  (break_statement)
+  "by"
+  "capture"
+  "case"
+  (continue_statement)
+  (custom_unpaired_statement)
+  "cycle"
+  "decrement"
+  "doc"
+  "echo"
+  "else"
+  "elsif"
+  "endcapture"
+  "endcase"
+  "enddoc"
+  "endfor"
+  "endform"
+  "endif"
+  "endjavascript"
+  "endpaginate"
+  "endraw"
+  "endschema"
+  "endstyle"
+  "endstylesheet"
+  "endtablerow"
+  "endunless"
+  "for"
+  "form"
+  "if"
+  "include"
+  "include_relative"
+  "increment"
+  "javascript"
+  "layout"
+  "liquid"
+  "paginate"
+  "raw"
+  "render"
+  "schema"
+  "section"
+  "sections"
+  "style"
+  "stylesheet"
+  "tablerow"
+  "unless"
+  "when"
+  "with"
+  ] @keyword
+ (#set! priority 101))
+
+([
+  "and"
+  "contains"
+  "in"
+  "or"
+  ] @keyword.operator
+ (#set! priority 101))
+
+([
+  "|"
+  ":"
+  "="
+  (predicate)
+  ] @operator
+ (#set! priority 101))
+
+((identifier) @variable (#set! priority 101))
+((string) @string (#set! priority 101))
+((boolean) @boolean (#set! priority 101))
+((number) @number (#set! priority 101))
+
+(filter
+  name: (identifier) @function.call (#set! priority 101))
+
+(raw_statement
+  (raw_content) @text.reference (#set! priority 102))
+
+((comment) @comment (#set! priority 102))
+
+((doc) @comment.documentation (#set! priority 102))
+((doc_content) @comment.documentation (#set! priority 102))
+((doc_description_annotation) @keyword (#set! priority 103))
+((doc_example_annotation) @comment.documentation (#set! priority 102))
+((doc_example_content) @none (#set! priority 103))
+((doc_param_name) @variable (#set! priority 103))
+((doc_type) @type (#set! priority 103))
+("@param" @keyword (#set! priority 103))
+("@example" @keyword (#set! priority 103))

package/out/liquid/injections.scm

@@ -0,0 +1,22 @@
+((template_content) @injection.content
+  (#set! injection.language "html")
+  (#set! injection.combined))
+
+((json_content) @injection.content
+  (#set! injection.language "json")
+  (#set! injection.combined))
+
+((style_content) @injection.content
+  (#set! injection.language "css")
+  (#set! injection.combined))
+
+((stylesheet_content) @injection.content
+  (#set! injection.language "css")
+  (#set! injection.combined))
+
+((js_content) @injection.content
+  (#set! injection.language "javascript")
+  (#set! injection.combined))
+
+((front_matter) @injection.content
+  (#set! injection.language "yaml"))

package/out/ocaml_interface/folds.scm

@@ -0,0 +1 @@
+; inherits: ocaml

package/out/ocaml_interface/indents.scm

@@ -0,0 +1 @@
+; inherits: ocaml

package/out/ocaml_interface/injections.scm

@@ -0,0 +1 @@
+; inherits: ocaml

package/out/php_only/folds.scm

@@ -0,0 +1,19 @@
+[
+  (if_statement)
+  (switch_statement)
+  (while_statement)
+  (do_statement)
+  (for_statement)
+  (foreach_statement)
+  (try_statement)
+  (function_definition)
+  (class_declaration)
+  (interface_declaration)
+  (trait_declaration)
+  (enum_declaration)
+  (function_static_declaration)
+  (method_declaration)
+  (namespace_use_declaration)+
+  (array_creation_expression)
+  (match_expression)
+] @fold