cross-packer 0.1.0

package/templates/win/nsis/include/getProcessInfo.nsh

@@ -0,0 +1,157 @@
+; NSIS PROCESS INFO LIBRARY - GetProcessInfo.nsh
+; Version 1.1 - Mar 28th, 2011
+;
+; Description:
+;   Gets process information.
+;
+; Usage example:
+;   ${GetProcessInfo} 0 $0 $1 $2 $3 $4
+;   DetailPrint "pid=$0 parent_pid=$1 priority=$2 process_name=$3 exe=$4"
+;
+; History:
+;   1.1 - 28/03/2011 - Added uninstall function, include guards, file header. Fixed getting full exe path on pre vista systems. (Sergius)
+;
+
+!ifndef GETPROCESSINFO_INCLUDED
+!define GETPROCESSINFO_INCLUDED
+
+!define PROCESSINFO.TH32CS_SNAPPROCESS      2
+!define PROCESSINFO.INVALID_HANDLE_VALUE    -1
+
+!define GetProcessInfo '!insertmacro GetProcessInfo'
+
+;@in pid_in - if 0 - get current process info
+;@out pid_out - real process id (may be useful, if pid_in=0)
+;@out ppid - parent process id
+;@out priority
+;@out name - name of process
+;@out fullname - fully-qualified path of process
+!macro GetProcessInfo pid_in pid_out ppid priority name fullname
+    Push ${pid_in}
+    !ifdef BUILD_UNINSTALLER
+        Call un._GetProcessInfo
+    !else
+        Call _GetProcessInfo
+    !endif
+    ;name;pri;ppid;fname;pid;
+    Pop ${name}
+    Pop ${priority}
+    Pop ${ppid}
+    Pop ${fullname}
+    Pop ${pid_out}
+!macroend
+
+!macro FUNC_GETPROCESSINFO
+    Exch $R3 ;pid
+    Push $0
+    Push $1
+    Push $2
+    Push $3
+    Push $4
+    Push $5
+    Push $R0 ;hSnapshot
+    Push $R1 ;result
+    Push $R9 ;PROCESSENTRY32;MODULEENTRY32 and so on
+    Push $R8
+
+    ;zero registers to waste trash, if error occurred
+    StrCpy $0 ""
+    StrCpy $1 ""
+    StrCpy $2 ""
+    StrCpy $3 ""
+    StrCpy $4 ""
+    StrCpy $5 ""
+
+    IntCmp $R3 0 0 skip_pid_detection skip_pid_detection
+    System::Call 'kernel32::GetCurrentProcess() i.R0'
+    System::Call "Kernel32::GetProcessId(i R0) i.R3"
+
+skip_pid_detection:
+    System::Call 'Kernel32::CreateToolhelp32Snapshot(i ${PROCESSINFO.TH32CS_SNAPPROCESS},i R3) i.R0'
+
+    IntCmp $R0 ${PROCESSINFO.INVALID_HANDLE_VALUE} end ;someting wrong
+
+    ;$R9=PROCESSENTRY32
+    ;typedef struct tagPROCESSENTRY32 {
+    ;  DWORD     dwSize;
+    ;  DWORD     cntUsage;
+    ;  DWORD     th32ProcessID;
+    ;  ULONG_PTR th32DefaultHeapID;
+    ;  DWORD     th32ModuleID;
+    ;  DWORD     cntThreads;
+    ;  DWORD     th32ParentProcessID;
+    ;  LONG      pcPriClassBase;
+    ;  DWORD     dwFlags;
+    ;  TCHAR     szExeFile[MAX_PATH];
+    ;}PROCESSENTRY32, *PPROCESSENTRY32;
+    ;dwSize=4*9+2*260
+
+    System::Alloc 1024
+    pop $R9
+    System::Call "*$R9(i 556)"
+
+    System::Call 'Kernel32::Process32FirstW(i R0, i $R9) i.R1'
+    StrCmp $R1 0 end
+
+nnext_iteration:
+    System::Call "*$R9(i,i,i.R1)" ;get PID
+    IntCmp $R1 $R3 exitloop
+
+    System::Call 'Kernel32::Process32NextW(i R0, i $R9) i.R1'
+    IntCmp $R1 0 0 nnext_iteration nnext_iteration
+
+exitloop:
+    ;$0 - pid
+    ;$1 - threads
+    ;$2 - ppid
+    ;$3 - priority
+    ;$4 - process name
+    System::Call "*$R9(i,i,i.r0,i,i,i.r1,i.r2,i.r3,i,&w256.r4)" ; Get next module
+
+    ;free:
+    System::Free $R9
+    System::Call "Kernel32::CloseToolhelp32Snapshot(i R0)"
+
+    ;===============
+    ;now get full path and commandline
+
+    System::Call "Kernel32::OpenProcess(i 1040, i 0, i r0)i .R0"
+
+    StrCmp $R0 0 end
+
+    IntOp $R8 0 + 256
+    System::Call "psapi::GetModuleFileNameExW(i R0,i 0,t .r5, *i $R8)i .R1"
+
+end:
+    Pop $R8
+    Pop $R9
+    Pop $R1
+    Pop $R0
+    Exch $5
+    Exch 1
+    Exch $4
+    Exch 2
+    Exch $3
+    Exch 3
+    Exch $2
+    Exch 4
+    Pop $1
+    Exch 4
+    Exch $0
+    Exch 5
+    Pop $R3
+!macroend ;FUNC_GETPROCESSINFO
+
+!ifndef BUILD_UNINSTALLER
+Function _GetProcessInfo
+    !insertmacro FUNC_GETPROCESSINFO
+FunctionEnd
+!endif
+
+!ifdef BUILD_UNINSTALLER
+Function un._GetProcessInfo
+    !insertmacro FUNC_GETPROCESSINFO
+FunctionEnd
+!endif
+
+!endif ;GETPROCESSINFO_INCLUDED

