javonet-nodejs-sdk 2.1.1 → 2.1.3

package/Binaries/Perl/MacOs/X64/deps/lib/perl5/URI/_punycode.pm

@@ -1,217 +0,0 @@
-package URI::_punycode;
-
-use strict;
-use warnings;
-
-our $VERSION = '5.17';
-
-use Exporter 'import';
-our @EXPORT = qw(encode_punycode decode_punycode);
-
-use integer;
-
-our $DEBUG = 0;
-
-use constant BASE => 36;
-use constant TMIN => 1;
-use constant TMAX => 26;
-use constant SKEW => 38;
-use constant DAMP => 700;
-use constant INITIAL_BIAS => 72;
-use constant INITIAL_N => 128;
-
-my $Delimiter = chr 0x2D;
-my $BasicRE   = qr/[\x00-\x7f]/;
-
-sub _croak { require Carp; Carp::croak(@_); }
-
-sub digit_value {
-    my $code = shift;
-    return ord($code) - ord("A") if $code =~ /[A-Z]/;
-    return ord($code) - ord("a") if $code =~ /[a-z]/;
-    return ord($code) - ord("0") + 26 if $code =~ /[0-9]/;
-    return;
-}
-
-sub code_point {
-    my $digit = shift;
-    return $digit + ord('a') if 0 <= $digit && $digit <= 25;
-    return $digit + ord('0') - 26 if 26 <= $digit && $digit <= 36;
-    die 'NOT COME HERE';
-}
-
-sub adapt {
-    my($delta, $numpoints, $firsttime) = @_;
-    $delta = $firsttime ? $delta / DAMP : $delta / 2;
-    $delta += $delta / $numpoints;
-    my $k = 0;
-    while ($delta > ((BASE - TMIN) * TMAX) / 2) {
-	$delta /= BASE - TMIN;
-	$k += BASE;
-    }
-    return $k + (((BASE - TMIN + 1) * $delta) / ($delta + SKEW));
-}
-
-sub decode_punycode {
-    my $code = shift;
-
-    my $n      = INITIAL_N;
-    my $i      = 0;
-    my $bias   = INITIAL_BIAS;
-    my @output;
-
-    if ($code =~ s/(.*)$Delimiter//o) {
-	push @output, map ord, split //, $1;
-	return _croak('non-basic code point') unless $1 =~ /^$BasicRE*$/o;
-    }
-
-    while ($code) {
-	my $oldi = $i;
-	my $w    = 1;
-    LOOP:
-	for (my $k = BASE; 1; $k += BASE) {
-	    my $cp = substr($code, 0, 1, '');
-	    my $digit = digit_value($cp);
-	    defined $digit or return _croak("invalid punycode input");
-	    $i += $digit * $w;
-	    my $t = ($k <= $bias) ? TMIN
-		: ($k >= $bias + TMAX) ? TMAX : $k - $bias;
-	    last LOOP if $digit < $t;
-	    $w *= (BASE - $t);
-	}
-	$bias = adapt($i - $oldi, @output + 1, $oldi == 0);
-	warn "bias becomes $bias" if $DEBUG;
-	$n += $i / (@output + 1);
-	$i = $i % (@output + 1);
-	splice(@output, $i, 0, $n);
-	warn join " ", map sprintf('%04x', $_), @output if $DEBUG;
-	$i++;
-    }
-    return join '', map chr, @output;
-}
-
-sub encode_punycode {
-    my $input = shift;
-    my @input = split //, $input;
-
-    my $n     = INITIAL_N;
-    my $delta = 0;
-    my $bias  = INITIAL_BIAS;
-
-    my @output;
-    my @basic = grep /$BasicRE/, @input;
-    my $h = my $b = @basic;
-    push @output, @basic;
-    push @output, $Delimiter if $b && $h < @input;
-    warn "basic codepoints: (@output)" if $DEBUG;
-
-    while ($h < @input) {
-	my $m = min(grep { $_ >= $n } map ord, @input);
-	warn sprintf "next code point to insert is %04x", $m if $DEBUG;
-	$delta += ($m - $n) * ($h + 1);
-	$n = $m;
-	for my $i (@input) {
-	    my $c = ord($i);
-	    $delta++ if $c < $n;
-	    if ($c == $n) {
-		my $q = $delta;
-	    LOOP:
-		for (my $k = BASE; 1; $k += BASE) {
-		    my $t = ($k <= $bias) ? TMIN :
-			($k >= $bias + TMAX) ? TMAX : $k - $bias;
-		    last LOOP if $q < $t;
-		    my $cp = code_point($t + (($q - $t) % (BASE - $t)));
-		    push @output, chr($cp);
-		    $q = ($q - $t) / (BASE - $t);
-		}
-		push @output, chr(code_point($q));
-		$bias = adapt($delta, $h + 1, $h == $b);
-		warn "bias becomes $bias" if $DEBUG;
-		$delta = 0;
-		$h++;
-	    }
-	}
-	$delta++;
-	$n++;
-    }
-    return join '', @output;
-}
-
-sub min {
-    my $min = shift;
-    for (@_) { $min = $_ if $_ <= $min }
-    return $min;
-}
-
-1;
-__END__
-
-=encoding utf8
-
-=head1 NAME
-
-URI::_punycode - encodes Unicode string in Punycode
-
-=head1 SYNOPSIS
-
-  use strict;
-  use warnings;
-  use utf8;
-
-  use URI::_punycode qw(encode_punycode decode_punycode);
-
-  # encode a unicode string
-  my $punycode = encode_punycode('http://☃.net'); # http://.net-xc8g
-  $punycode = encode_punycode('bücher'); # bcher-kva
-  $punycode = encode_punycode('他们为什么不说中文'); # ihqwcrb4cv8a8dqg056pqjye
-
-  # decode a punycode string back into a unicode string
-  my $unicode = decode_punycode('http://.net-xc8g'); # http://☃.net
-  $unicode = decode_punycode('bcher-kva'); # bücher
-  $unicode = decode_punycode('ihqwcrb4cv8a8dqg056pqjye'); # 他们为什么不说中文
-
-=head1 DESCRIPTION
-
-L<URI::_punycode> is a module to encode / decode Unicode strings into
-L<Punycode|https://tools.ietf.org/html/rfc3492>, an efficient
-encoding of Unicode for use with L<IDNA|https://tools.ietf.org/html/rfc5890>.
-
-=head1 FUNCTIONS
-
-All functions throw exceptions on failure. You can C<catch> them with
-L<Syntax::Keyword::Try> or L<Try::Tiny>. The following functions are exported
-by default.
-
-=head2 encode_punycode
-
-  my $punycode = encode_punycode('http://☃.net');  # http://.net-xc8g
-  $punycode = encode_punycode('bücher'); # bcher-kva
-  $punycode = encode_punycode('他们为什么不说中文') # ihqwcrb4cv8a8dqg056pqjye
-
-Takes a Unicode string (UTF8-flagged variable) and returns a Punycode
-encoding for it.
-
-=head2 decode_punycode
-
-  my $unicode = decode_punycode('http://.net-xc8g'); # http://☃.net
-  $unicode = decode_punycode('bcher-kva'); # bücher
-  $unicode = decode_punycode('ihqwcrb4cv8a8dqg056pqjye'); # 他们为什么不说中文
-
-Takes a Punycode encoding and returns original Unicode string.
-
-=head1 AUTHOR
-
-Tatsuhiko Miyagawa <F<miyagawa@bulknews.net>> is the author of
-L<IDNA::Punycode> which was the basis for this module.
-
-=head1 SEE ALSO
-
-L<IDNA::Punycode>, L<RFC 3492|https://tools.ietf.org/html/rfc3492>,
-L<RFC 5891|https://tools.ietf.org/html/rfc5891>
-
-=head1 COPYRIGHT AND LICENSE
-
-This library is free software; you can redistribute it and/or modify
-it under the same terms as Perl itself.
-
-=cut

