ts-wasms 1.1.0 → 3.0.0

package/out/tsx/injections.scm

@@ -0,0 +1 @@
+; inherits: typescript,jsx

package/out/typescript/folds.scm

@@ -0,0 +1,8 @@
+; inherits: ecma
+
+[
+  (interface_declaration)
+  (internal_module)
+  (type_alias_declaration)
+  (enum_declaration)
+] @fold

package/out/typescript/indents.scm

@@ -0,0 +1,7 @@
+; inherits: ecma
+
+[
+  (enum_declaration)
+  (interface_declaration)
+  (object_type)
+] @indent.begin

package/out/typescript/injections.scm

@@ -0,0 +1,28 @@
+; inherits: ecma
+
+; styled.div<{}>`<css>`
+(call_expression
+  function: (non_null_expression
+    (instantiation_expression
+      (member_expression
+        object: (identifier) @_name
+        (#eq? @_name "styled")
+        property: (property_identifier))
+      type_arguments: (type_arguments)))
+  arguments: ((template_string) @injection.content
+    (#offset! @injection.content 0 1 0 -1)
+    (#set! injection.include-children)
+    (#set! injection.language "styled")))
+
+; styled.div<T>`<css>`
+(binary_expression
+  left: (binary_expression
+    left: (member_expression
+      object: (identifier) @_name
+      (#eq? @_name "styled")
+      property: (property_identifier))
+    right: (identifier))
+  right: (template_string) @injection.content
+  (#offset! @injection.content 0 1 0 -1)
+  (#set! injection.include-children)
+  (#set! injection.language "styled"))

package/out/vim/folds.scm

@@ -0,0 +1,4 @@
+[
+  (if_statement)
+  (function_definition)
+] @fold

package/out/vim/highlights.scm

@@ -0,0 +1,362 @@
+(identifier) @variable
+
+((identifier) @constant
+  (#lua-match? @constant "^[A-Z][A-Z_0-9]*$"))
+
+; Keywords
+[
+  "if"
+  "else"
+  "elseif"
+  "endif"
+] @keyword.conditional
+
+[
+  "try"
+  "catch"
+  "finally"
+  "endtry"
+  "throw"
+] @keyword.exception
+
+[
+  "for"
+  "endfor"
+  "in"
+  "while"
+  "endwhile"
+  "break"
+  "continue"
+] @keyword.repeat
+
+[
+  "function"
+  "endfunction"
+] @keyword.function
+
+; Function related
+(function_declaration
+  name: (_) @function)
+
+(call_expression
+  function: (identifier) @function.call)
+
+(call_expression
+  function: (scoped_identifier
+    (identifier) @function.call))
+
+(parameters
+  (identifier) @variable.parameter)
+
+(default_parameter
+  (identifier) @variable.parameter)
+
+[
+  (bang)
+  (spread)
+] @punctuation.special
+
+[
+  (no_option)
+  (inv_option)
+  (default_option)
+  (option_name)
+] @variable.builtin
+
+[
+  (scope)
+  "a:"
+  "$"
+] @module
+
+; Commands and user defined commands
+[
+  "let"
+  "unlet"
+  "const"
+  "call"
+  "execute"
+  "normal"
+  "set"
+  "setfiletype"
+  "setlocal"
+  "silent"
+  "echo"
+  "echon"
+  "echohl"
+  "echomsg"
+  "echoerr"
+  "autocmd"
+  "augroup"
+  "return"
+  "syntax"
+  "filetype"
+  "source"
+  "lua"
+  "ruby"
+  "perl"
+  "python"
+  "highlight"
+  "command"
+  "delcommand"
+  "comclear"
+  "colorscheme"
+  "scriptencoding"
+  "startinsert"
+  "stopinsert"
+  "global"
+  "runtime"
+  "wincmd"
+  "cnext"
+  "cprevious"
+  "cNext"
+  "tab"
+  "vertical"
+  "leftabove"
+  "aboveleft"
+  "rightbelow"
+  "belowright"
+  "topleft"
+  "botright"
+  (unknown_command_name)
+  "edit"
+  "enew"
+  "find"
+  "ex"
+  "visual"
+  "view"
+  "eval"
+  "sign"
+  "abort"
+  "substitute"
+] @keyword
+
+(map_statement
+  cmd: _ @keyword)
+
+(keycode) @character.special
+
+(command_name) @function.macro
+
+; Filetype command
+(filetype_statement
+  [
+    "detect"
+    "plugin"
+    "indent"
+    "on"
+    "off"
+  ] @keyword)
+
+; Syntax command
+(syntax_statement
+  (keyword) @string)
+
+(syntax_statement
+  [
+    "enable"
+    "on"
+    "off"
+    "reset"
+    "case"
+    "spell"
+    "foldlevel"
+    "iskeyword"
+    "keyword"
+    "match"
+    "cluster"
+    "region"
+    "clear"
+    "include"
+  ] @keyword)
+
+(syntax_argument
+  name: _ @keyword)
+
+[
+  "<buffer>"
+  "<nowait>"
+  "<silent>"
+  "<script>"
+  "<expr>"
+  "<unique>"
+] @constant.builtin
+
+(augroup_name) @module
+
+(au_event) @constant
+
+(normal_statement
+  (commands) @constant)
+
+; Highlight command
+(hl_attribute
+  key: _ @property
+  val: _ @constant)
+
+(hl_group) @type
+
+(highlight_statement
+  [
+    "default"
+    "link"
+    "clear"
+  ] @keyword)
+
+; Command command
+(command) @string
+
+(command_attribute
+  name: _ @property
+  val: (behavior
+    name: _ @constant
+    val: (identifier)? @function)?)
+
+; Edit command
+(plus_plus_opt
+  val: _? @constant) @property
+
+(plus_cmd
+  "+" @property) @property
+
+; Runtime command
+(runtime_statement
+  (where) @keyword.operator)
+
+; Colorscheme command
+(colorscheme_statement
+  (name) @string)
+
+; Scriptencoding command
+(scriptencoding_statement
+  (encoding) @string.special)
+
+; Literals
+(string_literal) @string
+
+(integer_literal) @number
+
+(float_literal) @number.float
+
+(comment) @comment @spell
+
+(line_continuation_comment) @comment @spell
+
+(pattern) @string.special
+
+(pattern_multi) @string.regexp
+
+(filename) @string.special.path
+
+(heredoc
+  (body) @string)
+
+(heredoc
+  (parameter) @keyword)
+
+(script
+  (parameter) @keyword)
+
+[
+  (marker_definition)
+  (endmarker)
+] @label
+
+(literal_dictionary
+  (literal_key) @property)
+
+((scoped_identifier
+  (scope) @_scope
+  .
+  (identifier) @boolean)
+  (#eq? @_scope "v:")
+  (#any-of? @boolean "true" "false"))
+
+; Operators
+[
+  "||"
+  "&&"
+  "&"
+  "+"
+  "-"
+  "*"
+  "/"
+  "%"
+  ".."
+  "=="
+  "!="
+  ">"
+  ">="
+  "<"
+  "<="
+  "=~"
+  "!~"
+  "="
+  "^="
+  "+="
+  "-="
+  "*="
+  "/="
+  "%="
+  ".="
+  "..="
+  "<<"
+  "=<<"
+  "->"
+  (match_case)
+] @operator
+
+[
+  "is"
+  "isnot"
+] @keyword.operator
+
+; Some characters have different meanings based on the context
+(unary_operation
+  "!" @operator)
+
+(binary_operation
+  "." @operator)
+
+(lua_statement
+  "=" @keyword)
+
+; Punctuation
+[
+  "("
+  ")"
+  "{"
+  "}"
+  "["
+  "]"
+  "#{"
+] @punctuation.bracket
+
+(field_expression
+  "." @punctuation.delimiter)
+
+[
+  ","
+  ":"
+] @punctuation.delimiter
+
+(ternary_expression
+  [
+    "?"
+    ":"
+  ] @keyword.conditional.ternary)
+
+; Options
+((set_value) @number
+  (#lua-match? @number "^[%d]+(%.[%d]+)?$"))
+
+(inv_option
+  "!" @operator)
+
+(set_item
+  "?" @operator)
+
+((set_item
+  option: (option_name) @_option
+  value: (set_value) @function)
+  (#any-of? @_option "tagfunc" "tfu" "completefunc" "cfu" "omnifunc" "ofu" "operatorfunc" "opfunc"))

package/out/vim/injections.scm

@@ -0,0 +1,44 @@
+(lua_statement
+  (script
+    (body) @injection.content
+    (#set! injection.language "lua")))
+
+(lua_statement
+  (chunk) @injection.content
+  (#set! injection.language "lua"))
+
+(ruby_statement
+  (script
+    (body) @injection.content
+    (#set! injection.language "ruby")))
+
+(ruby_statement
+  (chunk) @injection.content
+  (#set! injection.language "ruby"))
+
+(python_statement
+  (script
+    (body) @injection.content
+    (#set! injection.language "python")))
+
+(python_statement
+  (chunk) @injection.content
+  (#set! injection.language "python"))
+
+; If we support perl at some point...
+; (perl_statement (script (body) @perl))
+; (perl_statement (chunk) @perl)
+(autocmd_statement
+  (pattern) @injection.content
+  (#set! injection.language "regex"))
+
+((set_item
+  option: (option_name) @_option
+  value: (set_value) @injection.content)
+  (#any-of? @_option
+    "includeexpr" "inex" "printexpr" "pexpr" "formatexpr" "fex" "indentexpr" "inde" "foldtext" "fdt"
+    "foldexpr" "fde" "diffexpr" "dex" "patchexpr" "pex" "charconvert" "ccv")
+  (#set! injection.language "vim"))
+
+((comment) @injection.content
+  (#set! injection.language "comment"))

package/out/vim/locals.scm

@@ -0,0 +1,19 @@
+[
+  (script_file)
+  (function_definition)
+] @local.scope
+
+(function_declaration
+  name: (identifier) @local.definition.function)
+
+(function_declaration
+  parameters: (parameters
+    (identifier) @local.definition.parameter))
+
+(let_statement
+  [
+    (scoped_identifier)
+    (identifier)
+  ] @local.definition.var)
+
+(identifier) @local.reference

package/out/vimdoc/injections.scm

@@ -0,0 +1,4 @@
+((codeblock
+  (language) @injection.language
+  (code) @injection.content)
+  (#set! injection.include-children))

package/out/vue/folds.scm

@@ -0,0 +1,6 @@
+[
+  (element)
+  (template_element)
+  (script_element)
+  (style_element)
+] @fold

package/out/vue/highlights.scm

@@ -0,0 +1,54 @@
+; inherits: html_tags
+
+[
+  "["
+  "]"
+] @punctuation.bracket
+
+[
+  ":"
+  "."
+] @character.special
+
+[
+  (interpolation)
+  "@"
+] @punctuation.special
+
+(interpolation
+  (raw_text) @none)
+
+(dynamic_directive_inner_value) @variable
+
+(directive_name) @tag.attribute
+
+; Accessing a component object's field
+(":"
+  .
+  (directive_value) @variable.member)
+
+("."
+  .
+  (directive_value) @property)
+
+; @click is like onclick for HTML
+("@"
+  .
+  (directive_value) @function.method)
+
+; Used in v-slot, declaring position the element should be put in
+("#"
+  .
+  (directive_value) @variable)
+
+(directive_attribute
+  (quoted_attribute_value) @punctuation.special)
+
+(directive_attribute
+  (quoted_attribute_value
+    (attribute_value) @none))
+
+(directive_modifier) @function.method
+
+((template_element) @_template
+  (#set! @_template bo.commentstring "<!-- %s -->"))

package/out/vue/indents.scm

@@ -0,0 +1,7 @@
+; inherits: html_tags
+
+(template_element) @indent.begin
+
+(template_element
+  (end_tag
+    ">" @indent.end) @indent.branch)

package/out/vue/injections.scm

@@ -0,0 +1,78 @@
+; inherits: html_tags
+
+; <script lang="css">
+((style_element
+  (start_tag
+    (attribute
+      (attribute_name) @_lang
+      (quoted_attribute_value
+        (attribute_value) @injection.language)))
+  (raw_text) @injection.content)
+  (#eq? @_lang "lang")
+  (#any-of? @injection.language "css" "scss"))
+
+; TODO: When nvim-treesitter has postcss and less parsers, use @injection.language and @injection.content instead
+; <script lang="scss">
+(style_element
+  (start_tag
+    (attribute
+      (attribute_name) @_lang
+      (quoted_attribute_value
+        (attribute_value) @_scss)))
+  (raw_text) @injection.content
+  (#eq? @_lang "lang")
+  (#any-of? @_scss "less" "postcss" "sass")
+  (#set! injection.language "scss"))
+
+; <script lang="js">
+((script_element
+  (start_tag
+    (attribute
+      (attribute_name) @_lang
+      (quoted_attribute_value
+        (attribute_value) @_js)))
+  (raw_text) @injection.content)
+  (#eq? @_lang "lang")
+  (#eq? @_js "js")
+  (#set! injection.language "javascript"))
+
+; <script lang="ts">
+((script_element
+  (start_tag
+    (attribute
+      (attribute_name) @_lang
+      (quoted_attribute_value
+        (attribute_value) @_ts)))
+  (raw_text) @injection.content)
+  (#eq? @_lang "lang")
+  (#eq? @_ts "ts")
+  (#set! injection.language "typescript"))
+
+; <script lang="tsx">
+; <script lang="jsx">
+(script_element
+  (start_tag
+    (attribute
+      (attribute_name) @_attr
+      (quoted_attribute_value
+        (attribute_value) @injection.language)))
+  (#eq? @_attr "lang")
+  (#any-of? @injection.language "tsx" "jsx")
+  (raw_text) @injection.content)
+
+((interpolation
+  (raw_text) @injection.content)
+  (#set! injection.language "typescript"))
+
+(directive_attribute
+  (quoted_attribute_value
+    (attribute_value) @injection.content
+    (#set! injection.language "typescript")))
+
+(template_element
+  (start_tag
+    (attribute
+      (quoted_attribute_value
+        (attribute_value) @injection.language)))
+  (text) @injection.content
+  (#eq? @injection.language "pug"))

package/out/xml/folds.scm

@@ -0,0 +1,5 @@
+[
+  (element)
+  (doctypedecl)
+  (Comment)
+] @fold

package/out/xml/indents.scm

@@ -0,0 +1,16 @@
+(element) @indent.begin
+
+[
+  (Attribute)
+  (AttlistDecl)
+  (contentspec)
+] @indent.align
+
+(ETag) @indent.branch
+
+(doctypedecl) @indent.ignore
+
+[
+  (Comment)
+  (ERROR)
+] @indent.auto

package/out/xml/injections.scm

@@ -0,0 +1,32 @@
+((Comment) @injection.content
+  (#set! injection.language "comment"))
+
+; SVG style
+((element
+  (STag
+    (Name) @_name)
+  (content) @injection.content)
+  (#eq? @_name "style")
+  (#set! injection.combined)
+  (#set! injection.include-children)
+  (#set! injection.language "css"))
+
+; SVG script
+((element
+  (STag
+    (Name) @_name)
+  (content) @injection.content)
+  (#eq? @_name "script")
+  (#set! injection.combined)
+  (#set! injection.include-children)
+  (#set! injection.language "javascript"))
+
+; phpMyAdmin dump
+((element
+  (STag
+    (Name) @_name)
+  (content) @injection.content)
+  (#eq? @_name "pma:table")
+  (#set! injection.combined)
+  (#set! injection.include-children)
+  (#set! injection.language "sql"))