elm-pages 2.1.7 → 2.1.11

package/src/TerminalText.elm

@@ -0,0 +1,242 @@
+module TerminalText exposing
+    ( Text(..)
+    , ansi
+    , ansiPrefix
+    , blue
+    , colorToString
+    , cyan
+    , encoder
+    , fromAnsiString
+    , green
+    , red
+    , resetColors
+    , text
+    , toString
+    , toString_
+    , yellow
+    )
+
+import Ansi
+import Json.Encode as Encode
+
+
+type Text
+    = Style AnsiStyle String
+
+
+text : String -> Text
+text value =
+    Style blankStyle value
+
+
+cyan : String -> Text
+cyan inner =
+    Style { blankStyle | color = Just Ansi.Cyan } inner
+
+
+green : String -> Text
+green inner =
+    Style { blankStyle | color = Just Ansi.Green } inner
+
+
+yellow : String -> Text
+yellow inner =
+    Style { blankStyle | color = Just Ansi.Yellow } inner
+
+
+red : String -> Text
+red inner =
+    Style { blankStyle | color = Just Ansi.Red } inner
+
+
+blue : String -> Text
+blue inner =
+    Style { blankStyle | color = Just Ansi.Blue } inner
+
+
+resetColors : String
+resetColors =
+    ansi "[0m"
+
+
+ansi : String -> String
+ansi code =
+    ansiPrefix ++ code
+
+
+ansiPrefix : String
+ansiPrefix =
+    "\u{001B}"
+
+
+colorToString : Ansi.Color -> String
+colorToString color =
+    ansi <|
+        case color of
+            Ansi.Red ->
+                "[31m"
+
+            Ansi.Blue ->
+                "[34m"
+
+            Ansi.Green ->
+                "[32m"
+
+            Ansi.Yellow ->
+                "[33m"
+
+            Ansi.Cyan ->
+                "[36m"
+
+            _ ->
+                -- TODO
+                ""
+
+
+toString : List Text -> String
+toString list =
+    list
+        |> List.map toString_
+        |> String.join ""
+
+
+toString_ : Text -> String
+toString_ (Style ansiStyle innerText) =
+    String.concat
+        [ ansiStyle.color |> Maybe.withDefault Ansi.White |> colorToString
+        , innerText
+        , resetColors
+        ]
+
+
+fromAnsiString : String -> List Text
+fromAnsiString ansiString =
+    Ansi.parseInto ( blankStyle, [] ) parseInto ansiString
+        |> Tuple.second
+        |> List.reverse
+
+
+type alias AnsiStyle =
+    { bold : Bool
+    , underline : Bool
+    , color : Maybe Ansi.Color
+    }
+
+
+blankStyle : AnsiStyle
+blankStyle =
+    { bold = False
+    , underline = False
+    , color = Nothing
+    }
+
+
+parseInto : Ansi.Action -> ( AnsiStyle, List Text ) -> ( AnsiStyle, List Text )
+parseInto action ( pendingStyle, soFar ) =
+    case action of
+        Ansi.Print string ->
+            ( blankStyle, Style pendingStyle string :: soFar )
+
+        Ansi.Remainder _ ->
+            ( pendingStyle, soFar )
+
+        Ansi.SetForeground maybeColor ->
+            case maybeColor of
+                Just newColor ->
+                    ( { pendingStyle
+                        | color = Just newColor
+                      }
+                    , soFar
+                    )
+
+                Nothing ->
+                    ( blankStyle, soFar )
+
+        Ansi.SetBold bool ->
+            ( { pendingStyle | bold = bool }, soFar )
+
+        Ansi.SetFaint _ ->
+            ( pendingStyle, soFar )
+
+        Ansi.SetItalic _ ->
+            ( pendingStyle, soFar )
+
+        Ansi.SetUnderline bool ->
+            ( { pendingStyle | underline = bool }, soFar )
+
+        Ansi.SetBackground _ ->
+            ( pendingStyle, soFar )
+
+        Ansi.Linebreak ->
+            case soFar of
+                next :: rest ->
+                    ( pendingStyle, Style blankStyle "\n" :: next :: rest )
+
+                [] ->
+                    ( pendingStyle, soFar )
+
+        _ ->
+            ( pendingStyle, soFar )
+
+
+encoder : Text -> Encode.Value
+encoder (Style ansiStyle string) =
+    Encode.object
+        [ ( "bold", Encode.bool ansiStyle.bold )
+        , ( "underline", Encode.bool ansiStyle.underline )
+        , ( "color"
+          , Encode.string <|
+                case ansiStyle.color |> Maybe.withDefault Ansi.White of
+                    Ansi.Red ->
+                        "red"
+
+                    Ansi.Blue ->
+                        "blue"
+
+                    Ansi.Green ->
+                        "green"
+
+                    Ansi.Yellow ->
+                        "yellow"
+
+                    Ansi.Cyan ->
+                        "cyan"
+
+                    Ansi.Black ->
+                        "black"
+
+                    Ansi.Magenta ->
+                        "magenta"
+
+                    Ansi.White ->
+                        "white"
+
+                    Ansi.BrightBlack ->
+                        "BLACK"
+
+                    Ansi.BrightRed ->
+                        "RED"
+
+                    Ansi.BrightGreen ->
+                        "GREEN"
+
+                    Ansi.BrightYellow ->
+                        "YELLOW"
+
+                    Ansi.BrightBlue ->
+                        "BLUE"
+
+                    Ansi.BrightMagenta ->
+                        "MAGENTA"
+
+                    Ansi.BrightCyan ->
+                        "CYAN"
+
+                    Ansi.BrightWhite ->
+                        "WHITE"
+
+                    Ansi.Custom _ _ _ ->
+                        ""
+          )
+        , ( "string", Encode.string string )
+        ]

package/src/Test/Html/Internal/ElmHtml/Constants.elm

@@ -0,0 +1,53 @@
+module Test.Html.Internal.ElmHtml.Constants exposing
+    ( propKey, styleKey, eventKey, attributeKey, attributeNamespaceKey
+    , knownKeys
+    )
+
+{-| Constants for representing internal keys for Elm's vdom implementation
+
+@docs propKey, styleKey, eventKey, attributeKey, attributeNamespaceKey
+@docs knownKeys
+
+-}
+
+
+{-| Internal key for attribute properties
+-}
+propKey : String
+propKey =
+    "a2"
+
+
+{-| Internal key for style
+-}
+styleKey : String
+styleKey =
+    "a1"
+
+
+{-| Internal key for style
+-}
+eventKey : String
+eventKey =
+    "a0"
+
+
+{-| Internal key for style
+-}
+attributeKey : String
+attributeKey =
+    "a3"
+
+
+{-| Internal key for style
+-}
+attributeNamespaceKey : String
+attributeNamespaceKey =
+    "a4"
+
+
+{-| Keys that we are aware of and should pay attention to
+-}
+knownKeys : List String
+knownKeys =
+    [ styleKey, eventKey, attributeKey, attributeNamespaceKey ]

package/src/Test/Html/Internal/ElmHtml/Helpers.elm

@@ -0,0 +1,17 @@
+module Test.Html.Internal.ElmHtml.Helpers exposing (filterKnownKeys)
+
+{-| Internal helpers for ElmHtml
+
+@docs filterKnownKeys
+
+-}
+
+import Dict exposing (Dict)
+import Test.Html.Internal.ElmHtml.Constants exposing (knownKeys)
+
+
+{-| Filter out keys that we don't know
+-}
+filterKnownKeys : Dict String a -> Dict String a
+filterKnownKeys =
+    Dict.filter (\key _ -> not (List.member key knownKeys))