package/Binaries/Perl/MacOs/X64/deps/lib/perl5/URI/_query.pm

@@ -1,178 +0,0 @@
-package URI::_query;
-
-use strict;
-use warnings;
-
-use URI ();
-use URI::Escape qw(uri_unescape);
-
-our $VERSION = '5.17';
-
-sub query
-{
-    my $self = shift;
-    $$self =~ m,^([^?\#]*)(?:\?([^\#]*))?(.*)$,s or die;
-
-    if (@_) {
-	my $q = shift;
-	$$self = $1;
-	if (defined $q) {
-	    $q =~ s/([^$URI::uric])/ URI::Escape::escape_char($1)/ego;
-	    utf8::downgrade($q);
-	    $$self .= "?$q";
-	}
-	$$self .= $3;
-    }
-    $2;
-}
-
-# Handle ...?foo=bar&bar=foo type of query
-sub query_form {
-    my $self = shift;
-    my $old = $self->query;
-    if (@_) {
-        # Try to set query string
-        my $delim;
-        my $r = $_[0];
-        if (ref($r) eq "ARRAY") {
-            $delim = $_[1];
-            @_ = @$r;
-        }
-        elsif (ref($r) eq "HASH") {
-            $delim = $_[1];
-            @_ = map { $_ => $r->{$_} } sort keys %$r;
-        }
-        $delim = pop if @_ % 2;
-
-        my @query;
-        while (my($key,$vals) = splice(@_, 0, 2)) {
-            $key = '' unless defined $key;
-	    $key =~ s/([;\/?:@&=+,\$\[\]%])/ URI::Escape::escape_char($1)/eg;
-	    $key =~ s/ /+/g;
-	    $vals = [ref($vals) eq "ARRAY" ? @$vals : $vals];
-            for my $val (@$vals) {
-                $val = '' unless defined $val;
-		$val =~ s/([;\/?:@&=+,\$\[\]%])/ URI::Escape::escape_char($1)/eg;
-                $val =~ s/ /+/g;
-                push(@query, "$key=$val");
-            }
-        }
-        if (@query) {
-            unless ($delim) {
-                $delim = $1 if $old && $old =~ /([&;])/;
-                $delim ||= $URI::DEFAULT_QUERY_FORM_DELIMITER || "&";
-            }
-            $self->query(join($delim, @query));
-        }
-        else {
-            $self->query(undef);
-        }
-    }
-    return if !defined($old) || !length($old) || !defined(wantarray);
-    return unless $old =~ /=/; # not a form
-    map { s/\+/ /g; uri_unescape($_) }
-         map { /=/ ? split(/=/, $_, 2) : ($_ => '')} split(/[&;]/, $old);
-}
-
-# Handle ...?dog+bones type of query
-sub query_keywords
-{
-    my $self = shift;
-    my $old = $self->query;
-    if (@_) {
-        # Try to set query string
-	my @copy = @_;
-	@copy = @{$copy[0]} if @copy == 1 && ref($copy[0]) eq "ARRAY";
-	for (@copy) { s/([;\/?:@&=+,\$\[\]%])/ URI::Escape::escape_char($1)/eg; }
-	$self->query(@copy ? join('+', @copy) : undef);
-    }
-    return if !defined($old) || !defined(wantarray);
-    return if $old =~ /=/;  # not keywords, but a form
-    map { uri_unescape($_) } split(/\+/, $old, -1);
-}
-
-# Some URI::URL compatibility stuff
-sub equery { goto &query }
-
-sub query_param {
-    my $self = shift;
-    my @old = $self->query_form;
-
-    if (@_ == 0) {
-        # get keys
-        my (%seen, $i);
-        return grep !($i++ % 2 || $seen{$_}++), @old;
-    }
-
-    my $key = shift;
-    my @i = grep $_ % 2 == 0 && $old[$_] eq $key, 0 .. $#old;
-
-    if (@_) {
-        my @new = @old;
-        my @new_i = @i;
-        my @vals = map { ref($_) eq 'ARRAY' ? @$_ : $_ } @_;
-
-        while (@new_i > @vals) {
-            splice @new, pop @new_i, 2;
-        }
-        if (@vals > @new_i) {
-            my $i = @new_i ? $new_i[-1] + 2 : @new;
-            my @splice = splice @vals, @new_i, @vals - @new_i;
-
-            splice @new, $i, 0, map { $key => $_ } @splice;
-        }
-        if (@vals) {
-            #print "SET $new_i[0]\n";
-            @new[ map $_ + 1, @new_i ] = @vals;
-        }
-
-        $self->query_form(\@new);
-    }
-
-    return wantarray ? @old[map $_+1, @i] : @i ? $old[$i[0]+1] : undef;
-}
-
-sub query_param_append {
-    my $self = shift;
-    my $key = shift;
-    my @vals = map { ref $_ eq 'ARRAY' ? @$_ : $_ } @_;
-    $self->query_form($self->query_form, $key => \@vals);  # XXX
-    return;
-}
-
-sub query_param_delete {
-    my $self = shift;
-    my $key = shift;
-    my @old = $self->query_form;
-    my @vals;
-
-    for (my $i = @old - 2; $i >= 0; $i -= 2) {
-        next if $old[$i] ne $key;
-        push(@vals, (splice(@old, $i, 2))[1]);
-    }
-    $self->query_form(\@old) if @vals;
-    return wantarray ? reverse @vals : $vals[-1];
-}
-
-sub query_form_hash {
-    my $self = shift;
-    my @old = $self->query_form;
-    if (@_) {
-        $self->query_form(@_ == 1 ? %{shift(@_)} : @_);
-    }
-    my %hash;
-    while (my($k, $v) = splice(@old, 0, 2)) {
-        if (exists $hash{$k}) {
-            for ($hash{$k}) {
-                $_ = [$_] unless ref($_) eq "ARRAY";
-                push(@$_, $v);
-            }
-        }
-        else {
-            $hash{$k} = $v;
-        }
-    }
-    return \%hash;
-}
-
-1;

package/Binaries/Perl/MacOs/X64/deps/lib/perl5/URI/_segment.pm

@@ -1,24 +0,0 @@
-package URI::_segment;
-
-# Represents a generic path_segment so that it can be treated as
-# a string too.
-
-use strict;
-use warnings;
-
-use URI::Escape qw(uri_unescape);
-
-use overload '""' => sub { $_[0]->[0] },
-             fallback => 1;
-
-our $VERSION = '5.17';
-
-sub new
-{
-    my $class = shift;
-    my @segment = split(';', shift, -1);
-    $segment[0] = uri_unescape($segment[0]);
-    bless \@segment, $class;
-}
-
-1;

package/Binaries/Perl/MacOs/X64/deps/lib/perl5/URI/_server.pm

@@ -1,167 +0,0 @@
-package URI::_server;
-
-use strict;
-use warnings;
-
-use parent 'URI::_generic';
-
-use URI::Escape qw(uri_unescape);
-
-our $VERSION = '5.17';
-
-sub _uric_escape {
-    my($class, $str) = @_;
-    if ($str =~ m,^((?:$URI::scheme_re:)?)//([^/?\#]*)(.*)$,os) {
-	my($scheme, $host, $rest) = ($1, $2, $3);
-	my $ui = $host =~ s/(.*@)// ? $1 : "";
-	my $port = $host =~ s/(:\d+)\z// ? $1 : "";
-	if (_host_escape($host)) {
-	    $str = "$scheme//$ui$host$port$rest";
-	}
-    }
-    return $class->SUPER::_uric_escape($str);
-}
-
-sub _host_escape {
-  return if  URI::HAS_RESERVED_SQUARE_BRACKETS  and  $_[0] !~ /[^$URI::uric]/;
-  return if !URI::HAS_RESERVED_SQUARE_BRACKETS  and  $_[0] !~ /[^$URI::uric4host]/;
-    eval {
-	require URI::_idna;
-	$_[0] = URI::_idna::encode($_[0]);
-    };
-    return 0 if $@;
-    return 1;
-}
-
-sub as_iri {
-    my $self = shift;
-    my $str = $self->SUPER::as_iri;
-    if ($str =~ /\bxn--/) {
-	if ($str =~ m,^((?:$URI::scheme_re:)?)//([^/?\#]*)(.*)$,os) {
-	    my($scheme, $host, $rest) = ($1, $2, $3);
-	    my $ui = $host =~ s/(.*@)// ? $1 : "";
-	    my $port = $host =~ s/(:\d+)\z// ? $1 : "";
-	    require URI::_idna;
-	    $host = URI::_idna::decode($host);
-	    $str = "$scheme//$ui$host$port$rest";
-	}
-    }
-    return $str;
-}
-
-sub userinfo
-{
-    my $self = shift;
-    my $old = $self->authority;
-
-    if (@_) {
-	my $new = $old;
-	$new = "" unless defined $new;
-	$new =~ s/.*@//;  # remove old stuff
-	my $ui = shift;
-	if (defined $ui) {
-          $ui =~ s/([^$URI::uric4user])/ URI::Escape::escape_char($1)/ego;
-          $new = "$ui\@$new";
-	}
-	$self->authority($new);
-    }
-    return undef if !defined($old) || $old !~ /(.*)@/;
-    return $1;
-}
-
-sub host
-{
-    my $self = shift;
-    my $old = $self->authority;
-    if (@_) {
-	my $tmp = $old;
-	$tmp = "" unless defined $tmp;
-	my $ui = ($tmp =~ /(.*@)/) ? $1 : "";
-	my $port = ($tmp =~ /(:\d+)$/) ? $1 : "";
-	my $new = shift;
-	$new = "" unless defined $new;
-	if (length $new) {
-	    $new =~ s/[@]/%40/g;   # protect @
-	    if ($new =~ /^[^:]*:\d*\z/ || $new =~ /]:\d*\z/) {
-		$new =~ s/(:\d*)\z// || die "Assert";
-		$port = $1;
-	    }
-	    $new = "[$new]" if $new =~ /:/ && $new !~ /^\[/; # IPv6 address
-	    _host_escape($new);
-	}
-	$self->authority("$ui$new$port");
-    }
-    return undef unless defined $old;
-    $old =~ s/.*@//;
-    $old =~ s/:\d+$//;          # remove the port
-    $old =~ s{^\[(.*)\]$}{$1};  # remove brackets around IPv6 (RFC 3986 3.2.2)
-    return uri_unescape($old);
-}
-
-sub ihost
-{
-    my $self = shift;
-    my $old = $self->host(@_);
-    if ($old =~ /(^|\.)xn--/) {
-	require URI::_idna;
-	$old = URI::_idna::decode($old);
-    }
-    return $old;
-}
-
-sub _port
-{
-    my $self = shift;
-    my $old = $self->authority;
-    if (@_) {
-	my $new = $old;
-	$new =~ s/:\d*$//;
-	my $port = shift;
-	$new .= ":$port" if defined $port;
-	$self->authority($new);
-    }
-    return $1 if defined($old) && $old =~ /:(\d*)$/;
-    return;
-}
-
-sub port
-{
-    my $self = shift;
-    my $port = $self->_port(@_);
-    $port = $self->default_port if !defined($port) || $port eq "";
-    $port;
-}
-
-sub host_port
-{
-    my $self = shift;
-    my $old = $self->authority;
-    $self->host(shift) if @_;
-    return undef unless defined $old;
-    $old =~ s/.*@//;        # zap userinfo
-    $old =~ s/:$//;         # empty port should be treated the same a no port
-    $old .= ":" . $self->port unless $old =~ /:\d+$/;
-    $old;
-}
-
-
-sub default_port { undef }
-
-sub canonical
-{
-    my $self = shift;
-    my $other = $self->SUPER::canonical;
-    my $host = $other->host || "";
-    my $port = $other->_port;
-    my $uc_host = $host =~ /[A-Z]/;
-    my $def_port = defined($port) && ($port eq "" ||
-                                      $port == $self->default_port);
-    if ($uc_host || $def_port) {
-	$other = $other->clone if $other == $self;
-	$other->host(lc $host) if $uc_host;
-	$other->port(undef)    if $def_port;
-    }
-    $other;
-}
-
-1;

package/Binaries/Perl/MacOs/X64/deps/lib/perl5/URI/_userpass.pm

@@ -1,55 +0,0 @@
-package URI::_userpass;
-
-use strict;
-use warnings;
-
-use URI::Escape qw(uri_unescape);
-
-our $VERSION = '5.17';
-
-sub user
-{
-    my $self = shift;
-    my $info = $self->userinfo;
-    if (@_) {
-	my $new = shift;
-	my $pass = defined($info) ? $info : "";
-	$pass =~ s/^[^:]*//;
-
-	if (!defined($new) && !length($pass)) {
-	    $self->userinfo(undef);
-	} else {
-	    $new = "" unless defined($new);
-	    $new =~ s/%/%25/g;
-	    $new =~ s/:/%3A/g;
-	    $self->userinfo("$new$pass");
-	}
-    }
-    return undef unless defined $info;
-    $info =~ s/:.*//;
-    uri_unescape($info);
-}
-
-sub password
-{
-    my $self = shift;
-    my $info = $self->userinfo;
-    if (@_) {
-	my $new = shift;
-	my $user = defined($info) ? $info : "";
-	$user =~ s/:.*//;
-
-	if (!defined($new) && !length($user)) {
-	    $self->userinfo(undef);
-	} else {
-	    $new = "" unless defined($new);
-	    $new =~ s/%/%25/g;
-	    $self->userinfo("$user:$new");
-	}
-    }
-    return undef unless defined $info;
-    return undef unless $info =~ s/^[^:]*://;
-    uri_unescape($info);
-}
-
-1;