ts-wasms 1.1.0 → 2.0.0

package/out/yaml/highlights.scm

@@ -0,0 +1,79 @@
+(boolean_scalar) @boolean
+
+(null_scalar) @constant.builtin
+
+[
+  (double_quote_scalar)
+  (single_quote_scalar)
+  (block_scalar)
+  (string_scalar)
+] @string
+
+[
+  (integer_scalar)
+  (float_scalar)
+] @number
+
+(comment) @comment
+
+[
+  (anchor_name)
+  (alias_name)
+] @label
+
+(tag) @type
+
+[
+  (yaml_directive)
+  (tag_directive)
+  (reserved_directive)
+] @attribute
+
+(block_mapping_pair
+  key: (flow_node
+    [
+      (double_quote_scalar)
+      (single_quote_scalar)
+    ] @property))
+
+(block_mapping_pair
+  key: (flow_node
+    (plain_scalar
+      (string_scalar) @property)))
+
+(flow_mapping
+  (_
+    key: (flow_node
+      [
+        (double_quote_scalar)
+        (single_quote_scalar)
+      ] @property)))
+
+(flow_mapping
+  (_
+    key: (flow_node
+      (plain_scalar
+        (string_scalar) @property))))
+
+[
+  ","
+  "-"
+  ":"
+  ">"
+  "?"
+  "|"
+] @punctuation.delimiter
+
+[
+  "["
+  "]"
+  "{"
+  "}"
+] @punctuation.bracket
+
+[
+  "*"
+  "&"
+  "---"
+  "..."
+] @punctuation.special

package/out/yaml/indents.scm

@@ -0,0 +1,7 @@
+[
+  (block_mapping_pair
+    value: (block_node))
+  (block_sequence_item)
+] @indent.begin
+
+(ERROR) @indent.auto

package/out/yaml/injections.scm

