libwz 0.1.0

package/deps/zlib/contrib/CMakeLists.txt

@@ -0,0 +1,61 @@
+function(zlib_add_contrib_lib name description dir)
+    option(ZLIB_BUILD_${name} "Enable building of ${description}" OFF)
+
+    if(ZLIB_BUILD_${name})
+        if(NOT DEFINED ZLIB_${name}_BUILD_SHARED)
+            set(ZLIB_${name}_BUILD_SHARED ${ZLIB_BUILD_SHARED} CACHE BOOL "")
+        endif(NOT DEFINED ZLIB_${name}_BUILD_SHARED)
+
+        if(NOT DEFINED ZLIB_${name}_BUILD_STATIC)
+            set(ZLIB_${name}_BUILD_STATIC ${ZLIB_BUILD_STATIC} CACHE BOOL "")
+        endif(NOT DEFINED ZLIB_${name}_BUILD_STATIC)
+
+        if(NOT DEFINED ZLIB_${name}_BUILD_TESTING)
+            set(ZLIB_${name}_BUILD_TESTING ${ZLIB_BUILD_TESTING} CACHE BOOL "")
+        endif(NOT DEFINED ZLIB_${name}_BUILD_TESTING)
+
+        if(NOT DEFINED ZLIB_${name}_INSTALL)
+            set(ZLIB_${name}_INSTALL ${ZLIB_INSTALL} CACHE BOOL "")
+        endif(NOT DEFINED ZLIB_${name}_INSTALL)
+
+        add_subdirectory(${dir}/)
+    endif(ZLIB_BUILD_${name})
+endfunction(zlib_add_contrib_lib name description dir)
+
+function(zlib_add_contrib_feature name description dir)
+    if(ARGC EQUAL 4)
+        set(default_on ${ARGV3})
+    else()
+        set(default_on Off)
+    endif()
+
+    option(ZLIB_WITH_${name}
+           "Enable build ${description}"
+           ${default_on})
+
+    if(ZLIB_WITH_${name})
+        add_subdirectory(${dir}/)
+    endif(ZLIB_WITH_${name})
+endfunction(zlib_add_contrib_feature name description dir)
+
+zlib_add_contrib_feature("GVMAT64"
+    "of an optimized longest_match for 32 bits x86_64"
+    gcc_gvmat64)
+
+zlib_add_contrib_feature(INFBACK9 "with support for method 9 deflate" infback9)
+zlib_add_contrib_feature(CRC32VX "with S390X-CRC32VX implementation" crc32vx)
+zlib_add_contrib_lib(ADA "Ada bindings" ada)
+zlib_add_contrib_lib(BLAST "blast binary" blast)
+zlib_add_contrib_lib(IOSTREAM3 "IOStream C++ bindings V3" iostream3)
+zlib_add_contrib_lib(MINIZIP "minizip library" minizip)
+zlib_add_contrib_lib(PUFF "puff decompress library" puff)
+
+if(WIN32)
+    zlib_add_contrib_lib(TESTZLIB "testzlib binary" testzlib)
+
+    if (ZLIB_BUILD_ZLIB1_DLL)
+        add_subdirectory(zlib1-dll/)
+    endif (ZLIB_BUILD_ZLIB1_DLL)
+
+    option(ZLIB_BUILD_ZLIB1_DLL "Build the legacy zlib + minizip DLL" OFF)
+endif(WIN32)

package/deps/zlib/contrib/README.contrib

