hane 1.0.0

package/vendor/zlib/contrib/minizip/CMakeLists.txt

@@ -0,0 +1,380 @@
+cmake_minimum_required(VERSION 3.12...3.31)
+
+project(
+    minizip
+    VERSION 1.0.0
+    LANGUAGES C
+    DESCRIPTION "A library for creating zipfiles based in zlib"
+    HOMEPAGE_URL "https://www.winimage.com/zLibDll/minizip.html")
+
+if(CMAKE_SIZEOF_VOID_P LESS 8 AND NOT MINGW)
+    message(WARNING "libminizip needs 64bit - stopping here")
+    return()
+endif(CMAKE_SIZEOF_VOID_P LESS 8 AND NOT MINGW)
+
+# ============================================================================
+# CPack
+# ============================================================================
+set(CPACK_PACKAGE_VENDOR "zlib-Project")
+set(CPACK_PACKAGE_DESCRIPTION_FILE ${minizip_SOURCE_DIR}/MiniZip64_info.txt)
+set(CPACK_RESOURCE_FILE_LICENSE ${minizip_SOURCE_DIR}/../../LICENSE)
+set(CPACK_RESOURCE_FILE_README ${minizip_SOURCE_DIR}/MiniZip64_info.txt)
+
+# ============================================================================
+# configuration
+# ============================================================================
+option(MINIZIP_BUILD_SHARED "Enable building minizip shared library" ON)
+option(MINIZIP_BUILD_STATIC "Enable building minizip static library" ON)
+option(MINIZIP_BUILD_TESTING "Enable testing of minizip" ON)
+option(MINIZIP_ENABLE_BZIP2 "Build minizip withj bzip2 support" ON)
+option(MINIZIP_INSTALL "Enable installation of minizip" ON)
+
+if(MINGW)
+    option(MINIZIP_INSTALL_COMPAT_DLL "Install a copy as libminizip-1.dll" ON)
+endif(MINGW)
+
+include(CheckCSourceCompiles)
+include(CheckFunctionExists)
+include(CheckIncludeFile)
+include(CMakePackageConfigHelpers)
+include(CheckTypeSize)
+include(GNUInstallDirs)
+
+if(NOT CPACK_INCLUDED)
+    include(CPack)
+endif(NOT CPACK_INCLUDED)
+
+if(MINIZIP_ENABLE_BZIP2)
+    find_package(BZip2 REQUIRED)
+endif(MINIZIP_ENABLE_BZIP2)
+
+#
+# Check for fopen64
+#
+check_function_exists(fopen64 HAVE_FOPEN64)
+
+#
+# Check for fseeko
+#
+check_function_exists(fseeko HAVE_FSEEKO)
+
+#
+# Check for unistd.h
+#
+check_include_file(unistd.h HAVE_UNISTD_H)
+
+#
+# Check to see if we have large file support
+#
+set(CMAKE_REQUIRED_DEFINITIONS -D_LARGEFILE64_SOURCE=1)
+check_type_size(off64_t OFF64_T)
+unset(CMAKE_REQUIRED_DEFINITIONS) # clear variable
+
+#
+# Check visibility attribute is supported
+#
+if(MSVC)
+    set(CMAKE_REQUIRED_FLAGS "-WX")
+else(MSVC)
+    set(CMAKE_REQUIRED_FLAGS "-WError")
+endif(MSVC)
+
+check_c_source_compiles(
+    "
+        #include <stdlib.h>
+        static void f(void) __attribute__ ((visibility(\"hidden\")));
+        int main(void) {return 0;}
+    "
+    HAVE___ATTR__VIS_HIDDEN)
+
+unset(CMAKE_REQUIRED_FLAGS)
+
+if(NOT TARGET ZLIB::ZLIB)
+    find_package(ZLIB REQUIRED CONFIG)
+endif(NOT TARGET ZLIB::ZLIB)
+
+set(LIBMINIZIP_SRCS ioapi.c mztools.c unzip.c zip.c)
+
+set(LIBMINIZIP_HDRS crypt.h ints.h ioapi.h mztools.h unzip.h zip.h)
+
+set(MINIZIP_SRCS ioapi.c $<$<BOOL:${WIN32}>:iowin32.c> minizip.c zip.c)
+
+set(MINIZIP_HDRS crypt.h ints.h ioapi.h $<$<BOOL:${WIN32}>:iowin32.h> skipset.h
+                 zip.h)
+
+set(MINIUNZIP_SRCS ioapi.c $<$<BOOL:${WIN32}>:iowin32.c> miniunz.c unzip.c
+                   zip.c)
+
+set(MINIUNZIP_HDRS
+    crypt.h
+    ints.h
+    ioapi.h
+    $<$<BOOL:${WIN32}>:iowin32.h>
+    skipset.h
+    unzip.h
+    zip.h)
+
+if(WIN32 OR CYGWIN)
+    set(minizip_static_suffix "s")
+    set(CMAKE_DEBUG_POSTFIX "d")
+endif(WIN32 OR CYGWIN)
+
+if(MINIZIP_BUILD_SHARED)
+    set(CMAKE_WINDOWS_EXPORT_ALL_SYMBOLS TRUE)
+    add_library(libminizip SHARED ${LIBMINIZIP_SRCS} ${LIBMINIZIP_HDRS})
+    add_library(MINIZIP::minizip ALIAS libminizip)
+    target_include_directories(
+        libminizip PUBLIC $<BUILD_INTERFACE:${minizip_SOURCE_DIR}>
+                          $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>)
+    target_compile_definitions(
+        libminizip
+        PRIVATE $<$<BOOL:${MSVC}>:_CRT_SECURE_NO_WARNINGS>
+                $<$<BOOL:${HAVE___ATTR__VIS_HIDDEN}>:HAVE_HIDDEN>
+                $<$<BOOL:${HAVE_UNISTD_H}>:HAVE_UNISTD_H=1>
+        PUBLIC $<$<BOOL:${HAVE_OFF64_T}>:_LARGEFILE64_SOURCE=1>
+                $<$<BOOL:${BZIP2_FOUND}>:HAVE_BZIP2=1>
+                $<$<BOOL:NOT:${HAVE_FOPEN64}>:USE_FILE32API=1>)
+
+    if(NOT CYGWIN)
+        set_target_properties(libminizip PROPERTIES SOVERSION
+                                                    ${minizip_VERSION_MAJOR})
+    endif(NOT CYGWIN)
+
+    set_target_properties(
+        libminizip
+        PROPERTIES EXPORT_NAME minizip
+                   OUTPUT_NAME minizip
+                   VERSION ${minizip_VERSION}
+                   SOVERSION ${minizip_VERSION_MAJOR})
+
+    target_link_libraries(libminizip
+        PUBLIC ZLIB::ZLIB
+            $<$<BOOL:${BZIP2_FOUND}>:BZip2::BZip2>)
+
+    add_executable(minizip ${MINIZIP_SRCS} ${MINIZIP_HDRS})
+    set_target_properties(minizip PROPERTIES EXPORT_NAME minizip_executable)
+    target_compile_definitions(
+        minizip PRIVATE $<$<BOOL:${MSVC}>:_CRT_SECURE_NO_WARNINGS>)
+    target_link_libraries(minizip PRIVATE MINIZIP::minizip)
+    add_executable(miniunzip ${MINIUNZIP_SRCS} ${MINIUNZIP_HDRS})
+    set_target_properties(miniunzip PROPERTIES EXPORT_NAME miniunzip_executable)
+    target_compile_definitions(
+        miniunzip PRIVATE $<$<BOOL:${MSVC}>:_CRT_SECURE_NO_WARNINGS>)
+    target_link_libraries(miniunzip PRIVATE MINIZIP::minizip)
+endif(MINIZIP_BUILD_SHARED)
+
+if(MINIZIP_BUILD_STATIC)
+    add_library(libminizipstatic STATIC ${LIBMINIZIP_SRCS} ${LIBMINIZIP_HDRS})
+    add_library(MINIZIP::minizipstatic ALIAS libminizipstatic)
+    target_include_directories(
+        libminizipstatic
+        PUBLIC $<BUILD_INTERFACE:${minizip_SOURCE_DIR}>
+               $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>)
+    target_compile_definitions(
+        libminizipstatic
+        PRIVATE $<$<BOOL:${MSVC}>:_CRT_SECURE_NO_WARNINGS>
+                $<$<BOOL:${HAVE___ATTR__VIS_HIDDEN}>:HAVE_HIDDEN>
+                $<$<BOOL:${HAVE_UNISTD_H}>:HAVE_UNISTD_H=1>
+        PUBLIC $<$<BOOL:${HAVE_OFF64_T}>:_LARGEFILE64_SOURCE=1>
+                $<$<BOOL:${BZIP2_FOUND}>:HAVE_BZIP2=1>
+                $<$<BOOL:NOT:${HAVE_FOPEN64}>:USE_FILE32API=1>)
+    set_target_properties(
+        libminizipstatic PROPERTIES EXPORT_NAME minizipstatic
+                                    OUTPUT_NAME minizip${minizip_static_suffix})
+
+    if(CYGWIN)
+        set_target_properties(libminizipstatic PROPERTIES SUFFIX ".dll.a")
+    endif(CYGWIN)
+
+    target_link_libraries(libminizipstatic PUBLIC ZLIB::ZLIBSTATIC
+        $<$<BOOL:${BZIP2_FOUND}>:BZip2::BZip2>)
+
+    add_executable(minizipstatic ${MINIZIP_SRCS} ${MINIZIP_HDRS})
+    set_target_properties(minizipstatic PROPERTIES EXPORT_NAME
+                                                   minizip_static_executable)
+    target_compile_definitions(
+        minizipstatic PRIVATE $<$<BOOL:${MSVC}>:_CRT_SECURE_NO_WARNINGS>)
+    target_link_libraries(minizipstatic PRIVATE MINIZIP::minizipstatic)
+    add_executable(miniunzipstatic ${MINIUNZIP_SRCS} ${MINIUNZIP_HDRS})
+    set_target_properties(miniunzipstatic
+                          PROPERTIES EXPORT_NAME miniunzip_static_executable)
+    target_compile_definitions(
+        miniunzipstatic PRIVATE $<$<BOOL:${MSVC}>:_CRT_SECURE_NO_WARNINGS>)
+    target_link_libraries(miniunzipstatic PRIVATE MINIZIP::minizipstatic)
+endif(MINIZIP_BUILD_STATIC)
+
+if(MINIZIP_INSTALL)
+    if(MINIZIP_BUILD_SHARED)
+        install(
+            TARGETS libminizip minizip miniunzip
+            COMPONENT Runtime
+            EXPORT minizipSharedExport
+            RUNTIME DESTINATION "${CMAKE_INSTALL_BINDIR}"
+            ARCHIVE DESTINATION "${CMAKE_INSTALL_LIBDIR}"
+            LIBRARY DESTINATION "${CMAKE_INSTALL_LIBDIR}")
+        install(
+            EXPORT minizipSharedExport
+            FILE minizip-shared.cmake
+            NAMESPACE MINIZIP::
+            DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/minizip)
+        if(MINIZIP_INSTALL_COMPAT_DLL)
+            install(
+                FILES $<TARGET_FILE:libminizip>
+                COMPONENT Runtime
+                RENAME libminizip-${minizip_VERSION_MAJOR}.dll
+                DESTINATION "${CMAKE_INSTALL_BINDIR}")
+        endif(MINIZIP_INSTALL_COMPAT_DLL)
+
+        if(MSVC)
+            install(
+                FILES $<TARGET_PDB_FILE:libminizip>
+                COMPONENT Runtime
+                DESTINATION ${CMAKE_INSTALL_BINDIR}
+                CONFIGURATIONS Debug OR RelWithDebInfo
+                OPTIONAL)
+        endif(MSVC)
+    endif(MINIZIP_BUILD_SHARED)
+
+    if(MINIZIP_BUILD_STATIC)
+        install(
+            TARGETS libminizipstatic
+            COMPONENT Development
+            TARGETS minizipstatic miniunzipstatic
+            COMPONENT Runtime
+            EXPORT minizipStaticExport
+            RUNTIME DESTINATION "${CMAKE_INSTALL_BINDIR}"
+            ARCHIVE DESTINATION "${CMAKE_INSTALL_LIBDIR}"
+            LIBRARY DESTINATION "${CMAKE_INSTALL_LIBDIR}")
+        install(
+            EXPORT minizipStaticExport
+            FILE minizip-static.cmake
+            NAMESPACE MINIZIP::
+            DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/minizip)
+    endif(MINIZIP_BUILD_STATIC)
+
+    configure_package_config_file(
+        ${minizip_SOURCE_DIR}/minizipConfig.cmake.in
+        ${minizip_BINARY_DIR}/minizipConfig.cmake
+        INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/minizip)
+    write_basic_package_version_file(
+        "${minizip_BINARY_DIR}/minizipConfigVersion.cmake"
+        VERSION "${minizip_VERSION}"
+        COMPATIBILITY AnyNewerVersion)
+    install(FILES ${minizip_BINARY_DIR}/minizipConfig.cmake
+                  ${minizip_BINARY_DIR}/minizipConfigVersion.cmake
+            DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/minizip)
+    install(
+        FILES ${LIBMINIZIP_HDRS}
+        COMPONENT Development
+        DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}")
+endif(MINIZIP_INSTALL)
+
+if(MINIZIP_BUILD_TESTING)
+    enable_testing()
+
+    if(MINIZIP_BUILD_SHARED AND NOT ${CMAKE_SHARED_LIBRARY_SUFFIX} STREQUAL
+                                ".dll")
+        add_test(
+            NAME minizip_prepare_shared_zip
+            COMMAND ${CMAKE_COMMAND} -DCREATE_SHARED=ON -P
+                    ${CMAKE_CURRENT_SOURCE_DIR}/test/test_helper.cm
+            WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/test)
+        add_test(
+            NAME minizip_zipping_test_file_shared
+            COMMAND minizip test_file_shared.zip test_file_shared.txt
+            WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/test)
+        add_test(
+            NAME minizip_prepare_shared_unzip
+            COMMAND ${CMAKE_COMMAND} -DMOVE_SHARED=ON -P
+                    ${CMAKE_CURRENT_SOURCE_DIR}/test/test_helper.cm
+            WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/test)
+        add_test(
+            NAME minizip_miniunzipping_test_file_shared.zip
+            COMMAND miniunzip test_file_shared.zip
+            WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/test)
+        add_test(
+            NAME minizip_compare_shared
+            COMMAND ${CMAKE_COMMAND} -E compare_files test_file_shared.txt
+                    test_file_shared.orig
+            WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/test)
+        add_test(
+            NAME minizip_clean_shared_zip
+            COMMAND ${CMAKE_COMMAND} -DDELETE_SHARED=ON -P
+                    ${CMAKE_CURRENT_SOURCE_DIR}/test/test_helper.cm
+            WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/test)
+        set_tests_properties(minizip_prepare_shared_zip
+                             PROPERTIES FIXTURES_SETUP prepare_shared)
+        set_tests_properties(
+            minizip_zipping_test_file_shared
+            PROPERTIES FIXTURES_REQUIRED prepare_shared FIXTURES_SETUP
+                       zip_shared)
+        set_tests_properties(
+            minizip_prepare_shared_unzip
+            PROPERTIES FIXTURES_REQUIRED zip_shared FIXTURES_SETUP
+                       prepare_unzip_shared)
+        set_tests_properties(
+            minizip_miniunzipping_test_file_shared.zip
+            PROPERTIES FIXTURES_REQUIRED prepare_unzip_shared FIXTURES_SETUP
+                       prepare_compare_shared)
+        set_tests_properties(
+            minizip_compare_shared
+            PROPERTIES FIXTURES_REQUIRED prepare_compare_shared FIXTURES_SETUP
+                       compared_shared)
+        set_tests_properties(minizip_clean_shared_zip
+                             PROPERTIES FIXTURES_CLEANUP compared_shared)
+    endif(MINIZIP_BUILD_SHARED AND NOT ${CMAKE_SHARED_LIBRARY_SUFFIX} STREQUAL
+                                   ".dll")
+
+    if(MINIZIP_BUILD_STATIC)
+        add_test(
+            NAME minizip_prepare_static_zip
+            COMMAND ${CMAKE_COMMAND} -DCREATE_STATIC=ON -P
+                    ${CMAKE_CURRENT_SOURCE_DIR}/test/test_helper.cm
+            WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/test)
+        add_test(
+            NAME minizip_zipping_test_file_static
+            COMMAND minizipstatic test_file_static.zip test_file_static.txt
+            WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/test)
+        add_test(
+            NAME minizip_prepare_static_unzip
+            COMMAND ${CMAKE_COMMAND} -DMOVE_STATIC=ON -P
+                    ${CMAKE_CURRENT_SOURCE_DIR}/test/test_helper.cm
+            WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/test)
+        add_test(
+            NAME minizip_miniunzipping_test_file_static.zip
+            COMMAND miniunzipstatic test_file_static.zip
+            WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/test)
+        add_test(
+            NAME minizip_compare_static
+            COMMAND ${CMAKE_COMMAND} -E compare_files test_file_static.txt
+                    test_file_static.orig
+            WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/test)
+        add_test(
+            NAME minizip_clean_static_zip
+            COMMAND ${CMAKE_COMMAND} -DDELETE_STATIC=ON -P
+                    ${CMAKE_CURRENT_SOURCE_DIR}/test/test_helper.cm
+            WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/test)
+        set_tests_properties(minizip_prepare_static_zip
+                             PROPERTIES FIXTURES_SETUP prepare_static)
+        set_tests_properties(
+            minizip_zipping_test_file_static
+            PROPERTIES FIXTURES_REQUIRED prepare_static FIXTURES_SETUP
+                       zip_static)
+        set_tests_properties(
+            minizip_prepare_static_unzip
+            PROPERTIES FIXTURES_REQUIRED zip_static FIXTURES_SETUP
+                       prepare_unzip_static)
+        set_tests_properties(
+            minizip_miniunzipping_test_file_static.zip
+            PROPERTIES FIXTURES_REQUIRED prepare_unzip_static FIXTURES_SETUP
+                       prepare_compare_static)
+        set_tests_properties(
+            minizip_compare_static
+            PROPERTIES FIXTURES_REQUIRED prepare_compare_static FIXTURES_SETUP
+                       compared_static)
+        set_tests_properties(minizip_clean_static_zip
+                             PROPERTIES FIXTURES_CLEANUP compared_static)
+    endif(MINIZIP_BUILD_STATIC)
+
+    add_subdirectory(test)
+endif(MINIZIP_BUILD_TESTING)

package/vendor/zlib/contrib/minizip/Makefile

@@ -0,0 +1,37 @@
+CC?=cc
+CFLAGS := -O $(CFLAGS) -I../..
+
+UNZ_OBJS = miniunz.o unzip.o ioapi.o ../../libz.a
+ZIP_OBJS = minizip.o zip.o   ioapi.o ../../libz.a
+
+.c.o:
+	$(CC) -c $(CFLAGS) $*.c
+
+all: miniunz minizip
+
+miniunz.o: miniunz.c unzip.h iowin32.h
+minizip.o: minizip.c zip.h iowin32.h ints.h
+unzip.o: unzip.c unzip.h crypt.h
+zip.o: zip.c zip.h crypt.h skipset.h ints.h
+ioapi.o: ioapi.c ioapi.h ints.h
+iowin32.o: iowin32.c iowin32.h ioapi.h
+mztools.o: mztools.c unzip.h
+
+miniunz: $(UNZ_OBJS)
+	$(CC) $(CFLAGS) -o $@ $(UNZ_OBJS)
+
+minizip: $(ZIP_OBJS)
+	$(CC) $(CFLAGS) -o $@ $(ZIP_OBJS)
+
+test: miniunz minizip
+	@rm -f test.*
+	@echo hello hello hello > test.txt
+	./minizip test test.txt
+	./miniunz -l test.zip
+	@mv test.txt test.old
+	./miniunz test.zip
+	@cmp test.txt test.old
+	@rm -f test.*
+
+clean:
+	/bin/rm -f *.o *~ minizip miniunz test.*

package/vendor/zlib/contrib/minizip/Makefile.am

@@ -0,0 +1,45 @@
+lib_LTLIBRARIES = libminizip.la
+
+if COND_DEMOS
+bin_PROGRAMS = miniunzip minizip
+endif
+
+zlib_top_srcdir = $(top_srcdir)/../..
+zlib_top_builddir = $(top_builddir)/../..
+
+AM_CPPFLAGS = -I$(zlib_top_srcdir)
+AM_LDFLAGS = -L$(zlib_top_builddir)
+
+if WIN32
+iowin32_src = iowin32.c
+iowin32_h = iowin32.h
+endif
+
+libminizip_la_SOURCES = \
+	ioapi.c \
+	mztools.c \
+	unzip.c \
+	zip.c \
+	${iowin32_src}
+
+libminizip_la_LDFLAGS = $(AM_LDFLAGS) -version-info 1:0:0 -lz
+
+minizip_includedir = $(includedir)/minizip
+minizip_include_HEADERS = \
+	crypt.h \
+	ioapi.h \
+	mztools.h \
+	unzip.h \
+	zip.h \
+	${iowin32_h}
+
+pkgconfigdir = $(libdir)/pkgconfig
+pkgconfig_DATA = minizip.pc
+
+EXTRA_PROGRAMS = miniunzip minizip
+
+miniunzip_SOURCES = miniunz.c
+miniunzip_LDADD = libminizip.la
+
+minizip_SOURCES = minizip.c
+minizip_LDADD = libminizip.la -lz

package/vendor/zlib/contrib/minizip/MiniZip64_Changes.txt

@@ -0,0 +1,6 @@
+
+MiniZip 1.1 was derived from MiniZip at version 1.01f
+
+Change in 1.0 (Okt 2009)
+ - **TODO - Add history**
+

package/vendor/zlib/contrib/minizip/MiniZip64_info.txt

@@ -0,0 +1,74 @@
+MiniZip - Copyright (c) 1998-2010 - by Gilles Vollant - version 1.1 64 bits from Mathias Svensson
+
+Introduction
+---------------------
+MiniZip 1.1 is built from MiniZip 1.0 by Gilles Vollant ( http://www.winimage.com/zLibDll/minizip.html )
+
+When adding ZIP64 support into minizip it would result into risk of breaking compatibility with minizip 1.0.
+All possible work was done for compatibility.
+
+
+Background
+---------------------
+When adding ZIP64 support Mathias Svensson found that Even Rouault have added ZIP64 
+support for unzip.c into minizip for a open source project called gdal ( http://www.gdal.org/ )
+
+That was used as a starting point. And after that ZIP64 support was added to zip.c
+some refactoring and code cleanup was also done.
+
+
+Changed from MiniZip 1.0 to MiniZip 1.1
+---------------------------------------
+* Added ZIP64 support for unzip ( by Even Rouault )
+* Added ZIP64 support for zip ( by Mathias Svensson )
+* Reverted some changed that Even Rouault did.
+* Bunch of patches received from Gulles Vollant that he received for MiniZip from various users.
+* Added unzip patch for BZIP Compression method (patch create by Daniel Borca)
+* Added BZIP Compress method for zip
+* Did some refactoring and code cleanup
+
+
+Credits
+
+ Gilles Vollant    - Original MiniZip author
+ Even Rouault      - ZIP64 unzip Support
+ Daniel Borca      - BZip Compression method support in unzip
+ Mathias Svensson  - ZIP64 zip support
+ Mathias Svensson  - BZip Compression method support in zip
+
+ Resources
+
+ ZipLayout   http://result42.com/projects/ZipFileLayout
+             Command line tool for Windows that shows the layout and information of the headers in a zip archive.
+             Used when debugging and validating the creation of zip files using MiniZip64
+
+
+ ZIP App Note  http://www.pkware.com/documents/casestudies/APPNOTE.TXT
+               Zip File specification
+
+
+Notes.
+ * To be able to use BZip compression method in zip64.c or unzip64.c the BZIP2 lib is needed and HAVE_BZIP2 need to be defined.
+
+License
+----------------------------------------------------------
+   Condition of use and distribution are the same than zlib :
+
+  This software is provided 'as-is', without any express or implied
+  warranty.  In no event will the authors be held liable for any damages
+  arising from the use of this software.
+
+  Permission is granted to anyone to use this software for any purpose,
+  including commercial applications, and to alter it and redistribute it
+  freely, subject to the following restrictions:
+
+  1. The origin of this software must not be misrepresented; you must not
+     claim that you wrote the original software. If you use this software
+     in a product, an acknowledgment in the product documentation would be
+     appreciated but is not required.
+  2. Altered source versions must be plainly marked as such, and must not be
+     misrepresented as being the original software.
+  3. This notice may not be removed or altered from any source distribution.
+
+----------------------------------------------------------
+

package/vendor/zlib/contrib/minizip/configure.ac

@@ -0,0 +1,32 @@
+#                                               -*- Autoconf -*-
+# Process this file with autoconf to produce a configure script.
+
+AC_INIT([minizip], [1.3.1.1], [bugzilla.redhat.com])
+AC_CONFIG_SRCDIR([minizip.c])
+AM_INIT_AUTOMAKE([foreign])
+LT_INIT
+
+AC_MSG_CHECKING([whether to build example programs])
+AC_ARG_ENABLE([demos], AS_HELP_STRING([--enable-demos], [build example programs]))
+AM_CONDITIONAL([COND_DEMOS], [test "$enable_demos" = yes])
+if test "$enable_demos" = yes
+then
+	AC_MSG_RESULT([yes])
+else
+	AC_MSG_RESULT([no])
+fi
+
+case "${host}" in
+	*-mingw* | mingw*)
+		WIN32="yes"
+		;;
+	*)
+		;;
+esac
+AM_CONDITIONAL([WIN32], [test "${WIN32}" = "yes"])
+
+
+AC_SUBST([HAVE_UNISTD_H], [0])
+AC_CHECK_HEADER([unistd.h], [HAVE_UNISTD_H=1], [])
+AC_CONFIG_FILES([Makefile minizip.pc])
+AC_OUTPUT