rooibos-roku 4.4.2

package/dist/lib/framework/ConsoleTestReporter.bs

@@ -0,0 +1,200 @@
+namespace rooibos
+  class ConsoleTestReporter extends rooibos.BaseTestReporter
+
+    private lineWidth = 60
+
+    function new(testRunner)
+      super(testRunner)
+      if m.config.lineWidth <> invalid
+        m.lineWidth = m.config.lineWidth
+      else
+        m.lineWidth = 60
+      end if
+    end function
+
+    override function reportResults(allStats)
+      m.allStats = allStats
+      m.startReport()
+
+      for each testSuite in m.testRunner.testSuites
+        if not m.allStats.hasFailures or ((not m.config.showOnlyFailures) or testSuite.stats.failedCount > 0 or testSuite.stats.crashedCount > 0)
+          m.printSuiteStart(testSuite)
+
+          for each testGroup in testSuite.groups
+            m.printGroup(testGroup)
+          end for
+        end if
+      end for
+
+      m.printLine()
+
+      'bs:disable-next-line
+      ignoredInfo = m.testRunner.runtimeConfig.getIgnoredTestInfo()
+      m.printLine(0, "Total: " + Rooibos.Common.AsString(m.allStats.ranCount))
+      m.printLine(0, "  Passed: " + Rooibos.Common.AsString(m.allStats.passedCount))
+      m.printLine(0, "  Crashed: " + Rooibos.Common.AsString(m.allStats.crashedCount))
+      m.printLine(0, "  Failed: " + Rooibos.Common.AsString(m.allStats.failedCount))
+      m.printLine(0, "  Ignored: " + Rooibos.Common.AsString(ignoredInfo.count))
+      m.printLine(0, "  Time: " + Rooibos.Common.AsString(m.allStats.time) + "ms")
+      m.printLine()
+      m.printLine()
+
+      if ignoredInfo.count > 0
+        m.printLine(0, "IGNORED TESTS:")
+        for each ignoredItemName in ignoredInfo.items
+          m.printLine(1, ignoredItemName)
+        end for
+        m.printLine()
+        m.printLine()
+      end if
+
+      if m.allStats.hasFailures
+        overrallResult = "Fail"
+      else
+        overrallResult = "Success"
+      end if
+      m.printLine(0, "RESULT: " + overrallResult)
+      m.endReport()
+    end function
+
+    function printGroup(testGroup)
+      isGroupPrinted = false
+
+      for each test in testGroup.tests
+        if not m.allStats.hasFailures or ((not m.config.showOnlyFailures) or test.result.isFail)
+          if not isGroupPrinted
+            m.printGroupStart(testGroup)
+            isGroupPrinted = true
+          end if
+
+          m.printTest(test)
+        end if
+      end for
+
+      if isGroupPrinted
+        m.printLine(0, " |")
+      end if
+    end function
+
+    function printTest(test)
+
+      testLocationLine = StrI(test.lineNumber).trim()
+
+      locationLine = invalid
+      if test.result.isCrash
+        testChar = "|"
+        locationLine = StrI(test.lineNumber).trim()
+      else if test.result.isFail
+        testChar = "-"
+        locationLine = StrI(test.result.lineNumber + 1).trim()
+      else
+        testChar = "|"
+        locationLine = StrI(test.lineNumber).trim()
+      end if
+
+      testLocationText = "file://" + test.testSuite.filePath.trim() + ":" + testLocationLine
+
+      if m.config.printTestTimes = true
+        timeText = " (" + stri(test.result.time).trim() + "ms)"
+      else
+        timeText = ""
+      end if
+
+      insetText = ""
+      if test.isParamTest <> true
+        messageLine = Rooibos.Common.fillText(" " + testChar + " |--" + test.name + " : ", ".", m.lineWidth)
+        m.printLine(0, messageLine + test.result.getStatusText() + timeText)
+        m.printLine(0, " | " + insettext + "  |--Test : " + testLocationText)
+      else if test.paramTestIndex = 0
+        name = test.name
+        if len(name) > 1 and right(name, 1) = "0"
+          name = left(name, len(name) - 1)
+        end if
+        m.printLine(0, " " + testChar + " |--" + name + " : ")
+        m.printLine(0, " | " + insettext + "  |--Test : " + testLocationText)
+      end if
+
+      locationText = "file://" + test.testSuite.filePath.trim() + ":" + locationLine
+      if test.isParamTest = true
+        insetText = "  "
+
+        if type(test.rawParams) = "roAssociativeArray"
+          rawParams = {}
+          for each key in test.rawParams
+            if type(test.rawParams[key]) <> "Function" and type(test.rawParams[key]) <> "roFunction"
+              rawParams[key] = test.rawParams[key]
+            end if
+          end for
+        else
+          rawParams = test.rawParams
+        end if
+        messageLine = Rooibos.Common.fillText(" " + testChar + insetText + " |--" + formatJson(rawParams) + " : ", ".", m.lineWidth)
+        m.printLine(0, messageLine + test.result.getStatusText() + timeText)
+      end if
+
+      if test.result.isCrash
+        m.printLine(0, " | " + insettext + "  |--Crashed at: " + locationText)
+        m.printStackTrace(insettext, test.result.error)
+        m.printLine(0, " | ")
+      else if test.result.isFail
+        m.printLine(0, " | " + insettext + "  |--Failed at: " + locationText)
+        if test.isParamTest = true
+          m.printLine(0, " | " + insettext + "  |--Param Line: " + StrI(test.paramLineNumber - 1).trim())
+        end if
+        m.printLine(0, " | " + insettext + "  |--Error Message: " + test.result.message)
+        m.printLine(0, " | ")
+      end if
+    end function
+
+    function printStackTrace(insettext, error)
+      m.printLine(0, " | " + insettext + "  |")
+      m.printLine(0, " | " + insettext + "  |--Message: " + error.message)
+      m.printLine(0, " | " + insettext + "  |--Stack trace: ")
+
+      for i = error.backTrace.count() - 1 to 0 step -1
+        e = error.backTrace[i]
+        if e.filename.instr("pkg:/source/rooibos") = -1
+          m.printLine(0, " | " + insettext + "    " + e.filename + "(" + stri(e.line_number).trim() + ")")
+        end if
+      end for
+    end function
+
+    function startReport()
+      m.printLine()
+      m.printLine(0, "[START TEST REPORT]")
+      m.printLine()
+    end function
+
+    function endReport()
+      m.printLine()
+      m.printLine(0, "[END TEST REPORT]")
+      m.printLine()
+    end function
+
+    function printSuiteStart(testSuite)
+      m.printLine(0, " " + testSuite.name + " file://" + testSuite.filePath.trim() + ":" + str(testSuite.lineNumber).trim())
+
+    end function
+
+    function printGroupStart(testGroup)
+      m.printLine(0, " |-" + testGroup.name)
+    end function
+
+    '+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
+    '++ printing
+    '+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
+
+    override function testLogInfo(text)
+      ? "INFO " ; text
+    end function
+
+    override function testLogError(text)
+      ? "ERROR " ; text
+    end function
+
+    function printLine(depth = 0, text = "")
+      ? " " ; text
+    end function
+
+  end class
+end namespace

