rooibos-roku 4.4.2

package/dist/lib/framework/Test.bs

@@ -0,0 +1,109 @@
+namespace rooibos
+  class Test
+
+    public name
+    public isSolo
+    public noCatch = false
+    public funcName
+    public isIgnored
+    public lineNumber
+    public paramLineNumber
+    public testSuite = invalid
+    public testGroup = invalid
+
+    public rawParams
+    public paramTestIndex
+    public isParamTest = false
+    public isParamsValid = false
+    public expectedNumberOfParams = 0
+
+    public result = invalid
+
+    function new(testGroup, data)
+      m.testGroup = testGroup
+      m.testSuite = testGroup.testSuite
+      m.isSolo = data.isSolo
+      m.noCatch = data.noCatch
+      m.funcName = data.funcName
+      m.isIgnored = data.isIgnored
+      m.name = data.name
+      m.lineNumber = data.lineNumber
+      m.paramLineNumber = data.paramLineNumber
+      m.rawParams = data.rawParams
+      m.paramTestIndex = data.paramTestIndex
+      m.isParamTest = data.isParamTest
+      m.expectedNumberOfParams = data.expectedNumberOfParams
+
+      if m.isParamTest
+        m.name = m.name + stri(m.paramTestIndex)
+      end if
+
+      m.result = new TestResult(m)
+      return this
+    end function
+
+    function run()
+      timer = createObject("roTimespan")
+      timer.mark()
+
+      if m.isParamTest
+        m.runParamsTest()
+      else
+        m.testSuite[m.funcName]()
+      end if
+
+      m.result.time = timer.totalMilliseconds()
+
+    end function
+
+    function runParamsTest()
+      testParams = m.getTestParams()
+
+      if m.expectedNumberOfParams = 1
+        m.testSuite[m.funcName](testParams[0])
+      else if m.expectedNumberOfParams = 2
+        m.testSuite[m.funcName](testParams[0], testParams[1])
+      else if m.expectedNumberOfParams = 3
+        m.testSuite[m.funcName](testParams[0], testParams[1], testParams[2])
+      else if m.expectedNumberOfParams = 4
+        m.testSuite[m.funcName](testParams[0], testParams[1], testParams[2], testParams[3])
+      else if m.expectedNumberOfParams = 5
+        m.testSuite[m.funcName](testParams[0], testParams[1], testParams[2], testParams[3], testParams[4])
+      else if m.expectedNumberOfParams = 6
+        m.testSuite[m.funcName](testParams[0], testParams[1], testParams[2], testParams[3], testParams[4], testParams[5])
+      else if m.expectedNumberOfParams = 7
+        m.testSuite[m.funcName](testParams[0], testParams[1], testParams[2], testParams[3], testParams[4], testParams[5], testParams[6])
+      else if m.expectedNumberOfParams = 8
+        m.testSuite[m.funcName](testParams[0], testParams[1], testParams[2], testParams[3], testParams[4], testParams[5], testParams[6], testParams[7])
+      else if m.expectedNumberOfParams = 9
+        m.testSuite[m.funcName](testParams[0], testParams[1], testParams[2], testParams[3], testParams[4], testParams[5], testParams[6], testParams[7], testParams[8])
+      else if m.expectedNumberOfParams = 10
+        m.testSuite[m.funcName](testParams[0], testParams[1], testParams[2], testParams[3], testParams[4], testParams[5], testParams[6], testParams[7], testParams[8], testParams[9])
+      else if m.expectedNumberOfParams = 11
+        m.testSuite[m.funcName](testParams[0], testParams[1], testParams[2], testParams[3], testParams[4], testParams[5], testParams[6], testParams[7], testParams[8], testParams[9], testParams[10])
+      else if m.expectedNumberOfParams = 12
+        m.testSuite[m.funcName](testParams[0], testParams[1], testParams[2], testParams[3], testParams[4], testParams[5], testParams[6], testParams[7], testParams[8], testParams[9], testParams[10], testParams[11])
+      else if m.expectedNumberOfParams > 12
+        m.testSuite.fail("Test case had more than 12 params. Max of 12 params is supported")
+      end if
+    end function
+
+    function getTestParams()
+      params = []
+      for paramIndex = 0 to m.rawParams.count()
+        paramValue = m.rawParams[paramIndex]
+        if type(paramValue) = "roString" and len(paramValue) >= 8 and left(paramValue, 8) = "#RBSNode"
+          nodeType = "ContentNode"
+          paramDirectiveArgs = paramValue.split("|")
+          if paramDirectiveArgs.count() > 1
+            nodeType = paramDirectiveArgs[1]
+          end if
+          paramValue = createObject("roSGNode", nodeType)
+        end if
+        params.push(paramValue)
+      end for
+      return params
+    end function
+
+  end class
+end namespace

