react-native-enriched-html 0.0.0 → 1.1.0-nightly-20260617-3dfd09072

package/ios/internals/EnrichedTextViewShadowNode.h

@@ -0,0 +1,34 @@
+#pragma once
+#include <ReactNativeEnrichedHtml/EnrichedTextViewState.h>
+#include <ReactNativeEnrichedHtml/EventEmitters.h>
+#include <ReactNativeEnrichedHtml/Props.h>
+#include <jsi/jsi.h>
+#include <react/renderer/components/view/ConcreteViewShadowNode.h>
+#include <react/renderer/core/LayoutConstraints.h>
+
+namespace facebook::react {
+
+JSI_EXPORT extern const char EnrichedTextViewComponentName[];
+
+class EnrichedTextViewShadowNode
+    : public ConcreteViewShadowNode<
+          EnrichedTextViewComponentName, EnrichedTextViewProps,
+          EnrichedTextViewEventEmitter, EnrichedTextViewState> {
+public:
+  using ConcreteViewShadowNode::ConcreteViewShadowNode;
+  Size
+  measureContent(const LayoutContext &layoutContext,
+                 const LayoutConstraints &layoutConstraints) const override;
+
+  static ShadowNodeTraits BaseTraits() {
+    auto traits = ConcreteViewShadowNode::BaseTraits();
+    traits.set(ShadowNodeTraits::Trait::LeafYogaNode);
+    traits.set(ShadowNodeTraits::Trait::MeasurableYogaNode);
+    return traits;
+  }
+
+private:
+  id setupMockTextView_() const;
+};
+
+} // namespace facebook::react

package/ios/internals/EnrichedTextViewShadowNode.mm

@@ -0,0 +1,72 @@
+#import "EnrichedTextViewShadowNode.h"
+#import "CoreText/CoreText.h"
+#import <EnrichedTextView.h>
+#import <React/RCTShadowView+Layout.h>
+#import <react/utils/ManagedObjectWrapper.h>
+
+namespace facebook::react {
+
+extern const char EnrichedTextViewComponentName[] = "EnrichedTextView";
+
+id EnrichedTextViewShadowNode::setupMockTextView_() const {
+  const int veryFarAway = 20000;
+  const int mockSize = 1000;
+  EnrichedTextView *mockView = [[EnrichedTextView alloc]
+      initWithFrame:(CGRectMake(veryFarAway, veryFarAway, mockSize, mockSize))];
+  const auto props = this->getProps();
+  [mockView updateProps:props oldProps:nullptr];
+  return mockView;
+}
+
+Size EnrichedTextViewShadowNode::measureContent(
+    const LayoutContext &layoutContext,
+    const LayoutConstraints &layoutConstraints) const {
+  const auto state = this->getStateData();
+  const auto componentRef = state.getComponentViewRef();
+  RCTInternalGenericWeakWrapper *weakWrapper =
+      (RCTInternalGenericWeakWrapper *)unwrapManagedObject(componentRef);
+
+  if (weakWrapper != nullptr) {
+    id componentObject = weakWrapper.object;
+    EnrichedTextView *typedComponentObject =
+        (EnrichedTextView *)componentObject;
+
+    if (typedComponentObject != nullptr) {
+      __block CGSize estimatedSize;
+
+      if ([NSThread isMainThread]) {
+        estimatedSize = [typedComponentObject
+            measureSize:layoutConstraints.maximumSize.width];
+      } else {
+        dispatch_sync(dispatch_get_main_queue(), ^{
+          estimatedSize = [typedComponentObject
+              measureSize:layoutConstraints.maximumSize.width];
+        });
+      }
+
+      return {estimatedSize.width,
+              MIN(estimatedSize.height, layoutConstraints.maximumSize.height)};
+    }
+  } else {
+    __block CGSize estimatedSize;
+
+    if ([NSThread isMainThread]) {
+      EnrichedTextView *mockView = setupMockTextView_();
+      estimatedSize =
+          [mockView measureSize:layoutConstraints.maximumSize.width];
+    } else {
+      dispatch_sync(dispatch_get_main_queue(), ^{
+        EnrichedTextView *mockView = setupMockTextView_();
+        estimatedSize =
+            [mockView measureSize:layoutConstraints.maximumSize.width];
+      });
+    }
+
+    return {estimatedSize.width,
+            MIN(estimatedSize.height, layoutConstraints.maximumSize.height)};
+  }
+
+  return Size();
+}
+
+} // namespace facebook::react

