p5 2.0.0 → 2.0.1

package/src/webgl/shaders/light.vert

@@ -1,37 +0,0 @@
-// include lighting.glgl
-
-IN vec3 aPosition;
-IN vec3 aNormal;
-IN vec2 aTexCoord;
-IN vec4 aVertexColor;
-
-uniform mat4 uModelViewMatrix;
-uniform mat4 uProjectionMatrix;
-uniform mat3 uNormalMatrix;
-
-uniform bool uUseVertexColor;
-uniform vec4 uMaterialColor;
-
-OUT highp vec2 vVertTexCoord;
-OUT vec3 vDiffuseColor;
-OUT vec3 vSpecularColor;
-OUT vec4 vColor;
-
-void main(void) {
-
-  vec4 viewModelPosition = uModelViewMatrix * vec4(aPosition, 1.0);
-  gl_Position = uProjectionMatrix * viewModelPosition;
-
-  vec3 vertexNormal = normalize(uNormalMatrix * aNormal);
-  vVertTexCoord = aTexCoord;
-
-  totalLight(viewModelPosition.xyz, vertexNormal, vDiffuseColor, vSpecularColor);
-
-  for (int i = 0; i < 8; i++) {
-    if (i < uAmbientLightCount) {
-      vDiffuseColor += uAmbientColor[i];
-    }
-  }
-  
-  vColor = ((uUseVertexColor && aVertexColor.x >= 0.0) ? aVertexColor : uMaterialColor);
-}

package/src/webgl/shaders/light_texture.frag

@@ -1,26 +0,0 @@
-uniform vec4 uTint;
-uniform sampler2D uSampler;
-uniform bool isTexture;
-uniform bool uEmissive;
-
-IN highp vec2 vVertTexCoord;
-IN vec3 vDiffuseColor;
-IN vec3 vSpecularColor;
-IN vec4 vColor;
-
-void main(void) {
-  if(uEmissive && !isTexture) {
-    OUT_COLOR = vColor;
-  }
-  else {
-    vec4 baseColor = isTexture
-      // Textures come in with premultiplied alpha. To apply tint and still have
-      // premultiplied alpha output, we need to multiply the RGB channels by the
-      // tint RGB, and all channels by the tint alpha.
-      ? TEXTURE(uSampler, vVertTexCoord) * vec4(uTint.rgb/255., 1.) * (uTint.a/255.)
-      // Colors come in with unmultiplied alpha, so we need to multiply the RGB
-      // channels by alpha to convert it to premultiplied alpha.
-      : vec4(vColor.rgb * vColor.a, vColor.a);
-    OUT_COLOR = vec4(baseColor.rgb * vDiffuseColor + vSpecularColor, baseColor.a);
-  }
-}

package/src/webgl/shaders/lighting.glsl