package/dist/lib/framework/Coverage.bs

@@ -0,0 +1,51 @@
+namespace rooibos.Coverage
+
+'   function createLCovOutput()
+'     ? "Generating lcov.info file..."
+
+'     cc = m.global._rbs_ccn
+'     expectedMap = cc.expectedMap
+'     filePathMap = cc.filePathMap
+'     resolvedMap = cc.resolvedMap
+
+'     buffer = ""
+
+'     for each module in filePathMap.items()
+'       moduleNumber = module.key
+'       filePath = module.value
+'       packageName = "."
+
+'       relativePath = filePath.replace("pkg:", packageName)
+'       sanitizedPath = relativePath.replace("\\", "/")
+
+'       buffer = buffer + "TN:" + chr(10)
+'       buffer = buffer + "SF:" + sanitizedPath + chr(10)
+
+'       for each expected in expectedMap[moduleNumber]
+'         lineNumber = expected[0]
+'         SHIFT = 1
+
+'         if resolvedMap[moduleNumber] <> invalid and resolvedMap[moduleNumber].doesExist(str(lineNumber)) then
+'           buffer = buffer + "DA:" + str(lineNumber + SHIFT) + ",1" + chr(10)
+'         else
+'           buffer = buffer + "DA:" + str(lineNumber + SHIFT) + ",0" + chr(10)
+'         end if
+'       end for
+
+'       buffer = buffer + "end_of_record" + chr(10)
+'     end for
+'     return buffer
+'   end function
+
+'   function printLCovInfo()
+'     ?
+'     ? "+++++++++++++++++++++++++++++++++++++++++++"
+'     ? "LCOV.INFO FILE"
+'     ? "+++++++++++++++++++++++++++++++++++++++++++"
+'     ?
+'     ? "+-=-coverage:start"
+'     ? Coverage.createLCovOutput()
+'     ? "+-=-coverage:end"
+'   end function
+
+end namespace