package/ios/internals/EnrichedTextViewState.cpp

@@ -0,0 +1,7 @@
+#include "EnrichedTextViewState.h"
+
+namespace facebook::react {
+std::shared_ptr<void> EnrichedTextViewState::getComponentViewRef() const {
+  return componentViewRef_;
+}
+} // namespace facebook::react

package/ios/internals/EnrichedTextViewState.h

@@ -0,0 +1,18 @@
+#pragma once
+#include <memory>
+
+namespace facebook::react {
+
+class EnrichedTextViewState {
+public:
+  EnrichedTextViewState() : componentViewRef_(nullptr) {}
+  explicit EnrichedTextViewState(std::shared_ptr<void> ref) {
+    componentViewRef_ = ref;
+  }
+  std::shared_ptr<void> getComponentViewRef() const;
+
+private:
+  std::shared_ptr<void> componentViewRef_{};
+};
+
+} // namespace facebook::react

package/ios/styles/AlignmentStyle.mm

@@ -0,0 +1,203 @@
+#import "AlignmentUtils.h"
+#import "StyleHeaders.h"
+#import "TextListsUtils.h"
+
+@implementation AlignmentStyle
+
++ (StyleType)getType {
+  return Alignment;
+}
+
+- (NSString *)getValue {
+  return @"EnrichedAlignmentNatural";
+}
+
+- (NSString *)getMarkerPrefix {
+  return @"EnrichedAlignment";
+}
+
+- (BOOL)isParagraph {
+  return YES;
+}
+
+- (BOOL)appliesStylingToTyping {
+  return YES;
+}
+
+- (void)toggle:(NSRange)range {
+  // no-op for alignments
+}
+
+- (void)applyStyling:(NSRange)range {
+  [self.host.textView.textStorage
+      enumerateAttribute:NSParagraphStyleAttributeName
+                 inRange:range
+                 options:0
+              usingBlock:^(id _Nullable value, NSRange subRange,
+                           BOOL *_Nonnull stop) {
+                NSMutableParagraphStyle *pStyle =
+                    [(NSParagraphStyle *)value mutableCopy];
+
+                NSString *marker =
+                    [TextListsUtils
+                        firstTextListWithPrefix:[self getMarkerPrefix]
+                                        inArray:pStyle.textLists]
+                        .markerFormat;
+                NSTextAlignment alignment =
+                    [AlignmentUtils markerToAlignment:marker];
+                pStyle.alignment = alignment;
+                [self.host.textView.textStorage
+                    addAttribute:NSParagraphStyleAttributeName
+                           value:pStyle
+                           range:subRange];
+              }];
+}
+
+- (NSRange)actualUsedRange:(NSRange)range {
+  NSRange paragraphRange =
+      [self.host.textView.textStorage.string paragraphRangeForRange:range];
+  return [self expandRangeToContiguousList:paragraphRange];
+}
+
+- (void)addAlignment:(NSTextAlignment)alignment
+               range:(NSRange)range
+          withTyping:(BOOL)withTyping
+      withDirtyRange:(BOOL)withDirtyRange {
+  NSString *value = [AlignmentUtils alignmentToMarker:alignment];
+
+  [self add:range
+           withValue:value
+          withTyping:withTyping
+      withDirtyRange:withDirtyRange];
+}
+
+- (BOOL)styleCondition:(id)value range:(NSRange)range {
+  NSParagraphStyle *pStyle = (NSParagraphStyle *)value;
+  if (pStyle == nil)
+    return NO;
+  return [TextListsUtils textLists:pStyle.textLists
+                    containsPrefix:[self getMarkerPrefix]];
+}
+
+- (void)reapplyFromStylePair:(StylePair *)pair {
+  NSRange range = [pair.rangeValue rangeValue];
+  NSParagraphStyle *savedPStyle = pair.styleValue;
+  NSString *markerFormat =
+      [TextListsUtils firstTextListWithPrefix:[self getMarkerPrefix]
+                                      inArray:savedPStyle.textLists]
+          .markerFormat;
+  if (markerFormat == nil)
+    return;
+
+  [self add:range withValue:markerFormat withTyping:NO withDirtyRange:NO];
+}
+
+- (NSString *)getStyleState {
+  UITextView *textView = self.host.textView;
+  NSParagraphStyle *paraStyle =
+      textView.typingAttributes[NSParagraphStyleAttributeName];
+
+  NSString *marker =
+      [TextListsUtils firstTextListWithPrefix:[self getMarkerPrefix]
+                                      inArray:paraStyle.textLists]
+          .markerFormat;
+
+  NSTextAlignment currentAlignment = [AlignmentUtils markerToAlignment:marker];
+  return [AlignmentUtils alignmentToString:currentAlignment];
+}
+
+- (void)applyStylingToTypingAttrs:(NSMutableDictionary *)attributes {
+  NSMutableParagraphStyle *pStyle =
+      [attributes[NSParagraphStyleAttributeName] mutableCopy];
+  if (pStyle == nil)
+    return;
+  NSString *marker =
+      [TextListsUtils firstTextListWithPrefix:[self getMarkerPrefix]
+                                      inArray:pStyle.textLists]
+          .markerFormat;
+  NSTextAlignment alignment = [AlignmentUtils markerToAlignment:marker];
+  pStyle.alignment = alignment;
+  attributes[NSParagraphStyleAttributeName] = pStyle;
+}
+
+- (NSRange)expandRangeToContiguousList:(NSRange)range {
+  NSString *text = self.host.textView.textStorage.string;
+  if (text.length == 0)
+    return range;
+
+  NSArray<StyleBase *> *listStyles = @[
+    self.host.stylesDict[@([UnorderedListStyle getType])],
+    self.host.stylesDict[@([OrderedListStyle getType])],
+    self.host.stylesDict[@([CheckboxListStyle getType])]
+  ];
+
+  NSRange expandedRange = range;
+
+  // Expand Backward
+  NSRange startParagraph =
+      [text paragraphRangeForRange:NSMakeRange(range.location, 0)];
+
+  // Find which list style is active at the start
+  StyleBase *activeStartStyle = nil;
+  for (StyleBase *style in listStyles) {
+    if ([style detect:startParagraph]) {
+      activeStartStyle = style;
+      break;
+    }
+  }
+
+  // If we found a list style, walk backwards until it stops
+  if (activeStartStyle) {
+    NSRange currentPara = startParagraph;
+    while (currentPara.location > 0) {
+      // Check the paragraph before the current one
+      NSRange prevPara = [text
+          paragraphRangeForRange:NSMakeRange(currentPara.location - 1, 0)];
+
+      if ([activeStartStyle detect:prevPara]) {
+        // It's still the same list -> Expand our range.
+        expandedRange = NSUnionRange(expandedRange, prevPara);
+        currentPara = prevPara;
+      } else {
+        // The list ended here.
+        break;
+      }
+    }
+  }
+
+  // Expand forward, we check the paragraph at the end of the current selection
+  NSUInteger endLoc =
+      (range.length > 0) ? (NSMaxRange(range) - 1) : range.location;
+  NSRange endParagraph = [text paragraphRangeForRange:NSMakeRange(endLoc, 0)];
+
+  // Find which list style is active at the end
+  StyleBase *activeEndStyle = nil;
+  for (StyleBase *style in listStyles) {
+    if ([style detect:endParagraph]) {
+      activeEndStyle = style;
+      break;
+    }
+  }
+
+  // If we found a list style, walk forwards until it stops
+  if (activeEndStyle) {
+    NSRange currentPara = endParagraph;
+    while (NSMaxRange(currentPara) < text.length) {
+      // Check the paragraph after the current one
+      NSRange nextPara =
+          [text paragraphRangeForRange:NSMakeRange(NSMaxRange(currentPara), 0)];
+
+      if ([activeEndStyle detect:nextPara]) {
+        // It's still the same list -> expand our range.
+        expandedRange = NSUnionRange(expandedRange, nextPara);
+        currentPara = nextPara;
+      } else {
+        break;
+      }
+    }
+  }
+
+  return expandedRange;
+}
+
+@end

