elm-pages 2.1.7 → 2.1.11

package/src/RenderRequest.elm

@@ -0,0 +1,163 @@
+module RenderRequest exposing
+    ( IncludeHtml(..)
+    , RenderRequest(..)
+    , RequestPayload(..)
+    , decoder
+    , default
+    , maybeRequestPayload
+    )
+
+import ApiRoute
+import HtmlPrinter
+import Internal.ApiRoute
+import Json.Decode as Decode
+import Json.Encode as Encode
+import Pages.ProgramConfig exposing (ProgramConfig)
+import Path exposing (Path)
+import Regex
+import Url exposing (Url)
+
+
+type RequestPayload route
+    = Page { path : Path, frontmatter : route }
+    | Api ( String, ApiRoute.ApiRoute ApiRoute.Response )
+    | NotFound Path
+
+
+type RenderRequest route
+    = SinglePage IncludeHtml (RequestPayload route) Decode.Value
+
+
+default : RenderRequest route
+default =
+    SinglePage
+        HtmlAndJson
+        (NotFound (Path.fromString "/error"))
+        Encode.null
+
+
+maybeRequestPayload : RenderRequest route -> Maybe Decode.Value
+maybeRequestPayload renderRequest =
+    case renderRequest of
+        SinglePage _ _ rawJson ->
+            Just rawJson
+
+
+type IncludeHtml
+    = HtmlAndJson
+    | OnlyJson
+
+
+decoder :
+    ProgramConfig userMsg userModel (Maybe route) siteData pageData sharedData
+    -> Decode.Decoder (RenderRequest (Maybe route))
+decoder config =
+    Decode.field "request"
+        (Decode.map3
+            (\includeHtml requestThing payload ->
+                SinglePage includeHtml requestThing payload
+            )
+            (Decode.field "kind" Decode.string
+                |> Decode.andThen
+                    (\kind ->
+                        case kind of
+                            "single-page" ->
+                                Decode.field "jsonOnly" Decode.bool
+                                    |> Decode.map
+                                        (\jsonOnly ->
+                                            if jsonOnly then
+                                                OnlyJson
+
+                                            else
+                                                HtmlAndJson
+                                        )
+
+                            _ ->
+                                Decode.fail "Unhandled"
+                    )
+            )
+            (requestPayloadDecoder config)
+            (Decode.field "payload" Decode.value)
+        )
+
+
+
+{-
+   payload: modifiedRequest,
+   kind: "single-page",
+   jsonOnly: isJson,
+-}
+
+
+requestPayloadDecoder :
+    ProgramConfig userMsg userModel (Maybe route) siteData pageData sharedData
+    -> Decode.Decoder (RequestPayload (Maybe route))
+requestPayloadDecoder config =
+    (Decode.string
+        |> Decode.map
+            (\rawPath ->
+                let
+                    path : String
+                    path =
+                        rawPath
+                            |> dropTrailingIndexHtml
+
+                    route : Maybe route
+                    route =
+                        pathToUrl path |> config.urlToRoute
+
+                    apiRoute : Maybe (ApiRoute.ApiRoute ApiRoute.Response)
+                    apiRoute =
+                        Internal.ApiRoute.firstMatch (String.dropLeft 1 path)
+                            (config.apiRoutes HtmlPrinter.htmlToString)
+                in
+                case route of
+                    Just _ ->
+                        if isFile rawPath then
+                            case apiRoute of
+                                Just justApi ->
+                                    ( path, justApi ) |> Api
+
+                                Nothing ->
+                                    NotFound (Path.fromString path)
+
+                        else
+                            Page
+                                { frontmatter = route
+                                , path = config.routeToPath route |> Path.join
+                                }
+
+                    Nothing ->
+                        case apiRoute of
+                            Just justApi ->
+                                ( path, justApi ) |> Api
+
+                            Nothing ->
+                                NotFound (Path.fromString path)
+            )
+    )
+        |> Decode.field "path"
+        |> Decode.field "payload"
+
+
+isFile : String -> Bool
+isFile rawPath =
+    rawPath
+        |> String.contains "."
+
+
+pathToUrl : String -> Url
+pathToUrl path =
+    { protocol = Url.Https
+    , host = "TODO"
+    , port_ = Nothing
+    , path = path
+    , query = Nothing
+    , fragment = Nothing
+    }
+
+
+dropTrailingIndexHtml : String -> String
+dropTrailingIndexHtml =
+    Regex.replace (Regex.fromString "/index\\.html$" |> Maybe.withDefault Regex.never)
+        (\_ -> "")

package/src/RequestsAndPending.elm

