ts-wasms 2.0.0 → 3.0.0

package/out/d/helix-highlights.scm

@@ -0,0 +1,241 @@
+; highlights.scm
+;
+; Highlighting queries for D code for use by Tree-Sitter.
+;
+; Copyright 2023 Garrett D'Amore
+;
+; Distributed under the MIT License.
+; (See accompanying file LICENSE.txt or https://opensource.org/licenses/MIT)
+; SPDX-License-Identifier: MIT
+
+; these are listed first, because they override keyword queries
+(identity_expression (in) @operator)
+(identity_expression (is) @operator)
+
+(storage_class) @keyword.storage
+
+(function_declaration (identifier) @function)
+
+(call_expression (identifier) @function)
+(call_expression (type (identifier) @function))
+
+(module_fqn) @namespace
+
+[
+    (abstract)
+    (alias)
+    (align)
+    (asm)
+    (assert)
+    (auto)
+    (cast)
+    (const)
+    (debug)
+    (delete)
+    (deprecated)
+    (export)
+    (extern)
+    (final)
+    (immutable)
+    (in)
+    (inout)
+    (invariant)
+    (is)
+    (lazy)
+    ; "macro" - obsolete
+    (mixin)
+    (module)
+    (new)
+    (nothrow)
+    (out)
+    (override)
+    (package)
+    (pragma)
+    (private)
+    (protected)
+    (public)
+    (pure)
+    (ref)
+    (scope)
+    (shared)
+    (static)
+    (super)
+    (synchronized)
+    (template)
+    (this)
+    (throw)
+    (typeid)
+    (typeof)
+    (unittest)
+    (version)
+    (with)
+    (gshared)
+    (traits)
+    (vector)
+    (parameters_)
+] @keyword
+
+[
+    (class)
+    (struct)
+    (interface)
+    (union)
+    (enum)
+    (function)
+    (delegate)
+] @keyword.storage.type
+
+[
+    (break)
+    (case)
+    (catch)
+    (continue)
+    (do)
+    (default)
+    (finally)
+    (else)
+    (goto)
+    (if)
+    (switch)
+    (try)
+] @keyword.control
+
+(return) @keyword.control.return
+
+(import) @keyword.control.import
+
+[
+    (for)
+    (foreach)
+    (foreach_reverse)
+    (while)
+] @keyword.control.repeat
+
+[
+    (not_in)
+    (not_is)
+    "/="
+    "/"
+    ".."
+    "..."
+    "&"
+    "&="
+    "&&"
+    "|"
+    "|="
+    "||"
+    "-"
+    "-="
+    "--"
+    "+"
+    "+="
+    "++"
+    "<"
+    "<="
+    "<<"
+    "<<="
+    ">"
+    ">="
+    ">>="
+    ">>>="
+    ">>"
+    ">>>"
+    "!"
+    "!="
+    "?"
+    "$"
+    "="
+    "=="
+    "*"
+    "*="
+    "%"
+    "%="
+    "^"
+    "^="
+    "^^"
+    "^^="
+    "~"
+    "~="
+    "@"
+    "=>"
+] @operator
+
+[
+    "("
+    ")"
+    "["
+    "]"
+    "{"
+    "}"
+] @punctuation.bracket
+
+[
+    ";"
+    "."
+    ":"
+    ","
+] @punctuation.delimiter
+
+[
+    (true)
+    (false)
+] @constant.builtin.boolean
+
+(null) @constant.builtin
+
+(special_keyword) @constant.builtin
+
+(directive) @keyword.directive
+(shebang) @keyword.directive
+
+(comment) @comment
+
+[
+    (void)
+    (bool)
+    (byte)
+    (ubyte)
+    (char)
+    (short)
+    (ushort)
+    (wchar)
+    (dchar)
+    (int)
+    (uint)
+    (long)
+    (ulong)
+    (real)
+    (double)
+    (float)
+    (size_t)
+    (ptrdiff_t)
+    (string)
+    (cstring)
+    (dstring)
+    (wstring)
+    (noreturn)
+] @type.builtin
+
+[
+    (cent)
+    (ucent)
+    (ireal)
+    (idouble)
+    (ifloat)
+    (creal)
+    (double)
+    (cfloat)
+] @warning ; these types are deprecated
+
+(label (identifier) @label)
+(goto_statement (goto) @keyword (identifier) @label)
+
+(string_literal) @string
+(int_literal) @constant.numeric.integer
+(float_literal) @constant.numeric.float
+(char_literal) @constant.character
+(identifier) @variable
+(at_attribute) @attribute
+
+; everything after __EOF_ is plain text
+(end_file) @ui.text

package/out/d/helix-indents.scm

@@ -0,0 +1,17 @@
+[
+  (parameters)
+  (template_parameters)
+  (expression_statement)
+  (aggregate_body)
+  (function_body)
+  (scope_statement)
+  (block_statement)
+  (case_statement)
+] @indent
+
+[
+  (case)
+  (default)
+  "}"
+  "]"
+] @outdent

package/out/d/helix-injections.scm

@@ -0,0 +1,2 @@
+((comment) @injection.content
+ (#set! injection.language "comment"))

package/out/d/helix-textobjects.scm

@@ -0,0 +1,9 @@
+(function_declaration (function_body) @function.inside) @function.around
+(comment) @comment.inside
+(comment)+ @comment.around
+(class_declaration (aggregate_body) @class.inside) @class.around
+(interface_declaration (aggregate_body) @class.inside) @class.around
+(struct_declaration (aggregate_body) @class.inside) @class.around
+(unittest_declaration (block_statement) @test.insid) @test.around
+(parameter) @parameter.inside
+(template_parameter) @parameter.inside

package/out/d/highlights.scm

@@ -0,0 +1,259 @@
+; highlights.scm
+;
+; Highlighting queries for D code for use by Tree-Sitter.
+;
+; Copyright 2024 Garrett D'Amore
+;
+; Distributed under the MIT License.
+; (See accompanying file LICENSE.txt or https://opensource.org/licenses/MIT)
+; SPDX-License-Identifier: MIT
+
+(string_literal) @string
+(int_literal) @number
+(float_literal) @number
+(char_literal) @number
+(identifier) @variable
+(at_attribute) @property
+(htmlentity) @string.special
+(escape_sequence) @string.escape
+
+[
+	(lazy)
+	(align)
+	(extern)
+	(static)
+	(abstract)
+	(final)
+	(override)
+	(synchronized)
+	(auto)
+	(scope)
+	(gshared)
+	(ref)
+	(deprecated)
+	(nothrow)
+	(pure)
+	(type_ctor)
+] @keyword.storage
+
+(parameter_attribute (return) @keyword.storage)
+(parameter_attribute (in) @keyword.storage)
+(parameter_attribute (out) @keyword.storage)
+
+(function_declaration (identifier) @function)
+
+(call_expression (identifier) @function)
+(call_expression (type (template_instance (identifier) @function)))
+(template_arguments (identifier) @variable.parameter)
+
+(named_argument (identifier) @variable.parameter)
+
+[
+    (abstract)
+    (alias)
+    (align)
+    (asm)
+    (assert)
+    (auto)
+    (cast)
+    (class)
+    (const)
+    (debug)
+    (delegate)
+    (delete)
+    (deprecated)
+    (enum)
+    (export)
+    (extern)
+    (final)
+    (function)
+    (immutable)
+    (import)
+    (in)
+    (inout)
+    (interface)
+    (invariant)
+    (is)
+    (lazy)
+    ; "macro" - obsolete
+    (mixin)
+    (module)
+    (new)
+    (nothrow)
+    (out)
+    (override)
+    (package)
+    (pragma)
+    (private)
+    (protected)
+    (public)
+    (pure)
+    (ref)
+    (scope)
+    (shared)
+    (static)
+    (struct)
+    (super)
+    (synchronized)
+    (template)
+    (this)
+    (throw)
+    (typeid)
+    (typeof)
+    (union)
+    (unittest)
+    (version)
+    (with)
+    (gshared)
+    (traits)
+    (vector)
+    (parameters_)
+] @keyword
+
+[
+    (break)
+    (case)
+    (catch)
+    (continue)
+    (do)
+    (default)
+    (finally)
+    (else)
+    (for)
+    (foreach)
+    (foreach_reverse)
+    (goto)
+    (if)
+    (switch)
+    (try)
+    (return)
+    (while)
+] @keyword.control
+
+[
+    (not_in)
+    (not_is)
+    "/="
+    "/"
+    ".."
+    "..."
+    "&"
+    "&="
+    "&&"
+    "|"
+    "|="
+    "||"
+    "-"
+    "-="
+    "--"
+    "+"
+    "+="
+    "++"
+    "<"
+    "<="
+    "<<"
+    "<<="
+    ">"
+    ">="
+    ">>="
+    ">>>="
+    ">>"
+    ">>>"
+    "!"
+    "!="
+    "?"
+    "$"
+    "="
+    "=="
+    "*"
+    "*="
+    "%"
+    "%="
+    "^"
+    "^="
+    "^^"
+    "^^="
+    "~"
+    "~="
+    "@"
+    "=>"
+] @operator
+
+[
+    ";"
+    "."
+    ":"
+    ","
+] @punctuation.delimiter
+
+[
+    "("
+    ")"
+    "["
+    "["
+    "{"
+    "}"
+] @punctuation.bracket
+
+[
+    (null)
+    (true)
+    (false)
+] @constant.language
+
+(special_keyword) @constant.language
+
+(directive) @keyword.directive
+(shebang) @keyword.directive
+
+(comment) @comment
+
+[
+    (void)
+    (bool)
+    (byte)
+    (ubyte)
+    (char)
+    (short)
+    (ushort)
+    (wchar)
+    (dchar)
+    (int)
+    (uint)
+    (long)
+    (ulong)
+    (real)
+    (double)
+    (float)
+    (size_t)
+    (ptrdiff_t)
+    (string)
+    (cstring)
+    (wstring)
+    (noreturn)
+] @type.builtin
+
+[
+    (cent)
+    (ucent)
+    (ireal)
+    (idouble)
+    (ifloat)
+    (creal)
+    (double)
+    (cfloat)
+] @type.deprecated
+
+(label (identifier) @label)
+(goto_statement (goto) @keyword.control (identifier) @label)
+
+; this covers other cases where the identifier can only
+; be a type (such as in an is-expression on a constraint)
+(type (identifier) @type)
+
+; these are listed last, because they override keyword queries
+(identity_expression (in) @operator)
+(identity_expression (is) @operator)
+
+; everything after __EOF_ is plain text
+(end_file) @text

package/out/d/indents.scm

@@ -0,0 +1,17 @@
+[
+  (parameters)
+  (template_parameters)
+  (expression_statement)
+  (aggregate_body)
+  (function_body)
+  (scope_statement)
+  (block_statement)
+  (case_statement)
+] @indent
+
+[
+  (case)
+  (default)
+  "}"
+  "]"
+] @outdent

package/out/d/injections.scm

@@ -0,0 +1,2 @@
+((comment) @injection.content
+ (#set! injection.language "comment"))

package/out/d/locals.scm

@@ -0,0 +1,79 @@
+; Scopes
+[
+  (source_file)
+  (block_statement)
+  (aggregate_body)
+] @local.scope
+
+; References
+(identifier) @local.reference
+
+; Definitions
+(module_def
+  (module_declaration
+    (module_fqn) @local.definition.namespace)
+  (#set! definition.namespace.scope "global"))
+
+(enum_declaration
+  (enum_member
+    .
+    (identifier) @local.definition.enum))
+
+(class_declaration
+  (class)
+  .
+  (identifier) @local.definition.type)
+
+(struct_declaration
+  (struct)
+  .
+  (identifier) @local.definition.type)
+
+(union_declaration
+  (union)
+  .
+  (identifier) @local.definition.type)
+
+(enum_declaration
+  (enum)
+  .
+  (identifier) @local.definition.type)
+
+(alias_declaration
+  (alias_initializer
+    .
+    (identifier) @local.definition.type))
+
+(constructor
+  (this) @local.definition.method)
+
+(destructor
+  (this) @local.definition.method)
+
+(postblit
+  (this) @local.definition.method)
+
+(aggregate_body
+  (function_declaration
+    (identifier) @local.definition.method))
+
+(manifest_declarator
+  .
+  (identifier) @local.definition.constant)
+
+(anonymous_enum_declaration
+  (enum_member
+    .
+    (identifier) @local.definition.constant))
+
+(variable_declaration
+  (declarator
+    (identifier) @local.definition.var))
+
+(aggregate_body
+  (variable_declaration
+    (declarator
+      (identifier) @local.definition.field)))
+
+(function_declaration
+  (identifier) @local.definition.function)

package/out/d/nova-folds.scm

@@ -0,0 +1,6 @@
+(struct_declaration (aggregate_body (#set! role type)) @subtree)
+(class_declaration (aggregate_body (#set! role type)) @subtree)
+(union_declaration (aggregate_body (#set! role type)) @subtree)
+(interface_declaration (aggregate_body (#set! role type)) @subtree)
+
+(block_statement (#set! role block)) @subtree