package/ios/styles/BlockQuoteStyle.mm

@@ -0,0 +1,54 @@
+#import "ColorExtension.h"
+#import "EnrichedTextInputView.h"
+#import "StyleHeaders.h"
+
+@implementation BlockQuoteStyle
+
++ (StyleType)getType {
+  return BlockQuote;
+}
+
+- (NSString *)getValue {
+  return @"EnrichedBlockQuote";
+}
+
+- (BOOL)isParagraph {
+  return YES;
+}
+
+- (BOOL)needsZWS {
+  return YES;
+}
+
+- (void)applyStyling:(NSRange)range {
+  CGFloat indent = [self.host.config blockquoteBorderWidth] +
+                   [self.host.config blockquoteGapWidth];
+  [self.host.textView.textStorage
+      enumerateAttribute:NSParagraphStyleAttributeName
+                 inRange:range
+                 options:0
+              usingBlock:^(id _Nullable value, NSRange subRange,
+                           BOOL *_Nonnull stop) {
+                NSMutableParagraphStyle *pStyle =
+                    [(NSParagraphStyle *)value mutableCopy];
+                pStyle.headIndent = indent;
+                pStyle.firstLineHeadIndent = indent;
+                [self.host.textView.textStorage
+                    addAttribute:NSParagraphStyleAttributeName
+                           value:pStyle
+                           range:subRange];
+              }];
+
+  UIColor *bqColor = [self.host.config blockquoteColor];
+  [self.host.textView.textStorage addAttribute:NSForegroundColorAttributeName
+                                         value:bqColor
+                                         range:range];
+  [self.host.textView.textStorage addAttribute:NSUnderlineColorAttributeName
+                                         value:bqColor
+                                         range:range];
+  [self.host.textView.textStorage addAttribute:NSStrikethroughColorAttributeName
+                                         value:bqColor
+                                         range:range];
+}
+
+@end