package/templates/win/nsis/include/installUtil.nsh

@@ -0,0 +1,248 @@
+!macro moveFile FROM TO
+  ClearErrors
+  Rename `${FROM}` `${TO}`
+  ${if} ${errors}
+    # not clear - can NSIS rename on another drive or not, so, in case of error, just copy
+    ClearErrors
+    !insertmacro copyFile `${FROM}` `${TO}`
+    Delete `${FROM}`
+  ${endif}
+!macroend
+
+!macro copyFile FROM TO
+  ${StdUtils.GetParentPath} $R5 `${TO}`
+  CreateDirectory `$R5`
+  ClearErrors
+  CopyFiles /SILENT `${FROM}` `${TO}`
+!macroend
+
+Function GetInQuotes
+  Exch $R0
+  Push $R1
+  Push $R2
+  Push $R3
+
+   StrCpy $R2 -1
+   IntOp $R2 $R2 + 1
+    StrCpy $R3 $R0 1 $R2
+    StrCmp $R3 "" 0 +3
+     StrCpy $R0 ""
+     Goto Done
+    StrCmp $R3 '"' 0 -5
+
+   IntOp $R2 $R2 + 1
+   StrCpy $R0 $R0 "" $R2
+
+   StrCpy $R2 0
+   IntOp $R2 $R2 + 1
+    StrCpy $R3 $R0 1 $R2
+    StrCmp $R3 "" 0 +3
+     StrCpy $R0 ""
+     Goto Done
+    StrCmp $R3 '"' 0 -5
+
+   StrCpy $R0 $R0 $R2
+   Done:
+
+  Pop $R3
+  Pop $R2
+  Pop $R1
+  Exch $R0
+FunctionEnd
+
+!macro GetInQuotes Var Str
+  Push "${Str}"
+  Call GetInQuotes
+  Pop "${Var}"
+!macroend
+
+Function GetFileParent
+  Exch $R0
+  Push $R1
+  Push $R2
+  Push $R3
+
+  StrCpy $R1 0
+  StrLen $R2 $R0
+
+  loop:
+    IntOp $R1 $R1 + 1
+    IntCmp $R1 $R2 get 0 get
+    StrCpy $R3 $R0 1 -$R1
+    StrCmp $R3 "\" get
+  Goto loop
+
+  get:
+    StrCpy $R0 $R0 -$R1
+
+    Pop $R3
+    Pop $R2
+    Pop $R1
+    Exch $R0
+FunctionEnd
+
+Var /GLOBAL isTryToKeepShortcuts
+
+!macro setIsTryToKeepShortcuts
+  StrCpy $isTryToKeepShortcuts "true"
+  !ifdef allowToChangeInstallationDirectory
+    ${ifNot} ${isUpdated}
+      StrCpy $isTryToKeepShortcuts "false"
+    ${endIf}
+  !endif
+!macroend
+
+# https://nsis-dev.github.io/NSIS-Forums/html/t-172971.html
+!macro readReg VAR ROOT_KEY SUB_KEY NAME
+  ${if} "${ROOT_KEY}" == "SHELL_CONTEXT"
+    ReadRegStr "${VAR}" SHELL_CONTEXT "${SUB_KEY}" "${NAME}"
+  ${elseif} "${ROOT_KEY}" == "HKEY_CURRENT_USER"
+    ReadRegStr "${VAR}" HKEY_CURRENT_USER "${SUB_KEY}" "${NAME}"
+  ${elseif} "${ROOT_KEY}" == "HKEY_LOCAL_MACHINE"
+    ReadRegStr "${VAR}" HKEY_LOCAL_MACHINE "${SUB_KEY}" "${NAME}"
+  ${else}
+    MessageBox MB_OK "Unsupported ${ROOT_KEY}"
+  ${endif}
+!macroend
+
+Function handleUninstallResult
+  Var /GLOBAL rootKey_uninstallResult
+  Exch $rootKey_uninstallResult
+
+  ${if} "$rootKey_uninstallResult" == "SHELL_CONTEXT"
+    !ifmacrodef customUnInstallCheck
+      !insertmacro customUnInstallCheck
+      Return
+    !endif
+  ${elseif} "$rootKey_uninstallResult" == "HKEY_CURRENT_USER"
+    !ifmacrodef customUnInstallCheckCurrentUser
+      !insertmacro customUnInstallCheckCurrentUser
+      Return
+    !endif
+  ${endif}
+
+  IfErrors 0 +3
+  DetailPrint `Uninstall was not successful. Not able to launch uninstaller!`
+  Return
+
+  ${if} $R0 != 0
+    MessageBox MB_OK|MB_ICONEXCLAMATION "$(uninstallFailed): $R0"
+    DetailPrint `Uninstall was not successful. Uninstaller error code: $R0.`
+    SetErrorLevel 2
+    Quit
+  ${endif}
+FunctionEnd
+
+!macro handleUninstallResult ROOT_KEY
+  Push "${ROOT_KEY}"
+  Call handleUninstallResult
+!macroend
+
+# http://stackoverflow.com/questions/24595887/waiting-for-nsis-uninstaller-to-finish-in-nsis-installer-either-fails-or-the-uni
+Function uninstallOldVersion
+  Var /GLOBAL uninstallerFileName
+  Var /Global uninstallerFileNameTemp
+  Var /GLOBAL installationDir
+  Var /GLOBAL uninstallString
+  Var /GLOBAL rootKey
+
+  ClearErrors
+  Exch $rootKey
+
+  Push 0
+  Pop $R0
+
+  !insertmacro readReg $uninstallString "$rootKey" "${UNINSTALL_REGISTRY_KEY}" UninstallString
+  ${if} $uninstallString == ""
+    !ifdef UNINSTALL_REGISTRY_KEY_2
+      !insertmacro readReg $uninstallString "$rootKey" "${UNINSTALL_REGISTRY_KEY_2}" UninstallString
+    !endif
+    ${if} $uninstallString == ""
+      ClearErrors
+      Return
+    ${endif}
+  ${endif}
+
+  # uninstaller should be copied out of app installation dir (because this dir will be deleted), so, extract uninstaller file name
+  !insertmacro GetInQuotes $uninstallerFileName "$uninstallString"
+
+  !insertmacro readReg $installationDir "$rootKey" "${INSTALL_REGISTRY_KEY}" InstallLocation
+  ${if} $installationDir == ""
+  ${andIf} $uninstallerFileName != ""
+    # https://github.com/electron-userland/electron-builder/issues/735#issuecomment-246918567
+    Push $uninstallerFileName
+    Call GetFileParent
+    Pop $installationDir
+  ${endif}
+
+  ${if} $installationDir == ""
+  ${andIf} $uninstallerFileName == ""
+    ClearErrors
+    Return
+  ${endif}
+
+  ${if} $installMode == "CurrentUser"
+  ${orIf} $rootKey == "HKEY_CURRENT_USER"
+    StrCpy $0 "/currentuser"
+  ${else}
+    StrCpy $0 "/allusers"
+  ${endif}
+
+  !insertMacro setIsTryToKeepShortcuts
+
+  ${if} $isTryToKeepShortcuts == "true"
+    !insertmacro readReg $R5 "$rootKey" "${INSTALL_REGISTRY_KEY}" KeepShortcuts
+    # if true, it means that old uninstaller supports --keep-shortcuts flag
+    ${if} $R5 == "true"
+    ${andIf} ${FileExists} "$appExe"
+      StrCpy $0 "$0 --keep-shortcuts"
+    ${endIf}
+  ${endIf}
+
+  ${if} ${isDeleteAppData}
+    StrCpy $0 "$0 --delete-app-data"
+  ${else}
+    # always pass --updated flag - to ensure that if DELETE_APP_DATA_ON_UNINSTALL is defined, user data will be not removed
+    StrCpy $0 "$0 --updated"
+  ${endif}
+
+  StrCpy $uninstallerFileNameTemp "$PLUGINSDIR\old-uninstaller.exe"
+  !insertmacro copyFile "$uninstallerFileName" "$uninstallerFileNameTemp"
+
+  # Retry counter
+  StrCpy $R5 0
+
+  UninstallLoop:
+    IntOp $R5 $R5 + 1
+
+    ${if} $R5 > 5
+      MessageBox MB_RETRYCANCEL|MB_ICONEXCLAMATION "$(appCannotBeClosed)" /SD IDCANCEL IDRETRY OneMoreAttempt
+      Return
+    ${endIf}
+
+  OneMoreAttempt:
+    ExecWait '"$uninstallerFileNameTemp" /S /KEEP_APP_DATA $0 _?=$installationDir' $R0
+    ifErrors TryInPlace CheckResult
+
+    TryInPlace:
+      # the execution failed - might have been caused by some group policy restrictions
+      # we try to execute the uninstaller in place
+      ExecWait '"$uninstallerFileName" /S /KEEP_APP_DATA $0 _?=$installationDir' $R0
+      ifErrors DoesNotExist
+
+    CheckResult:
+      ${if} $R0 == 0
+        Return
+      ${endIf}
+
+    Sleep 1000
+    Goto UninstallLoop
+
+  DoesNotExist:
+    SetErrors
+FunctionEnd
+
+!macro uninstallOldVersion ROOT_KEY
+  Push "${ROOT_KEY}"
+  Call uninstallOldVersion
+!macroend