@@ -0,0 +1,57 @@
+All files under this contrib directory are UNSUPPORTED. They were
+provided by users of zlib and were not tested by the authors of zlib.
+Use at your own risk. Please contact the authors of the contributions
+for help about these, not the zlib authors. Thanks.
+
+
+ada/        by Dmitriy Anisimkov <anisimkov@yahoo.com>
+        Support for Ada
+        See https://zlib-ada.sourceforge.net/
+
+blast/      by Mark Adler <madler@alumni.caltech.edu>
+        Decompressor for output of PKWare Data Compression Library (DCL)
+
+delphi/     by Cosmin Truta <cosmint@cs.ubbcluj.ro>
+        Support for Delphi and C++ Builder
+
+dotzlib/    by Henrik Ravn <henrik@ravn.com>
+        Support for Microsoft .Net and Visual C++ .Net
+
+gcc_gvmat64/by Gilles Vollant <info@winimage.com>
+        GCC Version of x86 64-bit (AMD64 and Intel EM64t) code for x64
+        assembler to replace longest_match() and inflate_fast()
+
+infback9/   by Mark Adler <madler@alumni.caltech.edu>
+        Unsupported diffs to infback to decode the deflate64 format
+
+iostream/   by Kevin Ruland <kevin@rodin.wustl.edu>
+        A C++ I/O streams interface to the zlib gz* functions
+
+iostream2/  by Tyge Løvset <Tyge.Lovset@cmr.no>
+        Another C++ I/O streams interface
+
+iostream3/  by Ludwig Schwardt <schwardt@sun.ac.za>
+            and Kevin Ruland <kevin@rodin.wustl.edu>
+        Yet another C++ I/O streams interface
+
+minizip/    by Gilles Vollant <info@winimage.com>
+        Mini zip and unzip based on zlib
+        Includes Zip64 support by Mathias Svensson <mathias@result42.com>
+        See https://www.winimage.com/zLibDll/minizip.html
+
+pascal/     by Bob Dellaca <bobdl@xtra.co.nz> et al.
+        Support for Pascal
+
+puff/       by Mark Adler <madler@alumni.caltech.edu>
+        Small, low memory usage inflate.  Also serves to provide an
+        unambiguous description of the deflate format.
+
+crc32vx/      by Ilya Leoshkevich <iii@linux.ibm.com>
+        Hardware-accelerated CRC32 on IBM Z with Z13 VX extension.
+
+testzlib/   by Gilles Vollant <info@winimage.com>
+        Example of the use of zlib
+
+zlib1-dll/
+            by @Vollstrecker on github.com
+        Build the legacy zlib1.dll with zlib and minizip.

package/deps/zlib/contrib/ada/CMakeLists.txt