package/ios/styles/BoldStyle.mm

@@ -0,0 +1,37 @@
+#import "EnrichedTextInputView.h"
+#import "FontExtension.h"
+#import "StyleHeaders.h"
+
+@implementation BoldStyle : StyleBase
+
++ (StyleType)getType {
+  return Bold;
+}
+
+- (NSString *)getKey {
+  return @"EnrichedBold";
+}
+
+- (BOOL)isParagraph {
+  return NO;
+}
+
+- (void)applyStyling:(NSRange)range {
+  [self.host.textView.textStorage
+      enumerateAttribute:NSFontAttributeName
+                 inRange:range
+                 options:0
+              usingBlock:^(id _Nullable value, NSRange range,
+                           BOOL *_Nonnull stop) {
+                UIFont *font = (UIFont *)value;
+                if (font != nullptr) {
+                  UIFont *newFont = [font setBold];
+                  [self.host.textView.textStorage
+                      addAttribute:NSFontAttributeName
+                             value:newFont
+                             range:range];
+                }
+              }];
+}
+
+@end

package/ios/styles/CheckboxListStyle.mm

@@ -0,0 +1,154 @@
+#import "EnrichedTextInputView.h"
+#import "RangeUtils.h"
+#import "StyleHeaders.h"
+#import "TextInsertionUtils.h"
+#import "TextListsUtils.h"
+
+@implementation CheckboxListStyle
+
++ (StyleType)getType {
+  return CheckboxList;
+}
+
+- (NSString *)getValue {
+  return @"EnrichedCheckbox0";
+}
+
+- (NSString *)getMarkerPrefix {
+  return @"EnrichedCheckbox";
+}
+
+- (BOOL)isParagraph {
+  return YES;
+}
+
+- (BOOL)needsZWS {
+  return YES;
+}
+
+- (void)applyStyling:(NSRange)range {
+  CGFloat listHeadIndent = [self.host.config checkboxListMarginLeft] +
+                           [self.host.config checkboxListGapWidth] +
+                           [self.host.config checkboxListBoxSize];
+
+  [self.host.textView.textStorage
+      enumerateAttribute:NSParagraphStyleAttributeName
+                 inRange:range
+                 options:0
+              usingBlock:^(id _Nullable value, NSRange range,
+                           BOOL *_Nonnull stop) {
+                NSMutableParagraphStyle *pStyle =
+                    [(NSParagraphStyle *)value mutableCopy];
+                pStyle.headIndent = listHeadIndent;
+                pStyle.firstLineHeadIndent = listHeadIndent;
+                [self.host.textView.textStorage
+                    addAttribute:NSParagraphStyleAttributeName
+                           value:pStyle
+                           range:range];
+              }];
+}
+
+- (BOOL)styleCondition:(id)value range:(NSRange)range {
+  NSParagraphStyle *pStyle = (NSParagraphStyle *)value;
+  if (pStyle == nil)
+    return NO;
+  return [TextListsUtils textLists:pStyle.textLists
+                    containsPrefix:[self getMarkerPrefix]];
+}
+
+- (void)toggleWithChecked:(BOOL)checked range:(NSRange)range {
+  NSRange actualRange = [self actualUsedRange:range];
+  BOOL isPresent = [self detect:actualRange];
+
+  if (isPresent) {
+    [self remove:actualRange withDirtyRange:YES];
+  } else {
+    [self addWithChecked:checked
+                   range:actualRange
+              withTyping:YES
+          withDirtyRange:YES];
+  }
+}
+
+- (void)addWithChecked:(BOOL)checked
+                 range:(NSRange)range
+            withTyping:(BOOL)withTyping
+        withDirtyRange:(BOOL)withDirtyRange {
+  NSString *value = checked ? @"EnrichedCheckbox1" : @"EnrichedCheckbox0";
+  [self add:range
+           withValue:value
+          withTyping:withTyping
+      withDirtyRange:withDirtyRange];
+}
+
+// During dirty range re-application the default add: would use getValue
+// (EnrichedCheckbox0) and lose the checked state. Instead, read the original
+// marker format from the saved StylePair
+- (void)reapplyFromStylePair:(StylePair *)pair {
+  NSRange range = [pair.rangeValue rangeValue];
+  NSParagraphStyle *savedPStyle = (NSParagraphStyle *)pair.styleValue;
+  BOOL checked = [TextListsUtils textLists:savedPStyle.textLists
+                             containsValue:@"EnrichedCheckbox1"];
+  [self addWithChecked:checked range:range withTyping:NO withDirtyRange:NO];
+}
+
+- (void)toggleCheckedAt:(NSUInteger)location
+         withDirtyRange:(BOOL)withDirtyRange {
+  if (location >= self.host.textView.textStorage.length) {
+    return;
+  }
+
+  NSParagraphStyle *pStyle =
+      [self.host.textView.textStorage attribute:NSParagraphStyleAttributeName
+                                        atIndex:location
+                                 effectiveRange:NULL];
+  NSTextList *list =
+      [TextListsUtils firstTextListWithPrefix:[self getMarkerPrefix]
+                                      inArray:pStyle.textLists];
+  BOOL isCurrentlyChecked =
+      [list.markerFormat isEqualToString:@"EnrichedCheckbox1"];
+
+  NSRange paragraphRange = [self.host.textView.textStorage.string
+      paragraphRangeForRange:NSMakeRange(location, 0)];
+
+  [self addWithChecked:!isCurrentlyChecked
+                 range:paragraphRange
+            withTyping:NO
+        withDirtyRange:withDirtyRange];
+}
+
+- (BOOL)getCheckboxStateAt:(NSUInteger)location {
+  if (location >= self.host.textView.textStorage.length) {
+    return NO;
+  }
+
+  NSParagraphStyle *style =
+      [self.host.textView.textStorage attribute:NSParagraphStyleAttributeName
+                                        atIndex:location
+                                 effectiveRange:NULL];
+
+  return [TextListsUtils textLists:style.textLists
+                     containsValue:@"EnrichedCheckbox1"];
+}
+
+- (BOOL)handleNewlinesInRange:(NSRange)range replacementText:(NSString *)text {
+  if ([self detect:self.host.textView.selectedRange] && text.length > 0 &&
+      [[NSCharacterSet newlineCharacterSet]
+          characterIsMember:[text characterAtIndex:text.length - 1]]) {
+    // do the replacement manually
+    [TextInsertionUtils replaceText:text
+                                 at:range
+               additionalAttributes:nullptr
+                               host:self.host
+                      withSelection:YES];
+    // apply unchecked checkbox attributes to the new paragraph
+    [self addWithChecked:NO
+                   range:self.host.textView.selectedRange
+              withTyping:YES
+          withDirtyRange:YES];
+    return YES;
+  }
+  return NO;
+}
+
+@end

