cross-packer 0.1.0

package/templates/win/nsis/include/UAC.nsh

@@ -0,0 +1,299 @@
+/*** UAC Plug-in ***
+
+Interactive User (MediumIL)        Admin user (HighIL)
+***[Setup.exe]*************      ***[Setup.exe]**************
+*                         *      *                          *
+* +++[.OnInit]+++++++++++ *      * +++[.OnInit]++++++++++++ *
+* + UAC_RunElevated >---+-+----> * +                      + *
+* + NSIS.Quit           + *      * +                      + *
+* +++++++++++++++++++++++ *      * ++++++++++++++++++++++++ *
+*                         *      *                          *
+*                         *      *                          *
+* +++[Section]+++++++++++ *      * +++[Section]++++++++++++ *
+* +                     + *   /--+-+-<UAC_AsUser_ExecShell+ *
+* +++++++++++++++++++++++ *   |  * ++++++++++++++++++++++++ *
+*                         *   |  *                          *
+*  Win32.ShellExecute <---+--/   *                          *
+*                         *      *                          *
+***************************      ****************************
+
+*/
+
+!ifndef UAC_HDR__INC
+!verbose push
+!verbose 3
+!ifndef UAC_VERBOSE  
+	!define UAC_VERBOSE 3
+!endif
+!verbose ${UAC_VERBOSE}
+
+!define UAC_HDR__INC 0x00020400 ;MMmmbbrr
+
+!include LogicLib.nsh
+
+
+
+/* UAC_RunElevated
+**
+** Starts the elevation operation.
+**
+** Return values:
+**
+** $0: Win32 error code (0 on success, 1223 if user aborted elevation dialog, anything else should be treated as a fatal error)
+** $1: If $0==0:
+**     0 UAC is not supported by the OS
+**     1 Started a elevated child process, the current process should act like a wrapper (Call Quit without any further processing)
+**     2 The process is already running @ HighIL (Member of admin group)
+**     3 You should call RunElevated again (This can happen if a user without admin priv. is used in the runas dialog)
+** $2: If $0==0 && $1==1: ExitCode of the elevated fork process (The NSIS errlvl is also set)
+** $3: If $0==0: 1 if the user is a member of the admin group or 0 otherwise
+**/
+!macro UAC_RunElevated
+UAC::_ 0
+!macroend
+!macro UAC_PageElevation_RunElevated
+UAC::_ 0
+!macroend
+/*!macro UAC_OnInitElevation_RunElevated
+UAC::_ 0
+!macroend
+!macro UAC_OnInitElevation_OnGuiInit
+!macroend*/
+
+
+
+/* UAC_GetIntegrityLevel <NSISVar:Output | "s">
+**
+** Get integrity level of current process
+**
+**/
+!macro UAC_GetIntegrityLevel outvar
+UAC::_ 6
+!if "${outvar}" != "s"
+	Pop ${outvar}
+!endif
+!macroend
+
+
+
+/* UAC_IsAdmin
+**
+** Is the current process running with administrator privileges? Result in $0
+**
+** ${If} ${UAC_IsAdmin} ...
+**
+**/
+!macro UAC_IsAdmin
+UAC::_ 2
+!macroend
+!define UAC_IsAdmin `"" UAC_IsAdmin ""`
+!macro _UAC_IsAdmin _a _b _t _f
+!insertmacro _UAC_MakeLL_Cmp _!= 0 2s
+!macroend
+
+
+
+/* UAC_IsInnerInstance
+**
+** Does the current process have a NSIS/UAC parent process that is part of the elevation operation?
+**
+** ${If} ${UAC_IsInnerInstance} ...
+**
+**/
+!macro UAC_IsInnerInstance
+UAC::_ 3
+!macroend
+!define UAC_IsInnerInstance `"" UAC_IsInnerInstance ""`
+!macro _UAC_IsInnerInstance _a _b _t _f
+!insertmacro _UAC_MakeLL_Cmp _!= 0 3s
+!macroend
+
+
+
+/* UAC_PageElevation_OnInit, UAC_PageElevation_OnGuiInit,
+**
+** Helper macros for elevation on a custom elevation page, see the DualMode example for more information.
+**
+**/
+!macro UAC_Notify_OnGuiInit
+UAC::_ 4
+!macroend
+!macro UAC_PageElevation_OnGuiInit
+!insertmacro UAC_Notify_OnGuiInit
+!macroend
+!macro UAC_PageElevation_OnInit
+UAC::_ 5
+${IfThen} ${Errors} ${|} Quit ${|}
+!macroend
+
+
+
+/* UAC_AsUser_Call <Function|Label> <NSISAddressName> <UAC_* flags>
+**
+** Calls a function or label in the user process instance.
+** All the UAC_AsUser_* macros use this helper macro.
+**
+**/
+!define UAC_SYNCREGISTERS 0x1
+;define UAC_SYNCSTACK     0x2
+!define UAC_SYNCOUTDIR    0x4
+!define UAC_SYNCINSTDIR   0x8
+;define UAC_CLEARERRFLAG  0x10
+!macro UAC_AsUser_Call type name flags
+push $0
+Get${type}Address $0 ${name}
+!verbose push
+!verbose ${UAC_VERBOSE}
+!insertmacro _UAC_ParseDefineFlagsToInt _UAC_AsUser_Call__flags ${flags}
+!verbose pop
+StrCpy $0 "1$0:${_UAC_AsUser_Call__flags}"
+!undef _UAC_AsUser_Call__flags
+Exch $0
+UAC::_
+!macroend
+
+
+
+/*
+** UAC_AsUser_GetSection <Flags|InstTypes|Size|Text> <SectionIndex> <NSISVar:Output>
+*/
+!macro UAC_AsUser_GetSection secprop secidx outvar
+!insertmacro _UAC_AsUser_GenOp ${outvar} SectionGet${secprop} ${secidx} ""
+!macroend
+
+
+
+/*
+** UAC_AsUser_GetGlobalVar <NSISVar:SourceAndOutput>
+** UAC_AsUser_GetGlobal <NSISVar:Output> <NSISVar:Source>
+*/
+!macro UAC_AsUser_GetGlobalVar var
+!insertmacro _UAC_AsUser_GenOp ${var} StrCpy "" ${var}
+!macroend
+!macro UAC_AsUser_GetGlobal outvar srcvar
+!insertmacro _UAC_AsUser_GenOp ${outvar} StrCpy "" ${srcvar}
+!macroend
+
+
+
+/*
+** UAC_AsUser_ExecShell <Verb> <ApplicationOrFile> <Parameters> <Working Directory> <SW_*>
+**
+** Call ExecShell in the user process instance.
+**
+*/
+!macro UAC_AsUser_ExecShell verb command params workdir show
+!insertmacro _UAC_IncL
+goto _UAC_L_E_${__UAC_L}
+_UAC_L_F_${__UAC_L}:
+ExecShell "${verb}" "${command}" '${params}' ${show}
+return
+_UAC_L_E_${__UAC_L}:
+!if "${workdir}" != ""
+	push $outdir
+	SetOutPath "${workdir}"
+!endif
+!insertmacro UAC_AsUser_Call Label _UAC_L_F_${__UAC_L} ${UAC_SYNCREGISTERS}|${UAC_SYNCOUTDIR}|${UAC_SYNCINSTDIR} #|${UAC_CLEARERRFLAG}
+!if "${workdir}" != ""
+	pop $outdir 
+	SetOutPath $outdir
+!endif
+!macroend
+
+
+
+!macro _UAC_MakeLL_Cmp cmpop cmp pluginparams
+!insertmacro _LOGICLIB_TEMP
+UAC::_ ${pluginparams}
+pop $_LOGICLIB_TEMP
+!insertmacro ${cmpop} $_LOGICLIB_TEMP ${cmp} `${_t}` `${_f}`
+!macroend
+!macro _UAC_definemath def val1 op val2
+!define /math _UAC_definemath "${val1}" ${op} ${val2}
+!ifdef ${def}
+	!undef ${def}
+!endif
+!define ${def} "${_UAC_definemath}"
+!undef _UAC_definemath
+!macroend
+!macro _UAC_ParseDefineFlags_orin parse outflags
+!searchparse /noerrors ${${parse}} "" _UAC_ParseDefineFlags_orin_f1 "|" _UAC_ParseDefineFlags_orin_f2
+!define _UAC_ParseDefineFlags_orin_this ${_UAC_ParseDefineFlags_orin_f1}
+!undef ${parse}
+!define ${parse} ${_UAC_ParseDefineFlags_orin_f2}
+!define _UAC_ParseDefineFlags_orin_saveout ${${outflags}}
+!undef ${outflags}
+!define /math ${outflags} "${_UAC_ParseDefineFlags_orin_saveout}" | "${_UAC_ParseDefineFlags_orin_this}"
+!undef _UAC_ParseDefineFlags_orin_saveout
+!undef _UAC_ParseDefineFlags_orin_this
+!ifdef _UAC_ParseDefineFlags_orin_f1
+	!undef _UAC_ParseDefineFlags_orin_f1
+!endif
+!ifdef _UAC_ParseDefineFlags_orin_f2
+	!undef _UAC_ParseDefineFlags_orin_f2
+!endif
+!macroend
+!macro _UAC_ParseDefineFlags_Begin _outdef _in
+!define _UAC_PDF${_outdef}_parse "${_in}"
+!define _UAC_PDF${_outdef}_flags ""
+!define _UAC_PDF${_outdef}_r 0
+!insertmacro _UAC_ParseDefineFlags_orin _UAC_PDF${_outdef}_parse _UAC_PDF${_outdef}_flags	;0x1
+!insertmacro _UAC_ParseDefineFlags_orin _UAC_PDF${_outdef}_parse _UAC_PDF${_outdef}_flags	;0x2
+!insertmacro _UAC_ParseDefineFlags_orin _UAC_PDF${_outdef}_parse _UAC_PDF${_outdef}_flags	;0x4
+!insertmacro _UAC_ParseDefineFlags_orin _UAC_PDF${_outdef}_parse _UAC_PDF${_outdef}_flags	;0x8
+!insertmacro _UAC_ParseDefineFlags_orin _UAC_PDF${_outdef}_parse _UAC_PDF${_outdef}_flags	;0x10
+!macroend
+!macro _UAC_ParseDefineFlags_End _outdef
+!define ${_outdef} ${_UAC_PDF${_outdef}_r}
+!undef _UAC_PDF${_outdef}_r
+!undef _UAC_PDF${_outdef}_flags
+!undef _UAC_PDF${_outdef}_parse
+!macroend
+!macro _UAC_ParseDefineFlags_IncludeFlag _outdef flag
+!if ${_UAC_PDF${_outdef}_flags} & ${flag}
+	!insertmacro _UAC_definemath _UAC_PDF${_outdef}_r ${_UAC_PDF${_outdef}_r} | ${flag}
+!endif
+!macroend
+!macro _UAC_ParseDefineFlagsToInt _outdef _in
+!insertmacro _UAC_ParseDefineFlags_Begin _UAC_ParseDefineFlagsToInt_tmp "${_in}"
+!define ${_outdef} ${_UAC_PDF_UAC_ParseDefineFlagsToInt_tmp_flags}
+!insertmacro _UAC_ParseDefineFlags_End _UAC_ParseDefineFlagsToInt_tmp
+!undef _UAC_ParseDefineFlagsToInt_tmp
+!macroend
+!macro _UAC_IncL
+!insertmacro _UAC_definemath __UAC_L "${__UAC_L}" + 1
+!macroend
+!macro _UAC_AsUser_GenOp outvar op opparam1 opparam2
+!define _UAC_AUGOGR_ID _UAC_AUGOGR_OP${outvar}${op}${opparam1}${opparam2}
+!ifndef ${_UAC_AUGOGR_ID} ;Has this exact action been done before? 
+	!if ${outvar} == $0
+		!define ${_UAC_AUGOGR_ID} $1
+	!else
+		!define ${_UAC_AUGOGR_ID} $0
+	!endif
+	!if "${opparam1}" == ""
+		!define _UAC_AUGOGR_OPP1 ${${_UAC_AUGOGR_ID}}
+		!define _UAC_AUGOGR_OPP2 ${opparam2}
+	!else
+		!define _UAC_AUGOGR_OPP1 ${opparam1}
+		!define _UAC_AUGOGR_OPP2 ${${_UAC_AUGOGR_ID}}
+	!endif	
+	goto ${_UAC_AUGOGR_ID}_C
+	${_UAC_AUGOGR_ID}_F:
+		${op} ${_UAC_AUGOGR_OPP1} ${_UAC_AUGOGR_OPP2}
+		return
+	${_UAC_AUGOGR_ID}_C:
+	!undef _UAC_AUGOGR_OPP1
+	!undef _UAC_AUGOGR_OPP2
+!endif
+push ${${_UAC_AUGOGR_ID}}
+!insertmacro UAC_AsUser_Call Label ${_UAC_AUGOGR_ID}_F ${UAC_SYNCREGISTERS}
+StrCpy ${outvar} ${${_UAC_AUGOGR_ID}}
+pop ${${_UAC_AUGOGR_ID}}
+!undef _UAC_AUGOGR_ID
+!macroend
+
+
+
+!verbose pop
+!endif /* UAC_HDR__INC */