@@ -0,0 +1,217 @@
+cmake_minimum_required(VERSION 3.12...3.31)
+
+set(CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake/Modules")
+
+project(
+    zlibAda
+    VERSION 1.0.0
+    LANGUAGES C ADA
+    DESCRIPTION "A library for creating zipfiles based in zlib"
+    HOMEPAGE_URL "https://www.zlib.net")
+
+option(ZLIB_ADA_BUILD_SHARED "Enable building ada bindings shared library" ON)
+option(ZLIB_ADA_BUILD_STATIC "Enable building ada bindings static library" ON)
+option(ZLIB_ADA_BUILD_TESTING "Enable building tests for ada bindings library" ON)
+
+if(WIN32 OR CYGWIN)
+    set(zlib_Ada_static_suffix "s")
+    set(CMAKE_DEBUG_POSTFIX "d")
+endif(WIN32 OR CYGWIN)
+
+if(NOT DEFINED ZLIB_BUILD_ADA)
+    if(ZLIB_ADA_BUILD_SHARED)
+        list(APPEND REQUIRED_COMPONENTS "shared")
+    endif(ZLIB_ADA_BUILD_SHARED)
+
+    if(ZLIB_ADA_BUILD_STATIC)
+        list(APPEND REQUIRED_COMPONENTS "static")
+    endif(ZLIB_ADA_BUILD_STATIC)
+
+    find_package(ZLIB REQUIRED COMPONENTS ${REQUIRED_COMPONENTS} CONFIG)
+endif(NOT DEFINED ZLIB_BUILD_ADA)
+
+function(ZLIB_ADA_findTestEnv testName)
+    set(testEnv "PATH=")
+
+    if(MSVC OR MINGW)
+        set(separator "\\\;")
+    else()
+        set(separator ":")
+    endif()
+
+    string(APPEND testEnv "$<TARGET_FILE_DIR:ZLIB::ZLIB>${separator}")
+    string(APPEND testEnv "$ENV{PATH}")
+
+    set_tests_properties(${testName} PROPERTIES ENVIRONMENT "${testEnv}")
+endfunction(ZLIB_ADA_findTestEnv testName)
+
+if(ZLIB_ADA_BUILD_SHARED)
+    ada_add_library(zlib_ada_Ada SHARED
+        zlib-thin.adb
+        zlib.adb)
+
+    set_target_properties(zlib_ada_Ada
+        PROPERTIES OUTPUT_NAME zlib-ada)
+
+    target_link_libraries(zlib_ada_Ada
+        INTERFACE ZLIB::ZLIB)
+
+    ada_add_library(zlib_ada_streams SHARED
+        zlib-streams.adb)
+
+    target_link_libraries(zlib_ada_streams
+        PUBLIC
+            zlib_ada_Ada)
+
+    ada_find_ali(zlib_ada_streams)
+
+    if(ZLIB_ADA_BUILD_TESTING)
+        enable_testing()
+        ada_add_executable(zlib_ada_test test.adb)
+
+        target_link_libraries(zlib_ada_test
+            PRIVATE
+                zlib_ada_Ada
+                zlib_ada_streams)
+
+        ada_find_ali(zlib_ada_test)
+
+        add_test(NAME zlib_ada_ada-test COMMAND zlib_ada_test)
+        set_tests_properties(zlib_ada_ada-test PROPERTIES FIXTURES_REQUIRED zlib_ada_cleanup)
+
+        if(MSVC
+           OR MSYS
+           OR MINGW
+           OR CYGWIN)
+            zlib_ada_findtestenv(zlib_ada_ada-test)
+        endif(
+            MSVC
+            OR MSYS
+            OR MINGW
+            OR CYGWIN)
+
+        ada_add_executable(zlib_ada_buffer_demo buffer_demo.adb)
+
+        target_link_libraries(zlib_ada_buffer_demo
+            PRIVATE
+                zlib_ada_Ada)
+
+        ada_find_ali(zlib_ada_buffer_demo)
+
+        add_test(NAME zlib_ada_buffer-demo COMMAND zlib_ada_buffer_demo)
+
+        if(MSVC
+           OR MSYS
+           OR MINGW
+           OR CYGWIN)
+            zlib_ada_findtestenv(zlib_ada_buffer-demo)
+        endif(
+            MSVC
+            OR MSYS
+            OR MINGW
+            OR CYGWIN)
+
+        ada_add_executable(zlib_ada_mtest mtest.adb)
+
+        target_link_libraries(zlib_ada_mtest
+            PRIVATE
+                zlib_ada_Ada)
+
+        ada_find_ali(zlib_ada_mtest)
+
+        #Not adding test as this is an endless-loop
+
+        ada_add_executable(zlib_ada_read read.adb)
+
+        target_link_libraries(zlib_ada_read
+            PRIVATE
+                zlib_ada_Ada)
+
+        ada_find_ali(zlib_ada_read)
+
+        add_test(NAME zlib_ada_read COMMAND zlib_ada_read)
+
+        if(MSVC
+           OR MSYS
+           OR MINGW
+           OR CYGWIN)
+            zlib_ada_findtestenv(zlib_ada_read)
+        endif(
+            MSVC
+            OR MSYS
+            OR MINGW
+            OR CYGWIN)
+    endif(ZLIB_ADA_BUILD_TESTING)
+endif(ZLIB_ADA_BUILD_SHARED)
+
+if(ZLIB_ADA_BUILD_STATIC)
+    ada_add_library(zlib_ada_AdaStatic STATIC
+        zlib-thin.adb
+        zlib.adb)
+
+    target_link_libraries(zlib_ada_AdaStatic
+        INTERFACE ZLIB::ZLIBSTATIC)
+
+    set_target_properties(zlib_ada_AdaStatic
+        PROPERTIES OUTPUT_NAME zlib-ada${zlib_Ada_static_suffix})
+
+    ada_add_library(zlib_ada_streamsStatic STATIC
+        zlib-streams.adb)
+
+    target_link_libraries(zlib_ada_streamsStatic
+        PUBLIC
+            zlib_ada_AdaStatic)
+
+    ada_find_ali(zlib_ada_streamsStatic)
+
+    if(ZLIB_ADA_BUILD_TESTING)
+        enable_testing()
+        ada_add_executable(zlib_ada_testStatic test.adb)
+
+        target_link_libraries(zlib_ada_testStatic
+            PRIVATE
+                zlib_ada_AdaStatic
+                zlib_ada_streamsStatic)
+
+        ada_find_ali(zlib_ada_testStatic)
+
+        add_test(NAME zlib_ada_testStatic COMMAND zlib_ada_testStatic)
+        set_tests_properties(zlib_ada_testStatic PROPERTIES FIXTURES_REQUIRED zlib_ada_cleanup)
+
+        ada_add_executable(zlib_ada_buffer-demoStatic buffer_demo.adb)
+
+        target_link_libraries(zlib_ada_buffer-demoStatic
+            PRIVATE
+                zlib_ada_AdaStatic)
+
+        ada_find_ali(zlib_ada_buffer-demoStatic)
+
+        add_test(NAME zlib_ada_buffer-demoStatic COMMAND zlib_ada_buffer-demoStatic)
+
+        ada_add_executable(zlib_ada_mtestStatic mtest.adb)
+
+        target_link_libraries(zlib_ada_mtestStatic
+            PRIVATE
+                zlib_ada_AdaStatic)
+
+        ada_find_ali(zlib_ada_mtestStatic)
+
+        # Not adding test as this is an endless-loop
+
+        ada_add_executable(zlib_ada_readStatic read.adb)
+
+        target_link_libraries(zlib_ada_readStatic
+            PRIVATE
+                zlib_ada_AdaStatic)
+
+        ada_find_ali(zlib_ada_readStatic)
+
+        add_test(NAME zlib_ada_readStatic COMMAND zlib_ada_readStatic)
+    endif(ZLIB_ADA_BUILD_TESTING)
+endif(ZLIB_ADA_BUILD_STATIC)
+
+if(ZLIB_ADA_BUILD_TESTING)
+    add_test(NAME zlib_ada_cleanup COMMAND ${CMAKE_COMMAND} -E rm ${CMAKE_CURRENT_BINARY_DIR}/testzlib.in
+        ${CMAKE_CURRENT_BINARY_DIR}/testzlib.out ${CMAKE_CURRENT_BINARY_DIR}/testzlib.zlb)
+    set_tests_properties(zlib_ada_cleanup PROPERTIES FIXTURES_CLEANUP zlib_ada_cleanup)
+endif(ZLIB_ADA_BUILD_TESTING)

package/deps/zlib/contrib/ada/buffer_demo.adb

@@ -0,0 +1,106 @@
+----------------------------------------------------------------
+--  ZLib for Ada thick binding.                               --
+--                                                            --
+--  Copyright (C) 2002-2004 Dmitriy Anisimkov                 --
+--                                                            --
+--  Open source license information is in the zlib.ads file.  --
+----------------------------------------------------------------
+--
+--  $Id: buffer_demo.adb,v 1.3 2004/09/06 06:55:35 vagul Exp $
+
+--  This demo program provided by Dr Steve Sangwine <sjs@essex.ac.uk>
+--
+--  Demonstration of a problem with Zlib-Ada (already fixed) when a buffer
+--  of exactly the correct size is used for decompressed data, and the last
+--  few bytes passed in to Zlib are checksum bytes.
+
+--  This program compresses a string of text, and then decompresses the
+--  compressed text into a buffer of the same size as the original text.
+
+with Ada.Streams; use Ada.Streams;
+with Ada.Text_IO;
+
+with ZLib; use ZLib;
+
+procedure Buffer_Demo is
+   EOL  : Character renames ASCII.LF;
+   Text : constant String
+     := "Four score and seven years ago our fathers brought forth," & EOL &
+        "upon this continent, a new nation, conceived in liberty," & EOL &
+        "and dedicated to the proposition that `all men are created equal'.";
+
+   Source : Stream_Element_Array (1 .. Text'Length);
+   for Source'Address use Text'Address;
+
+begin
+   Ada.Text_IO.Put (Text);
+   Ada.Text_IO.New_Line;
+   Ada.Text_IO.Put_Line
+     ("Uncompressed size : " & Positive'Image (Text'Length) & " bytes");
+
+   declare
+      Compressed_Data : Stream_Element_Array (1 .. Text'Length);
+      L               : Stream_Element_Offset;
+   begin
+      Compress : declare
+         Compressor : Filter_Type;
+         I : Stream_Element_Offset;
+      begin
+         Deflate_Init (Compressor);
+
+         --  Compress the whole of T at once.
+
+         Translate (Compressor, Source, I, Compressed_Data, L, Finish);
+         pragma Assert (I = Source'Last);
+
+         Close (Compressor);
+
+         Ada.Text_IO.Put_Line
+           ("Compressed size :   "
+            & Stream_Element_Offset'Image (L) & " bytes");
+      end Compress;
+
+      --  Now we decompress the data, passing short blocks of data to Zlib
+      --  (because this demonstrates the problem - the last block passed will
+      --  contain checksum information and there will be no output, only a
+      --  check inside Zlib that the checksum is correct).
+
+      Decompress : declare
+         Decompressor : Filter_Type;
+
+         Uncompressed_Data : Stream_Element_Array (1 .. Text'Length);
+
+         Block_Size : constant := 4;
+         --  This makes sure that the last block contains
+         --  only Adler checksum data.
+
+         P : Stream_Element_Offset := Compressed_Data'First - 1;
+         O : Stream_Element_Offset;
+      begin
+         Inflate_Init (Decompressor);
+
+         loop
+            Translate
+              (Decompressor,
+               Compressed_Data
+                 (P + 1 .. Stream_Element_Offset'Min (P + Block_Size, L)),
+               P,
+               Uncompressed_Data
+                 (Total_Out (Decompressor) + 1 .. Uncompressed_Data'Last),
+               O,
+               No_Flush);
+
+               Ada.Text_IO.Put_Line
+                 ("Total in : " & Count'Image (Total_In (Decompressor)) &
+                  ", out : " & Count'Image (Total_Out (Decompressor)));
+
+               exit when P = L;
+         end loop;
+
+         Ada.Text_IO.New_Line;
+         Ada.Text_IO.Put_Line
+           ("Decompressed text matches original text : "
+             & Boolean'Image (Uncompressed_Data = Source));
+      end Decompress;
+   end;
+end Buffer_Demo;

package/deps/zlib/contrib/ada/cmake/Modules/CMakeADACompiler.cmake.in

@@ -0,0 +1,23 @@
+set(CMAKE_ADA_COMPILER "@CMAKE_ADA_COMPILER@")
+set(CMAKE_ADA_COMPILER_ARG1 "@CMAKE_ADA_COMPILER_ARG1@")
+set(CMAKE_ADA_COMPILER_ID "@CMAKE_ADA_COMPILER_ID@")
+set(CMAKE_ADA_COMPILER_VERSION "@CMAKE_ADA_COMPILER_VERSION@")
+set(CMAKE_ADA_PLATFORM_ID "@CMAKE_ADA_PLATFORM_ID@")
+set(CMAKE_AR "@CMAKE_AR@")
+#set(CMAKE_RANLIB "@CMAKE_RANLIB@")
+#set(CMAKE_LINKER "@CMAKE_LINKER@")
+set(CMAKE_ADA_COMPILER_LOADED TRUE)
+set(CMAKE_ADA_COMPILER_WORKS @CMAKE_ADA_COMPILER_WORKS@)
+#set(CMAKE_ADA_ABI_COMPILED @CMAKE_ADA_ABI_COMPILED@)
+
+set(CMAKE_ADA_COMPILER_ENV_VAR "ADA")
+
+set(CMAKE_ADA_COMPILER_ID_RUN TRUE)
+set(CMAKE_ADA_SOURCE_FILE_EXTENSIONS adb;ADB)
+set(CMAKE_ADA_IGNORE_EXTENSIONS ;o;O;obj;OBJ;ali)
+
+set(CMAKE_ADA_BINDER_HELPER "@CMAKE_ADA_BINDER_HELPER@")
+set(CMAKE_ADA_COMPILER_HELPER "@CMAKE_ADA_COMPILER_HELPER@")
+set(CMAKE_ADA_EXE_LINK_HELPER "@CMAKE_ADA_EXE_LINK_HELPER@")
+set(CMAKE_ADA_SHARED_LINK_HELPER "@CMAKE_ADA_SHARED_LINK_HELPER@")
+set(CMAKE_ADA_STATIC_LINK_HELPER "@CMAKE_ADA_STATIC_LINK_HELPER@")

package/deps/zlib/contrib/ada/cmake/Modules/CMakeADAInformation.cmake

@@ -0,0 +1,133 @@
+include(CMakeLanguageInformation)
+
+set(CMAKE_ADA_OUTPUT_EXTENSION .o)
+set(CMAKE_ADA_OUTPUT_EXTENSION_REPLACE TRUE)
+
+if(CMAKE_USER_MAKE_RULES_OVERRIDE)
+    include(${CMAKE_USER_MAKE_RULES_OVERRIDE} RESULT_VARIABLE _override)
+    set(CMAKE_USER_MAKE_RULES_OVERRIDE "${_override}")
+endif(CMAKE_USER_MAKE_RULES_OVERRIDE)
+
+
+if(CMAKE_USER_MAKE_RULES_OVERRIDE_ADA)
+    include(${CMAKE_USER_MAKE_RULES_OVERRIDE_ADA} RESULT_VARIABLE _override)
+    set(CMAKE_USER_MAKE_RULES_OVERRIDE_ADA "${_override}")
+endif(CMAKE_USER_MAKE_RULES_OVERRIDE_ADA)
+
+set(CMAKE_ADA_FLAGS_INIT "$ENV{ADAFLAGS} ${CMAKE_ADA_FLAGS_INIT}")
+
+string(APPEND CMAKE_ADA_FLAGS_INIT " ")
+string(APPEND CMAKE_ADA_FLAGS_DEBUG_INIT " -g")
+string(APPEND CMAKE_ADA_FLAGS_MINSIZEREL_INIT " -Os")
+string(APPEND CMAKE_ADA_FLAGS_RELEASE_INIT " -O3")
+string(APPEND CMAKE_ADA_FLAGS_RELWITHDEBINFO_INIT " -O2 -g")
+
+cmake_initialize_per_config_variable(CMAKE_ADA_FLAGS "Flags used by the Ada compiler")
+
+if(CMAKE_ADA_STANDARD_LIBRARIES_INIT)
+    set(CMAKE_ADA_STANDARD_LIBRARIES
+        "${CMAKE_ADA_STANDARD_LIBRARIES_INIT}"
+        CACHE
+        STRING "Libraries linked by default with all Ada applications.")
+    mark_as_advanced(CMAKE_ADA_STANDARD_LIBRARIES)
+endif(CMAKE_ADA_STANDARD_LIBRARIES_INIT)
+
+if(NOT CMAKE_ADA_COMPILER_LAUNCHER AND DEFINED ENV{CMAKE_ADA_COMPILER_LAUNCHER})
+    set(CMAKE_ADA_COMPILER_LAUNCHER
+        "$ENV{CMAKE_ADA_COMPILER_LAUNCHER}"
+        CACHE
+        STRING "Compiler launcher for Ada.")
+endif(NOT CMAKE_ADA_COMPILER_LAUNCHER AND DEFINED ENV{CMAKE_ADA_COMPILER_LAUNCHER})
+
+if(NOT CMAKE_ADA_LINKER_LAUNCHER AND DEFINED ENV{CMAKE_ADA_LINKER_LAUNCHER})
+    set(CMAKE_ADA_LINKER_LAUNCHER
+        "$ENV{CMAKE_ADA_LINKER_LAUNCHER}"
+        CACHE
+        STRING "Linker launcher for Ada.")
+endif(NOT CMAKE_ADA_LINKER_LAUNCHER AND DEFINED ENV{CMAKE_ADA_LINKER_LAUNCHER})
+
+include(CMakeCommonLanguageInclude)
+_cmake_common_language_platform_flags(ADA)
+
+if(NOT CMAKE_ADA_CREATE_SHARED_LIBRARY)
+    set(CMAKE_ADA_CREATE_SHARED_LIBRARY
+        "${CMAKE_ADA_BINDER_HELPER} <CMAKE_ADA_COMPILER> <OBJECTS> FLAGS <FLAGS> <LINK_FLAGS>"
+        "${CMAKE_ADA_SHARED_LINK_HELPER} <CMAKE_ADA_COMPILER> <TARGET> <OBJECTS> <LINK_LIBRARIES>")
+endif(NOT CMAKE_ADA_CREATE_SHARED_LIBRARY)
+
+if(NOT CMAKE_ADA_CREATE_STATIC_LIBRARY)
+    set(CMAKE_ADA_CREATE_STATIC_LIBRARY
+        "${CMAKE_ADA_STATIC_LINK_HELPER} ${CMAKE_AR} <TARGET> <OBJECTS>")
+endif(NOT CMAKE_ADA_CREATE_STATIC_LIBRARY)
+
+if(NOT CMAKE_ADA_COMPILE_OBJECT)
+    set(CMAKE_ADA_COMPILE_OBJECT
+        "${CMAKE_ADA_COMPILER_HELPER} <CMAKE_ADA_COMPILER> <OBJECT_DIR> <SOURCE> <FLAGS>")
+endif(NOT CMAKE_ADA_COMPILE_OBJECT)
+
+if(NOT CMAKE_ADA_LINK_EXECUTABLE)
+    set(CMAKE_ADA_LINK_EXECUTABLE
+        "${CMAKE_ADA_BINDER_HELPER} <CMAKE_ADA_COMPILER> <OBJECTS> FLAGS <FLAGS> <LINK_FLAGS>"
+        "${CMAKE_ADA_EXE_LINK_HELPER} <CMAKE_ADA_COMPILER> <TARGET> <FLAGS> <CMAKE_C_LINK_FLAGS> <LINK_FLAGS> OBJ <OBJECTS> LIBS <LINK_LIBRARIES>")
+endif(NOT CMAKE_ADA_LINK_EXECUTABLE)
+
+function(ada_add_executable)
+    if(ARGC GREATER 1)
+        math(EXPR last_index "${ARGC} - 1")
+        foreach(source RANGE 1 ${last_index})
+            list(APPEND SOURCES ${ARGV${source}})
+            string(REPLACE ".adb" "" ali "${ARGV${source}}")
+            set(clean_file "CMakeFiles/${ARGV0}.dir/${ali}.ali")
+            list(APPEND CLEAN_FILES ${clean_file})
+            list(APPEND CLEAN_FILES b~${ali}.adb)
+            list(APPEND CLEAN_FILES b~${ali}.ads)
+            list(APPEND CLEAN_FILES b~${ali}.ali)
+            list(APPEND CLEAN_FILES b~${ali}.o)
+        endforeach(source RANGE 1 ${ARGC})
+
+        add_executable(${ARGV0} ${ARGV1} ${SOURCES})
+
+        set_target_properties(${ARGV0}
+            PROPERTIES
+                ADDITIONAL_CLEAN_FILES "${CLEAN_FILES}")
+    endif(ARGC GREATER 1)
+endfunction(ada_add_executable)
+
+function(ada_add_library)
+    if(ARGC GREATER 2)
+        math(EXPR last_index "${ARGC} - 1")
+        foreach(source RANGE 2 ${last_index})
+            list(APPEND SOURCES ${ARGV${source}})
+            string(REPLACE ".adb" "" ali "${ARGV${source}}")
+            set(clean_file "CMakeFiles/${ARGV0}.dir/${ali}.ali")
+            list(APPEND CLEAN_FILES ${clean_file})
+            list(APPEND CLEAN_FILES b~${ali}.adb)
+            list(APPEND CLEAN_FILES b~${ali}.ads)
+            list(APPEND CLEAN_FILES b~${ali}.ali)
+            list(APPEND CLEAN_FILES b~${ali}.o)
+        endforeach(source RANGE 2 ${ARGC})
+
+        add_library(${ARGV0} ${ARGV1} ${SOURCES})
+
+        set_target_properties(${ARGV0}
+            PROPERTIES
+                ADDITIONAL_CLEAN_FILES "${CLEAN_FILES};dummylib.adb;dummylib.ali;dummylib.o"
+                ALI_FLAG "-aO${CMAKE_CURRENT_BINARY_DIR}/CMakeFiles/${ARGV0}.dir/")
+    endif(ARGC GREATER 2)
+endfunction(ada_add_library)
+
+function(ada_find_ali)
+    get_target_property(link_libs ${ARGV0} LINK_LIBRARIES)
+
+    foreach(lib IN LISTS link_libs)
+        get_target_property(ali ${lib} ALI_FLAG)
+        string(APPEND FLAGS ${ali} " ")
+        unset(ali)
+    endforeach(lib IN LISTS link_libs)
+
+    set_target_properties(${ARGV0}
+        PROPERTIES
+            LINK_FLAGS ${FLAGS})
+endfunction(ada_find_ali)
+
+set(CMAKE_ADA_INFORMATION_LOADED TRUE)

package/deps/zlib/contrib/ada/cmake/Modules/CMakeDetermineADACompiler.cmake

@@ -0,0 +1,33 @@
+include(${CMAKE_ROOT}/Modules/CMakeDetermineCompiler.cmake)
+
+# Load system-specific compiler preferences for this language.
+include(Platform/${CMAKE_SYSTEM_NAME}-Determine-Ada OPTIONAL)
+include(Platform/${CMAKE_SYSTEM_NAME}-Ada OPTIONAL)
+
+if(NOT CMAKE_ADA_COMPILER_NAMES)
+    set(CMAKE_ADA_COMPILER_NAMES gnat)
+
+    foreach(ver RANGE 11 99)
+        list(APPEND CMAKE_ADA_COMPILER_NAMES gnat-${ver})
+    endforeach(ver RANGE 11 99)
+endif(NOT CMAKE_ADA_COMPILER_NAMES)
+
+if(NOT CMAKE_ADA_COMPILER)
+    set(CMAKE_ADA_COMPILER_INIT NOTFOUND)
+    _cmake_find_compiler(ADA)
+else(NOT CMAKE_REAL_ADA_COMPILER)
+    _cmake_find_compiler_path(ADA)
+endif(NOT CMAKE_ADA_COMPILER)
+
+mark_as_advanced(CMAKE_ADA_COMPILER)
+set(CMAKE_ADA_COMPILER_ID "GNU")
+set(CMAKE_ADA_BINDER_HELPER "${CMAKE_COMMAND} -P ${CMAKE_CURRENT_SOURCE_DIR}/cmake/binder_helper.cmake")
+set(CMAKE_ADA_COMPILER_HELPER "${CMAKE_COMMAND} -P ${CMAKE_CURRENT_SOURCE_DIR}/cmake/compile_helper.cmake")
+set(CMAKE_ADA_EXE_LINK_HELPER "${CMAKE_COMMAND} -P ${CMAKE_CURRENT_SOURCE_DIR}/cmake/exe_link_helper.cmake")
+set(CMAKE_ADA_SHARED_LINK_HELPER "${CMAKE_COMMAND} -P ${CMAKE_CURRENT_SOURCE_DIR}/cmake/shared_link_helper.cmake")
+set(CMAKE_ADA_STATIC_LINK_HELPER "${CMAKE_COMMAND} -P ${CMAKE_CURRENT_SOURCE_DIR}/cmake/static_link_helper.cmake")
+
+configure_file(
+    ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Modules/CMakeADACompiler.cmake.in
+    ${CMAKE_PLATFORM_INFO_DIR}/CMakeADACompiler.cmake
+    @ONLY)

package/deps/zlib/contrib/ada/cmake/Modules/CMakeTestADACompiler.cmake

@@ -0,0 +1,46 @@
+include(CMakeTestCompilerCommon)
+unset(CMAKE_ADA_COMPILER_WORKS CACHE)
+
+if(NOT CMAKE_ADA_COMPILER_WORKS)
+    PrintTestCompilerStatus("ADA" "")
+    set(_ADA_TEST_FILE "${CMAKE_BINARY_DIR}/${CMAKE_FILES_DIRECTORY}/CMakeTmp/main.adb")
+
+    file(WRITE ${_ADA_TEST_FILE}
+        "with Ada.Text_IO; use Ada.Text_IO;\n"
+        "\n"
+        "procedure main is\n"
+        "begin\n"
+        "Put_Line(\"Hello, World!\");\n"
+        "end Main;\n")
+
+    try_compile(CMAKE_ADA_COMPILER_WORKS ${CMAKE_BINARY_DIR}
+                ${_ADA_TEST_FILE}
+                OUTPUT_VARIABLE __CMAKE_ADA_COMPILER_OUTPUT)
+
+    set(CMAKE_ADA_COMPILER_WORKS ${CMAKE_ADA_COMPILER_WORKS})
+    unset(CMAKE_ADA_COMPILER_WORKS CACHE)
+    set(ADA_TEST_WAS_RUN TRUE)
+endif(NOT CMAKE_ADA_COMPILER_WORKS)
+
+if(NOT CMAKE_ADA_COMPILER_WORKS)
+    PrintTestCompilerStatus("ADA" " -- broken")
+
+    file(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeError.log
+        "Determining if the Ada compiler works failed with "
+        "the following output:\n${__CMAKE_ADA_COMPILER_OUTPUT}\n\n")
+
+    message(FATAL_ERROR "The Ada compiler \"${CMAKE_ADA_COMPILER}\" "
+        "is not able to compile a simple test program.\nIt fails "
+        "with the following output:\n ${__CMAKE_ADA_COMPILER_OUTPUT}\n\n"
+        "CMake will not be able to correctly generate this project.")
+else(NOT CMAKE_ADA_COMPILER_WORKS)
+    if(ADA_TEST_WAS_RUN)
+        PrintTestCompilerStatus("ADA" " -- works")
+
+        file(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeOutput.log
+            "Determining if the Ada compiler works passed with "
+            "the following output:\n${__CMAKE_ADA_COMPILER_OUTPUT}\n\n")
+    endif(ADA_TEST_WAS_RUN)
+endif(NOT CMAKE_ADA_COMPILER_WORKS)
+
+unset(__CMAKE_ADA_COMPILER_OUTPUT)