package/ios/styles/CodeBlockStyle.mm

@@ -0,0 +1,49 @@
+#import "EnrichedTextInputView.h"
+#import "FontExtension.h"
+#import "StyleHeaders.h"
+
+@implementation CodeBlockStyle
+
++ (StyleType)getType {
+  return CodeBlock;
+}
+
+- (NSString *)getValue {
+  return @"EnrichedCodeBlock";
+}
+
+- (BOOL)isParagraph {
+  return YES;
+}
+
+- (BOOL)needsZWS {
+  return YES;
+}
+
+- (void)applyStyling:(NSRange)range {
+  [self.host.textView.textStorage
+      enumerateAttribute:NSFontAttributeName
+                 inRange:range
+                 options:0
+              usingBlock:^(id _Nullable value, NSRange subRange,
+                           BOOL *_Nonnull stop) {
+                UIFont *currentFont = (UIFont *)value;
+                if (currentFont == nullptr)
+                  return;
+                UIFont *monoFont = [[[self.host.config monospacedFont]
+                    withFontTraits:currentFont] setSize:currentFont.pointSize];
+                if (monoFont != nullptr) {
+                  [self.host.textView.textStorage
+                      addAttribute:NSFontAttributeName
+                             value:monoFont
+                             range:subRange];
+                }
+              }];
+
+  [self.host.textView.textStorage
+      addAttribute:NSForegroundColorAttributeName
+             value:[self.host.config codeBlockFgColor]
+             range:range];
+}
+
+@end