package/dist/lib/framework/Matchers.bs

@@ -0,0 +1,28 @@
+namespace rooibos.Matcher
+
+  function anyString(value)
+    return Rooibos.Common.isString(value)
+  end function
+
+  function anyBool(value)
+    return Rooibos.Common.isBoolean(value)
+  end function
+
+  function anyNumber(value)
+    return Rooibos.Common.isNumber(value)
+  end function
+
+  function anyAA(value)
+    return Rooibos.Common.isAssociativeArray(value)
+  end function
+
+  function anyArray(value)
+    return Rooibos.Common.isArray(value)
+  end function
+
+  function anyNode(value)
+    return Rooibos.Common.isSGNode(value)
+  end function
+
+
+end namespace

package/dist/lib/framework/Rooibos.bs

@@ -0,0 +1,83 @@
+namespace rooibos
+  function init() as void
+    args = {}
+    if createObject("roAPPInfo").IsDev() <> true then
+      ? " not running in dev mode! - rooibos tests only support sideloaded builds - aborting"
+      return
+    end if
+
+    screen = CreateObject("roSGScreen")
+    m.port = CreateObject("roMessagePort")
+    screen.setMessagePort(m.port)
+    testSceneName = "TestsScene"
+
+    ? "Starting test using test scene with name TestsScene" ; testSceneName
+    scene = screen.CreateScene(testSceneName)
+    scene.id = "ROOT"
+    screen.show()
+
+    m.global = screen.getGlobalNode()
+    m.global.addFields({ "testsScene": scene })
+
+    if scene.hasField("isReadyToStartTests") and scene.isReadyToStartTests = false
+      ? "The scene is not ready yet - waiting for it to set isReadyToStartTests to true"
+      scene.observeField("isReadyToStartTests", m.port)
+
+    else
+      ? "scene is ready; running tests now"
+      runner = new TestRunner(scene, m)
+      runner.Run()
+    end if
+
+    while(true)
+      msg = wait(0, m.port)
+      msgType = type(msg)
+      if msgType = "roSGScreenEvent"
+        if msg.isScreenClosed()
+          return
+        end if
+      else if msgType = "roSGNodeEvent"
+
+        if msg.getField() = "isReadyToStartTests" and msg.getData() = true
+          ? "scene is ready; running tests now"
+          runner = new TestRunner(scene, m)
+          runner.Run()
+        end if
+      end if
+    end while
+  end function
+
+  function versionCompare(v1, v2)
+    v1parts = v1.split(".")
+    v2parts = v2.split(".")
+
+    while v1parts.count() < v2parts.count()
+      v1parts.push("0")
+    end while
+
+    while v2parts.count() < v1parts.count()
+      v2parts.push("0")
+    end while
+
+    for i = 0 to v1parts.count() - 1
+      if v2parts.count() = i
+        return 1
+      end if
+
+      if v1parts[i] <> v2parts[i]
+        if v1parts[i] > v2parts[i]
+          return 1
+        else
+          return -1
+        end if
+      end if
+    end for
+
+    if v1parts.count() <> v2parts.count()
+      return -1
+    end if
+
+    return 0
+
+  end function
+end namespace