@@ -1,227 +0,0 @@
-#define PI 3.141592
-
-precision highp float;
-precision highp int;
-
-uniform mat4 uViewMatrix;
-
-uniform bool uUseLighting;
-
-uniform int uAmbientLightCount;
-uniform vec3 uAmbientColor[5];
-uniform mat3 uCameraRotation;
-uniform int uDirectionalLightCount;
-uniform vec3 uLightingDirection[5];
-uniform vec3 uDirectionalDiffuseColors[5];
-uniform vec3 uDirectionalSpecularColors[5];
-
-uniform int uPointLightCount;
-uniform vec3 uPointLightLocation[5];
-uniform vec3 uPointLightDiffuseColors[5];	
-uniform vec3 uPointLightSpecularColors[5];
-
-uniform int uSpotLightCount;
-uniform float uSpotLightAngle[5];
-uniform float uSpotLightConc[5];
-uniform vec3 uSpotLightDiffuseColors[5];
-uniform vec3 uSpotLightSpecularColors[5];
-uniform vec3 uSpotLightLocation[5];
-uniform vec3 uSpotLightDirection[5];
-
-uniform bool uSpecular;
-uniform float uShininess;
-uniform float uMetallic;
-
-uniform float uConstantAttenuation;
-uniform float uLinearAttenuation;
-uniform float uQuadraticAttenuation;
-
-// setting from  _setImageLightUniforms()
-// boolean to initiate the calculateImageDiffuse and calculateImageSpecular
-uniform bool uUseImageLight;
-// texture for use in calculateImageDiffuse
-uniform sampler2D environmentMapDiffused;
-// texture for use in calculateImageSpecular
-uniform sampler2D environmentMapSpecular;
-
-const float specularFactor = 2.0;
-const float diffuseFactor = 0.73;
-
-struct LightResult {
-  float specular;
-  float diffuse;
-};
-
-float _phongSpecular(
-  vec3 lightDirection,
-  vec3 viewDirection,
-  vec3 surfaceNormal,
-  float shininess) {
-
-  vec3 R = reflect(lightDirection, surfaceNormal);
-  return pow(max(0.0, dot(R, viewDirection)), shininess);
-}
-
-float _lambertDiffuse(vec3 lightDirection, vec3 surfaceNormal) {
-  return max(0.0, dot(-lightDirection, surfaceNormal));
-}
-
-LightResult _light(vec3 viewDirection, vec3 normal, vec3 lightVector, float shininess, float metallic) {
-
-  vec3 lightDir = normalize(lightVector);
-
-  //compute our diffuse & specular terms
-  LightResult lr;
-  float specularIntensity = mix(1.0, 0.4, metallic);
-  float diffuseIntensity = mix(1.0, 0.1, metallic);
-  if (uSpecular)
-    lr.specular = (_phongSpecular(lightDir, viewDirection, normal, shininess)) * specularIntensity;
-    lr.diffuse = _lambertDiffuse(lightDir, normal) * diffuseIntensity;
-  return lr;
-}
-
-// converts the range of "value" from [min1 to max1] to [min2 to max2]
-float map(float value, float min1, float max1, float min2, float max2) {
-  return min2 + (value - min1) * (max2 - min2) / (max1 - min1);
-}
-
-vec2 mapTextureToNormal( vec3 v ){
-  // x = r sin(phi) cos(theta)   
-  // y = r cos(phi)  
-  // z = r sin(phi) sin(theta)
-  float phi = acos( v.y );
-  // if phi is 0, then there are no x, z components
-  float theta = 0.0;
-  // else 
-  theta = acos(v.x / sin(phi));
-  float sinTheta = v.z / sin(phi);
-  if (sinTheta < 0.0) {
-    // Turn it into -theta, but in the 0-2PI range
-    theta = 2.0 * PI - theta;
-  }
-  theta = theta / (2.0 * 3.14159);
-  phi = phi / 3.14159 ;
-  
-  vec2 angles = vec2( fract(theta + 0.25), 1.0 - phi );
-  return angles;
-}
-
-
-vec3 calculateImageDiffuse(vec3 vNormal, vec3 vViewPosition, float metallic){
-  // make 2 seperate builds 
-  vec3 worldCameraPosition =  vec3(0.0, 0.0, 0.0);  // hardcoded world camera position
-  vec3 worldNormal = normalize(vNormal * uCameraRotation);
-  vec2 newTexCoor = mapTextureToNormal( worldNormal );
-  vec4 texture = TEXTURE( environmentMapDiffused, newTexCoor );
-  // this is to make the darker sections more dark
-  // png and jpg usually flatten the brightness so it is to reverse that
-  return mix(smoothstep(vec3(0.0), vec3(1.0), texture.xyz), vec3(0.0), metallic);
-}
-
-vec3 calculateImageSpecular(vec3 vNormal, vec3 vViewPosition, float shininess, float metallic){
-  vec3 worldCameraPosition =  vec3(0.0, 0.0, 0.0);
-  vec3 worldNormal = normalize(vNormal);
-  vec3 lightDirection = normalize( vViewPosition - worldCameraPosition );
-  vec3 R = reflect(lightDirection, worldNormal) * uCameraRotation;
-  vec2 newTexCoor = mapTextureToNormal( R );
-#ifdef WEBGL2
-  // In p5js the range of shininess is >= 1,
-  // Therefore roughness range will be ([0,1]*8)*20 or [0, 160]
-  // The factor of 8 is because currently the getSpecularTexture
-  // only calculated 8 different levels of roughness
-  // The factor of 20 is just to spread up this range so that,
-  // [1, max] of shininess is converted to [0,160] of roughness
-  float roughness = 20. / shininess;
-  vec4 outColor = textureLod(environmentMapSpecular, newTexCoor, roughness * 8.);
-#else
-  vec4 outColor = TEXTURE(environmentMapSpecular, newTexCoor);
-#endif
-  // this is to make the darker sections more dark
-  // png and jpg usually flatten the brightness so it is to reverse that
-  return mix(
-    pow(outColor.xyz, vec3(10)),
-    pow(outColor.xyz, vec3(1.2)),
-    metallic 
-  );
-}
-
-void totalLight(
-  vec3 modelPosition,
-  vec3 normal,
-  float shininess,
-  float metallic,
-  out vec3 totalDiffuse,
-  out vec3 totalSpecular
-) {
-
-  totalSpecular = vec3(0.0);
-
-  if (!uUseLighting) {
-    totalDiffuse = vec3(1.0);
-    return;
-  }
-
-  totalDiffuse = vec3(0.0);
-
-  vec3 viewDirection = normalize(-modelPosition);
-
-  for (int j = 0; j < 5; j++) {
-    if (j < uDirectionalLightCount) {
-      vec3 lightVector = (uViewMatrix * vec4(uLightingDirection[j], 0.0)).xyz;
-      vec3 lightColor = uDirectionalDiffuseColors[j];
-      vec3 specularColor = uDirectionalSpecularColors[j];
-      LightResult result = _light(viewDirection, normal, lightVector, shininess, metallic);
-      totalDiffuse += result.diffuse * lightColor;
-      totalSpecular += result.specular * lightColor * specularColor;
-    }
-
-    if (j < uPointLightCount) {
-      vec3 lightPosition = (uViewMatrix * vec4(uPointLightLocation[j], 1.0)).xyz;
-      vec3 lightVector = modelPosition - lightPosition;
-      //calculate attenuation
-      float lightDistance = length(lightVector);
-      float lightFalloff = 1.0 / (uConstantAttenuation + lightDistance * uLinearAttenuation + (lightDistance * lightDistance) * uQuadraticAttenuation);
-      vec3 lightColor = lightFalloff * uPointLightDiffuseColors[j];
-      vec3 specularColor = lightFalloff * uPointLightSpecularColors[j];
-
-      LightResult result = _light(viewDirection, normal, lightVector, shininess, metallic);
-      totalDiffuse += result.diffuse * lightColor;
-      totalSpecular += result.specular * lightColor * specularColor;
-    }
-
-    if(j < uSpotLightCount) {
-      vec3 lightPosition = (uViewMatrix * vec4(uSpotLightLocation[j], 1.0)).xyz;
-      vec3 lightVector = modelPosition - lightPosition;
-    
-      float lightDistance = length(lightVector);
-      float lightFalloff = 1.0 / (uConstantAttenuation + lightDistance * uLinearAttenuation + (lightDistance * lightDistance) * uQuadraticAttenuation);
-
-      vec3 lightDirection = (uViewMatrix * vec4(uSpotLightDirection[j], 0.0)).xyz;
-      float spotDot = dot(normalize(lightVector), normalize(lightDirection));
-      float spotFalloff;
-      if(spotDot < uSpotLightAngle[j]) {
-        spotFalloff = 0.0;
-      }
-      else {
-        spotFalloff = pow(spotDot, uSpotLightConc[j]);
-      }
-      lightFalloff *= spotFalloff;
-
-      vec3 lightColor = uSpotLightDiffuseColors[j];
-      vec3 specularColor = uSpotLightSpecularColors[j];
-     
-      LightResult result = _light(viewDirection, normal, lightVector, shininess, metallic);
-      
-      totalDiffuse += result.diffuse * lightColor * lightFalloff;
-      totalSpecular += result.specular * lightColor * specularColor * lightFalloff;
-    }
-  }
-
-  if( uUseImageLight ){
-    totalDiffuse += calculateImageDiffuse(normal, modelPosition, metallic);
-    totalSpecular += calculateImageSpecular(normal, modelPosition, shininess, metallic);
-  }
-
-  totalDiffuse *= diffuseFactor;
-  totalSpecular *= specularFactor;
-}