package/ios/styles/EnrichedTextStyles.mm

@@ -0,0 +1,61 @@
+#import "EnrichedTextStyleHeaders.h"
+
+@implementation EnrichedTextBoldStyle
+@end
+
+@implementation EnrichedTextItalicStyle
+@end
+
+@implementation EnrichedTextUnderlineStyle
+@end
+
+@implementation EnrichedTextStrikethroughStyle
+@end
+
+@implementation EnrichedTextInlineCodeStyle
+@end
+
+@implementation EnrichedTextH1Style
+@end
+
+@implementation EnrichedTextH2Style
+@end
+
+@implementation EnrichedTextH3Style
+@end
+
+@implementation EnrichedTextH4Style
+@end
+
+@implementation EnrichedTextH5Style
+@end
+
+@implementation EnrichedTextH6Style
+@end
+
+@implementation EnrichedTextBlockQuoteStyle
+@end
+
+@implementation EnrichedTextCodeBlockStyle
+@end
+
+@implementation EnrichedTextUnorderedListStyle
+@end
+
+@implementation EnrichedTextOrderedListStyle
+@end
+
+@implementation EnrichedTextLinkStyle
+@end
+
+@implementation EnrichedTextMentionStyle
+@end
+
+@implementation EnrichedTextCheckboxListStyle
+@end
+
+@implementation EnrichedTextAlignmentStyle
+@end
+
+@implementation EnrichedTextImageStyle
+@end