react-native-enriched-html 0.0.0 → 1.1.0-nightly-20260617-3dfd09072

package/ios/interfaces/StyleBase.mm

@@ -0,0 +1,279 @@
+#import "StyleBase.h"
+#import "AttributeEntry.h"
+#import "OccurenceUtils.h"
+#import "RangeUtils.h"
+#import "TextListsUtils.h"
+#import "ZeroWidthSpaceUtils.h"
+
+@implementation StyleBase
+
+// This method gets overridden
++ (StyleType)getType {
+  return None;
+}
+
+// This method gets overridden for inline styles
+- (NSString *)getKey {
+  if ([self isParagraph]) {
+    return NSParagraphStyleAttributeName;
+  }
+  return @"NoneAttribute";
+}
+
+// Basic inline styles will use this default value, paragraph styles will
+// override it and parametrised ones completely don't use it
+- (NSString *)getValue {
+  return @"AnyValue";
+}
+
+// Paragraph styles that store a family of mutually exclusive markers (e.g.
+// alignment variants) should override this to return the shared prefix.
+- (NSString *)getMarkerPrefix {
+  return nil;
+}
+
+// This method gets overridden
+- (BOOL)isParagraph {
+  return false;
+}
+
+- (BOOL)needsZWS {
+  return NO;
+}
+
+- (BOOL)appliesStylingToTyping {
+  return NO;
+}
+
+- (instancetype)initWithHost:(id<EnrichedViewHost>)host {
+  self = [super init];
+  _host = host;
+  return self;
+}
+
+// aligns range to whole paragraph for the paragraph stlyes
+- (NSRange)actualUsedRange:(NSRange)range {
+  if (![self isParagraph])
+    return range;
+  return [self.host.textView.textStorage.string paragraphRangeForRange:range];
+}
+
+- (void)toggle:(NSRange)range {
+  NSRange actualRange = [self actualUsedRange:range];
+
+  BOOL isPresent = [self detect:actualRange];
+  if (actualRange.length >= 1) {
+    isPresent ? [self remove:actualRange withDirtyRange:YES]
+              : [self add:actualRange withTyping:YES withDirtyRange:YES];
+  } else {
+    isPresent ? [self removeTyping] : [self addTypingWithValue:[self getValue]];
+  }
+}
+
+- (void)add:(NSRange)range
+        withTyping:(BOOL)withTyping
+    withDirtyRange:(BOOL)withDirtyRange {
+  [self add:range
+           withValue:[self getValue]
+          withTyping:withTyping
+      withDirtyRange:withDirtyRange];
+}
+
+- (void)add:(NSRange)range
+         withValue:(NSString *)value
+        withTyping:(BOOL)withTyping
+    withDirtyRange:(BOOL)withDirtyRange {
+  NSRange actualRange = [self actualUsedRange:range];
+
+  if (![self isParagraph]) {
+    [self.host.textView.textStorage addAttribute:[self getKey]
+                                           value:value
+                                           range:actualRange];
+  } else {
+    [self.host.textView.textStorage
+        enumerateAttribute:NSParagraphStyleAttributeName
+                   inRange:actualRange
+                   options:0
+                usingBlock:^(id _Nullable existingValue, NSRange subRange,
+                             BOOL *_Nonnull stop) {
+                  NSMutableParagraphStyle *pStyle =
+                      [(NSParagraphStyle *)existingValue mutableCopy];
+                  if (pStyle == nullptr)
+                    return;
+                  pStyle.textLists =
+                      [TextListsUtils textListsByAdding:value
+                                    withExclusivePrefix:[self getMarkerPrefix]
+                                                toArray:pStyle.textLists];
+                  [self.host.textView.textStorage
+                      addAttribute:NSParagraphStyleAttributeName
+                             value:pStyle
+                             range:subRange];
+                }];
+  }
+
+  if (withTyping) {
+    [self addTypingWithValue:value];
+  }
+
+  // Notify attributes manager of styling to be re-done if needed.
+  if (withDirtyRange) {
+    [self.host.attributesManager addDirtyRange:actualRange];
+  }
+}
+
+- (void)remove:(NSRange)range withDirtyRange:(BOOL)withDirtyRange {
+  NSRange actualRange = [self actualUsedRange:range];
+
+  if (![self isParagraph]) {
+    [self.host.textView.textStorage removeAttribute:[self getKey]
+                                              range:actualRange];
+  } else {
+    [self.host.textView.textStorage
+        enumerateAttribute:NSParagraphStyleAttributeName
+                   inRange:actualRange
+                   options:0
+                usingBlock:^(id _Nullable existingValue, NSRange subRange,
+                             BOOL *_Nonnull stop) {
+                  NSMutableParagraphStyle *pStyle =
+                      [(NSParagraphStyle *)existingValue mutableCopy];
+                  if (pStyle == nullptr)
+                    return;
+                  pStyle.textLists =
+                      [TextListsUtils textListsByRemoving:[self getValue]
+                                               withPrefix:[self getMarkerPrefix]
+                                                fromArray:pStyle.textLists];
+                  [self.host.textView.textStorage
+                      addAttribute:NSParagraphStyleAttributeName
+                             value:pStyle
+                             range:subRange];
+                }];
+  }
+  [self removeTyping];
+
+  // Notify attributes manager of styling to be re-done if needed.
+  if (withDirtyRange) {
+    [self.host.attributesManager addDirtyRange:actualRange];
+  }
+}
+
+- (void)addTypingWithValue:(NSString *)value {
+  NSMutableDictionary *newTypingAttrs =
+      [self.host.textView.typingAttributes mutableCopy];
+
+  if (![self isParagraph]) {
+    newTypingAttrs[[self getKey]] = value;
+  } else {
+    NSMutableParagraphStyle *pStyle =
+        [newTypingAttrs[NSParagraphStyleAttributeName] mutableCopy];
+    pStyle.textLists = [TextListsUtils textListsByAdding:value
+                                     withExclusivePrefix:[self getMarkerPrefix]
+                                                 toArray:pStyle.textLists];
+    newTypingAttrs[NSParagraphStyleAttributeName] = pStyle;
+  }
+
+  self.host.textView.typingAttributes = newTypingAttrs;
+}
+
+- (void)removeTyping {
+  NSMutableDictionary *newTypingAttrs =
+      [self.host.textView.typingAttributes mutableCopy];
+
+  if (![self isParagraph]) {
+    [newTypingAttrs removeObjectForKey:[self getKey]];
+    // attributes manager also needs to be notified of custom attributes that
+    // shouldn't be extended
+    [self.host.attributesManager didRemoveTypingAttribute:[self getKey]];
+  } else {
+    NSMutableParagraphStyle *pStyle =
+        [newTypingAttrs[NSParagraphStyleAttributeName] mutableCopy];
+    pStyle.textLists = pStyle.textLists =
+        [TextListsUtils textListsByRemoving:[self getValue]
+                                 withPrefix:[self getMarkerPrefix]
+                                  fromArray:pStyle.textLists];
+    newTypingAttrs[NSParagraphStyleAttributeName] = pStyle;
+  }
+
+  self.host.textView.typingAttributes = newTypingAttrs;
+}
+
+// custom styles (e.g. ImageStyle, MentionStyle) will likely need to override
+// this method
+- (BOOL)styleCondition:(id)value range:(NSRange)range {
+  if (![self isParagraph]) {
+    NSString *valueString = (NSString *)value;
+    return valueString != nullptr &&
+           [valueString isEqualToString:[self getValue]];
+  } else {
+    NSParagraphStyle *pStyle = (NSParagraphStyle *)value;
+    return pStyle != nullptr && [TextListsUtils textLists:pStyle.textLists
+                                            containsValue:[self getValue]];
+  }
+}
+
+- (BOOL)detect:(NSRange)range {
+  if (range.length >= 1) {
+    return [OccurenceUtils detect:[self getKey]
+                         withHost:self.host
+                          inRange:range
+                    withCondition:^BOOL(id _Nullable value, NSRange range) {
+                      return [self styleCondition:value range:range];
+                    }];
+  } else {
+    return [OccurenceUtils detect:[self getKey]
+                         withHost:self.host
+                          atIndex:range.location
+                    checkPrevious:[self isParagraph]
+                    withCondition:^BOOL(id _Nullable value, NSRange range) {
+                      return [self styleCondition:value range:range];
+                    }];
+  }
+}
+
+- (BOOL)any:(NSRange)range {
+  return [OccurenceUtils any:[self getKey]
+                    withHost:self.host
+                     inRange:range
+               withCondition:^BOOL(id _Nullable value, NSRange range) {
+                 return [self styleCondition:value range:range];
+               }];
+}
+
+- (NSArray<StylePair *> *)all:(NSRange)range {
+  return [OccurenceUtils all:[self getKey]
+                    withHost:self.host
+                     inRange:range
+               withCondition:^BOOL(id _Nullable value, NSRange range) {
+                 return [self styleCondition:value range:range];
+               }];
+}
+
+// This method gets overridden
+- (void)applyStyling:(NSRange)range {
+}
+
+// This method gets overridden when the style needs to apply certain typing
+// attributes
+- (void)applyStylingToTypingAttrs:(NSMutableDictionary *)attributes {
+}
+
+// Called during dirty range re-application to restore a style from a saved
+// StylePair
+- (void)reapplyFromStylePair:(StylePair *)pair {
+  NSRange range = [pair.rangeValue rangeValue];
+  [self add:range withTyping:NO withDirtyRange:NO];
+}
+
+// Gets a custom attribtue entry for the typingAttributes.
+// Only used with inline styles.
+- (AttributeEntry *)getEntryIfPresent:(NSRange)range {
+  if (![self detect:range]) {
+    return nullptr;
+  }
+
+  AttributeEntry *entry = [[AttributeEntry alloc] init];
+  entry.key = [self getKey];
+  entry.value = [self getValue];
+  return entry;
+}
+
+@end