@@ -0,0 +1,81 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))
+
+; Github actions ("run") / Gitlab CI ("scripts")
+; Taskfile scripts ("cmds", "cmd", "sh")
+(block_mapping_pair
+  key: (flow_node) @_run
+  (#any-of? @_run "run" "script" "before_script" "after_script" "cmds" "cmd" "sh")
+  value: (flow_node
+    (plain_scalar
+      (string_scalar) @injection.content)
+    (#set! injection.language "bash")))
+
+(block_mapping_pair
+  key: (flow_node) @_run
+  (#any-of? @_run "run" "script" "before_script" "after_script" "cmds" "cmd" "sh")
+  value: (block_node
+    (block_scalar) @injection.content
+    (#set! injection.language "bash")
+    (#offset! @injection.content 0 1 0 0)))
+
+(block_mapping_pair
+  key: (flow_node) @_run
+  (#any-of? @_run "run" "script" "before_script" "after_script" "cmds" "sh")
+  value: (block_node
+    (block_sequence
+      (block_sequence_item
+        (flow_node
+          (plain_scalar
+            (string_scalar) @injection.content))
+        (#set! injection.language "bash")))))
+
+(block_mapping_pair
+  key: (flow_node) @_run
+  (#any-of? @_run "script" "before_script" "after_script" "cmds" "sh")
+  value: (block_node
+    (block_sequence
+      (block_sequence_item
+        (block_node
+          (block_scalar) @injection.content
+          (#set! injection.language "bash")
+          (#offset! @injection.content 0 1 0 0))))))
+
+; Prometheus Alertmanager ("expr")
+(block_mapping_pair
+  key: (flow_node) @_expr
+  (#eq? @_expr "expr")
+  value: (flow_node
+    (plain_scalar
+      (string_scalar) @injection.content)
+    (#set! injection.language "promql")))
+
+(block_mapping_pair
+  key: (flow_node) @_expr
+  (#eq? @_expr "expr")
+  value: (block_node
+    (block_scalar) @injection.content
+    (#set! injection.language "promql")
+    (#offset! @injection.content 0 1 0 0)))
+
+(block_mapping_pair
+  key: (flow_node) @_expr
+  (#eq? @_expr "expr")
+  value: (block_node
+    (block_sequence
+      (block_sequence_item
+        (flow_node
+          (plain_scalar
+            (string_scalar) @injection.content))
+        (#set! injection.language "promql")))))
+
+(block_mapping_pair
+  key: (flow_node) @_expr
+  (#eq? @_expr "expr")
+  value: (block_node
+    (block_sequence
+      (block_sequence_item
+        (block_node
+          (block_scalar) @injection.content
+          (#set! injection.language "promql")
+          (#offset! @injection.content 0 1 0 0))))))

package/out/yaml/locals.scm

@@ -0,0 +1,9 @@
+[
+  (stream)
+  (document)
+  (block_node)
+] @local.scope
+
+(anchor_name) @local.definition
+
+(alias_name) @local.reference

package/out/zig/locals.scm

@@ -0,0 +1,96 @@
+; Definitions
+(function_declaration
+  name: (identifier) @local.definition.function)
+
+(parameter
+  name: (identifier) @local.definition.parameter)
+
+(variable_declaration
+  (identifier) @local.definition.var)
+
+(variable_declaration
+  (identifier) @local.definition.type
+  (enum_declaration))
+
+(container_field
+  type: (identifier) @local.definition.field)
+
+(enum_declaration
+  (function_declaration
+    name: (identifier) @local.definition.method))
+
+(variable_declaration
+  (identifier) @local.definition.type
+  (struct_declaration))
+
+(struct_declaration
+  (function_declaration
+    name: (identifier) @local.definition.method))
+
+(container_field
+  name: (identifier) @local.definition.field)
+
+(variable_declaration
+  (identifier) @local.definition.type
+  (union_declaration))
+
+(union_declaration
+  (function_declaration
+    name: (identifier) @local.definition.method))
+
+(payload
+  (identifier) @local.definition.var)
+
+(block_label
+  (identifier) @local.definition)
+
+; References
+(identifier) @local.reference
+
+(parameter
+  type: (identifier) @local.reference
+  (#set! reference.kind "type"))
+
+(pointer_type
+  (identifier) @local.reference
+  (#set! reference.kind "type"))
+
+(nullable_type
+  (identifier) @local.reference
+  (#set! reference.kind "type"))
+
+(struct_initializer
+  (identifier) @local.reference
+  (#set! reference.kind "type"))
+
+(array_type
+  (_)
+  (identifier) @local.reference
+  (#set! reference.kind "type"))
+
+(slice_type
+  (identifier) @local.reference
+  (#set! reference.kind "type"))
+
+(field_expression
+  member: (identifier) @local.reference
+  (#set! reference.kind "field"))
+
+(call_expression
+  function: (field_expression
+    member: (identifier) @local.reference
+    (#set! reference.kind "function")))
+
+(break_label
+  (identifier) @local.reference)
+
+[
+  (for_statement)
+  (if_statement)
+  (while_statement)
+  (function_declaration)
+  (block)
+  (source_file)
+  (enum_declaration)
+  (struct_declaration)
+] @local.scope

package/package.json

@@ -1,6 +1,6 @@
 {
   "name": "ts-wasms",
-  "version": "1.1.0",
+  "version": "2.0.0",
   "description": "Pre-built WebAssembly binaries for tree-sitter grammars.",
   "keywords": [
     "incremental",
@@ -12,15 +12,24 @@
   "bugs": {
     "url": "https://github.com/Crysthamus/ts-wasms/issues"
   },
-  "repository": {
-    "type": "git",
-    "url": "git+https://github.com/Crysthamus/ts-wasms.git"
-  },
+  "repository": "Crysthamus/ts-wasms",
   "author": "Crysthamus",
   "license": "MIT",
   "type": "module",
+  "main": "index.js",
+  "types": "index.d.ts",
+  "exports": {
+    ".": {
+      "types": "./index.d.ts",
+      "import": "./index.js",
+      "default": "./index.js"
+    },
+    "./*": "./out/*"
+  },
   "files": [
-    "out"
+    "out",
+    "index.js",
+    "index.d.ts"
   ],
   "devEngines": {
     "packageManager": {
@@ -42,36 +51,58 @@
     "@tree-sitter-grammars/tree-sitter-xml": "^0.7.0",
     "@tree-sitter-grammars/tree-sitter-zig": "^1.1.2",
     "p-map": "^7.0.4",
+    "tree-sitter-angular": "^0.9.2",
+    "tree-sitter-asm": "git+https://github.com/RubixDev/tree-sitter-asm.git#839741fef4dab5128952334624905c82b40c7133",
+    "tree-sitter-astro": "git+https://github.com/virchau13/tree-sitter-astro.git#213f6e6973d9b456c6e50e86f19f66877e7ef0ee",
     "tree-sitter-bash": "^0.25.1",
     "tree-sitter-c": "^0.24.1",
     "tree-sitter-c-sharp": "^0.23.5",
     "tree-sitter-cli": "^0.26.8",
-    "tree-sitter-clojure": "git+https://github.com/sogaiu/tree-sitter-clojure.git",
-    "tree-sitter-commonlisp": "git+https://github.com/tree-sitter-grammars/tree-sitter-commonlisp.git",
+    "tree-sitter-clojure": "git+https://github.com/sogaiu/tree-sitter-clojure.git#e43eff80d17cf34852dcd92ca5e6986d23a7040f",
+    "tree-sitter-cmake": "git+https://github.com/uyha/tree-sitter-cmake.git#c7b2a71e7f8ecb167fad4c97227c838439280175",
+    "tree-sitter-comment": "^0.3.0",
+    "tree-sitter-commonlisp": "git+https://github.com/tree-sitter-grammars/tree-sitter-commonlisp.git#32323509b3d9fe96607d151c2da2c9009eb13a2f",
     "tree-sitter-cpp": "^0.23.4",
     "tree-sitter-css": "^0.25.0",
+    "tree-sitter-csv": "git+https://github.com/tree-sitter-grammars/tree-sitter-csv.git#f6bf6e35eb0b95fbadea4bb39cb9709507fcb181",
     "tree-sitter-dart": "^1.0.0",
+    "tree-sitter-diff": "git+https://github.com/tree-sitter-grammars/tree-sitter-diff.git#2520c3f934b3179bb540d23e0ef45f75304b5fed",
+    "tree-sitter-dockerfile": "git+https://github.com/camdencheek/tree-sitter-dockerfile.git#971acdd908568b4531b0ba28a445bf0bb720aba5",
+    "tree-sitter-editorconfig": "git+https://github.com/ValdezFOmar/tree-sitter-editorconfig.git#bfd74395e393f56ba58db953458b346f02d6f7b2",
     "tree-sitter-elisp": "^1.6.1",
     "tree-sitter-elixir": "^0.3.5",
     "tree-sitter-embedded-template": "^0.25.0",
-    "tree-sitter-erlang": "git+https://github.com/WhatsApp/tree-sitter-erlang.git",
+    "tree-sitter-erlang": "git+https://github.com/WhatsApp/tree-sitter-erlang.git#e446ec60022a7cafe157805742b41c04b499cc5d",
+    "tree-sitter-fish": "git+https://github.com/ram02z/tree-sitter-fish.git#f435b0bd772578c70e5d158b85267bb886316f88",
+    "tree-sitter-gdscript": "^6.1.0",
+    "tree-sitter-gdshader": "git+https://github.com/airblast-dev/tree-sitter-gdshader.git#68268631c8b6dc093985f1246b099f81b30ea7d1",
+    "tree-sitter-git-config": "git+https://github.com/the-mikedavis/tree-sitter-git-config.git#0fbc9f99d5a28865f9de8427fb0672d66f9d83a5",
+    "tree-sitter-git-rebase": "git+https://github.com/the-mikedavis/tree-sitter-git-rebase.git#39bf3b7566c86ccffd70aaa5105c7c8b76788975",
+    "tree-sitter-gitattributes": "^0.1.6",
+    "tree-sitter-gitignore": "git+https://github.com/shunsambongi/tree-sitter-gitignore.git#f4685bf11ac466dd278449bcfe5fd014e94aa504",
     "tree-sitter-go": "^0.25.0",
-    "tree-sitter-graphql": "git+https://github.com/joowani/tree-sitter-graphql.git",
+    "tree-sitter-godot-resource": "^0.7.0",
+    "tree-sitter-graphql": "git+https://github.com/joowani/tree-sitter-graphql.git#df5b88d1d24dcfc02e64919d2d20491359abe4c8",
+    "tree-sitter-groovy": "git+https://github.com/murtaza64/tree-sitter-groovy.git#deb0dcf8c4544f07564060f6e9b9f6e4b0bfc27d",
     "tree-sitter-haskell": "^0.23.1",
     "tree-sitter-html": "^0.23.2",
+    "tree-sitter-ini": "git+https://github.com/justinmk/tree-sitter-ini.git#e4018b5176132b4f3c5d6e61cea383f42288d0f5",
     "tree-sitter-java": "^0.23.5",
     "tree-sitter-javascript": "^0.25.0",
     "tree-sitter-json": "^0.24.8",
-    "tree-sitter-julia": "git+https://github.com/tree-sitter/tree-sitter-julia.git",
+    "tree-sitter-julia": "git+https://github.com/tree-sitter/tree-sitter-julia.git#e0f9dcd180fdcfcfa8d79a3531e11d99e79321d3",
     "tree-sitter-kotlin": "^0.3.8",
-    "tree-sitter-nix": "git+https://github.com/nix-community/tree-sitter-nix.git",
+    "tree-sitter-matlab": "git+https://github.com/acristoffers/tree-sitter-matlab.git#c2390a59016f74e7d5f75ef09510768b4f30217e",
+    "tree-sitter-nim": "git+https://github.com/alaviss/tree-sitter-nim.git#3878440d9398515ae053c6f6024986e69868bb74",
+    "tree-sitter-nix": "git+https://github.com/nix-community/tree-sitter-nix.git#69fbfb02896cdd27cb7ff3cd61f7f3f6bde4f017",
     "tree-sitter-objc": "^3.0.2",
     "tree-sitter-ocaml": "^0.24.2",
     "tree-sitter-perl": "git+https://github.com/tree-sitter-perl/tree-sitter-perl.git#release",
     "tree-sitter-php": "^0.24.2",
-    "tree-sitter-prisma": "git+https://github.com/victorhqc/tree-sitter-prisma.git",
+    "tree-sitter-prisma": "^1.6.0",
     "tree-sitter-python": "^0.25.0",
-    "tree-sitter-query": "git+https://github.com/tree-sitter-grammars/tree-sitter-query.git",
+    "tree-sitter-qmljs": "^0.3.0",
+    "tree-sitter-query": "git+https://github.com/tree-sitter-grammars/tree-sitter-query.git#fc5409c6820dd5e02b0b0a309d3da2bfcde2db17",
     "tree-sitter-regex": "^0.25.0",
     "tree-sitter-ruby": "^0.23.1",
     "tree-sitter-rust": "^0.24.0",
@@ -79,9 +110,10 @@
     "tree-sitter-scss": "^1.0.0",
     "tree-sitter-swift": "^0.7.1",
     "tree-sitter-typescript": "^0.23.2",
-    "tree-sitter-vimdoc": "git+https://github.com/neovim/tree-sitter-vimdoc.git",
-    "tree-sitter-vue": "^0.2.1",
-    "tree-sitter-yaml": "git+https://github.com/ikatyang/tree-sitter-yaml.git"
+    "tree-sitter-vim": "git+https://github.com/tree-sitter-grammars/tree-sitter-vim.git#3092fcd99eb87bbd0fc434aa03650ba58bd5b43b",
+    "tree-sitter-vimdoc": "git+https://github.com/neovim/tree-sitter-vimdoc.git#f061895a0eff1d5b90e4fb60d21d87be3267031a",
+    "tree-sitter-vue": "git+https://github.com/tree-sitter-grammars/tree-sitter-vue.git#ce8011a414fdf8091f4e4071752efc376f4afb08",
+    "tree-sitter-yaml": "git+https://github.com/tree-sitter-grammars/tree-sitter-yaml.git#a1c4812a73ec5e089de8e441fdea3a921e8d5079"
   },
   "scripts": {
     "build": "node build.js",