buninu-browser 0.3.0 → 0.5.0

package/test/fixtures/qml/flea-theme/imports/qs/Commons/Color.qml

@@ -0,0 +1,258 @@
+pragma Singleton
+import QtQuick
+import Quickshell
+import Quickshell.Io
+import "BorderGeometry.js" as Geometry
+
+// Color surfaces for the shell. Foundational palette (foreground, background,
+// accent, urgent) comes from theme/colors.toml. Per-surface roles come from
+// theme/shell.toml — generated per theme from default/themed/shell.toml.tpl,
+// or shipped directly by a theme to replace the generated file. Surfaces that
+// don't appear in shell.toml fall back to the foundational palette.
+QtObject {
+  id: root
+
+  readonly property string home: Quickshell.env("HOME")
+  readonly property string stateHome: home + "/.local/state"
+  readonly property string currentThemePath: stateHome + "/omarchy/current/theme"
+
+  property color foreground: "#cacccc"
+  property color background: "#101315"
+  property color accent: "#cacccc"
+  property color urgent: "#a55555"
+  property color muted: "#707880"
+
+  // Flat dictionary of "section.key" -> raw string from shell.toml.
+  // Reassigning this whole property is what makes surface bindings below
+  // re-evaluate when the theme swaps; mutating it in place would not.
+  property var shellValues: ({})
+
+  function pick(key, fallback) {
+    var v = shellValues[key]
+    return (typeof v === "string" && v.length > 0) ? v : fallback
+  }
+
+  function pickAlpha(key, fallback) {
+    var v = shellValues[key]
+    if (typeof v !== "string" || v.length === 0) return fallback
+    var n = Number(v)
+    if (!isFinite(n)) return fallback
+    return Util.clampAlpha(n)
+  }
+
+  function firstColorToken(value) {
+    var parts = String(value || "").replace(/^\s+|\s+$/g, "").split(/\s+/)
+    for (var i = 0; i < parts.length; i++) {
+      if (!parts[i].match(/^-?\d+(?:\.\d+)?deg$/)) return parts[i]
+    }
+    return value
+  }
+
+  function flatColor(value, fallback) {
+    var seen = Object.create(null)
+    var token = firstColorToken(value)
+    var role = String(token || "").replace(/^\s+|\s+$/g, "").toLowerCase()
+    while (root.shellValues[role] && root.shellValues[role] !== token) {
+      if (seen[role]) return fallback
+      seen[role] = true
+      token = firstColorToken(root.shellValues[role])
+      role = String(token || "").replace(/^\s+|\s+$/g, "").toLowerCase()
+    }
+    if (role === "foreground" || role === "text") return root.foreground
+    if (role === "accent") return root.accent
+    if (role === "urgent") return root.urgent
+    if (role === "muted") return root.muted
+    if (role === "background") return root.background
+    if (role === "transparent") return Qt.rgba(0, 0, 0, 0)
+
+    var color = Geometry.canonicalColor(token, 1)
+    if (typeof color === "string" && color === token && token.charAt(0) !== "#") return fallback
+    return color
+  }
+
+  // Compose a color from a base-color key and its `-alpha` companion. If the
+  // base token is a gradient, color-only consumers use the first stop.
+  function composed(colorKey, alphaKey, colorFallback, alphaFallback) {
+    return Util.alpha(flatColor(pick(colorKey, colorFallback), colorFallback), pickAlpha(alphaKey, alphaFallback))
+  }
+
+  readonly property QtObject bar: QtObject {
+    property color background: root.composed("bar.background", "bar.background-alpha", root.background, 1.0)
+    property color text: root.pick("bar.text", root.foreground)
+    property color active: root.pick("bar.active", root.urgent)
+  }
+  readonly property QtObject popups: QtObject {
+    property color background: root.composed("popups.background", "popups.background-alpha", root.background, 1.0)
+    property color text: root.pick("popups.text", root.foreground)
+    property color border: root.composed("popups.border", "popups.border-alpha", root.accent, 1.0)
+  }
+  readonly property QtObject tooltip: QtObject {
+    property color background: root.composed("tooltip.background", "tooltip.background-alpha", root.background, 1.0)
+    property color text: root.pick("tooltip.text", root.foreground)
+    property color border: root.composed("tooltip.border", "tooltip.border-alpha", root.foreground, 1.0)
+  }
+  readonly property QtObject notifications: QtObject {
+    property color background: root.composed("notifications.background", "notifications.background-alpha", root.background, 1.0)
+    property color text: root.pick("notifications.text", root.foreground)
+    property color border: root.composed("notifications.border", "notifications.border-alpha", root.accent, 1.0)
+    property color countdown: root.pick("notifications.countdown", root.accent)
+  }
+  readonly property QtObject menu: QtObject {
+    property color background: root.composed("menu.background", "menu.background-alpha", root.background, 1.0)
+    property color text: root.pick("menu.text", root.foreground)
+    property color border: root.composed("menu.border", "menu.border-alpha", root.foreground, 1.0)
+    property color scrim: root.composed("menu.scrim", "menu.scrim-alpha", root.background, 0.5)
+    property color selectedBackground: root.composed("menu.selected-background", "menu.selected-background-alpha", root.foreground, 0.08)
+    property color selectedText: root.pick("menu.selected-text", root.accent)
+    property color selectedBorder: root.composed("menu.selected-border", "menu.selected-border-alpha", root.foreground, 0.0)
+  }
+  // polkit + lock share a single border-alpha across border / border-active /
+  // border-error: the three states are mutually exclusive in time, so one
+  // companion is enough.
+  readonly property QtObject polkit: QtObject {
+    property color background: root.composed("polkit.background", "polkit.background-alpha", root.background, 1.0)
+    property color text: root.pick("polkit.text", root.foreground)
+    property color textError: root.pick("polkit.text-error", root.urgent)
+    property color border: root.composed("polkit.border", "polkit.border-alpha", root.accent, 1.0)
+    property color borderError: root.composed("polkit.border-error", "polkit.border-alpha", root.urgent, 1.0)
+    property color accent: root.pick("polkit.accent", root.accent)
+    property color scrim: root.composed("polkit.scrim", "polkit.scrim-alpha", root.background, 0.5)
+  }
+  readonly property QtObject lock: QtObject {
+    property color background: root.composed("lock.background", "lock.background-alpha", root.background, 0.8)
+    property color text: root.pick("lock.text", root.foreground)
+    property color placeholder: root.shellValues["lock.placeholder"] ? root.flatColor(root.shellValues["lock.placeholder"], Util.alpha(root.foreground, 0.66)) : Util.alpha(root.foreground, 0.66)
+    property color textError: root.pick("lock.text-error", root.urgent)
+    property color border: root.composed("lock.border", "lock.border-alpha", root.foreground, 1.0)
+    property color borderActive: root.composed("lock.border-active", "lock.border-alpha", root.accent, 1.0)
+    property color borderError: root.composed("lock.border-error", "lock.border-alpha", root.urgent, 1.0)
+    property color selection: root.composed("lock.selection", "lock.selection-alpha", root.accent, 0.45)
+  }
+  // The image picker has no card surface or backdrop; per-slice dim
+  // overlays / text outlines use the foundational `background` color directly.
+  readonly property QtObject imagePicker: QtObject {
+    property color text: root.pick("image-picker.text", root.foreground)
+    property color selectedBorder: root.composed("image-picker.selected-border", "image-picker.selected-border-alpha", root.accent, 1.0)
+    property color unselectedBorder: root.composed("image-picker.unselected-border", "image-picker.unselected-border-alpha", root.foreground, 0.28)
+  }
+
+  function loadColors(raw) {
+    var lines = String(raw || "").split("\n")
+    var foundAccent = false
+    var foundMuted = false
+    var loadedForeground = false
+    var loadedBackground = false
+    var color0Value = ""
+    var color4Value = ""
+    var color7Value = ""
+    var color8Value = ""
+    for (var i = 0; i < lines.length; i++) {
+      var match = lines[i].match(/^\s*([A-Za-z0-9_-]+)\s*=\s*["']?(#[0-9A-Fa-f]{6})/)
+      if (!match) continue
+      if (match[1] === "foreground") { foreground = match[2]; loadedForeground = true }
+      else if (match[1] === "background") { background = match[2]; loadedBackground = true }
+      // Prefer the explicit `accent` key; only fall back to color4 when the
+      // theme doesn't define a separate accent. color4 appears later in the
+      // file so the old single-property approach clobbered accent with it.
+      else if (match[1] === "accent") { accent = match[2]; foundAccent = true }
+      else if (match[1] === "muted") { muted = match[2]; foundMuted = true }
+      else if (match[1] === "color0") color0Value = match[2]
+      else if (match[1] === "color4") color4Value = match[2]
+      else if (match[1] === "color7") color7Value = match[2]
+      else if (match[1] === "color8") color8Value = match[2]
+      else if (match[1] === "red" || match[1] === "color1") urgent = match[2]
+    }
+    if (!loadedBackground && color0Value.length > 0) background = color0Value
+    if (!loadedForeground && color7Value.length > 0) foreground = color7Value
+    if (!foundAccent && color4Value.length > 0) accent = color4Value
+    if (!foundMuted) muted = color8Value.length > 0 ? color8Value : foreground
+  }
+
+  // Last theme-supplied and user-supplied shell.toml dicts, kept separate so
+  // either can be reloaded without re-reading the other. `shellValues` is
+  // always the merge of theme (base) and user (override) — see mergeShell.
+  property var themeShellValues: ({})
+  property var userShellValues: ({})
+
+  // Single TOML walker for shell.toml. Both Color (surface roles) and Style
+  // (typography, spacing, bar, control states) consume the resulting dict.
+  // Accepts quoted strings, bare numeric values, bare width lists, and bare
+  // role names; tolerates inline comments. Numbers are kept as strings here —
+  // readers coerce when they pull a value.
+  function parseShell(raw) {
+    var parsed = {}
+    var text = String(raw || "")
+    if (text) {
+      var lines = text.split("\n")
+      var section = ""
+      for (var i = 0; i < lines.length; i++) {
+        var line = lines[i].replace(/^\s+|\s+$/g, "")
+        if (!line || line.charAt(0) === "#") continue
+        var sectionMatch = line.match(/^\[([A-Za-z0-9_-]+)\]\s*(#.*)?$/)
+        if (sectionMatch) { section = sectionMatch[1]; continue }
+        var stringKv = line.match(/^([A-Za-z0-9_-]+)\s*=\s*["']([^"']+)["']\s*(#.*)?$/)
+        var numKv = line.match(/^([A-Za-z0-9_-]+)\s*=\s*(-?\d+(?:\.\d+)?)\s*(#.*)?$/)
+        var widthKv = line.match(/^([A-Za-z0-9_-]+)\s*=\s*(-?\d+(?:\.\d+)?(?:\s+-?\d+(?:\.\d+)?){1,3})\s*(#.*)?$/)
+        var bareKv = line.match(/^([A-Za-z0-9_-]+)\s*=\s*([A-Za-z][A-Za-z0-9_-]*)\s*(#.*)?$/)
+        var kv = stringKv || numKv || widthKv || bareKv
+        if (!kv || !section) continue
+        parsed[section + "." + kv[1]] = kv[2]
+      }
+    }
+    return parsed
+  }
+
+  // Re-derive `shellValues` from theme base + user override and push it to
+  // Style. User keys win, so a machine-level `~/.config/omarchy/shell.toml`
+  // survives theme switches (which replace only themeShellValues).
+  function mergeShell() {
+    var merged = {}
+    for (var tk in themeShellValues) merged[tk] = themeShellValues[tk]
+    for (var uk in userShellValues) merged[uk] = userShellValues[uk]
+    shellValues = merged
+    Style.applyShellValues(merged)
+  }
+
+  function loadShell(raw) {
+    themeShellValues = parseShell(raw)
+    mergeShell()
+  }
+
+  function loadUserShell(raw) {
+    userShellValues = parseShell(raw)
+    mergeShell()
+  }
+
+  // Startup load only. Runtime theme switches push the payload explicitly
+  // through shell IPC.
+  property FileView colorsFile: FileView {
+    id: colorsFile
+    path: root.currentThemePath + "/colors.toml"
+    watchChanges: false
+    printErrors: false
+    onLoaded: root.loadColors(text())
+  }
+  property FileView shellFile: FileView {
+    id: shellFile
+    path: root.currentThemePath + "/shell.toml"
+    watchChanges: false
+    printErrors: false
+    onLoaded: root.loadShell(text())
+    onLoadFailed: root.loadShell("")
+  }
+  // Machine-level override, layered on top of whatever theme is active. This
+  // is where `omarchy display text size` writes `[font] base-size`. Watched so the
+  // CLI takes effect live without restarting the shell; absent by default.
+  property FileView userShellFile: FileView {
+    id: userShellFile
+    path: root.home + "/.config/omarchy/shell.toml"
+    watchChanges: true
+    printErrors: false
+    onLoaded: root.loadUserShell(text())
+    // Re-read on change (including first creation) before loading — `text()`
+    // is stale in the change signal itself, so route both paths through reload
+    // → onLoaded to always parse fresh content.
+    onFileChanged: reload()
+    onLoadFailed: root.loadUserShell("")
+  }
+}

package/test/fixtures/qml/flea-theme/imports/qs/Commons/I18n.qml

@@ -0,0 +1,118 @@
+pragma Singleton
+import QtQuick
+import Quickshell
+import Quickshell.Io
+import "Plural.js" as Plural
+import "Numbers.js" as Numbers
+
+// Display-language strings for the shell. The selected code lives in
+// ~/.config/omarchy/language (omarchy-language owns it); a missing file
+// means English. Strings come from default/i18n/<code>/shell.json layered
+// over the English catalog, so a missing translation falls back to English
+// per string. Use as I18n.t("common.search"), with .arg(...) for %1 holes,
+// and I18n.tn(key, count).arg(I18n.formatNumber(count)) for an
+// entry with plural forms.
+// The language file is watched, so switching language under Setup
+// re-renders the shell without a restart.
+QtObject {
+  id: root
+
+  readonly property string omarchyPath: Quickshell.env("OMARCHY_PATH")
+  readonly property string configHome: Quickshell.env("XDG_CONFIG_HOME") || (Quickshell.env("HOME") + "/.config")
+
+  readonly property string language: languageCode(languageFile.text())
+  readonly property var localeSettings: parseCatalog(registryFile.text())[root.language] || ({})
+  readonly property string formatLocale: localeSettings.formatLocale || "en-US"
+  // From the registry: how numbers are written and which way text runs.
+  readonly property string decimal: localeSettings.decimal || "."
+  readonly property string zeroDigit: localeSettings.zeroDigit || "0"
+  readonly property bool rightToLeft: localeSettings.direction === "rtl"
+
+  // Reading text() makes blockLoading take effect on the first lookup.
+  // These bindings also rebuild the maps when a watched catalog changes.
+  readonly property var englishStrings: parseCatalog(englishCatalogFile.text())
+  readonly property var languageStrings: parseCatalog(languageCatalogFile.text())
+  readonly property var strings: {
+    var merged = ({})
+    for (var k in root.englishStrings) merged[k] = root.englishStrings[k]
+    for (var k2 in root.languageStrings) merged[k2] = root.languageStrings[k2]
+    return merged
+  }
+
+  // The optional fallback is what imperative callers (the JS models) pass
+  // as their English text: for a key the catalogs do not carry, they keep
+  // sensible English instead of a raw key.
+  function t(key, fallback) {
+    var value = root.strings[key]
+    if (value && typeof value === "object") value = value.other
+    if (typeof value === "string" && value.length > 0) return value
+    return fallback !== undefined ? fallback : key
+  }
+
+  // The form of a plural entry for count, by the language's plural rules
+  // (Plural.js). The English entry answers when the translation has none.
+  function tn(key, count, fallback) {
+    var value = Plural.pick(root.languageStrings[key], root.language, count)
+    if (typeof value !== "string" || value.length === 0) value = Plural.pick(root.englishStrings[key], "en", count)
+    if (typeof value === "string" && value.length > 0) return value
+    return fallback !== undefined ? fallback : key
+  }
+
+  // A number with the language's decimal separator and digits, ungrouped:
+  // formatNumber(13.14, 1) is "13,1" in Danish. Pass decimals to round;
+  // without them the value is written as it is.
+  function formatNumber(value, decimals) {
+    return Numbers.format(value, decimals, root.decimal, root.zeroDigit)
+  }
+
+  function parseCatalog(raw) {
+    try {
+      var parsed = JSON.parse(raw || "{}")
+      return (parsed && typeof parsed === "object" && !Array.isArray(parsed)) ? parsed : ({})
+    } catch (e) {
+      return ({})
+    }
+  }
+
+  function languageCode(raw) {
+    var code = String(raw || "").trim()
+    if (!/^[a-z]{2,3}(-[A-Za-z]{2})?$/.test(code)) code = "en"
+    return code
+  }
+
+  // The catalogs are small local files, read synchronously so the first
+  // binding to call t() already gets the string rather than the raw key.
+  property FileView languageFile: FileView {
+    // OMARCHY_LANGUAGE_FILE overrides the location, as it does for
+    // omarchy-i18n, so tests can pin a language whatever the machine uses.
+    path: Quickshell.env("OMARCHY_LANGUAGE_FILE") || (root.configHome + "/omarchy/language")
+    watchChanges: true
+    printErrors: false
+    blockLoading: true
+    onFileChanged: reload()
+  }
+
+  property FileView englishCatalogFile: FileView {
+    path: root.omarchyPath + "/default/i18n/en/shell.json"
+    watchChanges: true
+    printErrors: false
+    blockLoading: true
+    onFileChanged: reload()
+  }
+
+  property FileView languageCatalogFile: FileView {
+    path: root.omarchyPath + "/default/i18n/" + root.language + "/shell.json"
+    watchChanges: true
+    printErrors: false
+    blockLoading: true
+    onFileChanged: reload()
+  }
+
+  property FileView registryFile: FileView {
+    path: root.omarchyPath + "/default/i18n/locales.json"
+    watchChanges: true
+    printErrors: false
+    blockLoading: true
+    onFileChanged: reload()
+  }
+}

package/test/fixtures/qml/flea-theme/imports/qs/Commons/Numbers.js

@@ -0,0 +1,19 @@
+// A number written with a language's decimal separator and digits from the
+// registry, ungrouped: format(13.14, 1, ",", "0") is "13,1". Without
+// decimals the value is written as it is. default/i18n/plural.jq's
+// localize_number does the same for omarchy-i18n.
+function format(value, decimals, decimal, zeroDigit) {
+  var number = Number(value)
+  if (!isFinite(number)) return String(value)
+  var text = decimals === undefined ? String(number) : number.toFixed(decimals)
+  if (decimal && decimal !== ".") text = text.replace(".", decimal)
+  if (zeroDigit && zeroDigit !== "0") {
+    var zero = zeroDigit.charCodeAt(0)
+    text = text.replace(/[0-9]/g, function(digit) { return String.fromCharCode(zero + digit.charCodeAt(0) - 48) })
+  }
+  return text
+}
+
+if (typeof module !== "undefined") {
+  module.exports = { format: format }
+}

package/test/fixtures/qml/flea-theme/imports/qs/Commons/Plural.js

@@ -0,0 +1,91 @@
+// CLDR cardinal plural categories for whole counts, per Omarchy language
+// code. A plural catalog entry is an object keyed by these categories
+// ({ "one": "%1 file", "other": "%1 files" }); every language needs "other",
+// plus whichever categories its counts can reach. default/i18n/plural.jq
+// holds the same rules for omarchy-i18n, and i18n-test.sh keeps the two
+// in agreement.
+
+function within(value, low, high) {
+  return value >= low && value <= high
+}
+
+function category(code, count) {
+  var n = Math.abs(Math.trunc(Number(count) || 0))
+  var n10 = n % 10
+  var n100 = n % 100
+  var millions = n !== 0 && n % 1000000 === 0
+
+  switch (String(code || "")) {
+  case "ja": case "ko": case "zh-CN": case "zh-TW": case "th": case "vi": case "id": case "ms":
+    return "other"
+  case "hi": case "bn": case "fa": case "si":
+    return n <= 1 ? "one" : "other"
+  case "fr": case "pt-BR":
+    return n <= 1 ? "one" : millions ? "many" : "other"
+  case "ca": case "es-MX": case "it": case "pt":
+    return n === 1 ? "one" : millions ? "many" : "other"
+  case "fil":
+    return (n10 === 4 || n10 === 6 || n10 === 9) ? "other" : "one"
+  case "is":
+    return n10 === 1 && n100 !== 11 ? "one" : "other"
+  case "cs": case "sk":
+    return n === 1 ? "one" : within(n, 2, 4) ? "few" : "other"
+  case "pl":
+    if (n === 1) return "one"
+    return within(n10, 2, 4) && !within(n100, 12, 14) ? "few" : "many"
+  case "ru": case "uk":
+    if (n10 === 1 && n100 !== 11) return "one"
+    return within(n10, 2, 4) && !within(n100, 12, 14) ? "few" : "many"
+  case "hr": case "sr":
+    if (n10 === 1 && n100 !== 11) return "one"
+    return within(n10, 2, 4) && !within(n100, 12, 14) ? "few" : "other"
+  case "sl":
+    if (n100 === 1) return "one"
+    if (n100 === 2) return "two"
+    return within(n100, 3, 4) ? "few" : "other"
+  case "lt":
+    if (within(n100, 11, 19)) return "other"
+    return n10 === 1 ? "one" : n10 >= 2 ? "few" : "other"
+  case "lv":
+    if (n10 === 0 || within(n100, 11, 19)) return "zero"
+    return n10 === 1 ? "one" : "other"
+  case "ro":
+    if (n === 1) return "one"
+    return n === 0 || within(n100, 1, 19) ? "few" : "other"
+  case "ar":
+    if (n <= 2) return ["zero", "one", "two"][n]
+    return within(n100, 3, 10) ? "few" : within(n100, 11, 99) ? "many" : "other"
+  case "he":
+    return n === 1 ? "one" : n === 2 ? "two" : "other"
+  case "ga":
+    if (n <= 2) return n === 0 ? "other" : n === 1 ? "one" : "two"
+    return within(n, 3, 6) ? "few" : within(n, 7, 10) ? "many" : "other"
+  default:
+    return n === 1 ? "one" : "other"
+  }
+}
+
+var ORDER = ["zero", "one", "two", "few", "many", "other"]
+
+// The categories a translation of a plural entry must provide.
+function categories(code) {
+  var seen = { other: true }
+  for (var n = 0; n <= 1000; n++) seen[category(code, n)] = true
+  seen[category(code, 1000000)] = true
+  return ORDER.filter(function(name) { return seen[name] })
+}
+
+// The string for a count from a plural entry, or the entry itself when it
+// is a plain string. A translation missing a category falls back to its
+// "other" form.
+function pick(entry, code, count) {
+  if (typeof entry === "string") return entry
+  if (!entry || typeof entry !== "object") return undefined
+  var form = entry[category(code, count)]
+  if (typeof form === "string" && form.length > 0) return form
+  return typeof entry.other === "string" ? entry.other : undefined
+}
+
+if (typeof module !== "undefined") {
+  module.exports = { category: category, categories: categories, pick: pick }
+}