package/ios/interfaces/StyleHeaders.h

@@ -0,0 +1,110 @@
+#pragma once
+#import "ImageData.h"
+#import "LinkData.h"
+#import "MentionParams.h"
+#import "StyleBase.h"
+
+@interface BoldStyle : StyleBase
+@end
+
+@interface ItalicStyle : StyleBase
+@end
+
+@interface UnderlineStyle : StyleBase
+@end
+
+@interface StrikethroughStyle : StyleBase
+@end
+
+@interface InlineCodeStyle : StyleBase
+@end
+
+@interface LinkStyle : StyleBase
+- (void)addLink:(LinkData *)linkData
+            range:(NSRange)range
+    withSelection:(BOOL)withSelection;
+- (LinkData *)getLinkDataAt:(NSUInteger)location;
+- (NSRange)getFullLinkRangeAt:(NSUInteger)location;
+- (void)handleAutomaticLinks:(NSString *)word inRange:(NSRange)wordRange;
+- (void)handleManualLinks:(NSString *)word inRange:(NSRange)wordRange;
+- (void)applyLinkMetaWithData:(LinkData *)linkData range:(NSRange)range;
+@end
+
+@interface MentionStyle : StyleBase
+- (void)addMention:(NSString *)indicator
+              text:(NSString *)text
+        attributes:(NSString *)attributes;
+- (void)addMentionAtRange:(NSRange)range params:(MentionParams *)params;
+- (void)startMentionWithIndicator:(NSString *)indicator;
+- (void)handleExistingMentions;
+- (void)manageMentionEditing;
+- (MentionParams *)getMentionParamsAt:(NSUInteger)location;
+- (NSRange)getFullMentionRangeAt:(NSUInteger)location;
+- (NSValue *)getActiveMentionRange;
+- (void)applyMentionMeta:(MentionParams *)params range:(NSRange)range;
+@end
+
+@interface HeadingStyleBase : StyleBase
+- (CGFloat)getHeadingFontSize;
+- (BOOL)isHeadingBold;
+- (BOOL)handleNewlinesInRange:(NSRange)range replacementText:(NSString *)text;
+@end
+
+@interface H1Style : HeadingStyleBase
+@end
+
+@interface H2Style : HeadingStyleBase
+@end
+
+@interface H3Style : HeadingStyleBase
+@end
+
+@interface H4Style : HeadingStyleBase
+@end
+
+@interface H5Style : HeadingStyleBase
+@end
+
+@interface H6Style : HeadingStyleBase
+@end
+
+@interface UnorderedListStyle : StyleBase
+@end
+
+@interface OrderedListStyle : StyleBase
+@end
+
+@interface CheckboxListStyle : StyleBase
+- (void)toggleWithChecked:(BOOL)checked range:(NSRange)range;
+- (void)addWithChecked:(BOOL)checked
+                 range:(NSRange)range
+            withTyping:(BOOL)withTyping
+        withDirtyRange:(BOOL)withDirtyRange;
+- (void)toggleCheckedAt:(NSUInteger)location
+         withDirtyRange:(BOOL)withDirtyRange;
+- (BOOL)getCheckboxStateAt:(NSUInteger)location;
+- (BOOL)handleNewlinesInRange:(NSRange)range replacementText:(NSString *)text;
+@end
+
+@interface AlignmentStyle : StyleBase
+- (void)addAlignment:(NSTextAlignment)alignment
+               range:(NSRange)range
+          withTyping:(BOOL)withTyping
+      withDirtyRange:(BOOL)withDirtyRange;
+- (NSString *)getStyleState;
+@end
+
+@interface BlockQuoteStyle : StyleBase
+@end
+
+@interface CodeBlockStyle : StyleBase
+@end
+
+@interface ImageStyle : StyleBase
+- (void)addImage:(NSString *)uri width:(CGFloat)width height:(CGFloat)height;
+- (void)addImageAtRange:(NSRange)range
+              imageData:(ImageData *)imageData
+          withSelection:(BOOL)withSelection
+         withDirtyRange:(BOOL)withDirtyRange;
+- (ImageData *)getImageDataAt:(NSUInteger)location;
+@end