package/templates/win/nsis/include/allowOnlyOneInstallerInstance.nsh

@@ -0,0 +1,164 @@
+!ifndef nsProcess::FindProcess
+    !include "nsProcess.nsh"
+!endif
+
+!ifmacrondef customCheckAppRunning
+  !include "getProcessInfo.nsh"
+  Var pid
+!endif
+
+# http://nsis.sourceforge.net/Allow_only_one_installer_instance
+!macro ALLOW_ONLY_ONE_INSTALLER_INSTANCE
+  BringToFront
+  !define /ifndef SYSTYPE_PTR p ; NSIS v3.0+
+  System::Call 'kernel32::CreateMutex(${SYSTYPE_PTR}0, i1, t"${APP_GUID}")?e'
+  Pop $0
+  IntCmpU $0 183 0 launch launch ; ERROR_ALREADY_EXISTS
+    StrLen $0 "$(^SetupCaption)"
+    IntOp $0 $0 + 1 ; GetWindowText count includes \0
+    StrCpy $1 "" ; Start FindWindow with NULL
+    loop:
+      FindWindow $1 "#32770" "" "" $1
+      StrCmp 0 $1 notfound
+      System::Call 'user32::GetWindowText(${SYSTYPE_PTR}r1, t.r2, ir0)'
+      StrCmp $2 "$(^SetupCaption)" 0 loop
+      SendMessage $1 0x112 0xF120 0 /TIMEOUT=2000 ; WM_SYSCOMMAND:SC_RESTORE to restore the window if it is minimized
+      System::Call "user32::SetForegroundWindow(${SYSTYPE_PTR}r1)"
+    notfound:
+      Abort
+  launch:
+!macroend
+
+!macro CHECK_APP_RUNNING
+  Var /GLOBAL CmdPath
+  Var /GLOBAL FindPath
+  Var /GLOBAL PowerShellPath
+  StrCpy $CmdPath "$SYSDIR\cmd.exe"
+  StrCpy $FindPath "$SYSDIR\find.exe"
+  StrCpy $PowerShellPath "$SYSDIR\WindowsPowerShell\v1.0\powershell.exe"
+  !ifmacrodef customCheckAppRunning
+    !insertmacro customCheckAppRunning
+  !else
+    !insertmacro IS_POWERSHELL_AVAILABLE
+    !insertmacro _CHECK_APP_RUNNING
+  !endif
+!macroend
+
+!macro IS_POWERSHELL_AVAILABLE
+  Var /GLOBAL IsPowerShellAvailable ; 0 = available, 1 = not available
+  # Try running PowerShell with a simple command to check if it's available
+  nsExec::Exec `"$PowerShellPath" -C "if (Get-Command Get-CimInstance -ErrorAction SilentlyContinue) { exit 0 } else { exit 1 }"`
+  Pop $0  # Return code (0 = success, other = error)
+
+  ${if} $0 == 0
+    # PowerShell is available, check if it's not blocked by policies
+    nsExec::Exec `"$PowerShellPath" -C "if ((Get-ExecutionPolicy -Scope Process) -eq 'Restricted') { exit 1 } else { exit 0 }"`
+    Pop $0
+  ${endIf}
+
+  ${if} $0 != 0
+    StrCpy $0 1
+  ${endIf}
+
+  StrCpy $IsPowerShellAvailable $0
+!macroend
+
+!macro FIND_PROCESS _FILE _RETURN
+  ${if} $IsPowerShellAvailable == 0
+    nsExec::Exec `"$PowerShellPath" -C "if ((Get-CimInstance -ClassName Win32_Process | ? {$$_.Path -and $$_.Path.StartsWith('$INSTDIR', 'CurrentCultureIgnoreCase')}).Count -gt 0) { exit 0 } else { exit 1 }"`
+    Pop ${_RETURN}
+  ${else}
+    !ifdef INSTALL_MODE_PER_ALL_USERS
+      ${nsProcess::FindProcess} "${_FILE}" ${_RETURN}
+    !else
+      # find process owned by current user
+      nsExec::Exec `"$CmdPath" /C tasklist /FI "USERNAME eq %USERNAME%" /FI "IMAGENAME eq ${_FILE}" /FO CSV | "$FindPath" "${_FILE}"`
+      Pop ${_RETURN}
+    !endif
+  ${endIf}
+!macroend
+
+!macro KILL_PROCESS _FILE _FORCE
+  Push $0
+  ${if} ${_FORCE} == 1
+    ${if} $IsPowerShellAvailable == 0
+      StrCpy $0 "-Force"
+    ${else}
+      StrCpy $0 "/F"
+    ${endIf}
+  ${else}
+    StrCpy $0 ""
+  ${endIf}
+
+  ${if} $IsPowerShellAvailable == 0
+    nsExec::Exec `"$PowerShellPath" -C "Get-CimInstance -ClassName Win32_Process | ? {$$_.Path -and $$_.Path.StartsWith('$INSTDIR', 'CurrentCultureIgnoreCase')} | % { Stop-Process -Id $$_.ProcessId $0 }"`
+  ${else}
+    !ifdef INSTALL_MODE_PER_ALL_USERS
+      nsExec::Exec `taskkill /IM "${_FILE}" /FI "PID ne $pid"`
+    !else
+      nsExec::Exec `"$CmdPath" /C taskkill $0 /IM "${_FILE}" /FI "PID ne $pid" /FI "USERNAME eq %USERNAME%"`
+    !endif
+  ${endIf}
+  Pop $0
+!macroend 
+
+!macro _CHECK_APP_RUNNING
+  ${GetProcessInfo} 0 $pid $1 $2 $3 $4
+  ${if} $3 != "${APP_EXECUTABLE_FILENAME}"
+    ${if} ${isUpdated}
+      # allow app to exit without explicit kill
+      Sleep 300
+    ${endIf}
+
+    !insertmacro FIND_PROCESS "${APP_EXECUTABLE_FILENAME}" $R0
+    ${if} $R0 == 0
+      ${if} ${isUpdated}
+        # allow app to exit without explicit kill
+        Sleep 1000
+        Goto doStopProcess
+      ${endIf}
+      MessageBox MB_OKCANCEL|MB_ICONEXCLAMATION "$(appRunning)" /SD IDOK IDOK doStopProcess
+      Quit
+
+      doStopProcess:
+
+      DetailPrint "$(appClosing)"
+
+      !insertmacro KILL_PROCESS "${APP_EXECUTABLE_FILENAME}" 0
+      # to ensure that files are not "in-use"
+      Sleep 300
+
+      # Retry counter
+      StrCpy $R1 0
+
+      loop:
+        IntOp $R1 $R1 + 1
+
+        !insertmacro FIND_PROCESS "${APP_EXECUTABLE_FILENAME}" $R0
+        ${if} $R0 == 0
+          # wait to give a chance to exit gracefully
+          Sleep 1000
+          !insertmacro KILL_PROCESS "${APP_EXECUTABLE_FILENAME}" 1 # 1 = force kill
+          !insertmacro FIND_PROCESS "${APP_EXECUTABLE_FILENAME}" $R0
+          ${if} $R0 == 0
+            DetailPrint `Waiting for "${PRODUCT_NAME}" to close.`
+            Sleep 2000
+          ${else}
+            Goto not_running
+          ${endIf}
+        ${else}
+          Goto not_running
+        ${endIf}
+
+        # App likely running with elevated permissions.
+        # Ask user to close it manually
+        ${if} $R1 > 1
+          MessageBox MB_RETRYCANCEL|MB_ICONEXCLAMATION "$(appCannotBeClosed)" /SD IDCANCEL IDRETRY loop
+          Quit
+        ${else}
+          Goto loop
+        ${endIf}
+      not_running:
+    ${endIf}
+  ${endIf}
+!macroend