package/src/webgl/shaders/line.frag

@@ -1,74 +0,0 @@
-precision highp int;
-precision highp float;
-
-uniform vec4 uMaterialColor;
-uniform int uStrokeCap;
-uniform int uStrokeJoin;
-
-IN vec4 vColor;
-IN vec2 vTangent;
-IN vec2 vCenter;
-IN vec2 vPosition;
-IN float vStrokeWeight;
-IN float vMaxDist;
-IN float vCap;
-IN float vJoin;
-
-float distSquared(vec2 a, vec2 b) {
-  vec2 aToB = b - a;
-  return dot(aToB, aToB);
-}
-
-struct Inputs {
-  vec4 color;
-  vec2 tangent;
-  vec2 center;
-  vec2 position;
-  float strokeWeight;
-};
-
-void main() {
-  HOOK_beforeFragment();
-
-  Inputs inputs;
-  inputs.color = vColor;
-  inputs.tangent = vTangent;
-  inputs.center = vCenter;
-  inputs.position = vPosition;
-  inputs.strokeWeight = vStrokeWeight;
-  inputs = HOOK_getPixelInputs(inputs);
-
-  if (vCap > 0.) {
-    if (
-      uStrokeCap == STROKE_CAP_ROUND &&
-      HOOK_shouldDiscard(distSquared(inputs.position, inputs.center) > inputs.strokeWeight * inputs.strokeWeight * 0.25)
-    ) {
-      discard;
-    } else if (
-      uStrokeCap == STROKE_CAP_SQUARE &&
-      HOOK_shouldDiscard(dot(inputs.position - inputs.center, inputs.tangent) > 0.)
-    ) {
-      discard;
-    // Use full area for PROJECT
-    } else if (HOOK_shouldDiscard(false)) {
-      discard;
-    }
-  } else if (vJoin > 0.) {
-    if (
-      uStrokeJoin == STROKE_JOIN_ROUND &&
-      HOOK_shouldDiscard(distSquared(inputs.position, inputs.center) > inputs.strokeWeight * inputs.strokeWeight * 0.25)
-    ) {
-      discard;
-    } else if (uStrokeJoin == STROKE_JOIN_BEVEL) {
-      vec2 normal = vec2(-inputs.tangent.y, inputs.tangent.x);
-      if (HOOK_shouldDiscard(abs(dot(inputs.position - inputs.center, normal)) > vMaxDist)) {
-        discard;
-      }
-    // Use full area for MITER
-    } else if (HOOK_shouldDiscard(false)) {
-      discard;
-    }
-  }
-  OUT_COLOR = HOOK_getFinalColor(vec4(inputs.color.rgb, 1.) * inputs.color.a);
-  HOOK_afterFragment();
-}