package/ios/interfaces/StylePair.h

@@ -0,0 +1,9 @@
+#pragma once
+#import <UIKit/UIKit.h>
+
+@interface StylePair : NSObject
+
+@property NSValue *rangeValue;
+@property id styleValue;
+
+@end

package/ios/interfaces/StylePair.mm

@@ -0,0 +1,4 @@
+#import "StylePair.h"
+
+@implementation StylePair
+@end

package/ios/interfaces/StyleTypeEnum.h

@@ -0,0 +1,27 @@
+#pragma once
+#import <UIKit/UIKit.h>
+
+// the order is aligned with the order of tags in parser
+typedef NS_ENUM(NSInteger, StyleType) {
+  BlockQuote,
+  CodeBlock,
+  UnorderedList,
+  OrderedList,
+  CheckboxList,
+  Alignment,
+  H1,
+  H2,
+  H3,
+  H4,
+  H5,
+  H6,
+  Link,
+  Mention,
+  Image,
+  InlineCode,
+  Bold,
+  Italic,
+  Underline,
+  Strikethrough,
+  None,
+};

package/ios/interfaces/TextDecorationLineEnum.h

@@ -0,0 +1,6 @@
+#pragma once
+#import <UIKit/UIKit.h>
+
+typedef NSString *TextDecorationLineEnum NS_TYPED_ENUM;
+extern TextDecorationLineEnum const DecorationUnderline;
+extern TextDecorationLineEnum const DecorationNone;