package/templates/win/nsis/include/extractAppPackage.nsh

@@ -0,0 +1,138 @@
+!macro extractEmbeddedAppPackage
+  !ifdef COMPRESS
+    SetCompress off
+  !endif
+
+  Var /GLOBAL packageArch
+  
+  !insertmacro identify_package
+  !insertmacro compute_files_for_current_arch
+
+  !ifdef COMPRESS
+    SetCompress "${COMPRESS}"
+  !endif
+
+  !insertmacro decompress
+  !insertmacro custom_files_post_decompression
+!macroend
+
+!macro identify_package 
+  !ifdef APP_32
+    StrCpy $packageArch "32"
+  !endif
+  !ifdef APP_64
+    ${if} ${RunningX64}
+    ${OrIf} ${IsNativeARM64}
+      StrCpy $packageArch "64"
+    ${endif}
+  !endif
+  !ifdef APP_ARM64
+    ${if} ${IsNativeARM64}
+      StrCpy $packageArch "ARM64"
+    ${endif}
+  !endif
+!macroend
+
+!macro compute_files_for_current_arch
+  ${if} $packageArch == "ARM64"
+    !ifdef APP_ARM64
+      !insertmacro arm64_app_files
+    !endif
+  ${elseif} $packageArch == "64"
+    !ifdef APP_64
+      !insertmacro x64_app_files
+    !endif
+  ${else}
+    !ifdef APP_32
+      !insertmacro ia32_app_files
+    !endif
+  ${endIf}
+!macroend
+
+!macro custom_files_post_decompression
+  ${if} $packageArch == "ARM64"
+    !ifmacrodef customFiles_arm64
+      !insertmacro customFiles_arm64
+    !endif
+  ${elseif} $packageArch == "64"
+    !ifmacrodef customFiles_x64
+      !insertmacro customFiles_x64
+    !endif
+  ${else}
+    !ifmacrodef customFiles_ia32
+      !insertmacro customFiles_ia32
+    !endif
+  ${endIf}
+!macroend
+
+!macro arm64_app_files
+  File /oname=$PLUGINSDIR\app-arm64.${COMPRESSION_METHOD} "${APP_ARM64}"
+!macroend
+
+!macro x64_app_files
+  File /oname=$PLUGINSDIR\app-64.${COMPRESSION_METHOD} "${APP_64}"
+!macroend
+
+!macro ia32_app_files
+  File /oname=$PLUGINSDIR\app-32.${COMPRESSION_METHOD} "${APP_32}"
+!macroend
+
+!macro decompress
+  !ifdef ZIP_COMPRESSION
+    nsisunz::Unzip "$PLUGINSDIR\app-$packageArch.zip" "$INSTDIR"
+    Pop $R0
+    StrCmp $R0 "success" +3
+      MessageBox MB_OK|MB_ICONEXCLAMATION "$(decompressionFailed)$\n$R0"
+      Quit
+  !else
+    !insertmacro extractUsing7za "$PLUGINSDIR\app-$packageArch.7z"
+  !endif
+!macroend
+
+!macro extractUsing7za FILE
+  Push $OUTDIR
+  CreateDirectory "$PLUGINSDIR\7z-out"
+  ClearErrors
+  SetOutPath "$PLUGINSDIR\7z-out"
+  Nsis7z::Extract "${FILE}"
+  Pop $R0
+  SetOutPath $R0
+
+  # Retry counter
+  StrCpy $R1 0
+
+  LoopExtract7za:
+    IntOp $R1 $R1 + 1
+
+    # Attempt to copy files in atomic way
+    CopyFiles /SILENT "$PLUGINSDIR\7z-out\*" $OUTDIR
+    IfErrors 0 DoneExtract7za
+
+    DetailPrint `Can't modify "${PRODUCT_NAME}"'s files.`
+    ${if} $R1 < 5
+      # Try copying a few times before asking for a user action.
+      Goto RetryExtract7za
+    ${else}
+      MessageBox MB_RETRYCANCEL|MB_ICONEXCLAMATION "$(appCannotBeClosed)" /SD IDRETRY IDCANCEL AbortExtract7za
+    ${endIf}
+
+    # As an absolutely last resort after a few automatic attempts and user
+    # intervention - we will just overwrite everything with `Nsis7z::Extract`
+    # even though it is not atomic and will ignore errors.
+
+    # Clear the temporary folder first to make sure we don't use twice as
+    # much disk space.
+    RMDir /r "$PLUGINSDIR\7z-out"
+
+    Nsis7z::Extract "${FILE}"
+    Goto DoneExtract7za
+
+  AbortExtract7za:
+    Quit
+
+  RetryExtract7za:
+    Sleep 1000
+    Goto LoopExtract7za
+
+  DoneExtract7za:
+!macroend