coa 0.4.1 → 1.0.3

package/src/completion.coffee

@@ -1,158 +0,0 @@
-###*
-Most of the code adopted from the npm package shell completion code.
-See https://github.com/isaacs/npm/blob/master/lib/completion.js
-###
-
-Q = require 'q'
-escape = require('./shell').escape
-unescape = require('./shell').unescape
-
-module.exports = ->
-    @title('Shell completion')
-        .helpful()
-        .arg()
-            .name('raw')
-            .title('Completion words')
-            .arr()
-            .end()
-        .act (opts, args) ->
-            if process.platform == 'win32'
-                e = new Error 'shell completion not supported on windows'
-                e.code = 'ENOTSUP'
-                e.errno = require('constants').ENOTSUP
-                return @reject(e)
-
-            # if the COMP_* isn't in the env, then just dump the script
-            if !process.env.COMP_CWORD? or !process.env.COMP_LINE? or !process.env.COMP_POINT?
-                return dumpScript(@_cmd._name)
-
-            console.error 'COMP_LINE:  %s', process.env.COMP_LINE
-            console.error 'COMP_CWORD: %s', process.env.COMP_CWORD
-            console.error 'COMP_POINT: %s', process.env.COMP_POINT
-            console.error 'args: %j', args.raw
-
-            # completion opts
-            opts = getOpts args.raw
-
-            # cmd
-            { cmd, argv } = @_cmd._parseCmd opts.partialWords
-            Q.when complete(cmd, opts), (compls) ->
-                console.error 'filtered: %j', compls
-                console.log compls.map(escape).join('\n')
-
-
-dumpScript = (name) ->
-    fs = require 'fs'
-    path = require 'path'
-    defer = Q.defer()
-
-    fs.readFile path.resolve(__dirname, 'completion.sh'), 'utf8', (err, d) ->
-        if err then return defer.reject err
-        d = d.replace(/{{cmd}}/g, path.basename name).replace(/^\#\!.*?\n/, '')
-
-        onError = (err) ->
-            # Darwin is a real dick sometimes.
-            #
-            # This is necessary because the "source" or "." program in
-            # bash on OS X closes its file argument before reading
-            # from it, meaning that you get exactly 1 write, which will
-            # work most of the time, and will always raise an EPIPE.
-            #
-            # Really, one should not be tossing away EPIPE errors, or any
-            # errors, so casually. But, without this, `. <(cmd completion)`
-            # can never ever work on OS X.
-            if err.errno == require('constants').EPIPE
-                process.stdout.removeListener 'error', onError
-                defer.resolve()
-            else
-                defer.reject(err)
-
-        process.stdout.on 'error', onError
-        process.stdout.write d, -> defer.resolve()
-
-    defer.promise
-
-
-getOpts = (argv) ->
-    # get the partial line and partial word, if the point isn't at the end
-    # ie, tabbing at: cmd foo b|ar
-    line = process.env.COMP_LINE
-    w = +process.env.COMP_CWORD
-    point = +process.env.COMP_POINT
-    words = argv.map unescape
-    word = words[w]
-    partialLine = line.substr 0, point
-    partialWords = words.slice 0, w
-
-    # figure out where in that last word the point is
-    partialWord = argv[w] or ''
-    i = partialWord.length
-    while partialWord.substr(0, i) isnt partialLine.substr(-1 * i) and i > 0
-        i--
-    partialWord = unescape partialWord.substr 0, i
-    if partialWord then partialWords.push partialWord
-
-    {
-        line: line
-        w: w
-        point: point
-        words: words
-        word: word
-        partialLine: partialLine
-        partialWords: partialWords
-        partialWord: partialWord
-    }
-
-
-complete = (cmd, opts) ->
-    compls = []
-
-    # complete on cmds
-    if opts.partialWord.indexOf('-')
-        compls = Object.keys(cmd._cmdsByName)
-        # Complete on required opts without '-' in last partial word
-        # (if required not already specified)
-        #
-        # Commented out because of uselessness:
-        # -b, --block suggest results in '-' on cmd line;
-        # next completion suggest all options, because of '-'
-        #.concat Object.keys(cmd._optsByKey).filter (v) -> cmd._optsByKey[v]._req
-    else
-        # complete on opt values: --opt=| case
-        if m = opts.partialWord.match /^(--\w[\w-_]*)=(.*)$/
-            optWord = m[1]
-            optPrefix = optWord + '='
-        else
-            # complete on opts
-            # don't complete on opts in case of --opt=val completion
-            # TODO: don't complete on opts in case of unknown arg after commands
-            # TODO: complete only on opts with arr() or not already used
-            # TODO: complete only on full opts?
-            compls = Object.keys cmd._optsByKey
-
-    # complete on opt values: next arg case
-    if not (o = opts.partialWords[opts.w - 1]).indexOf '-'
-        optWord = o
-
-    # complete on opt values: completion
-    if optWord and opt = cmd._optsByKey[optWord]
-        if not opt._flag and opt._comp
-            compls = Q.all([compls, opt._comp(opts)])
-                .spread (c, o) ->
-                    c.concat o.map (v) -> (optPrefix or '') + v
-
-    # TODO: complete on args values (context aware, custom completion?)
-
-    # custom completion on cmds
-    if cmd._comp
-        compls = Q.all([compls, cmd._comp(opts)])
-            .spread (c, o) ->
-                c.concat o
-
-    # TODO: context aware custom completion on cmds, opts and args
-    # (can depend on already entered values, especially options)
-
-    Q.when compls, (compls) ->
-        console.error 'partialWord: %s', opts.partialWord
-        console.error 'compls: %j', compls
-        compls.filter (c) -> c.indexOf(opts.partialWord) is 0

package/src/index.coffee

@@ -1,5 +0,0 @@
-exports.Cmd = require('./cmd').Cmd
-exports.Opt = require('./cmd').Opt
-exports.Arg = require('./cmd').Arg
-exports.shell = require('./shell')
-exports.require = require;

package/src/opt.coffee

@@ -1,243 +0,0 @@
-fs = require 'fs'
-Q = require 'q'
-Color = require('./color').Color
-Cmd = require('./cmd').Cmd
-
-###*
-Option
-
-Named entity. Options may have short and long keys for use from command line.
-@namespace
-@class Presents option
-###
-exports.Opt = class Opt
-
-    ###*
-    @constructs
-    @param {COA.Cmd} cmd parent command
-    ###
-    constructor: (@_cmd) -> @_cmd._opts.push @
-
-    ###*
-    Set a canonical option identifier to be used anywhere in the API.
-    @param {String} _name option name
-    @returns {COA.Opt} this instance (for chainability)
-    ###
-    name: (@_name) -> @
-
-    ###*
-    Set a long description for option to be used anywhere in text messages.
-    @param {String} _title option title
-    @returns {COA.Opt} this instance (for chainability)
-    ###
-    title: Cmd::title
-
-    ###*
-    Set a short key for option to be used with one hyphen from command line.
-    @param {String} _short
-    @returns {COA.Opt} this instance (for chainability)
-    ###
-    short: (@_short) -> @_cmd._optsByKey['-' + _short] = @
-
-    ###*
-    Set a short key for option to be used with double hyphens from command line.
-    @param {String} _long
-    @returns {COA.Opt} this instance (for chainability)
-    ###
-    long: (@_long) -> @_cmd._optsByKey['--' + _long] = @
-
-    ###*
-    Make an option boolean, i.e. option without value.
-    @returns {COA.Opt} this instance (for chainability)
-    ###
-    flag: () ->
-        @_flag = true
-        @
-
-    ###*
-    Makes an option accepts multiple values.
-    Otherwise, the value will be used by the latter passed.
-    @returns {COA.Opt} this instance (for chainability)
-    ###
-    arr: ->
-        @_arr = true
-        @
-
-    ###*
-    Makes an option required.
-    @returns {COA.Opt} this instance (for chainability)
-    ###
-    req: ->
-        @_req = true
-        @
-
-    ###*
-    Makes an option to act as a command,
-    i.e. program will exit just after option action.
-    @returns {COA.Opt} this instance (for chainability)
-    ###
-    only: ->
-        @_only = true
-        @
-
-    ###*
-    Set a validation (or value) function for option.
-    Value from command line passes through before becoming available from API.
-    Using for validation and convertion simple types to any values.
-    @param {Function} _val validating function,
-        invoked in the context of option instance
-        and has one parameter with value from command line
-    @returns {COA.Opt} this instance (for chainability)
-    ###
-    val: (@_val) -> @
-
-    ###*
-    Set a default value for option.
-    Default value passed through validation function as ordinary value.
-    @param {Object} _def
-    @returns {COA.Opt} this instance (for chainability)
-    ###
-    def: (@_def) -> @
-
-    ###*
-    Make option value inputting stream.
-    It's add useful validation and shortcut for STDIN.
-    @returns {COA.Opt} this instance (for chainability)
-    ###
-    input: ->
-        # XXX: hack to workaround a bug in node 0.6.x,
-        # see https://github.com/joyent/node/issues/2130
-        process.stdin.pause();
-
-        @
-            .def(process.stdin)
-            .val (v) ->
-                if typeof v is 'string'
-                    if v is '-'
-                        process.stdin
-                    else
-                        s = fs.createReadStream v, { encoding: 'utf8' }
-                        s.pause()
-                        s
-                else v
-
-    ###*
-    Make option value outputing stream.
-    It's add useful validation and shortcut for STDOUT.
-    @returns {COA.Opt} this instance (for chainability)
-    ###
-    output: ->
-        @
-            .def(process.stdout)
-            .val (v) ->
-                if typeof v is 'string'
-                    if v is '-'
-                        process.stdout
-                    else
-                        fs.createWriteStream v, { encoding: 'utf8' }
-                else v
-
-    ###*
-    Add action for current option command.
-    This action is performed if the current option
-    is present in parsed options (with any value).
-    @param {Function} act action function,
-        invoked in the context of command instance
-        and has the parameters:
-            - {Object} opts parsed options
-            - {Array} args parsed arguments
-            - {Object} res actions result accumulator
-        It can return rejected promise by Cmd.reject (in case of error)
-        or any other value treated as result.
-    @returns {COA.Opt} this instance (for chainability)
-    ###
-    act: (act) ->
-        opt = @
-        name = @_name
-        @_cmd.act (opts) ->
-            if name of opts
-                res = act.apply @, arguments
-                if opt._only
-                    Q.when res, (res) =>
-                        @reject {
-                            toString: -> res.toString()
-                            exitCode: 0
-                        }
-                else
-                    res
-        @
-
-    ###*
-    Set custom additional completion for current option.
-    @param {Function} completion generation function,
-        invoked in the context of option instance.
-        Accepts parameters:
-            - {Object} opts completion options
-        It can return promise or any other value treated as result.
-    @returns {COA.Opt} this instance (for chainability)
-    ###
-    comp: Cmd::comp
-
-    _saveVal: (opts, val) ->
-        if @_val then val = @_val val
-        if @_arr
-            (opts[@_name] or= []).push val
-        else
-            opts[@_name] = val
-        val
-
-    _parse: (argv, opts) ->
-        @_saveVal(
-            opts,
-            if @_flag
-                true
-            else
-                argv.shift()
-        )
-
-    _checkParsed: (opts, args) -> not opts.hasOwnProperty @_name
-
-    _usage: ->
-        res = []
-        nameStr = @_name.toUpperCase()
-
-        if @_short
-            res.push '-', Color 'lgreen', @_short
-            unless @_flag then res.push ' ' + nameStr
-            res.push ', '
-
-        if @_long
-            res.push '--', Color 'green', @_long
-            unless @_flag then res.push '=' + nameStr
-
-        res.push ' : ', @_title
-
-        if @_req then res.push ' ', Color('lred', '(required)')
-
-        res.join ''
-
-    _requiredText: -> 'Missing required option:\n  ' + @_usage()
-
-    ###*
-    Return rejected promise with error code.
-    Use in .val() for return with error.
-    @param {Object} reject reason
-        You can customize toString() method and exitCode property
-        of reason object.
-    @returns {Q.promise} rejected promise
-    ###
-    reject: Cmd::reject
-
-    ###*
-    Finish chain for current option and return parent command instance.
-    @returns {COA.Cmd} parent command
-    ###
-    end: Cmd::end
-
-    ###*
-    Apply function with arguments in context of option instance.
-    @param {Function} fn
-    @param {Array} args
-    @returns {COA.Opt} this instance (for chainability)
-    ###
-    apply: Cmd::apply

package/src/shell.coffee

@@ -1,10 +0,0 @@
-exports.unescape = (w) ->
-    w = if w.charAt(0) is '"'
-        w.replace(/^"|([^\\])"$/g, '$1')
-    else
-        w.replace(/\\ /g, ' ')
-    w.replace(/\\("|'|\$|`|\\)/g, '$1')
-
-exports.escape = (w) ->
-    w = w.replace(/(["'$`\\])/g,'\\$1')
-    if w.match(/\s+/) then '"' + w + '"' else w