package/ios/interfaces/TextDecorationLineEnum.mm

@@ -0,0 +1,4 @@
+#import "TextDecorationLineEnum.h"
+
+TextDecorationLineEnum const DecorationUnderline = @"underline";
+TextDecorationLineEnum const DecorationNone = @"none";

package/ios/internals/EnrichedTextComponentDescriptor.h

@@ -0,0 +1,19 @@
+#pragma once
+#include <ReactNativeEnrichedHtml/EnrichedTextViewShadowNode.h>
+#include <ReactNativeEnrichedHtml/Props.h>
+#include <react/debug/react_native_assert.h>
+#include <react/renderer/core/ConcreteComponentDescriptor.h>
+
+namespace facebook::react {
+class EnrichedTextComponentDescriptor final
+    : public ConcreteComponentDescriptor<EnrichedTextViewShadowNode> {
+public:
+  using ConcreteComponentDescriptor::ConcreteComponentDescriptor;
+  void adopt(ShadowNode &shadowNode) const override {
+    react_native_assert(
+        dynamic_cast<EnrichedTextViewShadowNode *>(&shadowNode));
+    ConcreteComponentDescriptor::adopt(shadowNode);
+  }
+};
+
+} // namespace facebook::react

package/ios/internals/EnrichedTextInputViewComponentDescriptor.h