@@ -0,0 +1,20 @@
+module RequestsAndPending exposing (RequestsAndPending, decoder, get)
+
+import Dict exposing (Dict)
+import Json.Decode as Decode
+
+
+type alias RequestsAndPending =
+    Dict String (Maybe String)
+
+
+get : String -> RequestsAndPending -> Maybe String
+get key requestsAndPending =
+    requestsAndPending
+        |> Dict.get key
+        |> Maybe.andThen identity
+
+
+decoder : Decode.Decoder RequestsAndPending
+decoder =
+    Decode.dict (Decode.string |> Decode.map Just)

package/src/Secrets.elm

@@ -0,0 +1,111 @@
+module Secrets exposing
+    ( Value
+    , lookup
+    , map
+    , maskedLookup
+    , succeed
+    , with
+    )
+
+import BuildError exposing (BuildError)
+import Fuzzy
+import SecretsDict exposing (SecretsDict)
+import TerminalText as Terminal
+
+
+type Value value
+    = Value (SecretsDict -> Result (List BuildError) value)
+
+
+lookup : SecretsDict -> Value a -> Result (List BuildError) a
+lookup secrets (Value lookupSecrets) =
+    lookupSecrets secrets
+
+
+maskedLookup : Value value -> value
+maskedLookup (Value lookupSecrets) =
+    case lookupSecrets SecretsDict.masked of
+        Ok value ->
+            value
+
+        Err _ ->
+            -- crash
+            maskedLookup (Value lookupSecrets)
+
+
+succeed : value -> Value value
+succeed value =
+    Value (\_ -> Ok value)
+
+
+buildError : String -> SecretsDict -> BuildError
+buildError secretName secretsDict =
+    let
+        availableEnvironmentVariables : List String
+        availableEnvironmentVariables =
+            SecretsDict.available secretsDict
+    in
+    { title = "Missing Secret"
+    , message =
+        [ Terminal.text "I expected to find this Secret in your environment variables but didn't find a match:\n\nSecrets.get \""
+        , Terminal.text secretName
+        , Terminal.text "\"\n             "
+        , Terminal.red <| underlineText (secretName |> String.length)
+        , Terminal.text "\n\nSo maybe "
+        , Terminal.yellow <| secretName
+        , Terminal.text " should be "
+        , Terminal.green <| (sortMatches secretName availableEnvironmentVariables |> List.head |> Maybe.withDefault "")
+        ]
+    , path = "" -- TODO wire in path here?
+    , fatal = True
+    }
+
+
+underlineText : Int -> String
+underlineText length =
+    String.repeat length "^"
+
+
+sortMatches : String -> List String -> List String
+sortMatches missingSecret availableSecrets =
+    let
+        simpleMatch : List Fuzzy.Config -> List String -> String -> String -> Int
+        simpleMatch config separators needle hay =
+            Fuzzy.match config separators needle hay |> .score
+    in
+    List.sortBy (simpleMatch [] [] missingSecret) availableSecrets
+
+
+map : (valueA -> valueB) -> Value valueA -> Value valueB
+map mapFunction (Value lookupSecrets) =
+    Value
+        (\secrets ->
+            lookupSecrets secrets
+                |> Result.map mapFunction
+        )
+
+
+with : String -> Value (String -> value) -> Value value
+with newSecret (Value lookupSecrets) =
+    Value <|
+        \secrets ->
+            case lookupSecrets secrets of
+                Ok value ->
+                    case SecretsDict.get newSecret secrets of
+                        Just newValue ->
+                            value newValue |> Ok
+
+                        Nothing ->
+                            Err [ buildError newSecret secrets ]
+
+                Err error ->
+                    case SecretsDict.get newSecret secrets of
+                        Just _ ->
+                            Err error
+
+                        Nothing ->
+                            -- TODO add more errors
+                            Err
+                                (buildError newSecret secrets
+                                    :: error
+                                )

package/src/SecretsDict.elm

@@ -0,0 +1,45 @@
+module SecretsDict exposing (SecretsDict, available, decoder, get, masked, unmasked)
+
+import Dict exposing (Dict)
+import Json.Decode as Decode exposing (Decoder)
+
+
+available : SecretsDict -> List String
+available secretsDict =
+    case secretsDict of
+        Masked ->
+            []
+
+        Unmasked dict ->
+            Dict.keys dict
+
+
+decoder : Decoder SecretsDict
+decoder =
+    Decode.dict Decode.string
+        |> Decode.map Unmasked
+
+
+unmasked : Dict String String -> SecretsDict
+unmasked dict =
+    Unmasked dict
+
+
+masked : SecretsDict
+masked =
+    Masked
+
+
+get : String -> SecretsDict -> Maybe String
+get secretName secretsDict =
+    case secretsDict of
+        Masked ->
+            Just <| "<" ++ secretName ++ ">"
+
+        Unmasked dict ->
+            dict |> Dict.get secretName
+
+
+type SecretsDict
+    = Masked
+    | Unmasked (Dict String String)

