p5 2.0.0 → 2.0.1

package/src/webgl/shaders/normal.vert

@@ -1,72 +0,0 @@
-IN vec3 aPosition;
-IN vec3 aNormal;
-IN vec2 aTexCoord;
-IN vec4 aVertexColor;
-
-#define HOOK_DEFINES
-
-#ifdef AUGMENTED_HOOK_getWorldInputs
-uniform mat4 uModelMatrix;
-uniform mat4 uViewMatrix;
-uniform mat3 uModelNormalMatrix;
-uniform mat3 uCameraNormalMatrix;
-#else
-uniform mat4 uModelViewMatrix;
-uniform mat3 uNormalMatrix;
-#endif
-uniform mat4 uProjectionMatrix;
-
-uniform vec4 uMaterialColor;
-uniform bool uUseVertexColor;
-
-OUT vec3 vVertexNormal;
-OUT highp vec2 vVertTexCoord;
-OUT vec4 vColor;
-
-struct Vertex {
-  vec3 position;
-  vec3 normal;
-  vec2 texCoord;
-  vec4 color;
-};
-
-void main(void) {
-  HOOK_beforeVertex();
-
-  Vertex inputs;
-  inputs.position = aPosition;
-  inputs.normal = aNormal;
-  inputs.texCoord = aTexCoord;
-  inputs.color = (uUseVertexColor && aVertexColor.x >= 0.0) ? aVertexColor : uMaterialColor;
-#ifdef AUGMENTED_HOOK_getObjectInputs
-  inputs = HOOK_getObjectInputs(inputs);
-#endif
-
-#ifdef AUGMENTED_HOOK_getWorldInputs
-  inputs.position = (uModelMatrix * vec4(inputs.position, 1.)).xyz;
-  inputs.normal = uModelNormalMatrix * inputs.normal;
-  inputs = HOOK_getWorldInputs(inputs);
-#endif
-
-#ifdef AUGMENTED_HOOK_getWorldInputs
-  // Already multiplied by the model matrix, just apply view
-  inputs.position = (uViewMatrix * vec4(inputs.position, 1.)).xyz;
-  inputs.normal = uCameraNormalMatrix * inputs.normal;
-#else
-  // Apply both at once
-  inputs.position = (uModelViewMatrix * vec4(inputs.position, 1.)).xyz;
-  inputs.normal = uNormalMatrix * inputs.normal;
-#endif
-#ifdef AUGMENTED_HOOK_getCameraInputs
-  inputs = HOOK_getCameraInputs(inputs);
-#endif
-
-  // Pass varyings to fragment shader
-  vVertTexCoord = inputs.texCoord;
-  vVertexNormal = normalize(inputs.normal);
-  vColor = inputs.color;
-
-  gl_Position = uProjectionMatrix * vec4(inputs.position, 1.);
-
-  HOOK_afterVertex();
-}

package/src/webgl/shaders/phong.frag

@@ -1,84 +0,0 @@
-// include lighting.glsl
-precision highp int;
-
-uniform bool uHasSetAmbient;
-uniform vec4 uSpecularMatColor;
-uniform vec4 uAmbientMatColor;
-uniform vec4 uEmissiveMatColor;
-
-uniform vec4 uTint;
-uniform sampler2D uSampler;
-uniform bool isTexture;
-
-IN vec3 vNormal;
-IN vec2 vTexCoord;
-IN vec3 vViewPosition;
-IN vec3 vAmbientColor;
-IN vec4 vColor;
-
-struct ColorComponents {
-  vec3 baseColor;
-  float opacity;
-  vec3 ambientColor;
-  vec3 specularColor;
-  vec3 diffuse;
-  vec3 ambient;
-  vec3 specular;
-  vec3 emissive;
-};
-
-struct Inputs {
-  vec3 normal;
-  vec2 texCoord;
-  vec3 ambientLight;
-  vec3 ambientMaterial;
-  vec3 specularMaterial;
-  vec3 emissiveMaterial;
-  vec4 color;
-  float shininess;
-  float metalness;
-};
-
-void main(void) {
-  HOOK_beforeFragment();
-
-  Inputs inputs;
-  inputs.normal = normalize(vNormal);
-  inputs.texCoord = vTexCoord;
-  inputs.ambientLight = vAmbientColor;
-  inputs.color = isTexture
-      ? TEXTURE(uSampler, vTexCoord) * uTint/255.
-      : vColor;
-  if (isTexture && inputs.color.a > 0.0) {
-    // Textures come in with premultiplied alpha. Temporarily unpremultiply it
-    // so hooks users don't have to think about premultiplied alpha.
-    inputs.color.rgb /= inputs.color.a;
-  }
-  inputs.shininess = uShininess;
-  inputs.metalness = uMetallic;
-  inputs.ambientMaterial = uHasSetAmbient ? uAmbientMatColor.rgb : inputs.color.rgb;
-  inputs.specularMaterial = uSpecularMatColor.rgb;
-  inputs.emissiveMaterial = uEmissiveMatColor.rgb;
-  inputs = HOOK_getPixelInputs(inputs);
-
-  vec3 diffuse;
-  vec3 specular;
-  totalLight(vViewPosition, inputs.normal, inputs.shininess, inputs.metalness, diffuse, specular);
-
-  // Calculating final color as result of all lights (plus emissive term).
-
-  vec2 texCoord = inputs.texCoord;
-  vec4 baseColor = inputs.color;
-  ColorComponents c;
-  c.opacity = baseColor.a;
-  c.baseColor = baseColor.rgb;
-  c.ambientColor = inputs.ambientMaterial;
-  c.specularColor = inputs.specularMaterial;
-  c.diffuse = diffuse;
-  c.ambient = inputs.ambientLight;
-  c.specular = specular;
-  c.emissive = inputs.emissiveMaterial;
-  OUT_COLOR = HOOK_getFinalColor(HOOK_combineColors(c));
-  OUT_COLOR.rgb *= OUT_COLOR.a; // Premultiply alpha before rendering
-  HOOK_afterFragment();
-}

