ts-wasms 1.1.0 → 3.0.0

package/out/gdscript/indents.scm

@@ -0,0 +1,78 @@
+[
+  (lambda)
+  (function_definition)
+  (constructor_definition)
+  (for_statement)
+  (while_statement)
+  (if_statement)
+  (class_definition)
+  (match_statement)
+  (pattern_section)
+  (setget)
+  (match_body)
+  (set_body)
+  (get_body)
+] @indent.begin
+
+[
+  (elif_clause)
+  (else_clause)
+] @indent.branch
+
+[
+  (string)
+  (comment)
+  (array)
+  (dictionary)
+  (parenthesized_expression)
+  (ERROR)
+] @indent.auto
+
+[
+  (pass_statement)
+  (continue_statement)
+  (break_statement)
+  (return_statement)
+] @indent.dedent
+
+[
+  (ERROR
+    "[")
+  (ERROR
+    "(")
+  (ERROR
+    "{")
+] @indent.begin
+
+; This only works with expanded tabs.
+; ((parameters) @indent.align (#set! indent.open_delimiter "(") (#set! indent.close_delimiter ")"))
+; ((arguments)  @indent.align (#set! indent.open_delimiter "(") (#set! indent.close_delimiter ")"))
+; The following queries either do not agree with the current body parsing or are
+; attempted workarounds. Specifically as the last statement of a body. Opening
+; a new line in between statements works well.
+;
+; The overall experience is poor, so I've opted for @indent.auto.
+;
+; The gdscript parser will need to be patched to accommodate more interactive
+; edits. As far as I can tell the parser greedily consumes whitespace
+; as a zero-width token which causes trouble when inserting indents.
+; This indents correctly with tabs.
+; (arguments) @indent.begin
+; (parameters) @indent.begin
+; (array) @indent.begin
+; (dictionary) @indent.begin
+; (parenthesized_expression) @indent.begin
+; Partial workaround for when the cursor is on the bracket character and a newline
+; is created with <o>. Without this the newline is opened with extra
+; indentation.
+; (body (_ (array "]" @indent.end) ) _)
+; Problematic behaviors occur at the last statement of a body.
+; with @dedent:
+;   - [ | ] i<CR> will dedent ] to 0.
+;   - [
+;   ]| o will open new line at correct indentation.
+; with @auto:
+;   - [ | ] i<CR> same
+;   - [
+;   ]| o will open new line with extra indent.
+;(body (_ (array "]" @indent.auto) ) .)

package/out/gdscript/injections.scm

@@ -0,0 +1,2 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))

package/out/gdscript/locals.scm

@@ -0,0 +1,121 @@
+; Scopes
+[
+  (if_statement)
+  (elif_clause)
+  (else_clause)
+  (for_statement)
+  (while_statement)
+  (function_definition)
+  (constructor_definition)
+  (class_definition)
+  (match_statement)
+  (pattern_section)
+  (lambda)
+  (get_body)
+  (set_body)
+] @local.scope
+
+; Parameters
+(parameters
+  (identifier) @local.definition.parameter)
+
+(default_parameter
+  (identifier) @local.definition.parameter)
+
+(typed_parameter
+  (identifier) @local.definition.parameter)
+
+(typed_default_parameter
+  (identifier) @local.definition.parameter)
+
+; Signals
+; Can gdscript 2 signals be considered fields?
+(signal_statement
+  (name) @local.definition.field)
+
+; Variable Definitions
+(const_statement
+  (name) @local.definition.constant)
+
+; onready and export variations are only properties.
+(variable_statement
+  (name) @local.definition.var)
+
+(setter) @local.reference
+
+(getter) @local.reference
+
+; Function Definition
+((function_definition
+  (name) @local.definition.function)
+  (#set! definition.function.scope "parent"))
+
+; Lambda
+; lambda names are not accessible and are only for debugging.
+(lambda
+  (name) @local.definition.function)
+
+; Source
+(class_name_statement
+  (name) @local.definition.type)
+
+(source
+  (variable_statement
+    (name) @local.definition.field))
+
+(source
+  (onready_variable_statement
+    (name) @local.definition.field))
+
+(source
+  (export_variable_statement
+    (name) @local.definition.field))
+
+; Class
+((class_definition
+  (name) @local.definition.type)
+  (#set! definition.type.scope "parent"))
+
+(class_definition
+  (body
+    (variable_statement
+      (name) @local.definition.field)))
+
+(class_definition
+  (body
+    (onready_variable_statement
+      (name) @local.definition.field)))
+
+(class_definition
+  (body
+    (export_variable_statement
+      (name) @local.definition.field)))
+
+(class_definition
+  (body
+    (signal_statement
+      (name) @local.definition.field)))
+
+; Although a script is also a class, let's only define functions in an inner class as
+; methods.
+((class_definition
+  (body
+    (function_definition
+      (name) @local.definition.method)))
+  (#set! definition.method.scope "parent"))
+
+; Enum
+(enum_definition
+  (name) @local.definition.enum)
+
+; Repeat
+(for_statement
+  .
+  (identifier) @local.definition.var)
+
+; Match Statement
+(pattern_binding
+  (identifier) @local.definition.var)
+
+; References
+(identifier) @local.reference

package/out/gdshader/highlights.scm

@@ -0,0 +1,256 @@
+; highlights.scm
+[
+  "group_uniforms"
+  "uniform"
+  "const"
+  "varying"
+  "discard"
+  "render_mode"
+  "shader_type"
+  "return"
+  "while"
+  "do"
+  "break"
+  "continue"
+  "if"
+  "else"
+  "switch"
+  "case"
+  "default"
+  "struct"
+  "for"
+] @keyword
+
+(parameter_qualifier) @keyword
+
+(interpolation_specifier) @keyword
+
+(precision_specifier) @keyword
+
+(scope) @keyword
+
+[
+  ";"
+  "."
+  ":"
+  ","
+] @punctuation.delimiter
+
+[
+  "("
+  ")"
+  "["
+  "]"
+  "{"
+  "}"
+] @punctuation.bracket
+
+[
+  "="
+  "-"
+  "*"
+  "/"
+  "+"
+  "%"
+  "~"
+  "|"
+  "&"
+  "^"
+  "<<"
+  ">>"
+  "<"
+  "<="
+  ">="
+  ">"
+  "=="
+  "!="
+  "!"
+  "&&"
+  "||"
+  "-="
+  "+="
+  "*="
+  "/="
+  "%="
+  "|="
+  "&="
+  "^="
+  ">>="
+  "<<="
+  "--"
+  "++"
+  "?"
+  ":"
+] @operator
+
+(comma_expression
+  operator: "," @operator)
+
+(primitive_type) @type.builtin
+
+(type_identifier) @type
+
+(number) @number
+
+(boolean) @boolean
+
+(case_statement
+  value: (identifier) @constant)
+
+; spatial
+(source_file
+  ; only comments and preprocessor directives are allowed before a shader type so ignore shader type
+  ; statements in any other node
+  (shader_type_statement
+    (shader_type) @_shader_type)
+  (#eq? @_shader_type "spatial")
+  (render_mode_statement
+    (render_mode) @keyword)
+  (#any-of? @keyword
+    "blend_mix" "blend_add" "blend_sub" "blend_mul" "blend_premul_alpha" "depth_draw_opaque"
+    "depth_draw_always" "depth_draw_never" "depth_prepass_alpha" "depth_test_disabled"
+    "sss_mode_skin" "cull_back" "cull_front" "cull_disabled" "unshaded" "wireframe"
+    "debug_shadow_splits" "diffuse_burley" "diffuse_lambert" "diffuse_lambert_wrap" "diffuse_toon"
+    "specular_schlick_ggx" "specular_toon" "specular_disabled" "skip_vertex_transform"
+    "world_vertex_coords" "ensure_correct_normals" "shadows_disabled" "ambient_light_disabled"
+    "shadow_to_opacity" "vertex_lighting" "particle_trails" "alpha_to_coverage"
+    "alpha_to_coverage_and_one" "fog_disabled"))
+
+; canvas_item
+(source_file
+  (shader_type_statement
+    (shader_type) @_shader_type)
+  (#eq? @_shader_type "canvas_item")
+  (render_mode_statement
+    (render_mode) @keyword)
+  (#any-of? @keyword
+    "blend_mix" "blend_add" "blend_sub" "blend_mul" "blend_premul_alpha" "blend_disabled" "unshaded"
+    "light_only" "skip_vertex_transform" "world_vertex_coords"))
+
+; particle
+(source_file
+  (shader_type_statement
+    (shader_type) @_shader_type)
+  (#eq? @_shader_type "particle")
+  (render_mode_statement
+    (render_mode) @keyword)
+  (#any-of? @keyword "keep_data" "disable_force" "disable_velocity" "collision_use_scale"))
+
+; sky
+(source_file
+  (shader_type_statement
+    (shader_type) @_shader_type)
+  (#eq? @_shader_type "sky")
+  (render_mode_statement
+    (render_mode) @keyword)
+  (#any-of? @keyword "use_half_res_pass" "use_quarter_res_pass" "disable_fog"))
+
+; fog has no render modes
+(shader_type_statement
+  (shader_type) @keyword
+  (#any-of? @keyword "spatial" "canvas_item" "particle" "sky" "fog"))
+
+(identifier) @variable
+
+(struct_definition
+  name: (identifier) @type)
+
+(struct_definition
+  (struct_fields
+    (field_definition
+      declarator: [
+        (identifier) @variable.member
+        (array_declarator
+          declarator: (identifier) @variable.member)
+      ])))
+
+[
+  "#undef"
+  "#include"
+  "#if"
+  "#ifdef"
+  "#ifndef"
+  "#elif"
+  "#else"
+  "#endif"
+  "#define"
+] @keyword
+
+(preproc_include
+  path: (_) @string)
+
+(preproc_undef
+  argument: (identifier) @constant)
+
+(comment) @comment
+
+; technically an injection site for bbcode TODO: maybe add it?
+((comment) @comment.documentation
+  (#match? @comment.documentation "^/\\*\\*[^/]"))
+
+(parameter_declaration
+  declarator: [
+    (identifier) @variable.parameter
+    (array_declarator
+      declarator: (identifier) @variable.parameter)
+  ])
+
+(function_definition
+  declarator: (identifier) @function)
+
+(field_expression
+  field: (_) @property)
+
+(call_expression
+  function: (identifier) @function)
+
+(method_expression
+  method: (_) @function)
+
+((call_expression
+  function: (identifier) @function.builtin)
+  (#any-of? @function.builtin
+    ; taken from: https://docs.godotengine.org/en/stable/tutorials/shaders/shader_reference/shader_functions.html
+    ; trigonometric builtins
+    "radians" "degrees" "sin" "cos" "tan" "asin" "acos" "atan" "sinh" "cosh" "tanh" "asinh" "acosh"
+    "atanh"
+    ; exponential and math builtins
+    "pow" "exp" "exp2" "log" "log2" "sqrt" "inversesqrt" "abs" "sign" "floor" "round" "roundEven"
+    "trunc" "ceil" "fract" "mod" "modf" "min" "max" "clamp" "mix" "fma" "step" "smoothstep" "isnan"
+    "isinf" "floatBitsToInt" "floatBitsToUint" "intBitsToFloat" "uintBitsToFloat"
+    ; geometric builtins
+    "length" "distance" "dot" "cross" "normalize" "reflect" "refract" "faceforward" "matrixCompMult"
+    "outerProduct" "transpose" "determinant" "inverse"
+    ; comparison builtins
+    "lessThan" "greaterThan" "lessThanEqual" "equal" "notEqual" "any" "all" "not"
+    ; texture builtins
+    "textureSize" "textureQueryLod" "textureQueryLevels" "texture" "textureProj" "textureLod"
+    "textureProjLod" "textureGrad" "textureProjGrad" "texelFetch" "textureGather" "dFdx"
+    "dFdxCoarse" "dFdxFine" "dFdy" "dFdyCoarse" "dFdyFine" "fwidth" "fwidthCoarse" "fwidthFine"
+    ; packing unpacking builtins
+    "packHalf2x16" "unpackHalf2x16" "packUnorm2x16" "unpackUnorm2x16" "packSnorm2x16"
+    "unpackSnorm2x16" "packUnorm4x8" "unpackUnorm4x8" "packSnorm4x8" "unpackSnorm4x8"
+    ; bitwise builtins
+    "bitfieldExtract" "bitfieldInsert" "bitfieldReverse" "bitCount" "findLSB" "findMSB" "imulExtend"
+    "umulExtend" "uaddCarry" "usubBorrow" "ldexp" "frexp"))
+
+; assume all uppercase variables as constants
+((identifier) @constant
+  (#match? @constant "^[A-Z][A-Z_0-9]*$"))
+
+((identifier) @constant.builtin
+  (#any-of? @constant.builtin
+    ; common / declared in all shader types
+    "PI" "E" "TAU" "CURRENT_RENDERER" "RENDERER_COMPATIBILITY" "RENDERER_MOBILE"
+    "RENDERER_FORWARD_PLUS"; TODO: add more builtins
+    ))
+
+((identifier) @variable.builtin
+  (#any-of? @variable.builtin "TIME"))
+
+(type_hint
+  [
+    (identifier) @attribute
+    (call_expression
+      function: (_) @attribute)
+  ])

package/out/gdshader/injections.scm

@@ -0,0 +1,2 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))

package/out/gdshader/locals.scm

@@ -0,0 +1,24 @@
+(function_definition
+  declarator: (identifier) @local.definition)
+
+(declaration
+  declarator: (identifier) @local.definition)
+
+(init_declarator
+  declarator: (identifier) @local.definition)
+
+(array_declarator
+  declarator: (identifier) @local.definition)
+
+(parameter_declaration
+  declarator: (identifier) @local.definition)
+
+(expression
+  [
+    left: (identifier) @local.reference
+    argument: (identifier) @local.reference
+  ])
+
+(expression/identifier) @local.reference
+
+(compound_statement) @local.scope

package/out/gdshader/tags.scm

@@ -0,0 +1,13 @@
+((function_definition
+  declarator: (identifier) @name) @definition.function)
+
+((call_expression
+  function: (_) @name) @reference.call)
+
+((method_expression
+  method: (identifier) @name) @reference.call)
+
+((struct_definition
+  name: (identifier) @name) @definition.class)
+
+(((type_identifier) @name) @reference.class)

package/out/git_config/folds.scm

@@ -0,0 +1,2 @@
+((section) @fold
+  (#trim! @fold))

package/out/git_config/highlights.scm

@@ -0,0 +1,28 @@
+(section_name) @tag
+
+((section_name) @function.builtin
+ (#eq? @function.builtin "include"))
+
+((section_header
+   (section_name) @function.builtin
+   (subsection_name))
+ (#eq? @function.builtin "includeIf"))
+
+(variable (name) @property)
+[(true) (false)] @constant.builtin
+(integer) @number
+
+[(string) (subsection_name)] @string
+
+((string) @string.special.path
+ (#match? @string.special.path "^(~|./|/)"))
+
+[
+  "["
+  "]"
+  "\""
+] @punctuation.bracket
+
+"=" @punctuation.delimiter
+
+(comment) @comment

package/out/git_config/injections.scm

@@ -0,0 +1,69 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))
+
+((variable
+  (name) @_name
+  value: (string) @injection.content)
+  (#any-of? @_name "cmd" "command" "textconv" "sendmailCmd" "sendmailcmd")
+  (#set! injection.language "bash"))
+
+(section
+  (variable
+    (name) @_name
+    value: (string) @injection.content)
+  (#eq? @_name "tool")
+  (#set! injection.language "bash"))
+
+(section
+  (section_header
+    (section_name) @_pager)
+  (variable
+    value: (string) @injection.content)
+  (#eq? @_pager "pager")
+  (#set! injection.language "bash"))
+
+(section
+  (section_header
+    (section_name) @_interactive)
+  (variable
+    (name) @_name
+    value: (string) @injection.content)
+  (#eq? @_interactive "interactive")
+  (#any-of? @_name "diffFilter" "difffilter")
+  (#set! injection.language "bash"))
+
+; https://github.com/git-lfs/git-lfs
+; git lfs install
+(section
+  (section_header
+    (section_name) @_filter
+    (subsection_name) @_lfs)
+  (variable
+    (name) @_name
+    value: (string) @injection.content)
+  (#eq? @_filter "filter")
+  (#eq? @_lfs "lfs")
+  (#any-of? @_name "smudge" "process" "clean")
+  (#set! injection.language "bash"))
+
+(section
+  (section_header
+    (section_name) @_alias)
+  (variable
+    value: (string) @injection.content)
+  (#eq? @_alias "alias")
+  (#lua-match? @injection.content "^!")
+  (#offset! @injection.content 0 1 0 0)
+  (#set! injection.language "bash"))
+
+(section
+  (section_header
+    (section_name) @_alias)
+  (variable
+    value: (string
+      "\""
+      "\"") @injection.content)
+  (#eq? @_alias "alias")
+  (#lua-match? @injection.content "^\"!")
+  (#offset! @injection.content 0 2 0 -1)
+  (#set! injection.language "bash"))

package/out/git_rebase/highlights.scm

@@ -0,0 +1,36 @@
+; a rough translation:
+; * constant.builtin - git hash
+; * constant - a git label
+; * keyword - command that acts on commits commits
+; * function - command that acts only on labels
+; * comment - discarded commentary on a command, has no effect on the rebase
+; * string - text used in the rebase operation
+; * operator - a 'switch' (used in fixup and merge), either -c or -C at time of writing
+
+(((command) @keyword
+  (label) @constant.builtin
+  (message)? @comment)
+ (#match? @keyword "^(p|pick|r|reword|e|edit|s|squash|d|drop)$"))
+
+(((command) @function
+  (label) @constant
+  (message)? @comment)
+ (#match? @function "^(l|label|t|reset)$"))
+
+((command) @keyword
+ (#match? @keyword "^(x|exec|b|break)$"))
+
+(((command) @attribute
+  (label) @constant.builtin
+  (message)? @comment)
+ (#match? @attribute "^(f|fixup)$"))
+
+(((command) @keyword
+  (label) @constant.builtin
+  (label) @constant
+  (message) @string)
+ (#match? @keyword "^(m|merge)$"))
+
+(option) @operator
+
+(comment) @comment

package/out/git_rebase/injections.scm

@@ -0,0 +1,8 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))
+
+((operation
+  (command) @_command
+  (message) @injection.content)
+  (#set! injection.language "bash")
+  (#any-of? @_command "exec" "x"))