package/dist/lib/framework/TestGroup.bs

@@ -0,0 +1,109 @@
+namespace rooibos
+  ' /**
+  '  * @module TestSuite
+  '  * @description All brs files that include `'@TestSuite` annotations automatically extend the TestSuite.
+  '  * The base test suite contains all of the assertions, and utility methods required to write our tests, as well as being responsible for tracking the state of the tests and groups.
+  '  */
+  class TestGroup
+    'test state
+    name = "Unnamed Suite"
+
+    testSuite = invalid
+    setupFunctionName = invalid
+    tearDownFunctionName = invalid
+    beforeEachFunctionName = invalid
+    afterEachFunctionName = invalid
+    isSolo = false
+    isLegacy = false
+    isIgnored = false
+    stats = invalid
+    scene = invalid
+    lineNumber = 00
+    top = invalid
+    valid = false
+    hasFailures = false
+    isNodeTest = false
+    nodeName = invalid
+    testsData = invalid
+    tests = []
+
+    function new(testSuite, data)
+      m.testSuite = testSuite
+      m.name = data.name
+      m.valid = data.valid
+      m.hasFailures = testSuite.hasFailures
+      m.isSolo = data.isSolo
+      m.isIgnored = data.isIgnored
+      m.testsData = data.testCases
+      m.isNodeTest = false
+      m.nodeName = invalid
+      m.setupFunctionName = data.setupFunctionName
+      m.tearDownFunctionName = data.tearDownFunctionName
+      m.beforeEachFunctionName = data.beforeEachFunctionName
+      m.afterEachFunctionName = data.afterEachFunctionName
+      m.lineNumber = data.lineNumber
+
+      'bs:disable-next-line
+      m.global = testSuite.global
+      m.top = testSuite.top
+      m.scene = testSuite.scene
+      m.stats = new Stats()
+    end function
+
+    '+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
+    '++ running
+    '+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
+
+    function run()
+      isOk = m.runSuiteFunction(m.setupFunctionName, "setup")
+
+      if isOk
+        for each testData in m.testsData
+          test = new Test(m, testData)
+          m.tests.push(test)
+
+          isOk = m.runSuiteFunction(m.beforeEachFunctionName, "beforeEach", test)
+
+          if isOk
+            m.testSuite.runTest(test)
+          end if
+
+          m.runSuiteFunction(m.afterEachFunctionName, "afterEach", test)
+
+          m.stats.appendTestResult(test.result)
+
+          if m.stats.hasFailures and m.testSuite.isFailingFast
+            ? "Terminating group due to failed test"
+            exit for
+          end if
+        end for
+      else
+        ? "ERROR running test setup function"
+      end if
+      m.runSuiteFunction(m.tearDownFunctionName, "tearDown")
+    end function
+
+    private function runSuiteFunction(methodName, defaultMethodName, test = invalid)
+
+      if methodName = invalid or methodName = ""
+        methodName = defaultMethodName
+      end if
+      if m.testSuite.catchCrashes and not m.testSuite.noCatch and not (test <> invalid and test.noCatch)
+        try
+          m.testSuite[methodName]()
+          return true
+        catch error
+          if test <> invalid
+            test.result.crash("function " + methodName + "crashed!", error)
+          end if
+        end try
+      else
+        m.testSuite[methodName]()
+        return true
+      end if
+
+      return false
+    end function
+
+  end class
+end namespace

package/dist/lib/framework/TestResult.bs

@@ -0,0 +1,74 @@
+namespace rooibos
+  class TestResult
+
+    public isFail = false
+    public isCrash = false
+    public message = ""
+    public lineNumber = -1
+    public test = invalid
+    public time = 0
+    public error = invalid
+
+    function new(test)
+      m.test = test
+    end function
+
+    function reset() as void
+      m.isFail = false
+      m.isCrash = false
+      m.time = 0
+      m.message = ""
+      m.lineNumber = -1
+    end function
+
+    function fail(message as string, lineNumber = -1)
+      if message <> "" and not m.isFail
+        if not m.isFail
+          m.lineNumber = lineNumber
+          m.isFail = true
+          m.message = message
+        end if
+      end if
+    end function
+
+    function crash(message as string, error)
+      if message <> "" and not m.isCrash
+        if not m.isCrash
+          m.error = error
+          m.message = "test crashed!"
+          m.isFail = true
+          m.isCrash = true
+        end if
+      end if
+    end function
+
+    function getMessage() as string
+      if m.isFail
+        if m.message <> invalid
+          return m.message
+        else
+          return "unknown test failure"
+        end if
+      else if m.isCrash
+        if m.message <> invalid
+          return m.message
+        else
+          return "unknown test crash"
+        end if
+      else
+        return ""
+      end if
+    end function
+
+    function getStatusText()
+      if m.isCrash
+        return "CRASH"
+      else if m.isFail
+        return "FAIL"
+      else
+        return "PASS"
+      end if
+    end function
+
+  end class
+end namespace

package/dist/lib/framework/TestRunner.bs

@@ -0,0 +1,187 @@
+namespace rooibos
+  ' /**
+  '  * @module TestRunner
+  '  */
+
+  ' /**
+  '  * @memberof module:TestRunner
+  '  * @name Rooibos_TestRunner
+  '  * @function
+  '  * @description Creates an instance of the test runner
+  '  */
+  class TestRunner
+    public testScene = invalid
+    public testReporter = invalid
+    public nodeContext = invalid
+    public config = invalid
+    public testSuites = []
+    private runtimeConfig = invalid
+    private stats = invalid
+    private top = invalid
+
+    public function new(testScene, nodeContext)
+      m.testScene = testScene
+      if nodeContext.top = invalid
+        nodeContext.top = testScene
+      end if
+      nodeContext.scene = testScene
+
+      m.nodeContext = nodeContext
+
+      m.stats = new Stats()
+      m.runtimeConfig = new RuntimeConfig()
+      m.config = m.runtimeConfig.getRuntimeConfig()
+      'TODO - allow providing different reporters via config
+      m.testReporter = new Rooibos.ConsoleTestReporter(m)
+    end function
+
+    ' /**
+    '  * @memberof module:TestRunner
+    '  * @name Run
+    '  * @function
+    '  * @instance
+    '  * @description Executes all tests for a project, as per the config
+    '  */
+    public function run()
+
+      timer = createObject("roTimespan")
+      timer.mark()
+      suiteNames = m.runtimeConfig.getAllTestSuitesNames()
+      includedSuites = []
+      for each name in suiteNames
+        'bs:disable-next-line
+        suiteClass = m.runtimeConfig.getTestSuiteClassWithName(name)
+        testSuite = invalid
+        if suiteClass <> invalid
+          testSuite = suiteClass()
+          testSuite.global = m.nodeContext.global
+          testSuite.context = m.nodeContext
+          testSuite.top = m.nodeContext.top
+          testSuite.scene = m.nodeContext.global.testsScene
+          testSuite.catchCrashes = m.config.catchCrashes
+          m.runTestSuite(testSuite)
+          if m.stats.hasFailures = true and m.config.failFast = true
+            exit for
+          end if
+        else
+          ? "ERROR! could not create test for suite : "; name
+        end if
+      end for
+
+      m.stats.time = timer.totalMilliseconds()
+
+      m.testReporter.reportResults(m.stats)
+
+      'code coverage is not enabled in rooibos 4.0.0 - will get added again in future
+      ' if Rooibos.Common.isFunction(RBS_reportCodeCoverage)
+      '   'bs:disable-next-line
+      '   RBS_reportCodeCoverage()
+
+      '   if m.config.printLcov = true
+      '     Coverage.printLCovInfo()
+      '   end if
+      ' end if
+      m.sendHomeKeypress()
+    end function
+
+    public function runInNodeMode(nodeTestName)
+      'bs:disable-next-line
+      suiteClass = m.getTestSuiteClassWithName(nodeTestName)
+      testSuite = invalid
+
+      if suiteClass <> invalid
+        testSuite = suiteClass(m.top)
+      end if
+
+      if testSuite <> invalid
+        testSuite.run()
+        return {
+          stats: testSuite.stats
+          tests: testSuite.tests
+        }
+      else
+        ? "[ERROR] could not create test suite " ; nodeTestName
+      end if
+
+      ? "ERROR! executing node test " + nodeTestName + " was unsuccesful."
+
+      return invalid
+    end function
+
+    private function runTestSuite(testSuite) as void
+      if testSuite.groupsData <> invalid and testSuite.groupsData.count() > 0
+        ? ""
+        ? Rooibos.Common.fillText("> SUITE: " + testSuite.name, ">", 80)
+        m.testSuites.push(testSuite)
+
+        if testSuite.isNodeTest
+          m.runNodeTest(testSuite)
+        else
+          testSuite.run()
+        end if
+
+        m.stats.merge(testSuite.stats)
+      end if
+    end function
+
+    private function runNodeTest(testSuite) as void
+      if testSuite.generatedNodeName <> ""
+        ? " +++++RUNNING NODE TEST"
+        ? " node type is " ; testSuite.generatedNodeName
+
+        node = m.testScene.createChild(testSuite.generatedNodeName)
+
+        if type(node) = "roSGNode"
+          nodeResults = node.rooibosTestResult
+          if nodeResults <> invalid
+            testSuite.stats = nodeResults.stats
+            testSuite.testCases = nodeResults.testCases
+          else
+            ? " ERROR! The node test"; testSuite.name; " did not return a result from from the rooibos_runNodeTestSuite method. This usually means you are not importing rooibos.brs and the required test file. Please refer to : https://github.com/georgejecook/rooibos/blob/master/docs/index.md#testing-scenegraph-nodes"
+          end if
+          m.testScene.removeChild(node)
+          return
+
+        else
+          ? " ERROR!! - could not create node required to execute tests for " ; testSuite.name
+          ? " Node of type " ; testSuite.generatedNodeName ; " was not found/could not be instantiated"
+        end if
+
+      else
+        ? " ERROR!! - could not create node required to execute tests for " ; testSuite.name
+        ? " No node type was provided"
+      end if
+
+      testSuite.stats.hasFailures = true
+      testSuite.failedCount += testSuite.testsData.count()
+    end function
+
+    private function sendHomeKeypress()
+      ut = createObject("roUrlTransfer")
+      ut.SetUrl("http://localhost:8060/keypress/Home")
+      ut.PostFromString("")
+    end function
+
+  end class
+
+  '+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
+  '++ This code is called inside of the node
+  '+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
+
+  function createTestNode(nodeType) as object
+    node = createObject("roSGNode", nodeType)
+
+    if type(node) = "roSGNode" and node.subType() = nodeType
+      m.top.AppendChild(node)
+      return node
+    else
+      ? " Error creating test node of type " ; nodeType
+      return invalid
+    end if
+  end function
+
+  function runNodeTestSuite(name)
+    nodeRunner = new TestRunner(m.top.getScene(), m)
+    return nodeRunner.runInNodeMode(name)
+  end function
+end namespace