package/src/webgl/shaders/phong.vert

@@ -1,87 +0,0 @@
-precision highp int;
-
-#define HOOK_DEFINES
-
-IN vec3 aPosition;
-IN vec3 aNormal;
-IN vec2 aTexCoord;
-IN vec4 aVertexColor;
-
-uniform vec3 uAmbientColor[5];
-
-#ifdef AUGMENTED_HOOK_getWorldInputs
-uniform mat4 uModelMatrix;
-uniform mat4 uViewMatrix;
-uniform mat3 uModelNormalMatrix;
-uniform mat3 uCameraNormalMatrix;
-#else
-uniform mat4 uModelViewMatrix;
-uniform mat3 uNormalMatrix;
-#endif
-uniform mat4 uProjectionMatrix;
-uniform int uAmbientLightCount;
-
-uniform bool uUseVertexColor;
-uniform vec4 uMaterialColor;
-
-OUT vec3 vNormal;
-OUT vec2 vTexCoord;
-OUT vec3 vViewPosition;
-OUT vec3 vAmbientColor;
-OUT vec4 vColor;
-
-struct Vertex {
-  vec3 position;
-  vec3 normal;
-  vec2 texCoord;
-  vec4 color;
-};
-
-void main(void) {
-  HOOK_beforeVertex();
-
-  Vertex inputs;
-  inputs.position = aPosition;
-  inputs.normal = aNormal;
-  inputs.texCoord = aTexCoord;
-  inputs.color = (uUseVertexColor && aVertexColor.x >= 0.0) ? aVertexColor : uMaterialColor;
-#ifdef AUGMENTED_HOOK_getObjectInputs
-  inputs = HOOK_getObjectInputs(inputs);
-#endif
-
-#ifdef AUGMENTED_HOOK_getWorldInputs
-  inputs.position = (uModelMatrix * vec4(inputs.position, 1.)).xyz;
-  inputs.normal = uModelNormalMatrix * inputs.normal;
-  inputs = HOOK_getWorldInputs(inputs);
-#endif
-
-#ifdef AUGMENTED_HOOK_getWorldInputs
-  // Already multiplied by the model matrix, just apply view
-  inputs.position = (uViewMatrix * vec4(inputs.position, 1.)).xyz;
-  inputs.normal = uCameraNormalMatrix * inputs.normal;
-#else
-  // Apply both at once
-  inputs.position = (uModelViewMatrix * vec4(inputs.position, 1.)).xyz;
-  inputs.normal = uNormalMatrix * inputs.normal;
-#endif
-#ifdef AUGMENTED_HOOK_getCameraInputs
-  inputs = HOOK_getCameraInputs(inputs);
-#endif
-
-  // Pass varyings to fragment shader
-  vViewPosition = inputs.position;
-  vTexCoord = inputs.texCoord;
-  vNormal = inputs.normal;
-  vColor = inputs.color;
-
-  // TODO: this should be a uniform
-  vAmbientColor = vec3(0.0);
-  for (int i = 0; i < 5; i++) {
-    if (i < uAmbientLightCount) {
-      vAmbientColor += uAmbientColor[i];
-    }
-  }
-
-  gl_Position = uProjectionMatrix * vec4(inputs.position, 1.);
-  HOOK_afterVertex();
-}

