ts-wasms 1.1.0 → 2.0.0

package/README.md

@@ -1,16 +1,31 @@
-# ts-wasms
-Prebuilt WASM binaries for tree-sitter's language parsers.
-You can find a list of supported packages [here](https://app.unpkg.com/ts-wasms/files/out)
+# ts-wasms [![npm version](https://img.shields.io/npm/v/ts-wasms.svg?style=flat-square)](https://www.npmjs.com/package/ts-wasms)
+Prebuilt WASM binaries and query files(`.scm`) for tree-sitter's language parsers.
+You can find a list of supported languages [here](https://app.unpkg.com/ts-wasms/files/out)
 
 ## Installation
 ```bash
+npm install ts-wasms
+# or
 pnpm add ts-wasms
+# or
+yarn add ts-wasms
+# or
+bun install ts-wasms
 ```
 
 ## Usage
-```ts
-import pythonWasm from "ts-wasms/out/python/tree-sitter-python.wasm"
-import pythonHighlights from "ts-wasms/out/python/highlights.scm"
+A type-safe API is provided for accessing grammars and queries at runtime
+```typescript
+import { getWasmPath, getQueryPath } from "ts-wasms";
+
+const wasmPath = getWasmPath("python");
+const queryPath = getQueryPath("python", "highlights");
+```
+
+You can also import the assets directly via your bundler
+```typescript
+import wasmUrl from "ts-wasms/python/tree-sitter-python.wasm?url";
+import wasmHighlights from "ts-wasms/python/highlights.scm?raw";
 ```
 
 Each language directory includes a `tree-sitter-<lang>.wasm` file but may also include:
@@ -22,12 +37,14 @@ Each language directory includes a `tree-sitter-<lang>.wasm` file but may also i
 - `indents.scm`
 
 ```txt
-out/python/
+python/
 ├── tree-sitter-python.wasm
 ├── highlights.scm
 └── tags.scm
 ```
 
 ## Licenses
-Licenses belong to their respective upstream grammar authors, however this repo is MIT licensed.
-(If you have a problem with this licensing, please open an issue.)
+The licenses for the generated .wasm and .scm files belong to their respective upstream grammar authors and can be found on their github repos.
+
+The code in this repository is licensed under MIT.
+If you maintain an upstream grammar and have a problem with this licensing, please open an issue.

package/index.d.ts

@@ -0,0 +1,102 @@
+/** Standard Tree-sitter query categories */
+export type TreeSitterQuery =
+    | "highlights"
+    | "injections"
+    | "locals"
+    | "tags"
+    | "folds"
+    | "indents";
+
+/** Supported language identifiers compiled during build step */
+export type SupportedLanguage =
+    | "angular"
+    | "asm"
+    | "astro"
+    | "bash"
+    | "c"
+    | "c-sharp"
+    | "clojure"
+    | "cmake"
+    | "comment"
+    | "commonlisp"
+    | "cpp"
+    | "css"
+    | "csv"
+    | "csv-psv"
+    | "csv-tsv"
+    | "dart"
+    | "diff"
+    | "dockerfile"
+    | "dtd"
+    | "editorconfig"
+    | "elisp"
+    | "elixir"
+    | "elm"
+    | "embedded-template"
+    | "erlang"
+    | "fish"
+    | "gdscript"
+    | "gdshader"
+    | "git-config"
+    | "git-rebase"
+    | "gitattributes"
+    | "gitignore"
+    | "go"
+    | "godot-resource"
+    | "graphql"
+    | "groovy"
+    | "haskell"
+    | "hcl"
+    | "html"
+    | "ini"
+    | "java"
+    | "javascript"
+    | "json"
+    | "julia"
+    | "kotlin"
+    | "lua"
+    | "markdown"
+    | "markdown-inline"
+    | "matlab"
+    | "nim"
+    | "nix"
+    | "objc"
+    | "ocaml"
+    | "ocaml-interface"
+    | "ocaml-type"
+    | "perl"
+    | "php"
+    | "php-only"
+    | "prisma"
+    | "python"
+    | "qmljs"
+    | "query"
+    | "r"
+    | "racket"
+    | "regex"
+    | "ruby"
+    | "rust"
+    | "scala"
+    | "scheme"
+    | "scss"
+    | "sql"
+    | "swift"
+    | "terraform"
+    | "toml"
+    | "tsx"
+    | "typescript"
+    | "vim"
+    | "vimdoc"
+    | "vue"
+    | "xml"
+    | "yaml"
+    | "zig";
+
+/** Resolves the absolute path to a specific language's WASM file. */
+export declare function getWasmPath(lang: SupportedLanguage): string;
+
+/** Resolves the absolute path to a specific language's query file. */
+export declare function getQueryPath(
+    lang: SupportedLanguage,
+    query: TreeSitterQuery,
+): string;

package/index.js

@@ -0,0 +1,27 @@
+import { fileURLToPath } from "node:url";
+
+/**
+ * Resolves the absolute path to a specific language's WASM file.
+ *
+ * @param {string} lang
+ * @returns {string}
+ */
+export function getWasmPath(lang) {
+	const url = new URL(
+		`./out/${lang}/tree-sitter-${lang}.wasm`,
+		import.meta.url,
+	);
+	return fileURLToPath(url);
+}
+
+/**
+ * Resolves the absolute path to a specific language's query file.
+ *
+ * @param {string} lang
+ * @param {string} query
+ * @returns {string}
+ */
+export function getQueryPath(lang, query) {
+	const url = new URL(`./out/${lang}/${query}.scm`, import.meta.url);
+	return fileURLToPath(url);
+}

package/out/angular/folds.scm

@@ -0,0 +1 @@
+; inherits: html

package/out/angular/highlights.scm

@@ -0,0 +1,178 @@
+; inherits: html
+
+(identifier) @variable
+
+(style_unit) @variable
+
+(pipe_operator) @operator
+
+(string) @string
+
+(number) @number
+
+(pipe_call
+  name: (identifier) @function)
+
+(pipe_call
+  arguments: (pipe_arguments
+    (identifier) @variable.parameter))
+
+(structural_directive
+  "*" @keyword
+  (identifier) @keyword)
+
+(attribute
+  (attribute_name) @variable.member
+  (#lua-match? @variable.member "#.*"))
+
+(binding_name
+  (identifier) @keyword)
+
+(class_binding
+  [
+    (identifier)
+    (class_name)
+  ] @keyword)
+
+(event_binding
+  (binding_name
+    (identifier) @keyword))
+
+(event_binding
+  "\"" @punctuation.delimiter)
+
+(property_binding
+  [
+   "\""
+   "\"\""
+  ] @punctuation.delimiter)
+
+(structural_assignment
+  operator: (identifier) @keyword)
+
+(member_expression
+  property: (identifier) @property)
+
+(call_expression
+  function: (identifier) @function)
+
+(call_expression
+  function: ((identifier) @function.builtin
+    (#eq? @function.builtin "$any")))
+
+(pair
+  key: ((identifier) @variable.builtin
+    (#eq? @variable.builtin "$implicit")))
+
+[
+  (control_keyword)
+  (special_keyword)
+] @keyword
+
+((control_keyword) @keyword.repeat
+  (#any-of? @keyword.repeat "for" "empty"))
+
+((control_keyword) @keyword.conditional
+  (#any-of? @keyword.conditional "if" "else" "switch" "case" "default"))
+
+((control_keyword) @keyword.coroutine
+  (#any-of? @keyword.coroutine "defer" "placeholder" "loading"))
+
+((control_keyword) @keyword.exception
+  (#eq? @keyword.exception "error"))
+
+((identifier) @boolean
+  (#any-of? @boolean "true" "false"))
+
+((identifier) @variable.builtin
+  (#any-of? @variable.builtin "this" "$event"))
+
+((identifier) @constant.builtin
+  (#eq? @constant.builtin "null"))
+
+[
+  (ternary_operator)
+  (conditional_operator)
+] @keyword.conditional.ternary
+
+[
+  "("
+  ")"
+  "["
+  "]"
+  "{"
+  "}"
+  "@"
+] @punctuation.bracket
+
+(two_way_binding
+  [
+    "[("
+    ")]"
+  ] @punctuation.bracket)
+
+[
+  "{{"
+  "}}"
+] @punctuation.special
+
+(template_substitution
+  [
+    "${"
+    "}"
+  ] @punctuation.special)
+
+(template_chars) @string
+
+[
+  ";"
+  "."
+  ","
+  "?."
+  "!."
+] @punctuation.delimiter
+
+(nullish_coalescing_expression
+  (coalescing_operator) @operator)
+
+(concatenation_expression
+  "+" @operator)
+
+(icu_clause) @keyword.operator
+
+(icu_category) @keyword.conditional
+
+(binary_expression
+  [
+    "-"
+    "&&"
+    "+"
+    "<"
+    "<="
+    "="
+    "=="
+    "==="
+    "!="
+    "!=="
+    ">"
+    ">="
+    "*"
+    "/"
+    "||"
+    "%"
+  ] @operator)
+
+(arrow_function
+  "=>" @operator)
+
+(object
+  (spread
+    "..." @operator))
+
+(array
+  (spread
+    "..." @operator))
+
+(arguments
+  (spread
+    "..." @operator))

package/out/angular/indents.scm

@@ -0,0 +1,16 @@
+; inherits: html
+
+[
+  (statement_block)
+  (switch_statement)
+] @indent.begin
+
+(statement_block
+  "{" @indent.branch)
+
+(statement_block
+  "}" @indent.end)
+
+"}" @indent.branch
+
+"}" @indent.end

package/out/angular/injections.scm

@@ -0,0 +1 @@
+; inherits: html

package/out/angular/locals.scm

@@ -0,0 +1 @@
+; inherits: html

package/out/asm/highlights.scm

@@ -0,0 +1,66 @@
+; General
+(label
+  [
+    (ident)
+    (word)
+  ] @label)
+
+(reg) @variable.builtin
+
+(meta
+  kind: (_) @function.builtin)
+
+(instruction
+  kind: (_) @function.builtin)
+
+(const
+  name: (word) @constant)
+
+; Comments
+[
+  (line_comment)
+  (block_comment)
+] @comment @spell
+
+; Literals
+(int) @number
+
+(float) @number.float
+
+(string) @string
+
+; Keywords
+[
+  "byte"
+  "word"
+  "dword"
+  "qword"
+  "ptr"
+  "rel"
+  "label"
+  "const"
+] @keyword
+
+; Operators & Punctuation
+[
+  "+"
+  "-"
+  "*"
+  "/"
+  "%"
+  "|"
+  "^"
+  "&"
+] @operator
+
+[
+  "("
+  ")"
+  "["
+  "]"
+] @punctuation.bracket
+
+[
+  ","
+  ":"
+] @punctuation.delimiter

package/out/asm/injections.scm

@@ -0,0 +1,5 @@
+([
+  (line_comment)
+  (block_comment)
+] @injection.content
+  (#set! injection.language "comment"))

package/out/astro/folds.scm

@@ -0,0 +1 @@
+; inherits: html

package/out/astro/highlights.scm

@@ -0,0 +1,12 @@
+(tag_name) @tag
+(erroneous_end_tag_name) @tag.error
+(doctype) @constant
+(attribute_name) @attribute
+(attribute_value) @string
+(comment) @comment
+
+[
+  "<"
+  ">"
+  "</"
+] @punctuation.bracket

package/out/astro/indents.scm

@@ -0,0 +1 @@
+; inherits: html

package/out/astro/injections.scm

@@ -0,0 +1,27 @@
+(frontmatter
+  (frontmatter_js_block) @injection.content
+  (#set! injection.language "typescript"))
+
+(attribute_interpolation
+  (attribute_js_expr) @injection.content
+  (#set! injection.language "typescript"))
+
+; TODO proper queries for html_interpolation highlighting
+(html_interpolation
+  (permissible_text) @injection.content
+  (#set! injection.language "typescript"))
+
+(script_element
+  (raw_text) @injection.content
+  (#set! injection.language "typescript"))
+
+(style_element
+  (start_tag
+    (attribute
+      (attribute_name) @_lang_attr
+      (quoted_attribute_value
+        (attribute_value) @_lang_value)))
+  (raw_text) @injection.content
+  (#eq? @_lang_attr "lang")
+  (#eq? @_lang_value "scss")
+  (#set! injection.language "scss"))

package/out/astro/locals.scm

@@ -0,0 +1 @@
+; inherits: html

package/out/bash/folds.scm

@@ -0,0 +1,9 @@
+[
+  (function_definition)
+  (if_statement)
+  (case_statement)
+  (for_statement)
+  (while_statement)
+  (c_style_for_statement)
+  (heredoc_redirect)
+] @fold

package/out/bash/indents.scm

@@ -0,0 +1,32 @@
+[
+  (if_statement)
+  (for_statement)
+  (while_statement)
+  (case_statement)
+  (function_definition)
+  (compound_statement)
+  (subshell)
+  (command_substitution)
+  (do_group)
+  (case_item)
+] @indent.begin
+
+[
+  "fi"
+  "done"
+  "esac"
+  "}"
+  ")"
+  "then"
+  "do"
+  (elif_clause)
+  (else_clause)
+] @indent.branch
+
+[
+  "fi"
+  "done"
+  "esac"
+  "}"
+  ")"
+] @indent.end

package/out/bash/injections.scm

@@ -0,0 +1,90 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))
+
+((regex) @injection.content
+  (#set! injection.language "regex"))
+
+(heredoc_redirect
+  (heredoc_body) @injection.content
+  (heredoc_end) @injection.language)
+
+; printf 'format'
+((command
+  name: (command_name) @_command
+  .
+  argument: [
+    (string) @injection.content
+    (concatenation
+      (string) @injection.content)
+    (raw_string) @injection.content
+    (concatenation
+      (raw_string) @injection.content)
+  ])
+  (#eq? @_command "printf")
+  (#offset! @injection.content 0 1 0 -1)
+  (#set! injection.include-children)
+  (#set! injection.language "printf"))
+
+; printf -v var 'format'
+((command
+  name: (command_name) @_command
+  argument: (word) @_arg
+  .
+  (_)
+  .
+  argument: [
+    (string) @injection.content
+    (concatenation
+      (string) @injection.content)
+    (raw_string) @injection.content
+    (concatenation
+      (raw_string) @injection.content)
+  ])
+  (#eq? @_command "printf")
+  (#eq? @_arg "-v")
+  (#offset! @injection.content 0 1 0 -1)
+  (#set! injection.include-children)
+  (#set! injection.language "printf"))
+
+; printf -- 'format'
+((command
+  name: (command_name) @_command
+  argument: (word) @_arg
+  .
+  argument: [
+    (string) @injection.content
+    (concatenation
+      (string) @injection.content)
+    (raw_string) @injection.content
+    (concatenation
+      (raw_string) @injection.content)
+  ])
+  (#eq? @_command "printf")
+  (#eq? @_arg "--")
+  (#offset! @injection.content 0 1 0 -1)
+  (#set! injection.include-children)
+  (#set! injection.language "printf"))
+
+((command
+  name: (command_name) @_command
+  .
+  argument: [
+    (string)
+    (raw_string)
+  ] @injection.content)
+  (#eq? @_command "bind")
+  (#offset! @injection.content 0 1 0 -1)
+  (#set! injection.include-children)
+  (#set! injection.language "readline"))
+
+((command
+  name: (command_name) @_command
+  .
+  argument: [
+    (string)
+    (raw_string)
+  ] @injection.content)
+  (#eq? @_command "trap")
+  (#offset! @injection.content 0 1 0 -1)
+  (#set! injection.include-children)
+  (#set! injection.self))

package/out/bash/locals.scm

@@ -0,0 +1,14 @@
+; Scopes
+(function_definition) @local.scope
+
+; Definitions
+(variable_assignment
+  name: (variable_name) @local.definition.var)
+
+(function_definition
+  name: (word) @local.definition.function)
+
+; References
+(variable_name) @local.reference
+
+(word) @local.reference

package/out/c/folds.scm

@@ -0,0 +1,23 @@
+[
+  (for_statement)
+  (if_statement)
+  (while_statement)
+  (do_statement)
+  (switch_statement)
+  (case_statement)
+  (function_definition)
+  (struct_specifier)
+  (enum_specifier)
+  (comment)
+  (preproc_if)
+  (preproc_elif)
+  (preproc_else)
+  (preproc_ifdef)
+  (preproc_function_def)
+  (initializer_list)
+  (gnu_asm_expression)
+  (preproc_include)+
+] @fold
+
+(compound_statement
+  (compound_statement) @fold)