@@ -0,0 +1,19 @@
+#pragma once
+#include <ReactNativeEnrichedHtml/EnrichedTextInputViewShadowNode.h>
+#include <ReactNativeEnrichedHtml/Props.h>
+#include <react/debug/react_native_assert.h>
+#include <react/renderer/core/ConcreteComponentDescriptor.h>
+
+namespace facebook::react {
+class EnrichedTextInputViewComponentDescriptor final
+    : public ConcreteComponentDescriptor<EnrichedTextInputViewShadowNode> {
+public:
+  using ConcreteComponentDescriptor::ConcreteComponentDescriptor;
+  void adopt(ShadowNode &shadowNode) const override {
+    react_native_assert(
+        dynamic_cast<EnrichedTextInputViewShadowNode *>(&shadowNode));
+    ConcreteComponentDescriptor::adopt(shadowNode);
+  }
+};
+
+} // namespace facebook::react

package/ios/internals/EnrichedTextInputViewShadowNode.h

@@ -0,0 +1,44 @@
+#pragma once
+#include <ReactNativeEnrichedHtml/EnrichedTextInputViewState.h>
+#include <ReactNativeEnrichedHtml/EventEmitters.h>
+#include <ReactNativeEnrichedHtml/Props.h>
+#include <jsi/jsi.h>
+#include <react/renderer/components/view/ConcreteViewShadowNode.h>
+#include <react/renderer/core/LayoutConstraints.h>
+
+namespace facebook::react {
+
+JSI_EXPORT extern const char EnrichedTextInputViewComponentName[];
+
+/*
+ * `ShadowNode` for <EnrichedTextInputView> component.
+ */
+class EnrichedTextInputViewShadowNode
+    : public ConcreteViewShadowNode<
+          EnrichedTextInputViewComponentName, EnrichedTextInputViewProps,
+          EnrichedTextInputViewEventEmitter, EnrichedTextInputViewState> {
+public:
+  using ConcreteViewShadowNode::ConcreteViewShadowNode;
+  EnrichedTextInputViewShadowNode(const ShadowNodeFragment &fragment,
+                                  const ShadowNodeFamily::Shared &family,
+                                  ShadowNodeTraits traits);
+  EnrichedTextInputViewShadowNode(const ShadowNode &sourceShadowNode,
+                                  const ShadowNodeFragment &fragment);
+  void dirtyLayoutIfNeeded();
+  Size
+  measureContent(const LayoutContext &layoutContext,
+                 const LayoutConstraints &layoutConstraints) const override;
+
+  static ShadowNodeTraits BaseTraits() {
+    auto traits = ConcreteViewShadowNode::BaseTraits();
+    traits.set(ShadowNodeTraits::Trait::LeafYogaNode);
+    traits.set(ShadowNodeTraits::Trait::MeasurableYogaNode);
+    return traits;
+  }
+
+private:
+  int localForceHeightRecalculationCounter_;
+  id setupMockTextInputView_() const;
+};
+
+} // namespace facebook::react

package/ios/internals/EnrichedTextInputViewShadowNode.mm