package/src/webgl/shaders/point.frag

@@ -1,29 +0,0 @@
-precision mediump int;
-uniform vec4 uMaterialColor;
-IN float vStrokeWeight;
-
-void main(){
-  HOOK_beforeFragment();
-  float mask = 0.0;
-
-  // make a circular mask using the gl_PointCoord (goes from 0 - 1 on a point)
-  // might be able to get a nicer edge on big strokeweights with smoothstep but slightly less performant
-
-  mask = step(0.98, length(gl_PointCoord * 2.0 - 1.0));
-
-  // if strokeWeight is 1 or less lets just draw a square
-  // this prevents weird artifacting from carving circles when our points are really small
-  // if strokeWeight is larger than 1, we just use it as is
-
-  mask = mix(0.0, mask, clamp(floor(vStrokeWeight - 0.5),0.0,1.0));
-
-  // throw away the borders of the mask
-  // otherwise we get weird alpha blending issues
-
-  if(HOOK_shouldDiscard(mask > 0.98)){
-    discard;
-  }
-
-  OUT_COLOR = HOOK_getFinalColor(vec4(uMaterialColor.rgb, 1.) * uMaterialColor.a);
-  HOOK_afterFragment();
-}

package/src/webgl/shaders/point.vert

@@ -1,19 +0,0 @@
-IN vec3 aPosition;
-uniform float uPointSize;
-OUT float vStrokeWeight;
-uniform mat4 uModelViewMatrix;
-uniform mat4 uProjectionMatrix;
-
-void main() {
-  HOOK_beforeVertex();
-  vec4 viewModelPosition = vec4(HOOK_getWorldPosition(
-    (uModelViewMatrix * vec4(HOOK_getLocalPosition(aPosition), 1.0)).xyz
-  ), 1.);
-  gl_Position = uProjectionMatrix * viewModelPosition;  
-
-  float pointSize = HOOK_getPointSize(uPointSize);
-
-	gl_PointSize = pointSize;
-	vStrokeWeight = pointSize;
-  HOOK_afterVertex();
-}

package/src/webgl/shaders/sphereMapping.frag

@@ -1,26 +0,0 @@
-#define PI 3.141592
-
-precision highp float;
-  
-uniform sampler2D uEnvMap;
-uniform mat3 uNewNormalMatrix;
-uniform float uFovY;
-uniform float uAspect;
-
-varying vec2 vTexCoord;
-  
-void main() {
-    float uFovX = uFovY * uAspect; 
-    float angleY = mix(uFovY/2.0,  -uFovY/2.0, vTexCoord.y);
-    float angleX = mix(uFovX/2.0, -uFovX/2.0, vTexCoord.x);
-    vec3 rotatedNormal = vec3( angleX, angleY, 1.0 );
-    rotatedNormal = uNewNormalMatrix * normalize(rotatedNormal);
-    float temp = rotatedNormal.z;
-    rotatedNormal.z = rotatedNormal.x;
-    rotatedNormal.x = -temp;
-    vec2 suv;
-    suv.y = 0.5 + 0.5 * (-rotatedNormal.y);
-    suv.x = atan(rotatedNormal.z, rotatedNormal.x) / (2.0 * PI) + 0.5;
-    vec4 newTexColor = texture2D(uEnvMap, suv.xy);
-    gl_FragColor = newTexColor;
-}

package/src/webgl/shaders/webgl2Compatibility.glsl

@@ -1,34 +0,0 @@
-#ifdef WEBGL2
-
-#define IN in
-#define OUT out
-
-#ifdef FRAGMENT_SHADER
-out vec4 outColor;
-#define OUT_COLOR outColor
-#endif
-#define TEXTURE texture
-
-#else
-
-#ifdef FRAGMENT_SHADER
-#define IN varying
-#else
-#define IN attribute
-#endif
-#define OUT varying
-#define TEXTURE texture2D
-
-#ifdef FRAGMENT_SHADER
-#define OUT_COLOR gl_FragColor
-#endif
-
-#endif
-
-#ifdef FRAGMENT_SHADER
-vec4 getTexture(in sampler2D content, vec2 coord) {
-  vec4 color = TEXTURE(content, coord);
-  color.rgb /= color.a;
-  return color;
-}
-#endif