package/templates/win/nsis/include/installer.nsh

@@ -0,0 +1,247 @@
+# functions (nsis macro) for installer
+
+!include "extractAppPackage.nsh"
+
+!ifdef APP_PACKAGE_URL
+  !include webPackage.nsh
+!endif
+
+!macro installApplicationFiles
+  !ifdef APP_BUILD_DIR
+    File /r "${APP_BUILD_DIR}\*.*"
+  !else
+    !ifdef APP_PACKAGE_URL
+      Var /GLOBAL packageFile
+      Var /GLOBAL isPackageFileExplicitlySpecified
+
+      ${StdUtils.GetParameter} $packageFile "package-file" ""
+      ${if} $packageFile == ""
+        !ifdef APP_64_NAME
+          !ifdef APP_32_NAME
+            !ifdef APP_ARM64_NAME
+              ${if} ${IsNativeARM64}
+                StrCpy $packageFile "${APP_ARM64_NAME}"
+                StrCpy $1 "${APP_ARM64_HASH}"
+              ${elseif} ${IsNativeAMD64}
+                StrCpy $packageFile "${APP_64_NAME}"
+                StrCpy $1 "${APP_64_HASH}"
+              ${else}
+                StrCpy $packageFile "${APP_32_NAME}"
+                StrCpy $1 "${APP_32_HASH}"
+              ${endif}
+            !else
+              ${if} ${RunningX64}
+                StrCpy $packageFile "${APP_64_NAME}"
+                StrCpy $1 "${APP_64_HASH}"
+              ${else}
+                StrCpy $packageFile "${APP_32_NAME}"
+                StrCpy $1 "${APP_32_HASH}"
+              ${endif}
+            !endif
+          !else
+            StrCpy $packageFile "${APP_64_NAME}"
+            StrCpy $1 "${APP_64_HASH}"
+          !endif
+        !else
+          StrCpy $packageFile "${APP_32_NAME}"
+          StrCpy $1 "${APP_32_HASH}"
+        !endif
+        StrCpy $4 "$packageFile"
+        StrCpy $packageFile "$EXEDIR/$packageFile"
+        StrCpy $isPackageFileExplicitlySpecified "false"
+      ${else}
+        StrCpy $isPackageFileExplicitlySpecified "true"
+      ${endIf}
+
+      # we do not check file hash is specifed explicitly using --package-file because it is clear that user definitely want to use this file and it is user responsibility to check
+      # 1. auto-updater uses --package-file and validates checksum
+      # 2. user can user another package file (use case - one installer suitable for any app version (use latest version))
+      ${if} ${FileExists} "$packageFile"
+        ${if} $isPackageFileExplicitlySpecified == "true"
+          Goto fun_extract
+        ${else}
+          ${StdUtils.HashFile} $3 "SHA2-512" "$packageFile"
+          ${if} $3 == $1
+            Goto fun_extract
+          ${else}
+            MessageBox MB_OK "Package file $4 found locally, but checksum doesn't match — expected $1, actual $3.$\r$\nLocal file is ignored and package will be downloaded from Internet."
+          ${endIf}
+        ${endIf}
+      ${endIf}
+
+      !insertmacro downloadApplicationFiles
+
+      fun_extract:
+        !insertmacro extractUsing7za "$packageFile"
+
+        # electron always uses per user app data
+        ${if} $installMode == "all"
+          SetShellVarContext current
+        ${endif}
+
+        !insertmacro moveFile "$packageFile" "$LOCALAPPDATA\${APP_PACKAGE_STORE_FILE}"
+
+        ${if} $installMode == "all"
+          SetShellVarContext all
+        ${endif}
+    !else
+      !insertmacro extractEmbeddedAppPackage
+      # electron always uses per user app data
+      ${if} $installMode == "all"
+        SetShellVarContext current
+      ${endif}
+      !insertmacro copyFile "$EXEPATH" "$LOCALAPPDATA\${APP_INSTALLER_STORE_FILE}"
+      ${if} $installMode == "all"
+        SetShellVarContext all
+      ${endif}
+    !endif
+  !endif
+
+  File "/oname=${UNINSTALL_FILENAME}" "${UNINSTALLER_OUT_FILE}"
+!macroend
+
+!macro registryAddInstallInfo
+  WriteRegStr SHELL_CONTEXT "${INSTALL_REGISTRY_KEY}" InstallLocation "$INSTDIR"
+  WriteRegStr SHELL_CONTEXT "${INSTALL_REGISTRY_KEY}" KeepShortcuts "true"
+  WriteRegStr SHELL_CONTEXT "${INSTALL_REGISTRY_KEY}" ShortcutName "${SHORTCUT_NAME}"
+  !ifdef MENU_FILENAME
+    WriteRegStr SHELL_CONTEXT "${INSTALL_REGISTRY_KEY}" MenuDirectory "${MENU_FILENAME}"
+  !endif
+
+  ${if} $installMode == "all"
+    StrCpy $0 "/allusers"
+    StrCpy $1 ""
+  ${else}
+    StrCpy $0 "/currentuser"
+    StrCpy $1 ""
+  ${endIf}
+
+  WriteRegStr SHELL_CONTEXT "${UNINSTALL_REGISTRY_KEY}" DisplayName "${UNINSTALL_DISPLAY_NAME}$1"
+  # https://github.com/electron-userland/electron-builder/issues/750
+  StrCpy $2 "$INSTDIR\${UNINSTALL_FILENAME}"
+  WriteRegStr SHELL_CONTEXT "${UNINSTALL_REGISTRY_KEY}" UninstallString '"$2" $0'
+  WriteRegStr SHELL_CONTEXT "${UNINSTALL_REGISTRY_KEY}" QuietUninstallString '"$2" $0 /S'
+
+  WriteRegStr SHELL_CONTEXT "${UNINSTALL_REGISTRY_KEY}" "DisplayVersion" "${VERSION}"
+  !ifdef UNINSTALLER_ICON
+    WriteRegStr SHELL_CONTEXT "${UNINSTALL_REGISTRY_KEY}" "DisplayIcon" "$INSTDIR\uninstallerIcon.ico"
+  !else
+    WriteRegStr SHELL_CONTEXT "${UNINSTALL_REGISTRY_KEY}" "DisplayIcon" "$appExe,0"
+  !endif
+
+  !ifdef COMPANY_NAME
+    WriteRegStr SHELL_CONTEXT "${UNINSTALL_REGISTRY_KEY}" "Publisher" "${COMPANY_NAME}"
+  !endif
+
+  !ifdef APP_DESCRIPTION
+    WriteRegStr SHELL_CONTEXT "${UNINSTALL_REGISTRY_KEY}" "Comments" "${APP_DESCRIPTION}"
+  !endif
+
+  !ifdef UNINSTALL_URL_HELP
+    WriteRegStr SHELL_CONTEXT "${UNINSTALL_REGISTRY_KEY}" "HelpLink" "${UNINSTALL_URL_HELP}"
+  !endif
+
+  !ifdef UNINSTALL_URL_INFO_ABOUT
+    WriteRegStr SHELL_CONTEXT "${UNINSTALL_REGISTRY_KEY}" "URLInfoAbout" "${UNINSTALL_URL_INFO_ABOUT}"
+  !endif
+
+  !ifdef UNINSTALL_URL_UPDATE_INFO
+    WriteRegStr SHELL_CONTEXT "${UNINSTALL_REGISTRY_KEY}" "URLUpdateInfo" "${UNINSTALL_URL_UPDATE_INFO}"
+  !endif
+
+  !ifdef UNINSTALL_URL_README
+    WriteRegStr SHELL_CONTEXT "${UNINSTALL_REGISTRY_KEY}" "Readme" "${UNINSTALL_URL_README}"
+  !endif
+
+  WriteRegDWORD SHELL_CONTEXT "${UNINSTALL_REGISTRY_KEY}" NoModify 1
+  WriteRegDWORD SHELL_CONTEXT "${UNINSTALL_REGISTRY_KEY}" NoRepair 1
+
+  # allow user to define ESTIMATED_SIZE to avoid GetSize call
+  !ifdef ESTIMATED_SIZE
+    IntFmt $0 "0x%08X" ${ESTIMATED_SIZE}
+  !else
+    ${GetSize} "$INSTDIR" "/S=0K" $0 $1 $2
+    IntFmt $0 "0x%08X" $0
+  !endif
+
+  WriteRegDWORD SHELL_CONTEXT "${UNINSTALL_REGISTRY_KEY}" "EstimatedSize" "$0"
+!macroend
+
+!macro cleanupOldMenuDirectory
+  ${if} $oldMenuDirectory != ""
+    !ifdef MENU_FILENAME
+      ${if} $oldMenuDirectory != "${MENU_FILENAME}"
+        RMDir "$SMPROGRAMS\$oldMenuDirectory"
+      ${endIf}
+    !else
+      RMDir "$SMPROGRAMS\$oldMenuDirectory"
+    !endif
+  ${endIf}
+!macroend
+
+!macro createMenuDirectory
+  !ifdef MENU_FILENAME
+    CreateDirectory "$SMPROGRAMS\${MENU_FILENAME}"
+    ClearErrors
+  !endif
+!macroend
+
+!macro addStartMenuLink keepShortcuts
+  !ifndef DO_NOT_CREATE_START_MENU_SHORTCUT
+    # The keepShortcuts mechanism is NOT enabled.
+    # Menu shortcut will be recreated.
+    ${if} $keepShortcuts  == "false"
+      !insertmacro cleanupOldMenuDirectory
+      !insertmacro createMenuDirectory
+
+      CreateShortCut "$newStartMenuLink" "$appExe" "" "$appExe" 0 "" "" "${APP_DESCRIPTION}"
+      # clear error (if shortcut already exists)
+      ClearErrors
+      WinShell::SetLnkAUMI "$newStartMenuLink" "${APP_ID}"
+    # The keepShortcuts mechanism IS enabled.
+    # The menu shortcut could either not exist (it shouldn't be recreated) or exist in an obsolete location.
+    ${elseif} $oldStartMenuLink != $newStartMenuLink
+    ${andIf} ${FileExists} "$oldStartMenuLink"
+      !insertmacro createMenuDirectory
+
+      Rename $oldStartMenuLink $newStartMenuLink
+      WinShell::UninstShortcut "$oldStartMenuLink"
+      WinShell::SetLnkAUMI "$newStartMenuLink" "${APP_ID}"
+
+      !insertmacro cleanupOldMenuDirectory
+    ${endIf}
+  !endif
+!macroend
+
+!macro addDesktopLink keepShortcuts
+  !ifndef DO_NOT_CREATE_DESKTOP_SHORTCUT
+    # https://github.com/electron-userland/electron-builder/pull/1432
+    ${ifNot} ${isNoDesktopShortcut}
+      # The keepShortcuts mechanism is NOT enabled.
+      # Shortcuts will be recreated.
+      ${if} $keepShortcuts == "false"
+        CreateShortCut "$newDesktopLink" "$appExe" "" "$appExe" 0 "" "" "${APP_DESCRIPTION}"
+        ClearErrors
+        WinShell::SetLnkAUMI "$newDesktopLink" "${APP_ID}"
+      # The keepShortcuts mechanism IS enabled.
+      # The desktop shortcut could exist in an obsolete location (due to name change).
+      ${elseif} $oldDesktopLink != $newDesktopLink
+      ${andIf} ${FileExists} "$oldDesktopLink"
+        Rename $oldDesktopLink $newDesktopLink
+        WinShell::UninstShortcut "$oldDesktopLink"
+        WinShell::SetLnkAUMI "$newDesktopLink" "${APP_ID}"
+
+      !ifdef RECREATE_DESKTOP_SHORTCUT
+      ${elseif} $oldDesktopLink != $newDesktopLink
+      ${orIfNot} ${FileExists} "$oldDesktopLink"
+        ${ifNot} ${isUpdated}
+          CreateShortCut "$newDesktopLink" "$appExe" "" "$appExe" 0 "" "" "${APP_DESCRIPTION}"
+          ClearErrors
+          WinShell::SetLnkAUMI "$newDesktopLink" "${APP_ID}"
+        ${endIf}
+      !endif
+      ${endIf}
+      System::Call 'Shell32::SHChangeNotify(i 0x8000000, i 0, i 0, i 0)'
+    ${endIf}
+  !endif
+!macroend

package/templates/win/nsis/include/nsProcess.nsh

@@ -0,0 +1,28 @@
+!define nsProcess::FindProcess `!insertmacro nsProcess::FindProcess`
+
+!macro nsProcess::FindProcess _FILE _ERR
+	nsProcess::_FindProcess /NOUNLOAD `${_FILE}`
+	Pop ${_ERR}
+!macroend
+
+
+!define nsProcess::KillProcess `!insertmacro nsProcess::KillProcess`
+
+!macro nsProcess::KillProcess _FILE _ERR
+	nsProcess::_KillProcess /NOUNLOAD `${_FILE}`
+	Pop ${_ERR}
+!macroend
+
+!define nsProcess::CloseProcess `!insertmacro nsProcess::CloseProcess`
+
+!macro nsProcess::CloseProcess _FILE _ERR
+	nsProcess::_CloseProcess /NOUNLOAD `${_FILE}`
+	Pop ${_ERR}
+!macroend
+
+
+!define nsProcess::Unload `!insertmacro nsProcess::Unload`
+
+!macro nsProcess::Unload
+	nsProcess::_Unload
+!macroend