package/dist/lib/framework/RooibosScene.xml

@@ -0,0 +1,50 @@
+<component
+    name='TestsScene'
+    extends='Scene'>
+  <interface>
+    <function name='Rooibos_CreateTestNode' />
+  </interface>
+
+  <!-- <script
+      type='text/brighterscript'
+      uri='source/rooibos/BaseTestSuite.bs' />
+  <script
+      type='text/brighterscript'
+      uri='source/rooibos/CommonUtils.bs' />
+  <script
+      type='text/brighterscript'
+      uri='source/rooibos/Coverage.bs' />
+  <script
+      type='text/brighterscript'
+      uri='source/rooibos/Matchers.bs' />
+  <script
+      type='text/brighterscript'
+      uri='source/rooibos/Rooibos.bs' />
+  <script
+      type='text/brighterscript'
+      uri='source/rooibos/RuntimeConfig.bs' />
+  <script
+      type='text/brighterscript'
+      uri='source/rooibos/Stats.bs' />
+  <script
+      type='text/brighterscript'
+      uri='source/rooibos/Test.bs' />
+  <script
+      type='text/brighterscript'
+      uri='source/rooibos/TestGroup.bs' />
+  <script
+      type='text/brighterscript'
+      uri='source/rooibos/TestLogger.bs' />
+  <script
+      type='text/brighterscript'
+      uri='source/rooibos/TestResult.bs' />
+  <script
+      type='text/brighterscript'
+      uri='source/rooibos/TestRunner.bs' /> -->
+
+  <children>
+    <LayoutGroup>
+      <Label text='Rooibos tests are running' />
+    </LayoutGroup>
+  </children>
+</component>

package/dist/lib/framework/RuntimeConfig.bs

@@ -0,0 +1,20 @@
+namespace rooibos
+  class RuntimeConfig
+
+    function getVersionText()
+    end function
+
+    function getRuntimeConfig()
+    end function
+
+    function getTestSuiteClassWithName(name)
+    end function
+
+    function getAllTestSuitesNames()
+    end function
+
+    function getIgnoredTestInfo()
+    end function
+
+  end class
+end namespace

package/dist/lib/framework/Stats.bs

@@ -0,0 +1,46 @@
+namespace rooibos
+  class Stats
+    public time = 0
+    public ranCount = 0
+    public passedCount = 0
+    public failedCount = 0
+    public crashedCount = 0
+    public ignoredCount = 0
+    public ignoredTestNames = []
+    public hasFailures = false
+    public testResult = invalid
+
+    function new()
+    end function
+
+    function merge(other) as void
+      m.time += other.time
+      m.ranCount += other.ranCount
+      m.passedCount += other.passedCount
+      m.failedCount += other.failedCount
+      m.crashedCount += other.crashedCount
+      m.ignoredCount += other.ignoredCount
+      m.ignoredTestNames.append(other.IgnoredTestNames)
+      m.onUpdate()
+    end function
+
+    function appendTestResult(result)
+      m.time += result.time
+      m.ranCount++
+      if result.isCrash
+        m.crashedCount++
+      else if result.isFail
+        m.failedCount++
+      else
+        m.passedCount++
+      end if
+
+      m.onUpdate()
+    end function
+
+    function onUpdate()
+      m.hasFailures = m.failedCount > 0 or m.crashedCount > 0
+    end function
+
+  end class
+end namespace