package/src/StructuredData.elm

@@ -0,0 +1,236 @@
+module StructuredData exposing (StructuredData(..), additionalName, article, article_, computerLanguage, elmLang, encode, episode, person, series, softwareSourceCode)
+
+import Json.Encode as Encode
+import Pages.Url
+
+
+{-| <https://schema.org/SoftwareSourceCode>
+-}
+softwareSourceCode :
+    { codeRepositoryUrl : String
+    , description : String
+    , author : String
+    , programmingLanguage : Encode.Value
+    }
+    -> Encode.Value
+softwareSourceCode info =
+    Encode.object
+        [ ( "@type", Encode.string "SoftwareSourceCode" )
+        , ( "codeRepository", Encode.string info.codeRepositoryUrl )
+        , ( "description", Encode.string info.description )
+        , ( "author", Encode.string info.author )
+        , ( "programmingLanguage", info.programmingLanguage )
+        ]
+
+
+{-| <https://schema.org/ComputerLanguage>
+-}
+computerLanguage : { url : String, name : String, imageUrl : String, identifier : String } -> Encode.Value
+computerLanguage info =
+    Encode.object
+        [ ( "@type", Encode.string "ComputerLanguage" )
+        , ( "url", Encode.string info.url )
+        , ( "name", Encode.string info.name )
+        , ( "image", Encode.string info.imageUrl )
+        , ( "identifier", Encode.string info.identifier )
+        ]
+
+
+elmLang : Encode.Value
+elmLang =
+    computerLanguage
+        { url = "http://elm-lang.org/"
+        , name = "Elm"
+        , imageUrl = "http://elm-lang.org/"
+        , identifier = "http://elm-lang.org/"
+        }
+
+
+{-| <https://schema.org/Article>
+-}
+article :
+    { title : String
+    , description : String
+    , author : StructuredData { authorMemberOf | personOrOrganization : () } authorPossibleFields
+    , publisher : StructuredData { publisherMemberOf | personOrOrganization : () } publisherPossibleFields
+    , url : String
+    , imageUrl : Pages.Url.Url
+    , datePublished : String
+    , mainEntityOfPage : Encode.Value
+    }
+    -> Encode.Value
+article info =
+    Encode.object
+        [ ( "@context", Encode.string "http://schema.org/" )
+        , ( "@type", Encode.string "Article" )
+        , ( "headline", Encode.string info.title )
+        , ( "description", Encode.string info.description )
+        , ( "image", Encode.string (Pages.Url.toString info.imageUrl) )
+        , ( "author", encode info.author )
+        , ( "publisher", encode info.publisher )
+        , ( "url", Encode.string info.url )
+        , ( "datePublished", Encode.string info.datePublished )
+        , ( "mainEntityOfPage", info.mainEntityOfPage )
+        ]
+
+
+type StructuredData memberOf possibleFields
+    = StructuredData String (List ( String, Encode.Value ))
+
+
+{-| <https://schema.org/Person>
+-}
+person :
+    { name : String
+    }
+    ->
+        StructuredData
+            { personOrOrganization : () }
+            { additionalName : ()
+            , address : ()
+            , affiliation : ()
+            }
+person info =
+    StructuredData "Person" [ ( "name", Encode.string info.name ) ]
+
+
+additionalName : String -> StructuredData memberOf { possibleFields | additionalName : () } -> StructuredData memberOf possibleFields
+additionalName value (StructuredData typeName fields) =
+    StructuredData typeName (( "additionalName", Encode.string value ) :: fields)
+
+
+{-| <https://schema.org/Article>
+-}
+article_ :
+    { title : String
+    , description : String
+    , author : String
+    , publisher : StructuredData { personOrOrganization : () } possibleFieldsPublisher
+    , url : String
+    , imageUrl : String
+    , datePublished : String
+    , mainEntityOfPage : Encode.Value
+    }
+    -> Encode.Value
+article_ info =
+    Encode.object
+        [ ( "@context", Encode.string "http://schema.org/" )
+        , ( "@type", Encode.string "Article" )
+        , ( "headline", Encode.string info.title )
+        , ( "description", Encode.string info.description )
+        , ( "image", Encode.string info.imageUrl )
+        , ( "author", Encode.string info.author )
+        , ( "publisher", encode info.publisher )
+        , ( "url", Encode.string info.url )
+        , ( "datePublished", Encode.string info.datePublished )
+        , ( "mainEntityOfPage", info.mainEntityOfPage )
+        ]
+
+
+encode : StructuredData memberOf possibleFieldsPublisher -> Encode.Value
+encode (StructuredData typeName fields) =
+    Encode.object
+        (( "@type", Encode.string typeName ) :: fields)
+
+
+
+--example :
+--    StructuredData
+--        { personOrOrganization : () }
+--        { address : ()
+--        , affiliation : ()
+--        }
+--example =
+--    person { name = "Dillon Kearns" }
+--        |> additionalName "Cornelius"
+--organization :
+--    {}
+--    -> StructuredDataHelper { personOrOrganization : () }
+--organization info =
+--    StructuredDataHelper "Organization" []
+--needsPersonOrOrg : StructuredDataHelper {}
+--needsPersonOrOrg =
+--    StructuredDataHelper "" []
+
+
+{-|
+
+```json
+   {
+      "@context": "http://schema.org/",
+      "@type": "PodcastSeries",
+      "image": "https://www.relay.fm/inquisitive_artwork.png",
+      "url": "http://www.relay.fm/inquisitive",
+      "name": "Inquisitive",
+      "description": "Inquisitive is a show for the naturally curious. Each week, Myke Hurley takes a look at what makes creative people successful and what steps they have taken to get there.",
+      "webFeed": "http://www.relay.fm//inquisitive/feed",
+      "author": {
+        "@type": "Person",
+        "name": "Myke Hurley"
+      }
+    }
+   }
+```
+
+-}
+series : Encode.Value
+series =
+    Encode.object
+        [ ( "@context", Encode.string "http://schema.org/" )
+        , ( "@type", Encode.string "PodcastSeries" )
+        , ( "image", Encode.string "TODO" )
+        , ( "url", Encode.string "http://elm-radio.com/episode/getting-started-with-elm-pages" )
+        , ( "name", Encode.string "Elm Radio" )
+        , ( "description", Encode.string "TODO" )
+        , ( "webFeed", Encode.string "https://elm-radio.com/feed.xml" )
+        ]
+
+
+{-|
+
+```json
+   {
+      "@context": "http://schema.org/",
+      "@type": "PodcastEpisode",
+      "url": "http://elm-radio.com/episode/getting-started-with-elm-pages",
+     "name": "001: Getting Started with elm-pages",
+      "datePublished": "2015-02-18",
+      "timeRequired": "PT37M",
+      "description": "In the first episode of “Behind the App”, a special series of Inquisitive, we take a look at the beginnings of iOS app development, by focusing on the introduction of the iPhone and the App Store.",
+      "associatedMedia": {
+        "@type": "MediaObject",
+        "contentUrl": "https://cdn.simplecast.com/audio/6a206b/6a206baa-9c8e-4c25-9037-2b674204ba84/ca009f6e-1710-4518-b869-ca34cb0b7d17/001-getting-started-elm-pages_tc.mp3 "
+      },
+      "partOfSeries": {
+        "@type": "PodcastSeries",
+        "name": "Elm Radio",
+        "url": "https://elm-radio.com"
+      }
+    }
+```
+
+-}
+episode : Encode.Value
+episode =
+    Encode.object
+        [ ( "@context", Encode.string "http://schema.org/" )
+        , ( "@type", Encode.string "PodcastEpisode" )
+        , ( "url", Encode.string "http://elm-radio.com/episode/getting-started-with-elm-pages" )
+        , ( "name", Encode.string "Getting Started with elm-pages" )
+        , ( "datePublished", Encode.string "2015-02-18" )
+        , ( "timeRequired", Encode.string "PT37M" )
+        , ( "description", Encode.string "TODO" )
+        , ( "associatedMedia"
+          , Encode.object
+                [ ( "@type", Encode.string "MediaObject" )
+                , ( "contentUrl", Encode.string "https://cdn.simplecast.com/audio/6a206b/6a206baa-9c8e-4c25-9037-2b674204ba84/ca009f6e-1710-4518-b869-ca34cb0b7d17/001-getting-started-elm-pages_tc.mp3" )
+                ]
+          )
+        , ( "partOfSeries"
+          , Encode.object
+                [ ( "@type", Encode.string "PodcastSeries" )
+                , ( "name", Encode.string "Elm Radio" )
+                , ( "url", Encode.string "https://elm-radio.com" )
+                ]
+          )
+        ]