package/src/webgl/shaders/line.vert

@@ -1,294 +0,0 @@
-/*
-  Part of the Processing project - http://processing.org
-  Copyright (c) 2012-15 The Processing Foundation
-  Copyright (c) 2004-12 Ben Fry and Casey Reas
-  Copyright (c) 2001-04 Massachusetts Institute of Technology
-  This library is free software; you can redistribute it and/or
-  modify it under the terms of the GNU Lesser General Public
-  License as published by the Free Software Foundation, version 2.1.
-  This library is distributed in the hope that it will be useful,
-  but WITHOUT ANY WARRANTY; without even the implied warranty of
-  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
-  Lesser General Public License for more details.
-  You should have received a copy of the GNU Lesser General
-  Public License along with this library; if not, write to the
-  Free Software Foundation, Inc., 59 Temple Place, Suite 330,
-  Boston, MA  02111-1307  USA
-*/
-
-#define PROCESSING_LINE_SHADER
-
-#define HOOK_DEFINES
-
-precision highp int;
-precision highp float;
-
-#ifdef AUGMENTED_HOOK_getWorldInputs
-uniform mat4 uModelMatrix;
-uniform mat4 uViewMatrix;
-#else
-uniform mat4 uModelViewMatrix;
-#endif
-
-uniform mat4 uProjectionMatrix;
-uniform float uStrokeWeight;
-
-uniform bool uUseLineColor;
-uniform bool uSimpleLines;
-uniform vec4 uMaterialColor;
-
-uniform vec4 uViewport;
-uniform int uPerspective;
-uniform int uStrokeJoin;
-
-IN vec3 aPosition;
-IN vec3 aTangentIn;
-IN vec3 aTangentOut;
-IN float aSide;
-IN vec4 aVertexColor;
-
-OUT vec4 vColor;
-OUT vec2 vTangent;
-OUT vec2 vCenter;
-OUT vec2 vPosition;
-OUT float vMaxDist;
-OUT float vCap;
-OUT float vJoin;
-OUT float vStrokeWeight;
-
-vec2 lineIntersection(vec2 aPoint, vec2 aDir, vec2 bPoint, vec2 bDir) {
-  // Rotate and translate so a starts at the origin and goes out to the right
-  bPoint -= aPoint;
-  vec2 rotatedBFrom = vec2(
-    bPoint.x*aDir.x + bPoint.y*aDir.y,
-    bPoint.y*aDir.x - bPoint.x*aDir.y
-  );
-  vec2 bTo = bPoint + bDir;
-  vec2 rotatedBTo = vec2(
-    bTo.x*aDir.x + bTo.y*aDir.y,
-    bTo.y*aDir.x - bTo.x*aDir.y
-  );
-  float intersectionDistance =
-    rotatedBTo.x + (rotatedBFrom.x - rotatedBTo.x) * rotatedBTo.y /
-    (rotatedBTo.y - rotatedBFrom.y);
-  return aPoint + aDir * intersectionDistance;
-}
-
-struct StrokeVertex {
-  vec3 position;
-  vec3 tangentIn;
-  vec3 tangentOut;
-  vec4 color;
-  float weight;
-};
-
-void main() {
-  HOOK_beforeVertex();
-
-  if (!uSimpleLines) {
-      // Caps have one of either the in or out tangent set to 0
-      vCap = (aTangentIn == vec3(0.)) != (aTangentOut == vec3(0.)) ? 1. : 0.;
-
-      // Joins have two unique, defined tangents
-      vJoin = (
-          aTangentIn != vec3(0.) &&
-          aTangentOut != vec3(0.) &&
-          aTangentIn != aTangentOut
-      ) ? 1. : 0.;
-  }
-
-  StrokeVertex inputs;
-  inputs.position = aPosition.xyz;
-  inputs.color = uUseLineColor ? aVertexColor : uMaterialColor;
-  inputs.weight = uStrokeWeight;
-  inputs.tangentIn = aTangentIn;
-  inputs.tangentOut = aTangentOut;
-
-#ifdef AUGMENTED_HOOK_getObjectInputs
-  inputs = HOOK_getObjectInputs(inputs);
-#endif
-
-#ifdef AUGMENTED_HOOK_getWorldInputs
-  inputs.position = (uModelMatrix * vec4(inputs.position, 1.)).xyz;
-  inputs.tangentIn = (uModelMatrix * vec4(aTangentIn, 0.)).xyz;
-  inputs.tangentOut = (uModelMatrix * vec4(aTangentOut, 0.)).xyz;
-  inputs = HOOK_getWorldInputs(inputs);
-#endif
-
-#ifdef AUGMENTED_HOOK_getWorldInputs
-  // Already multiplied by the model matrix, just apply view
-  inputs.position = (uViewMatrix * vec4(inputs.position, 1.)).xyz;
-  inputs.tangentIn = (uViewMatrix * vec4(aTangentIn, 0.)).xyz;
-  inputs.tangentOut = (uViewMatrix * vec4(aTangentOut, 0.)).xyz;
-#else
-  // Apply both at once
-  inputs.position = (uModelViewMatrix * vec4(inputs.position, 1.)).xyz;
-  inputs.tangentIn = (uModelViewMatrix * vec4(aTangentIn, 0.)).xyz;
-  inputs.tangentOut = (uModelViewMatrix * vec4(aTangentOut, 0.)).xyz;
-#endif
-#ifdef AUGMENTED_HOOK_getCameraInputs
-  inputs = hook_getCameraInputs(inputs);
-#endif
-
-  vec4 posp = vec4(inputs.position, 1.);
-  vec4 posqIn = vec4(inputs.position + inputs.tangentIn, 1.);
-  vec4 posqOut = vec4(inputs.position + inputs.tangentOut, 1.);
-  vStrokeWeight = inputs.weight;
-
-  float facingCamera = pow(
-    // The word space tangent's z value is 0 if it's facing the camera
-    abs(normalize(posqIn-posp).z),
-
-    // Using pow() here to ramp `facingCamera` up from 0 to 1 really quickly
-    // so most lines get scaled and don't get clipped
-    0.25
-  );
-
-  // Moving vertices slightly toward the camera
-  // to avoid depth-fighting with the fill triangles.
-  // A mix of scaling and offsetting is used based on distance
-  // Discussion here:
-  // https://github.com/processing/p5.js/issues/7200 
-
-  // using a scale <1 moves the lines towards nearby camera
-  // in order to prevent popping effects due to half of
-  // the line disappearing behind the geometry faces.
-  float zDistance = -posp.z; 
-  float distanceFactor = smoothstep(0.0, 800.0, zDistance); 
-  
-  // Discussed here:
-  // http://www.opengl.org/discussion_boards/ubbthreads.php?ubb=showflat&Number=252848  
-  float scale = mix(1., 0.995, facingCamera);
-  float dynamicScale = mix(scale, 1.0, distanceFactor); // Closer = more scale, farther = less
-
-  posp.xyz = posp.xyz * dynamicScale;
-  posqIn.xyz = posqIn.xyz * dynamicScale;
-  posqOut.xyz = posqOut.xyz * dynamicScale;
-
-  // Moving vertices slightly toward camera when far away 
-  // https://github.com/processing/p5.js/issues/6956 
-  float zOffset = mix(0., -1., facingCamera);
-  float dynamicZAdjustment = mix(0.0, zOffset, distanceFactor); // Closer = less zAdjustment, farther = more
-
-  posp.z -= dynamicZAdjustment;
-  posqIn.z -= dynamicZAdjustment;
-  posqOut.z -= dynamicZAdjustment;
-  
-  vec4 p = uProjectionMatrix * posp;
-  vec4 qIn = uProjectionMatrix * posqIn;
-  vec4 qOut = uProjectionMatrix * posqOut;
-
-  // formula to convert from clip space (range -1..1) to screen space (range 0..[width or height])
-  // screen_p = (p.xy/p.w + <1,1>) * 0.5 * uViewport.zw
-
-  // prevent division by W by transforming the tangent formula (div by 0 causes
-  // the line to disappear, see https://github.com/processing/processing/issues/5183)
-  // t = screen_q - screen_p
-  //
-  // tangent is normalized and we don't care which aDirection it points to (+-)
-  // t = +- normalize( screen_q - screen_p )
-  // t = +- normalize( (q.xy/q.w+<1,1>)*0.5*uViewport.zw - (p.xy/p.w+<1,1>)*0.5*uViewport.zw )
-  //
-  // extract common factor, <1,1> - <1,1> cancels out
-  // t = +- normalize( (q.xy/q.w - p.xy/p.w) * 0.5 * uViewport.zw )
-  //
-  // convert to common divisor
-  // t = +- normalize( ((q.xy*p.w - p.xy*q.w) / (p.w*q.w)) * 0.5 * uViewport.zw )
-  //
-  // remove the common scalar divisor/factor, not needed due to normalize and +-
-  // (keep uViewport - can't remove because it has different components for x and y
-  //  and corrects for aspect ratio, see https://github.com/processing/processing/issues/5181)
-  // t = +- normalize( (q.xy*p.w - p.xy*q.w) * uViewport.zw )
-
-  vec2 tangentIn = normalize((qIn.xy*p.w - p.xy*qIn.w) * uViewport.zw);
-  vec2 tangentOut = normalize((qOut.xy*p.w - p.xy*qOut.w) * uViewport.zw);
-
-  vec2 curPerspScale;
-  if(uPerspective == 1) {
-    // Perspective ---
-    // convert from world to clip by multiplying with projection scaling factor
-    // to get the right thickness (see https://github.com/processing/processing/issues/5182)
-
-    // The y value of the projection matrix may be flipped if rendering to a Framebuffer.
-    // Multiplying again by its sign here negates the flip to get just the scale.
-    curPerspScale = (uProjectionMatrix * vec4(1, sign(uProjectionMatrix[1][1]), 0, 0)).xy;
-  } else {
-    // No Perspective ---
-    // multiply by W (to cancel out division by W later in the pipeline) and
-    // convert from screen to clip (derived from clip to screen above)
-    curPerspScale = p.w / (0.5 * uViewport.zw);
-  }
-
-  vec2 offset;
-  if (vJoin == 1. && !uSimpleLines) {
-    vTangent = normalize(tangentIn + tangentOut);
-    vec2 normalIn = vec2(-tangentIn.y, tangentIn.x);
-    vec2 normalOut = vec2(-tangentOut.y, tangentOut.x);
-    float side = sign(aSide);
-    float sideEnum = abs(aSide);
-
-    // We generate vertices for joins on either side of the centerline, but
-    // the "elbow" side is the only one needing a join. By not setting the
-    // offset for the other side, all its vertices will end up in the same
-    // spot and not render, effectively discarding it.
-    if (sign(dot(tangentOut, vec2(-tangentIn.y, tangentIn.x))) != side) {
-      // Side enums:
-      //   1: the side going into the join
-      //   2: the middle of the join
-      //   3: the side going out of the join
-      if (sideEnum == 2.) {
-        // Calculate the position + tangent on either side of the join, and
-        // find where the lines intersect to find the elbow of the join
-        vec2 c = (posp.xy/posp.w + vec2(1.,1.)) * 0.5 * uViewport.zw;
-        vec2 intersection = lineIntersection(
-          c + (side * normalIn * inputs.weight / 2.),
-          tangentIn,
-          c + (side * normalOut * inputs.weight / 2.),
-          tangentOut
-        );
-        offset = (intersection - c);
-
-        // When lines are thick and the angle of the join approaches 180, the
-        // elbow might be really far from the center. We'll apply a limit to
-        // the magnitude to avoid lines going across the whole screen when this
-        // happens.
-        float mag = length(offset);
-        float maxMag = 3. * inputs.weight;
-        if (mag > maxMag) {
-          offset *= maxMag / mag;
-        }
-      } else if (sideEnum == 1.) {
-        offset = side * normalIn * inputs.weight / 2.;
-      } else if (sideEnum == 3.) {
-        offset = side * normalOut * inputs.weight / 2.;
-      }
-    }
-    if (uStrokeJoin == STROKE_JOIN_BEVEL) {
-      vec2 avgNormal = vec2(-vTangent.y, vTangent.x);
-      vMaxDist = abs(dot(avgNormal, normalIn * inputs.weight / 2.));
-    } else {
-      vMaxDist = inputs.weight / 2.;
-    }
-  } else {
-    vec2 tangent = aTangentIn == vec3(0.) ? tangentOut : tangentIn;
-    vTangent = tangent;
-    vec2 normal = vec2(-tangent.y, tangent.x);
-
-    float normalOffset = sign(aSide);
-    // Caps will have side values of -2 or 2 on the edge of the cap that
-    // extends out from the line
-    float tangentOffset = abs(aSide) - 1.;
-    offset = (normal * normalOffset + tangent * tangentOffset) *
-      inputs.weight * 0.5;
-    vMaxDist = inputs.weight / 2.;
-  }
-
-  vCenter = p.xy;
-  vPosition = vCenter + offset;
-  vColor = inputs.color;
-
-  gl_Position.xy = p.xy + offset.xy * curPerspScale;
-  gl_Position.zw = p.zw;
-  
-  HOOK_afterVertex();
-}

package/src/webgl/shaders/normal.frag

@@ -1,6 +0,0 @@
-IN vec3 vVertexNormal;
-void main(void) {
-  HOOK_beforeFragment();
-  OUT_COLOR = HOOK_getFinalColor(vec4(vVertexNormal, 1.0));
-  HOOK_afterFragment();
-}