@@ -0,0 +1,103 @@
+#import "EnrichedTextInputViewShadowNode.h"
+#import "CoreText/CoreText.h"
+#import <EnrichedTextInputView.h>
+#import <React/RCTShadowView+Layout.h>
+#import <react/utils/ManagedObjectWrapper.h>
+#import <yoga/Yoga.h>
+
+namespace facebook::react {
+
+extern const char EnrichedTextInputViewComponentName[] =
+    "EnrichedTextInputView";
+
+EnrichedTextInputViewShadowNode::EnrichedTextInputViewShadowNode(
+    const ShadowNodeFragment &fragment, const ShadowNodeFamily::Shared &family,
+    ShadowNodeTraits traits)
+    : ConcreteViewShadowNode(fragment, family, traits) {
+  localForceHeightRecalculationCounter_ = 0;
+}
+
+// mock input is used for the first measure calls that need to be done when the
+// real input isn't defined yet
+id EnrichedTextInputViewShadowNode::setupMockTextInputView_() const {
+  // it's rendered far away from the viewport
+  const int veryFarAway = 20000;
+  const int mockSize = 1000;
+  EnrichedTextInputView *mockTextInputView_ = [[EnrichedTextInputView alloc]
+      initWithFrame:(CGRectMake(veryFarAway, veryFarAway, mockSize, mockSize))];
+  const auto props = this->getProps();
+  mockTextInputView_->blockEmitting = YES;
+  [mockTextInputView_ updateProps:props oldProps:nullptr];
+  return mockTextInputView_;
+}
+
+EnrichedTextInputViewShadowNode::EnrichedTextInputViewShadowNode(
+    const ShadowNode &sourceShadowNode, const ShadowNodeFragment &fragment)
+    : ConcreteViewShadowNode(sourceShadowNode, fragment) {
+  dirtyLayoutIfNeeded();
+}
+
+void EnrichedTextInputViewShadowNode::dirtyLayoutIfNeeded() {
+  const auto state = this->getStateData();
+  const int receivedCounter = state.getForceHeightRecalculationCounter();
+
+  if (receivedCounter > localForceHeightRecalculationCounter_) {
+    localForceHeightRecalculationCounter_ = receivedCounter;
+    YGNodeMarkDirty(&yogaNode_);
+  }
+}
+
+Size EnrichedTextInputViewShadowNode::measureContent(
+    const LayoutContext &layoutContext,
+    const LayoutConstraints &layoutConstraints) const {
+  const auto state = this->getStateData();
+  const auto componentRef = state.getComponentViewRef();
+  RCTInternalGenericWeakWrapper *weakWrapper =
+      (RCTInternalGenericWeakWrapper *)unwrapManagedObject(componentRef);
+
+  if (weakWrapper != nullptr) {
+    id componentObject = weakWrapper.object;
+    EnrichedTextInputView *typedComponentObject =
+        (EnrichedTextInputView *)componentObject;
+
+    if (typedComponentObject != nullptr) {
+      __block CGSize estimatedSize;
+
+      // synchronously dispatch to main thread if needed
+      if ([NSThread isMainThread]) {
+        estimatedSize = [typedComponentObject
+            measureSize:layoutConstraints.maximumSize.width];
+      } else {
+        dispatch_sync(dispatch_get_main_queue(), ^{
+          estimatedSize = [typedComponentObject
+              measureSize:layoutConstraints.maximumSize.width];
+        });
+      }
+
+      return {estimatedSize.width,
+              MIN(estimatedSize.height, layoutConstraints.maximumSize.height)};
+    }
+  } else {
+    __block CGSize estimatedSize;
+
+    // synchronously dispatch to main thread if needed
+    if ([NSThread isMainThread]) {
+      EnrichedTextInputView *mockTextInputView = setupMockTextInputView_();
+      estimatedSize =
+          [mockTextInputView measureSize:layoutConstraints.maximumSize.width];
+    } else {
+      dispatch_sync(dispatch_get_main_queue(), ^{
+        EnrichedTextInputView *mockTextInputView = setupMockTextInputView_();
+        estimatedSize =
+            [mockTextInputView measureSize:layoutConstraints.maximumSize.width];
+      });
+    }
+
+    return {estimatedSize.width,
+            MIN(estimatedSize.height, layoutConstraints.maximumSize.height)};
+  }
+
+  return Size();
+}
+
+} // namespace facebook::react

package/ios/internals/EnrichedTextInputViewState.cpp

@@ -0,0 +1,10 @@
+#include "EnrichedTextInputViewState.h"
+
+namespace facebook::react {
+int EnrichedTextInputViewState::getForceHeightRecalculationCounter() const {
+  return forceHeightRecalculationCounter_;
+}
+std::shared_ptr<void> EnrichedTextInputViewState::getComponentViewRef() const {
+  return componentViewRef_;
+}
+} // namespace facebook::react

package/ios/internals/EnrichedTextInputViewState.h

@@ -0,0 +1,22 @@
+#pragma once
+#include <memory>
+
+namespace facebook::react {
+
+class EnrichedTextInputViewState {
+public:
+  EnrichedTextInputViewState()
+      : forceHeightRecalculationCounter_(0), componentViewRef_(nullptr) {}
+  EnrichedTextInputViewState(int counter, std::shared_ptr<void> ref) {
+    forceHeightRecalculationCounter_ = counter;
+    componentViewRef_ = ref;
+  }
+  int getForceHeightRecalculationCounter() const;
+  std::shared_ptr<void> getComponentViewRef() const;
+
+private:
+  int forceHeightRecalculationCounter_{};
+  std::shared_ptr<void> componentViewRef_{};
+};
+
+} // namespace facebook::react