javonet-nodejs-sdk 2.1.1 → 2.1.3

package/Binaries/Perl/MacOs/X64/deps/lib/perl5/URI/_generic.pm

@@ -1,283 +0,0 @@
-package URI::_generic;
-
-use strict;
-use warnings;
-
-use parent qw(URI URI::_query);
-
-use URI::Escape qw(uri_unescape);
-use Carp ();
-
-our $VERSION = '5.17';
-
-my $ACHAR = URI::HAS_RESERVED_SQUARE_BRACKETS ? $URI::uric : $URI::uric4host;  $ACHAR =~ s,\\[/?],,g;
-my $PCHAR = $URI::uric;                                                        $PCHAR =~ s,\\[?],,g;
-
-sub _no_scheme_ok { 1 }
-
-our $IPv6_re;
-
-sub _looks_like_raw_ip6_address {
-  my $addr = shift;
-
-  if ( !$IPv6_re ) { #-- lazy / runs once / use Regexp::IPv6 if installed
-    eval {
-      require Regexp::IPv6;
-      Regexp::IPv6->import( qw($IPv6_re) );
-      1;
-    }  ||  do { $IPv6_re = qr/[:0-9a-f]{3,}/; }; #-- fallback: unambitious guess
-  }
-
-  return 0 unless $addr;
-  return 0 if $addr =~ tr/:/:/ < 2;  #-- fallback must not create false positive for IPv4:Port = 0:0
-  return 1 if $addr =~ /^$IPv6_re$/i;
-  return 0;
-}
-
-
-sub authority
-{
-    my $self = shift;
-    $$self =~ m,^((?:$URI::scheme_re:)?)(?://([^/?\#]*))?(.*)$,os or die;
-
-    if (@_) {
-	my $auth = shift;
-	$$self = $1;
-	my $rest = $3;
-	if (defined $auth) {
-	    $auth =~ s/([^$ACHAR])/ URI::Escape::escape_char($1)/ego;
-            if ( my ($user, $host) = $auth =~ /^(.*@)?([^@]+)$/ ) { #-- special escape userinfo part
-              $user ||= '';
-              $user =~ s/([^$URI::uric4user])/ URI::Escape::escape_char($1)/ego;
-              $user =~ s/%40$/\@/; # recover final '@'
-              $host = "[$host]" if _looks_like_raw_ip6_address( $host );
-              $auth = $user . $host;
-            }
-	    utf8::downgrade($auth);
-	    $$self .= "//$auth";
-	}
-	_check_path($rest, $$self);
-	$$self .= $rest;
-    }
-    $2;
-}
-
-sub path
-{
-    my $self = shift;
-    $$self =~ m,^((?:[^:/?\#]+:)?(?://[^/?\#]*)?)([^?\#]*)(.*)$,s or die;
-
-    if (@_) {
-	$$self = $1;
-	my $rest = $3;
-	my $new_path = shift;
-	$new_path = "" unless defined $new_path;
-	$new_path =~ s/([^$PCHAR])/ URI::Escape::escape_char($1)/ego;
-	utf8::downgrade($new_path);
-	_check_path($new_path, $$self);
-	$$self .= $new_path . $rest;
-    }
-    $2;
-}
-
-sub path_query
-{
-    my $self = shift;
-    $$self =~ m,^((?:[^:/?\#]+:)?(?://[^/?\#]*)?)([^\#]*)(.*)$,s or die;
-
-    if (@_) {
-	$$self = $1;
-	my $rest = $3;
-	my $new_path = shift;
-	$new_path = "" unless defined $new_path;
-	$new_path =~ s/([^$URI::uric])/ URI::Escape::escape_char($1)/ego;
-	utf8::downgrade($new_path);
-	_check_path($new_path, $$self);
-	$$self .= $new_path . $rest;
-    }
-    $2;
-}
-
-sub _check_path
-{
-    my($path, $pre) = @_;
-    my $prefix;
-    if ($pre =~ m,/,) {  # authority present
-	$prefix = "/" if length($path) && $path !~ m,^[/?\#],;
-    }
-    else {
-	if ($path =~ m,^//,) {
-	    Carp::carp("Path starting with double slash is confusing")
-		if $^W;
-	}
-	elsif (!length($pre) && $path =~ m,^[^:/?\#]+:,) {
-	    Carp::carp("Path might look like scheme, './' prepended")
-		if $^W;
-	    $prefix = "./";
-	}
-    }
-    substr($_[0], 0, 0) = $prefix if defined $prefix;
-}
-
-sub path_segments
-{
-    my $self = shift;
-    my $path = $self->path;
-    if (@_) {
-	my @arg = @_;  # make a copy
-	for (@arg) {
-	    if (ref($_)) {
-		my @seg = @$_;
-		$seg[0] =~ s/%/%25/g;
-		for (@seg) { s/;/%3B/g; }
-		$_ = join(";", @seg);
-	    }
-	    else {
-		 s/%/%25/g; s/;/%3B/g;
-	    }
-	    s,/,%2F,g;
-	}
-	$self->path(join("/", @arg));
-    }
-    return $path unless wantarray;
-    map {/;/ ? $self->_split_segment($_)
-             : uri_unescape($_) }
-        split('/', $path, -1);
-}
-
-
-sub _split_segment
-{
-    my $self = shift;
-    require URI::_segment;
-    URI::_segment->new(@_);
-}
-
-
-sub abs
-{
-    my $self = shift;
-    my $base = shift || Carp::croak("Missing base argument");
-
-    if (my $scheme = $self->scheme) {
-	return $self unless $URI::ABS_ALLOW_RELATIVE_SCHEME;
-	$base = URI->new($base) unless ref $base;
-	return $self unless $scheme eq $base->scheme;
-    }
-
-    $base = URI->new($base) unless ref $base;
-    my $abs = $self->clone;
-    $abs->scheme($base->scheme);
-    return $abs if $$self =~ m,^(?:$URI::scheme_re:)?//,o;
-    $abs->authority($base->authority);
-
-    my $path = $self->path;
-    return $abs if $path =~ m,^/,;
-
-    if (!length($path)) {
-	my $abs = $base->clone;
-	my $query = $self->query;
-	$abs->query($query) if defined $query;
-	my $fragment = $self->fragment;
-	$abs->fragment($fragment) if defined $fragment;
-	return $abs;
-    }
-
-    my $p = $base->path;
-    $p =~ s,[^/]+$,,;
-    $p .= $path;
-    my @p = split('/', $p, -1);
-    shift(@p) if @p && !length($p[0]);
-    my $i = 1;
-    while ($i < @p) {
-	#print "$i ", join("/", @p), " ($p[$i])\n";
-	if ($p[$i-1] eq ".") {
-	    splice(@p, $i-1, 1);
-	    $i-- if $i > 1;
-	}
-	elsif ($p[$i] eq ".." && $p[$i-1] ne "..") {
-	    splice(@p, $i-1, 2);
-	    if ($i > 1) {
-		$i--;
-		push(@p, "") if $i == @p;
-	    }
-	}
-	else {
-	    $i++;
-	}
-    }
-    $p[-1] = "" if @p && $p[-1] eq ".";  # trailing "/."
-    if ($URI::ABS_REMOTE_LEADING_DOTS) {
-        shift @p while @p && $p[0] =~ /^\.\.?$/;
-    }
-    $abs->path("/" . join("/", @p));
-    $abs;
-}
-
-# The opposite of $url->abs.  Return a URI which is as relative as possible
-sub rel {
-    my $self = shift;
-    my $base = shift || Carp::croak("Missing base argument");
-    my $rel = $self->clone;
-    $base = URI->new($base) unless ref $base;
-
-    #my($scheme, $auth, $path) = @{$rel}{qw(scheme authority path)};
-    my $scheme = $rel->scheme;
-    my $auth   = $rel->canonical->authority;
-    my $path   = $rel->path;
-
-    if (!defined($scheme) && !defined($auth)) {
-	# it is already relative
-	return $rel;
-    }
-
-    #my($bscheme, $bauth, $bpath) = @{$base}{qw(scheme authority path)};
-    my $bscheme = $base->scheme;
-    my $bauth   = $base->canonical->authority;
-    my $bpath   = $base->path;
-
-    for ($bscheme, $bauth, $auth) {
-	$_ = '' unless defined
-    }
-
-    unless ($scheme eq $bscheme && $auth eq $bauth) {
-	# different location, can't make it relative
-	return $rel;
-    }
-
-    for ($path, $bpath) {  $_ = "/$_" unless m,^/,; }
-
-    # Make it relative by eliminating scheme and authority
-    $rel->scheme(undef);
-    $rel->authority(undef);
-
-    # This loop is based on code from Nicolai Langfeldt <janl@ifi.uio.no>.
-    # First we calculate common initial path components length ($li).
-    my $li = 1;
-    while (1) {
-	my $i = index($path, '/', $li);
-	last if $i < 0 ||
-                $i != index($bpath, '/', $li) ||
-	        substr($path,$li,$i-$li) ne substr($bpath,$li,$i-$li);
-	$li=$i+1;
-    }
-    # then we nuke it from both paths
-    substr($path, 0,$li) = '';
-    substr($bpath,0,$li) = '';
-
-    if ($path eq $bpath &&
-        defined($rel->fragment) &&
-        !defined($rel->query)) {
-        $rel->path("");
-    }
-    else {
-        # Add one "../" for each path component left in the base path
-        $path = ('../' x $bpath =~ tr|/|/|) . $path;
-	$path = "./" if $path eq "";
-        $rel->path($path);
-    }
-
-    $rel;
-}
-
-1;

package/Binaries/Perl/MacOs/X64/deps/lib/perl5/URI/_idna.pm

@@ -1,91 +0,0 @@
-package URI::_idna;
-
-# This module implements the RFCs 3490 (IDNA) and 3491 (Nameprep)
-# based on Python-2.6.4/Lib/encodings/idna.py
-
-use strict;
-use warnings;
-
-use URI::_punycode qw(decode_punycode encode_punycode);
-use Carp qw(croak);
-
-our $VERSION = '5.17';
-
-BEGIN {
-  *URI::_idna::_ENV_::JOIN_LEAKS_UTF8_FLAGS = "$]" < 5.008_003
-    ? sub () { 1 }
-    : sub () { 0 }
-  ;
-}
-
-my $ASCII = qr/^[\x00-\x7F]*\z/;
-
-sub encode {
-    my $idomain = shift;
-    my @labels = split(/\./, $idomain, -1);
-    my @last_empty;
-    push(@last_empty, pop @labels) if @labels > 1 && $labels[-1] eq "";
-    for (@labels) {
-	$_ = ToASCII($_);
-    }
-
-    return eval 'join(".", @labels, @last_empty)' if URI::_idna::_ENV_::JOIN_LEAKS_UTF8_FLAGS;
-    return join(".", @labels, @last_empty);
-}
-
-sub decode {
-    my $domain = shift;
-    return join(".", map ToUnicode($_), split(/\./, $domain, -1))
-}
-
-sub nameprep { # XXX real implementation missing
-    my $label = shift;
-    $label = lc($label);
-    return $label;
-}
-
-sub check_size {
-    my $label = shift;
-    croak "Label empty" if $label eq "";
-    croak "Label too long" if length($label) > 63;
-    return $label;
-}
-
-sub ToASCII {
-    my $label = shift;
-    return check_size($label) if $label =~ $ASCII;
-
-    # Step 2: nameprep
-    $label = nameprep($label);
-    # Step 3: UseSTD3ASCIIRules is false
-    # Step 4: try ASCII again
-    return check_size($label) if $label =~ $ASCII;
-
-    # Step 5: Check ACE prefix
-    if ($label =~ /^xn--/) {
-        croak "Label starts with ACE prefix";
-    }
-
-    # Step 6: Encode with PUNYCODE
-    $label = encode_punycode($label);
-
-    # Step 7: Prepend ACE prefix
-    $label = "xn--$label";
-
-    # Step 8: Check size
-    return check_size($label);
-}
-
-sub ToUnicode {
-    my $label = shift;
-    $label = nameprep($label) unless $label =~ $ASCII;
-    return $label unless $label =~ /^xn--/;
-    my $result = decode_punycode(substr($label, 4));
-    my $label2 = ToASCII($result);
-    if (lc($label) ne $label2) {
-	croak "IDNA does not round-trip: '\L$label\E' vs '$label2'";
-    }
-    return $result;
-}
-
-1;

package/Binaries/Perl/MacOs/X64/deps/lib/perl5/URI/_ldap.pm

@@ -1,140 +0,0 @@
-# Copyright (c) 1998 Graham Barr <gbarr@pobox.com>. All rights reserved.
-# This program is free software; you can redistribute it and/or
-# modify it under the same terms as Perl itself.
-
-package URI::_ldap;
-
-use strict;
-use warnings;
-
-our $VERSION = '5.17';
-
-use URI::Escape qw(uri_unescape);
-
-sub _ldap_elem {
-  my $self  = shift;
-  my $elem  = shift;
-  my $query = $self->query;
-  my @bits  = (split(/\?/,defined($query) ? $query : ""),("")x4);
-  my $old   = $bits[$elem];
-
-  if (@_) {
-    my $new = shift;
-    $new =~ s/\?/%3F/g;
-    $bits[$elem] = $new;
-    $query = join("?",@bits);
-    $query =~ s/\?+$//;
-    $query = undef unless length($query);
-    $self->query($query);
-  }
-
-  $old;
-}
-
-sub dn {
-  my $old = shift->path(@_);
-  $old =~ s:^/::;
-  uri_unescape($old);
-}
-
-sub attributes {
-  my $self = shift;
-  my $old = _ldap_elem($self,0, @_ ? join(",", map { my $tmp = $_; $tmp =~ s/,/%2C/g; $tmp } @_) : ());
-  return $old unless wantarray;
-  map { uri_unescape($_) } split(/,/,$old);
-}
-
-sub _scope {
-  my $self = shift;
-  my $old = _ldap_elem($self,1, @_);
-  return undef unless defined wantarray && defined $old;
-  uri_unescape($old);
-}
-
-sub scope {
-  my $old = &_scope;
-  $old = "base" unless length $old;
-  $old;
-}
-
-sub _filter {
-  my $self = shift;
-  my $old = _ldap_elem($self,2, @_);
-  return undef unless defined wantarray && defined $old;
-  uri_unescape($old); # || "(objectClass=*)";
-}
-
-sub filter {
-  my $old = &_filter;
-  $old = "(objectClass=*)" unless length $old;
-  $old;
-}
-
-sub extensions {
-  my $self = shift;
-  my @ext;
-  while (@_) {
-    my $key = shift;
-    my $value = shift;
-    push(@ext, join("=", map { $_="" unless defined; s/,/%2C/g; $_ } $key, $value));
-  }
-  @ext = join(",", @ext) if @ext;
-  my $old = _ldap_elem($self,3, @ext);
-  return $old unless wantarray;
-  map { uri_unescape($_) } map { /^([^=]+)=(.*)$/ } split(/,/,$old);
-}
-
-sub canonical
-{
-    my $self = shift;
-    my $other = $self->_nonldap_canonical;
-
-    # The stuff below is not as efficient as one might hope...
-
-    $other = $other->clone if $other == $self;
-
-    $other->dn(_normalize_dn($other->dn));
-
-    # Should really know about mixed case "postalAddress", etc...
-    $other->attributes(map lc, $other->attributes);
-
-    # Lowercase scope, remove default
-    my $old_scope = $other->scope;
-    my $new_scope = lc($old_scope);
-    $new_scope = "" if $new_scope eq "base";
-    $other->scope($new_scope) if $new_scope ne $old_scope;
-
-    # Remove filter if default
-    my $old_filter = $other->filter;
-    $other->filter("") if lc($old_filter) eq "(objectclass=*)" ||
-	                  lc($old_filter) eq "objectclass=*";
-
-    # Lowercase extensions types and deal with known extension values
-    my @ext = $other->extensions;
-    for (my $i = 0; $i < @ext; $i += 2) {
-	my $etype = $ext[$i] = lc($ext[$i]);
-	if ($etype =~ /^!?bindname$/) {
-	    $ext[$i+1] = _normalize_dn($ext[$i+1]);
-	}
-    }
-    $other->extensions(@ext) if @ext;
-    
-    $other;
-}
-
-sub _normalize_dn  # RFC 2253
-{
-    my $dn = shift;
-
-    return $dn;
-    # The code below will fail if the "+" or "," is embedding in a quoted
-    # string or simply escaped...
-
-    my @dn = split(/([+,])/, $dn);
-    for (@dn) {
-	s/^([a-zA-Z]+=)/lc($1)/e;
-    }
-    join("", @dn);
-}
-
-1;

package/Binaries/Perl/MacOs/X64/deps/lib/perl5/URI/_login.pm

@@ -1,13 +0,0 @@
-package URI::_login;
-
-use strict;
-use warnings;
-
-use parent qw(URI::_server URI::_userpass);
-
-our $VERSION = '5.17';
-
-# Generic terminal logins.  This is used as a base class for 'telnet',
-# 'tn3270', and 'rlogin' URL schemes.
-
-1;