desck 0.4.2

package/src/Deck.elm

@@ -0,0 +1,571 @@
+module Deck exposing (..)
+
+import Json.Decode as D exposing (Decoder)
+import Json.Encode exposing (Value, string)
+import Ordering exposing (Ordering)
+
+
+jokerCardOrdering : Ordering CardModel
+jokerCardOrdering =
+    Ordering.byRank
+        (\card ->
+            case card of
+                Ranked _ _ ->
+                    1
+
+                Joker _ ->
+                    2
+        )
+        (\x y ->
+            case ( x, y ) of
+                ( Ranked v1 s1, Ranked v2 s2 ) ->
+                    suitOrdering s1 s2
+                        |> Ordering.ifStillTiedThen
+                            (valueOrdering v1 v2)
+
+                _ ->
+                    Ordering.noConflicts
+        )
+
+
+suitOrdering : Ordering Suit
+suitOrdering =
+    Ordering.explicit [ Club, Heart, Diamond, Spade ]
+
+
+valueOrdering : Ordering Rank
+valueOrdering =
+    Ordering.explicit
+        [ Ace
+        , Two
+        , Three
+        , Four
+        , Five
+        , Six
+        , Seven
+        , Eight
+        , Nine
+        , Ten
+        , Jack
+        , Queen
+        , King
+        ]
+
+
+type Orientation
+    = Up
+    | Side
+
+
+type Suit
+    = Spade
+    | Heart
+    | Diamond
+    | Club
+
+
+type Rank
+    = Ace
+    | Two
+    | Three
+    | Four
+    | Five
+    | Six
+    | Seven
+    | Eight
+    | Nine
+    | Ten
+    | Jack
+    | Queen
+    | King
+
+
+type CardModel
+    = Ranked Rank Suit
+    | Joker Bool
+
+
+suitFromInt : Int -> Suit
+suitFromInt i =
+    case i of
+        0 ->
+            Spade
+
+        1 ->
+            Heart
+
+        2 ->
+            Diamond
+
+        _ ->
+            Club
+
+
+suitAsUnicode : Suit -> String
+suitAsUnicode s =
+    case s of
+        Spade ->
+            "♠"
+
+        Heart ->
+            "♥"
+
+        Diamond ->
+            "♦"
+
+        Club ->
+            "♣"
+
+
+suitAsString : Suit -> String
+suitAsString s =
+    case s of
+        Spade ->
+            "spade"
+
+        Heart ->
+            "heart"
+
+        Diamond ->
+            "diamond"
+
+        Club ->
+            "club"
+
+
+maybeSuit : CardModel -> Maybe Suit
+maybeSuit m =
+    case m of
+        Ranked _ suit ->
+            Just suit
+
+        Joker _ ->
+            Nothing
+
+
+maybeRank : CardModel -> Maybe Rank
+maybeRank m =
+    case m of
+        Ranked rank _ ->
+            Just rank
+
+        Joker _ ->
+            Nothing
+
+
+suitFromString : String -> Maybe Suit
+suitFromString s =
+    case s of
+        "spade" ->
+            Just Spade
+
+        "heart" ->
+            Just Heart
+
+        "diamond" ->
+            Just Diamond
+
+        "club" ->
+            Just Club
+
+        _ ->
+            Nothing
+
+
+suitAsChar : Suit -> String
+suitAsChar s =
+    suitAsString s
+        |> String.left 1
+        |> String.toLower
+
+
+suits : List Suit
+suits =
+    [ Spade, Heart, Diamond, Club ]
+
+
+ranks : List Rank
+ranks =
+    [ Ace, Two, Three, Four, Five, Six, Seven, Eight, Nine, Ten, Jack, Queen, King ]
+
+
+rankFromInt : Int -> Rank
+rankFromInt i =
+    case i of
+        1 ->
+            Ace
+
+        2 ->
+            Two
+
+        3 ->
+            Three
+
+        4 ->
+            Four
+
+        5 ->
+            Five
+
+        6 ->
+            Six
+
+        7 ->
+            Seven
+
+        8 ->
+            Eight
+
+        9 ->
+            Nine
+
+        10 ->
+            Ten
+
+        11 ->
+            Jack
+
+        12 ->
+            Queen
+
+        _ ->
+            King
+
+
+rankAsInt : Rank -> Int
+rankAsInt r =
+    case r of
+        Ace ->
+            1
+
+        Two ->
+            2
+
+        Three ->
+            3
+
+        Four ->
+            4
+
+        Five ->
+            5
+
+        Six ->
+            6
+
+        Seven ->
+            7
+
+        Eight ->
+            8
+
+        Nine ->
+            9
+
+        Ten ->
+            10
+
+        Jack ->
+            11
+
+        Queen ->
+            12
+
+        King ->
+            13
+
+
+printRank : CardModel -> String
+printRank m =
+    case m of
+        Ranked rank _ ->
+            case rank of
+                Ten ->
+                    "I0"
+
+                _ ->
+                    rankAsString rank |> String.toUpper
+
+        Joker _ ->
+            "★"
+
+
+rankAsChar : Rank -> String
+rankAsChar r =
+    case r of
+        Ten ->
+            "0"
+
+        _ ->
+            rankAsString r
+
+
+rankAsString : Rank -> String
+rankAsString r =
+    case r of
+        Ace ->
+            "a"
+
+        Ten ->
+            "10"
+
+        Jack ->
+            "j"
+
+        Queen ->
+            "q"
+
+        King ->
+            "k"
+
+        _ ->
+            rankAsInt r
+                |> String.fromInt
+
+
+parseRank : String -> Maybe Rank
+parseRank r =
+    let
+        int =
+            String.toInt r
+
+        upper =
+            String.toUpper r
+    in
+    case int of
+        Just i ->
+            case i of
+                1 ->
+                    Just Ace
+
+                2 ->
+                    Just Two
+
+                3 ->
+                    Just Three
+
+                4 ->
+                    Just Four
+
+                5 ->
+                    Just Five
+
+                6 ->
+                    Just Six
+
+                7 ->
+                    Just Seven
+
+                8 ->
+                    Just Eight
+
+                9 ->
+                    Just Nine
+
+                10 ->
+                    Just Ten
+
+                0 ->
+                    Just Ten
+
+                _ ->
+                    Nothing
+
+        Nothing ->
+            case upper of
+                "J" ->
+                    Just Jack
+
+                "Q" ->
+                    Just Queen
+
+                "K" ->
+                    Just King
+
+                "A" ->
+                    Just Ace
+
+                _ ->
+                    Nothing
+
+
+parseSuit : String -> Maybe Suit
+parseSuit s =
+    case String.toUpper s of
+        "S" ->
+            Just Spade
+
+        "D" ->
+            Just Diamond
+
+        "C" ->
+            Just Club
+
+        "H" ->
+            Just Heart
+
+        _ ->
+            Nothing
+
+
+isJust : Maybe a -> Bool
+isJust m =
+    case m of
+        Just _ ->
+            True
+
+        Nothing ->
+            False
+
+
+parseCard : List Char -> List CardModel
+parseCard chars =
+    let
+        mrank c =
+            parseRank <| String.fromChar c
+
+        msuit c =
+            parseSuit <| String.fromChar c
+    in
+    case chars of
+        [] ->
+            []
+
+        [ c ] ->
+            case mrank c of
+                Just rank ->
+                    List.map (\suit -> Ranked rank suit) suits
+
+                Nothing ->
+                    if c == 'x' then
+                        [ Joker True, Joker False ]
+
+                    else
+                        case msuit c of
+                            Just suit ->
+                                List.map (\rank -> Ranked rank suit) ranks
+                                    |> List.reverse
+
+                            Nothing ->
+                                []
+
+        [ a, b ] ->
+            case ( mrank a, msuit b ) of
+                ( Just rank, Just suit ) ->
+                    [ Ranked rank suit ]
+
+                _ ->
+                    case ( a, b ) of
+                        ( 'x', 'r' ) ->
+                            [ Joker True ]
+
+                        ( 'x', 'b' ) ->
+                            [ Joker False ]
+
+                        _ ->
+                            []
+
+        _ ->
+            []
+
+
+parseCards : String -> List CardModel
+parseCards s =
+    if s == "all" then
+        parseDeck "c d h s"
+
+    else
+        let
+            words =
+                String.split " " s
+                    |> List.map String.toList
+        in
+        List.map parseCard words
+            |> List.concat
+
+
+parseDeck : String -> List CardModel
+parseDeck s =
+    s |> String.words |> List.map parseCards |> List.reverse |> List.concat
+
+
+suitAsColor : Suit -> String
+suitAsColor s =
+    case s of
+        Spade ->
+            "black"
+
+        Club ->
+            "black"
+
+        _ ->
+            "red"
+
+
+modelAsColor : CardModel -> String
+modelAsColor m =
+    case m of
+        Ranked _ suit ->
+            suitAsColor suit
+
+        Joker isRed ->
+            if isRed then
+                "red"
+
+            else
+                "black"
+
+
+modelAsShort : CardModel -> String
+modelAsShort m =
+    case m of
+        Ranked rank suit ->
+            rankAsChar rank ++ suitAsChar suit
+
+        Joker red ->
+            "x"
+                ++ (if red then
+                        "r"
+
+                    else
+                        "b"
+                   )
+
+
+defaultModel : CardModel
+defaultModel =
+    Ranked Ace Spade
+
+
+modelUsing : CardModel -> List String
+modelUsing m =
+    case m of
+        Ranked rank suit ->
+            [ modelAsShort m
+            , rankAsChar rank
+            , suitAsString suit
+            ]
+
+        Joker _ ->
+            [ modelAsShort m
+            , "x"
+            ]
+
+
+modelDecoder : Decoder CardModel
+modelDecoder =
+    D.string
+        |> D.andThen
+            (\str ->
+                case List.head <| parseCards str of
+                    Just card ->
+                        D.succeed card
+
+                    Nothing ->
+                        D.fail ""
+            )
+
+
+encodeModel : CardModel -> Value
+encodeModel m =
+    string <| modelAsShort m