@tangelo/tangelo-configuration-toolkit 1.6.0 → 1.8.0-beta.1

package/build/project/tangelo-default-implementation/src/config/cmscustom/[customer]/[project]/pdf/pdf_base/pages/table_of_contents.xsl

@@ -1,302 +0,0 @@
-<xsl:stylesheet version="2.0"
-                xmlns:xs="http://www.w3.org/2001/XMLSchema"
-                xmlns:fo="http://www.w3.org/1999/XSL/Format"
-                xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
-                xmlns:axf="http://www.antennahouse.com/names/XSL/Extensions"
-                xmlns:tfn="http://www.tangelo.nl/xslt-functions"
-                exclude-result-prefixes="#all"
-                >
-  
-  <!-- sub-toc creation for nodes which sectiontype name ends with '_CONTENTS' -->
-  <xsl:template match="node[tfn:matches(@sectionTypeName, '.*_CONTENTS')]/element()[1][not(self::node)]" priority="2">
-    <xsl:apply-templates select="title | subtitle | pdfInsertion"/>
-    <xsl:apply-templates select="ancestor::node[2]" mode="create-sub-toc">
-      <xsl:with-param name="ct" select="false()" tunnel="yes"/>
-      <xsl:with-param name="toc" select="true()" as="xs:boolean" tunnel="yes"/>
-    </xsl:apply-templates>
-  </xsl:template>
-  <xsl:template match="node" mode="create-sub-toc">
-    <!-- To create a sub-toc without a specific contents-node use: <xsl:apply-templates select="ancestor::node[1]" mode="create-sub-toc"> -->
-    <fo:block-container id="sub-toc-{@sectionId}" xsl:use-attribute-sets="toc-wrapper sub-toc-wrapper">
-      <fo:block start-indent="0mm" end-indent="0mm">
-        <xsl:apply-templates select="node" mode="toc"/>
-      </fo:block>
-    </fo:block-container>
-  </xsl:template>
-  
-  <!-- main-toc creation for nodes which sectiontype name equals 'CONTENTS' -->
-  <xsl:template match="node[tfn:matches(@sectionTypeName, 'CONTENTS')]/element()[1][not(self::node)]" priority="1">
-    <xsl:apply-templates select="title | subtitle | pdfInsertion"/>
-    <xsl:apply-templates select="ancestor::node[1]" mode="create-main-toc">
-      <xsl:with-param name="ct" select="false()" tunnel="yes"/>
-      <xsl:with-param name="toc" select="true()" as="xs:boolean" tunnel="yes"/>
-    </xsl:apply-templates>
-  </xsl:template>
-  <xsl:template match="node" mode="create-main-toc">
-    <fo:block-container id="main-toc-{@sectionId}" xsl:use-attribute-sets="toc-wrapper main-toc-wrapper">
-      <fo:block start-indent="0mm" end-indent="0mm">
-        <xsl:apply-templates select="ancestor-or-self::node[not(ancestor::node)]/node" mode="toc"/>
-      </fo:block>
-    </fo:block-container>
-  </xsl:template>
-
-  <!-- ++++++++++++++++++++++++++++++++++++++ -->
-  <!-- MODE TOC -->
-  
-  <!-- 1) check if the node should be rendered; if not rendered and $contents.descendToChildren descend to children -->
-  <xsl:template match="node" mode="toc" priority="15">
-    <xsl:param name="page-config" tunnel="yes"/>
-    <xsl:param name="section-style" tunnel="yes" as="xs:string" select="'default'"/>
-    
-    <xsl:choose>
-      <xsl:when test="tfn:withinToc(.,$page-config,$section-style)">
-        <xsl:next-match/>
-      </xsl:when>
-      <xsl:when test="$contents.descendToChildren">
-        <xsl:apply-templates select="node" mode="toc"/>
-      </xsl:when>
-    </xsl:choose>
-  </xsl:template>
-  
-  <!-- 2a) Render node in toc - block-container -->
-  <xsl:template match="node" mode="toc" priority="5">
-    <xsl:param name="page-config" tunnel="yes"/>
-    <xsl:param name="page.column-count" as="xs:integer" tunnel="yes"/>
-    <xsl:param name="section-style" tunnel="yes" as="xs:string" select="'default'"/>
-    <xsl:variable name="toc.title.style" as="element()*" select="tfn:get-toc-style($section-style,current(),$page.column-count)"/>
-    
-    <fo:block-container>
-      <xsl:copy-of select="$toc.title.style/container/@*"/>
-      <xsl:if test="not(preceding-sibling::node[tfn:withinToc(.,$page-config,$section-style)])"><xsl:copy-of select="$toc.title.style/container/first/@*"/></xsl:if>
-      <xsl:if test="not(following-sibling::node[tfn:withinToc(.,$page-config,$section-style)])"><xsl:copy-of select="$toc.title.style/container/last/@*"/></xsl:if>
-      <xsl:if test="not(node[tfn:withinToc(.,$page-config,$section-style)])"><xsl:copy-of select="$toc.title.style/container/no-children/@*"/></xsl:if>
-      
-      <xsl:next-match>
-        <xsl:with-param name="toc.title.style" select="$toc.title.style" as="element()" tunnel="yes"/>
-      </xsl:next-match>
-      <xsl:apply-templates select="node" mode="toc"/>
-    </fo:block-container>   
-  </xsl:template>
-
- 
-  <!-- 2b) Render node in toc - table -->
-  <xsl:template match="node" mode="toc">
-    <xsl:param name="section-style" as="xs:string" tunnel="yes"/>
-    <xsl:variable name="current-node" select="."/>
-    
-    <xsl:variable name="toc-item-rendering" as="element()*" select="tfn:get-toc-item-rendering(.,$section-style)"/>
-    <xsl:for-each select="$toc-item-rendering/row | $toc-item-rendering[not(row)]">
-      <fo:table start-indent="0mm" end-indent="0mm" table-layout="auto" width="100%">
-        <xsl:copy-of select="@*"/><!-- copy row attributes -->
-        <xsl:for-each select="column">
-          <fo:table-column>
-            <xsl:if test="@number"><xsl:attribute name="column-number"><xsl:value-of select="@number"/></xsl:attribute></xsl:if>
-            <xsl:if test="@width"><xsl:attribute name="column-width"><xsl:value-of select="@width"/></xsl:attribute></xsl:if>
-          </fo:table-column>
-        </xsl:for-each>
-        <fo:table-body>
-          <fo:table-row>
-            <xsl:for-each select="column">
-              <fo:table-cell>
-                <xsl:copy-of select="cell-attributes/@*"/>
-                <xsl:choose>
-                  <xsl:when test="@render='text'">
-                    <xsl:apply-templates select="text" mode="render-toc-text"/>
-                  </xsl:when>
-                  <xsl:when test="@render='page-number'">
-                    <xsl:apply-templates select="$current-node" mode="render-toc-page-number">
-                      <xsl:with-param name="column-config" select="." tunnel="yes" as="element()"/>
-                    </xsl:apply-templates>
-                  </xsl:when>
-                  <xsl:when test="@render='chapter-number'">
-                    <xsl:apply-templates select="$current-node" mode="render-toc-chapter-number">
-                      <xsl:with-param name="column-config" select="." tunnel="yes" as="element()"/>
-                    </xsl:apply-templates>
-                  </xsl:when>
-                  <xsl:when test="@render='title'">
-                    <xsl:apply-templates select="$current-node" mode="render-toc-title">
-                      <xsl:with-param name="column-config" select="." tunnel="yes" as="element()"/>
-                    </xsl:apply-templates>
-                  </xsl:when>
-                  <xsl:when test="@render='title-and-page-number'">
-                    <xsl:apply-templates select="$current-node" mode="title-and-page-number">
-                      <xsl:with-param name="column-config" select="." tunnel="yes" as="element()"/>
-                    </xsl:apply-templates>
-                  </xsl:when>
-                  <xsl:when test="@render='page-number-and-title'">
-                    <xsl:apply-templates select="$current-node" mode="page-number-and-title">
-                      <xsl:with-param name="column-config" select="." tunnel="yes" as="element()"/>
-                    </xsl:apply-templates>
-                  </xsl:when>
-                  <xsl:when test="@render='chapter-number-and-title'">
-                    <xsl:apply-templates select="$current-node" mode="chapter-number-and-title">
-                      <xsl:with-param name="column-config" select="." tunnel="yes" as="element()"/>
-                    </xsl:apply-templates>
-                  </xsl:when>
-                  <xsl:when test="@render='nothing'">
-                    <fo:block xsl:use-attribute-sets="clear-block"/>
-                  </xsl:when>
-                  <xsl:when test="@render='custom'">
-                    <xsl:apply-templates select="$current-node" mode="toc-item-rendering-custom">
-                      <xsl:with-param name="column-config" select="." tunnel="yes" as="element()"/>
-                    </xsl:apply-templates>
-                  </xsl:when>
-                  <xsl:otherwise>
-                    <fo:block xsl:use-attribute-sets="clear-block"/>
-                  </xsl:otherwise>
-                </xsl:choose>
-              </fo:table-cell>
-            </xsl:for-each>
-          </fo:table-row>
-        </fo:table-body>
-      </fo:table>
-    </xsl:for-each>
-  </xsl:template>
-  
-  <!-- c) toc item rendering: text | title | chapter-number | page-number -->
-  <xsl:template match="text" mode="render-toc-text">
-      <xsl:param name="toc.title.style" as="element()" tunnel="yes"/>
-      <fo:block>
-        <xsl:copy-of select="$toc.title.style/title/@*"/>
-        <xsl:copy-of select="$toc.title.style/title/text/@*"/>
-        <xsl:copy-of select="@*"/>
-          <fo:inline>
-            <xsl:copy-of select="$toc.title.style/title/text/inline/@*"/>
-            <xsl:apply-templates select="node()"/>
-          </fo:inline>
-        </fo:block>
-    </xsl:template>
-    
-  <xsl:template match="node" mode="render-toc-page-number">
-    <xsl:param name="toc.title.style" as="element()" tunnel="yes"/>
-      
-    <fo:block>
-      <xsl:copy-of select="$toc.title.style/title/@*"/>       
-      <xsl:copy-of select="$toc.title.style/title/page-nr/@*"/>
-      <fo:basic-link>
-        <xsl:attribute name="internal-destination">
-          <xsl:apply-templates mode="get-node-id" select="."/>
-        </xsl:attribute>
-        <fo:inline>
-          <xsl:copy-of select="$toc.title.style/title/page-nr/inline/@*"/>
-          <xsl:apply-templates select="." mode="get-node-pagenr"/>
-        </fo:inline>
-      </fo:basic-link>
-    </fo:block>
-  </xsl:template>
-  <xsl:template match="node" mode="render-toc-chapter-number">
-    <xsl:param name="toc.title.style" as="element()" tunnel="yes"/>
-    
-    <fo:block>
-      <xsl:copy-of select="$toc.title.style/title/@*"/>
-      <xsl:copy-of select="$toc.title.style/title/chapter-nr/@*"/>
-
-      <xsl:variable name="chapter-nr">
-        <xsl:apply-templates select="." mode="get-node-chapternr"/>
-      </xsl:variable>
-      <xsl:if test="$chapter-nr != ''">
-        <fo:basic-link>
-          <xsl:attribute name="internal-destination">
-            <xsl:apply-templates mode="get-node-id" select="."/>
-          </xsl:attribute>
-          <fo:inline>
-            <xsl:copy-of select="$toc.title.style/title/chapter-nr/inline/@*"/>
-            <xsl:copy-of select="$chapter-nr"/>
-          </fo:inline>
-        </fo:basic-link>
-      </xsl:if>
-    </fo:block>
-  </xsl:template>
-  <xsl:template match="node" mode="render-toc-title">
-    <xsl:param name="toc.title.style" as="element()" tunnel="yes"/>
-    <xsl:param name="column-config" as="element()" tunnel="yes" select="."/>
-    <xsl:param name="title.prefix"/>
-    <xsl:param name="title.suffix"/>
-    
-    <fo:block>
-      <xsl:if test="$column-config/leader">
-        <xsl:attribute name="text-align-last">justify</xsl:attribute>
-      </xsl:if>
-      <xsl:copy-of select="$toc.title.style/title/@*"/>
-        
-      <fo:basic-link>
-        <xsl:attribute name="internal-destination">
-          <xsl:apply-templates mode="get-node-id" select="."/>
-        </xsl:attribute>
-              
-        <xsl:copy-of select="$title.prefix"/>
-        <xsl:apply-templates select="(*/tocTitle,*/title)[1]" mode="toc"/>
-        <xsl:if test="$column-config/leader">
-          <fo:leader>
-            <xsl:copy-of select="$column-config/leader/@*"/>
-          </fo:leader>
-        </xsl:if>
-        <xsl:copy-of select="$title.suffix"/>
-      </fo:basic-link>
-        
-    </fo:block>
-  </xsl:template>
-  <xsl:template match="node" mode="title-and-page-number">
-    <xsl:param name="toc.title.style" as="element()" tunnel="yes"/>
-    <xsl:apply-templates select="." mode="render-toc-title">
-      <xsl:with-param name="title.suffix">
-        <xsl:copy-of select="$toc.title.style/title/suffix/text()"/>
-        <fo:inline>
-          <xsl:copy-of select="$toc.title.style/title/page-nr/@*"/>
-          <xsl:apply-templates select="." mode="get-node-pagenr"/>
-        </fo:inline>
-      </xsl:with-param>
-    </xsl:apply-templates>
-  </xsl:template>
-  
-  <xsl:template match="node" mode="page-number-and-title">
-    <xsl:param name="toc.title.style" as="element()" tunnel="yes"/>
-    <xsl:apply-templates select="." mode="render-toc-title">
-      <xsl:with-param name="title.prefix">
-        <fo:inline>
-          <xsl:copy-of select="$toc.title.style/title/page-nr/@*"/>
-          <xsl:apply-templates select="." mode="get-node-pagenr"/>
-        </fo:inline>
-        <xsl:copy-of select="$toc.title.style/title/prefix/text()"/>
-      </xsl:with-param>
-    </xsl:apply-templates>
-  </xsl:template>
-  
-  <xsl:template match="node" mode="chapter-number-and-title">
-    <xsl:param name="toc.title.style" as="element()" tunnel="yes"/>
-    <xsl:apply-templates select="." mode="render-toc-title">
-      <xsl:with-param name="title.prefix">
-        <xsl:variable name="chapter-nr">
-          <xsl:apply-templates select="." mode="get-node-chapternr"/>
-        </xsl:variable>
-        <xsl:if test="$chapter-nr != ''">
-          <fo:inline>
-            <xsl:copy-of select="$toc.title.style/title/chapter-nr/@*"/>
-            <xsl:copy-of select="$chapter-nr"/>
-            <xsl:text>&#160;</xsl:text>
-          </fo:inline>
-          <fo:inline axf:indent-here="0pt"/>
-        </xsl:if>
-      </xsl:with-param>
-    </xsl:apply-templates>
-  </xsl:template>
-
-  <!-- d) Render the toc-title -->
-  <xsl:template match="node/*/tocTitle" mode="toc">
-    <xsl:apply-templates select="node()"/><!-- DO apply br's -->
-  </xsl:template>
-  <xsl:template match="node/*/title" mode="toc">
-    <xsl:apply-templates select="node()" mode="no-br"/>
-  </xsl:template>
-
-
-  <!-- ++++++++++++++++++++++++++++++++++++++ -->
-  <!-- part/node table of contents generation -->
-  <xsl:template match="node[tfn:pdftype-is('node|part') and ancestor::toc]" priority="1" mode="get-node-chapternr">
-    <xsl:value-of select="@paragraphCode"/>
-  </xsl:template>
-  <xsl:template match="node[tfn:pdftype-is('node|part') and ancestor::toc]" priority="1" mode="get-node-pagenr">
-    <xsl:text>##</xsl:text>
-  </xsl:template>
-  <!-- ++++++++++++++++++++++++++++++++++++++ -->
-</xsl:stylesheet>

package/build/project/tangelo-default-implementation/src/config/cmscustom/[customer]/[project]/pdf/pdf_base/parameters.xsl

@@ -1,206 +0,0 @@
-<xsl:stylesheet exclude-result-prefixes="#all" version="2.0" xmlns:axf="http://www.antennahouse.com/names/XSL/Extensions" xmlns:fo="http://www.w3.org/1999/XSL/Format" xmlns:tfn="http://www.tangelo.nl/xslt-functions" xmlns:xs="http://www.w3.org/2001/XMLSchema" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
-  
-  <xsl:include href="page-config.xsl"/>
-  <xsl:include href="../../../../tdi/pdf/pdf_base/_parameters.xsl"/>
-  
-  <xsl:function name="tfn:get-parameter" as="xs:string?">
-    <xsl:param name="name" as="xs:string"/>
-    <xsl:param name="default" as="xs:string?"/>
-    <xsl:value-of select="if ($parameters/param[@name=$name]) then $parameters/param[@name=$name]/@value else $default"/>
-  </xsl:function>
-  
-  <!-- input XML configs -->
-  <xsl:param name="resource.folder" select="concat(resolve-uri('../resources'),'/')"/>  
-  <xsl:param name="pdf-config" as="element()">
-    <xsl:apply-templates select="document('../config/_config.xml')/pdf_config" mode="page-config"/>
-  </xsl:param>
-  <xsl:param name="colors" select="document('../config/_colors.xml')/colors"/>
-  <xsl:variable name="pages" select="$pdf-config/pages"/>
-  <xsl:variable name="document-structure" select="$pdf-config/document-structure"/>
-  <xsl:variable name="footnote-settings" select="$pdf-config/footnotes"/>
-  
-  <!-- (suitable for) User input parameters -->
-  <xsl:param name="isEcoPDF"   as="xs:string" select="'false'"/>
-  <xsl:param name="cropmarks"  as="xs:string" select="if ($pdf-quality='high') then 'true' else 'false'"/>
-  <xsl:param name="comments"   as="xs:string" select="if ($pdf-quality='high') then 'false' else 'true'"/>
-  <xsl:param name="trackchanges" as="xs:string" select="'false'"/>
-  <xsl:param name="trackchanges.mode" as="xs:string" select="tfn:get-parameter('trackchanges.mode','default')"/><!-- default|blacklining -->
-  <xsl:param name="xfiMarking" as="xs:string" select="'false'"/>
-  <xsl:variable name="xfiMarking.enabled" as="xs:boolean" select="$xfiMarking='true'"/>
-  
-  <!-- Other input parameters -->
-  <xsl:param name="hcepath"/>
-  <xsl:param name="log-until-date" as="xs:date" select="xs:date('2018-01-01')"/>
-  <xsl:param name="log-user" as="xs:string" select="'ANY'"/>  
-  <xsl:param name="debug-user" as="xs:string" select="$log-user[.!='ANY']"/>
-  <xsl:param name="output-files" as="xs:boolean" select="$log-until-date &gt;= current-date() and $log-user[.='ANY' or upper-case(.)=$userName] and not($local-transformation)"/>  
-  <xsl:param name="debug" as="xs:boolean" select="$log-until-date &gt;= current-date() and $log-user[.='ANY' or upper-case(.)=$userName]"/>
-  <xsl:param name="local-transformation" as="xs:boolean" select="false()"/>
-  <xsl:param name="pdftype" as="xs:string" select="'document'"/><!-- document | part | node -->
-  <xsl:param name="txmpath"/>
-  <xsl:param name="tantxmpath" select="$txmpath"/>
-  <xsl:param name="pdf-quality" as="xs:string" select="'low'"/>
-  <xsl:param name="pdf-colorspace" as="xs:string" select="'cmyk'"/>
-  <xsl:param name="colors.output-pantone" as="xs:boolean" select="tfn:get-parameter('colors.output-pantone','true')='true'"/>
-  <xsl:param name="document-xml" as="element(document)" select="/document"/>
-  <xsl:param name="password.owner" as="xs:string?"><!-- for security settings of document --></xsl:param>
-  <xsl:param name="password.user"  as="xs:string?"><!-- for opening document --></xsl:param>
-  
-  <!-- variables -->
-  <xsl:variable name="cropmarks.enabled"   as="xs:boolean" select="$cropmarks='true'"/>
-  <xsl:variable name="current-date"        as="xs:date"    select="current-date()"/>
-  <xsl:variable name="current-time"        as="xs:time"    select="current-time()"/>
-  <xsl:variable name="default.page-width"  as="xs:double"  select="if ($pages/@page-width)  then $pages/@page-width  else 210"/>
-  <xsl:variable name="default.page-height" as="xs:double"  select="if ($pages/@page-height) then $pages/@page-height else 297"/>
-  <xsl:variable name="document.language"   as="xs:string"  select="/document/@locale"/>
-  <xsl:variable name="documentId"          as="xs:string?" select="/document/@id"/>
-  <xsl:variable name="documentVersionId"   as="xs:string?" select="/document/version/@id"/>
-  <xsl:variable name="parameters"          as="element()"  select="$pdf-config/parameters"/>
-  <xsl:variable name="pxpi"                as="xs:integer" select="96"/>
-  <xsl:variable name="userName"            as="xs:string"  select="upper-case(/document/@userName)"/>  
-  
-  <xsl:variable name="cropmarks.width" as="xs:double" select="xs:double(tfn:get-parameter('cropmarks.width','3'))"/>
-  <xsl:variable name="xfiMarking-color" as="xs:string" select="tfn:get-parameter('xfiMarking-color','#35dba9')"/>
-  <xsl:variable name="hce.chartTypeName" as="xs:string" select="tfn:get-parameter('hce.chartTypeName','default-chart-config')"/> 
-  <xsl:variable name="trackchanges.enabled" as="xs:boolean" select="$trackchanges='true'"/>
-  <xsl:variable name="date-format-picture" as="xs:string" select="'[D01]/[M01]/[Y0001]'"/>
-  <xsl:variable name="dateTime-format-picture" as="xs:string" select="'[D01]/[M01]/[Y0001] [h1]:[m01]'"/>
-  <xsl:variable name="comments.enabled" as="xs:boolean" select="$comments='true'"/>
-  <xsl:variable name="contents.descendToChildren" as="xs:boolean" select="tfn:get-parameter('contents.descendToChildren','false')='true'"/>
-  <xsl:variable name="trackchange-add-color" as="xs:string*" select="tfn:get-parameter('trackchange-add-color','green')"/>
-  <xsl:variable name="trackchange-remove-color" as="xs:string*" select="tfn:get-parameter('trackchange-remove-color','red')"/>
-  <xsl:variable name="custom-object-positioning-elements" as="xs:string*" select="tokenize(tfn:get-parameter('custom-object-positioning-elements',null),',')"/>
-  <xsl:variable name="object-positioning-ancestor-elements" as="xs:string*" select="tokenize(tfn:get-parameter('object-positioning-ancestor-elements',null),',')"/>
-  <xsl:variable name="backgroundContent.backgroundColor" as="xs:string" select="tfn:get-parameter('backgroundContent.backgroundColor','transparent')"/>
-  <xsl:variable name="pdfInsertion.scale" as="xs:boolean" select="tfn:get-parameter('pdfInsertion.scale','false')='true'"/>
-  <xsl:variable name="table-caption-position" as="xs:string" select="tfn:get-parameter('table-caption-position','before-footnotes')"/>
-  <xsl:variable name="table.keepTogether.default" as="xs:boolean" select="tfn:get-parameter('table.keepTogether.default','false')='true'"/>
-  <xsl:variable name="table.column.width" as="xs:string" select="tfn:get-parameter('table.column.width','normalize')"/>
-  <xsl:variable name="table.allow.brackets.first.column" as="xs:boolean" select="tfn:get-parameter('table.allow.brackets.first.column','false')='true'"/>
-  <xsl:variable name="handle-table-footnote" as="xs:string" select="tfn:get-parameter('handle-table-footnote','table-footnote')"/>
-  <xsl:variable name="handle-chart-footnote" as="xs:string" select="tfn:get-parameter('handle-chart-footnote','chart-footnote')"/>
-  <xsl:variable name="repeat-title-space-on-page-split" as="xs:boolean" select="tfn:get-parameter('repeat-title-space-on-page-split','true')='true'"/>
-  <xsl:variable name="color-profile" as="xs:string?" select="tfn:get-parameter('color-profile',null)"/><!--Note that the color profile .icc file must be added to the resource.folder -->
-  <xsl:variable name="bookmark.collapse.level" as="xs:integer" select="xs:integer(tfn:get-parameter('bookmark.collapse.level','2'))"/>
-  <xsl:variable name="chapter.number-suffix" as="xs:string?" select="tfn:get-parameter('chapter.number-suffix',null)"/>
-  <xsl:variable name="table.negativeNumbers.brackets" as="xs:boolean" select="tfn:get-parameter('table.negativeNumbers.brackets','false')='true'"/>
-  <xsl:variable name="table.bracket.width" as="xs:double" select="xs:double(tfn:get-parameter('table.bracket.width','1'))"/>
-  <xsl:variable name="table.apply.footnote.spacing" as="xs:boolean" select="tfn:get-parameter('table.apply.footnote.spacing','true')='true'"/>
-  <xsl:variable name="table.footnote.width" as="xs:double" select="xs:double(tfn:get-parameter('table.footnote.width','1'))"/>
-  <xsl:variable name="table.continue-next-marker" as="xs:boolean" select="tfn:get-parameter('table.continue-next-marker','false')='true'"/>
-  <xsl:variable name="table.continuation-previous-marker" as="xs:boolean" select="tfn:get-parameter('table.continuation-previous-marker','false')='true'"/>
-  <xsl:variable name="show-landscape-in-PDF" as="xs:boolean" select="tfn:get-parameter('show-landscape-in-PDF','false')='true'"/>
-  <xsl:variable name="balance-multi-column-pages" as="xs:boolean" select="tfn:get-parameter('balance-multi-column-pages','false')='true'"/>
-  <xsl:variable name="image.hidden.preserves.space" as="xs:boolean" select="tfn:get-parameter('image.hidden.preserves.space','false')='true'"/>
-  <xsl:variable name="image.render-alt-text" as="xs:boolean" select="tfn:get-parameter('image.render-alt-text','false')='true'"/>
-  <xsl:variable name="crop-image-to-multiple" as="xs:boolean" select="tfn:get-parameter('crop-image-to-multiple','true')='true'"/>
-  <xsl:variable name="crop-image-to-multiple.size" as="xs:string" select="tfn:get-parameter('crop-image-to-multiple.size',concat($line-height.default,'pt'))"/>
-  <xsl:variable name="render-within-pdftype.bookmarks" as="xs:string" select="tfn:get-parameter('render-within-pdftype.bookmarks','document|part')"/><!-- Allowed values: document|part|node|skip, multiple values are allowed (separated by '|') -->
-  <xsl:variable name="autospan.singleParagraph" as="xs:boolean" select="tfn:get-parameter('autospan.singleParagraph','true')='true'"/>
-  <xsl:variable name="autospan.titles" as="xs:boolean" select="tfn:get-parameter('autospan.titles','true')='true'"/>
-  <xsl:variable name="autospan.headers" as="xs:boolean" select="tfn:get-parameter('autospan.headers','true')='true'"/>
-  <xsl:variable name="use-ah-footnotes" as="xs:boolean" select="tfn:get-parameter('use-ah-footnotes','true')='true'"/>
-  <xsl:variable name="static-content-use-sequence" as="xs:boolean" select="tfn:get-parameter('static-content-use-sequence','false')='true'"/>
-  <xsl:param name="apply-settings-to-string-regex" as="xs:string" select="tfn:get-parameter('apply-settings-to-string-regex',null)">
-    <!-- Use multiple regular expression within brackets and separated by | -->
-    <!-- For example: 
-      (regex1)|(regex2)|(regex3)
-      -->
-    <!-- For example, to match a euro-sign followed by a normal space specify: 
-      (&#8364;&#32;)
-     This will be replaced by the base stylesheets for: '&#8364;&#160;'
-      -->
-    <!-- Other regular expressions will be automaticly replaced by:
-     <fo:inline keep-together-within-line>{$matched-substring}</fo:inline>
-      -->
-    <!-- Customizations can be realised by overiding the function 'tfn:apply-settings-to-string' -->
-  </xsl:param>  
-  <xsl:variable name="numberedListLevel" as="xs:string" select="tfn:get-parameter('numberedListLevel','single')"/>
-  <xsl:variable name="use-baseline-grid" as="xs:boolean" select="tfn:get-parameter('use-baseline-grid','false')='true'"/>
-  <xsl:param    name="baselinegridLayer.offset" as="xs:string" select="tfn:get-parameter('baselinegridLayer.offset','0pt')"/>
-  <xsl:param    name="baselinegridLayer.relativeTo" as="xs:string" select="tfn:get-parameter('baselinegridLayer.relativeTo','top margin')"/>
-
-  <xsl:param name="table-layout" as="xs:string" select="tfn:get-parameter('table-layout','auto')">
-    <!-- If using proportional-column-width() for at least one column => despite this setting the table is handled as fixed -->
-    <!-- more info: http://antennahouse.com/product/ahf60/docs/ahf-tech.html#table-auto-layout -->
-  </xsl:param>
-  <xsl:param name="table.width.default" as="xs:double" select="xs:double(tfn:get-parameter('table.width.default','100'))"/>
-
-  <xsl:param name="tableWidthCalcUntilRow" as="xs:integer" select="xs:integer(tfn:get-parameter('tableWidthCalcUntilRow','3'))"/>
-
-  <xsl:param name="node-chapternr-suffix" as="xs:string" select="tfn:get-parameter('node-chapternr-suffix','.')"/>
-  
-  <xsl:param name="pdf.pagelayout">
-    <!-- used in pdf_page_def.xsl > create-declarations-->
-    <!--AH-only-->
-    <xsl:choose>
-      <xsl:when test="$parameters/param[@name='initview.pagelayout.document'] and tfn:pdftype-is('document')">
-        <xsl:value-of select="$parameters/param[@name='initview.pagelayout.document']/@value"/>
-      </xsl:when>
-      <xsl:when test="$parameters/param[@name='initview.pagelayout.part'] and tfn:pdftype-is('part')">
-        <xsl:value-of select="$parameters/param[@name='initview.pagelayout.part']/@value"/>
-      </xsl:when>
-      <xsl:when test="$parameters/param[@name='initview.pagelayout.node'] and tfn:pdftype-is('node')">
-        <xsl:value-of select="$parameters/param[@name='initview.pagelayout.node']/@value"/>
-      </xsl:when>
-      <xsl:when test="tfn:pdftype-is('document')">TwoPageRight</xsl:when>
-      <!-- TwoPageRight: Start coverpage as single page and continue with 2 pages next to each other -->
-      <xsl:when test="tfn:pdftype-is('part')">TwoPageRight</xsl:when>
-      <!-- TwoPageRight: Start chapter-coverpage as single page and continue with 2 pages next to each other; change in paramters if not applicable -->
-      <xsl:when test="tfn:pdftype-is('node')">TwoPageLeft</xsl:when>
-      <!-- TwoPageLeft: Singlenode pdf has no coverpage page most of the time; hence TwoPageLeft is often the best default choice -->
-      <xsl:otherwise>SinglePage</xsl:otherwise>
-    </xsl:choose>
-  </xsl:param>
-  <xsl:param name="missing.color" as="xs:string" select="tfn:get-parameter('missing.color','yellow')"/>
-
-<!-- reconsider below -->
-  <xsl:param as="xs:double" name="float-margin-x" select="xs:double(tfn:get-parameter('float-margin-x',xs:string(tfn:convert($line-height.default, 'pt', 'mm'))))"/>
-  <xsl:param as="xs:double" name="float-float-margin-x">
-    <!-- margin between floats in mm (!) -->
-    <xsl:choose>
-      <xsl:when test="$parameters/param[@name='float-float-margin-x']">
-        <xsl:value-of select="$parameters/param[@name='float-float-margin-x']/@value"/>
-      </xsl:when>
-      <xsl:otherwise>
-        <xsl:value-of select="$float-margin-x"/>
-      </xsl:otherwise>
-    </xsl:choose>
-  </xsl:param>
-  <xsl:param as="xs:double" name="float-margin-y">
-    <!-- margin between float and text in mm (!) -->
-    <xsl:choose>
-      <xsl:when test="$parameters/param[@name='float-margin-y']">
-        <xsl:value-of select="$parameters/param[@name='float-margin-y']/@value"/>
-      </xsl:when>
-      <xsl:otherwise>
-        <xsl:value-of select="tfn:convert($line-height.default, 'pt', 'mm')"/>
-      </xsl:otherwise>
-    </xsl:choose>
-  </xsl:param>
-  <xsl:param as="xs:double" name="float-float-margin-y">
-    <!-- margin between floats in mm (!) -->
-    <xsl:choose>
-      <xsl:when test="$parameters/param[@name='float-float-margin-y']">
-        <xsl:value-of select="$parameters/param[@name='float-float-margin-y']/@value"/>
-      </xsl:when>
-      <xsl:otherwise>
-        <xsl:value-of select="$float-margin-y"/>
-      </xsl:otherwise>
-    </xsl:choose>
-  </xsl:param>
-  <xsl:param name="line-height.default" as="xs:double" select="12"/>
-  <xsl:param name="font-size.default"  as="xs:double" select="10"/>
-  <xsl:param name="font-size.table" as="xs:double" select="$font-size.default"/>
-  <xsl:param name="line-height.table" as="xs:double" select="$line-height.default"/>
-  
-  <xsl:variable name="tn-static-strings" select="$static-strings, document('../../../../tdi/pdf/config/_static_strings.xml')/strings"/>
-  <xsl:variable name="page-sequence-sectionNames" as="xs:string*" select="distinct-values($document-structure/pages/sectionType/@name)"><!-- todo extend with level=0,1,2, settings--></xsl:variable>
-  
-  <xsl:variable name="xmp-filename" select="concat($current-time,'-',generate-id($document-xml),'.xmp')" as="xs:string"/>
-  <xsl:param name="xmp-file.enabled" as="xs:boolean" select="tfn:get-parameter('xmp-file.enabled','false')='true'"/>
-  <xsl:param name="xmp-file-folder" select="concat($resource.folder,'../../../../../txd_pdf/temp/')"/>
-  
-  <xsl:param name="partpdf-contents-rendering"       select="/document/@partpdf-contents='true'" as="xs:boolean"/>
-  <xsl:param name="partpdf-contents-sectionTypeName" select="/document/@partpdf-contents-sectionTypeName" as="xs:string?"/>
-</xsl:stylesheet>

package/build/project/tangelo-default-implementation/src/config/cmscustom/[customer]/[project]/pdf/pdf_base/post-process/_post-process.xsl

@@ -1,81 +0,0 @@
-<xsl:stylesheet version="2.0"  
-                xmlns:xs="http://www.w3.org/2001/XMLSchema" 
-                xmlns:fo="http://www.w3.org/1999/XSL/Format" 
-                xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
-                xmlns:axf="http://www.antennahouse.com/names/XSL/Extensions"
-                xmlns:tfn="http://www.tangelo.nl/xslt-functions"
-                xmlns:fn="http://www.w3.org/2005/xpath-functions"
-                xmlns:post="http://www.tangelo.nl/post-proces"
-                exclude-result-prefixes="#all"
-                >   
-  
-  <xsl:include href="../parameters.xsl"/>
-  <xsl:include href="../functions/general.xsl"/>
-  <xsl:include href="../functions/colors.xsl"/> 
-  
-  <xsl:include href="../../../../../tdi/pdf/pdf_base/postproces.xsl"/>
-    
-  <!-- root template match -->
-  <xsl:template match="/">
-    <xsl:if test="$output-files">
-      <xsl:call-template name="output-xml">
-        <xsl:with-param name="xmlNode" select="/*"/>
-        <xsl:with-param name="filename" select="'2. output-xslfo-part'"/>
-      </xsl:call-template>
-      <xsl:call-template name="output-xml">
-        <xsl:with-param name="xmlNode">
-          <xsl:apply-templates select="document/node()" mode="post-proces"/>
-        </xsl:with-param>
-        <xsl:with-param name="filename" select="'3. output-xslfo-final'"/>
-      </xsl:call-template>
-    </xsl:if>
-    <xsl:apply-templates select="document/node()" mode="post-proces"/>
-  </xsl:template> 
-  
-  <xsl:template match="fo:inline/@post:baseline-correction" mode="post-proces" priority="1">
-    <xsl:if test="$use-baseline-grid and not(../../parent::*[not(@axf:baseline-grid='new')]/ancestor::*[@axf:baseline-grid][1][@axf:baseline-grid='none'])">
-      <xsl:attribute name="baseline-shift" select="string-join((concat('(-1 * ',.,')'),../@baseline-shift),' + ')"/>
-    </xsl:if>
-  </xsl:template>
-  <xsl:template match="@post:baseline-correction" mode="post-proces">
-    <xsl:if test="$use-baseline-grid and not(../parent::*[not(@axf:baseline-grid='new')]/ancestor::*[@axf:baseline-grid][1][@axf:baseline-grid='none'])">
-      <xsl:attribute name="margin-top" select="string-join((.,../@margin-top),' + ')"/>
-    </xsl:if>
-  </xsl:template>
-  
-  <xsl:template match="element()[not(self::post:*)][following-sibling::*[not(self::post:*) or self::post:endOfNodeId][1][self::post:endOfNodeId]]" mode="post-proces">
-    <xsl:variable name="endOfNodeId" select="following-sibling::*[1][self::post:endOfNodeId]/@id"/>
-    
-    <xsl:copy>
-      <xsl:if test="not(@id)">
-        <xsl:attribute name="id" select="$endOfNodeId"/>
-      </xsl:if>
-      <xsl:apply-templates select="node()|@*" mode="post-proces"/>
-      <xsl:if test="@id and not(self::fo:page-sequence)">
-        <fo:block-container position="absolute" height="0mm">
-          <fo:block font-size="0pt" line-height="0pt" id="{$endOfNodeId}"/>
-        </fo:block-container>
-      </xsl:if>
-    </xsl:copy>
-  </xsl:template>
-  
-  <xsl:template match="post:endOfNodeId" mode="post-proces"/>
-  
-  <xsl:template match="fo:page-sequence[fo:flow/*[1][self::fo:page-sequence]]" mode="post-proces">
-    <xsl:apply-templates select="fo:flow/*[1][self::fo:page-sequence[not(preceding-sibling::*[not(fo:page-sequence)])]]" mode="post-proces"/>
-    <xsl:copy>
-      <xsl:apply-templates select="@*" mode="post-proces"/>
-      <xsl:apply-templates select="*[not(self::fo:flow)]" mode="post-proces"/>
-      <fo:flow>
-        <xsl:apply-templates select="fo:flow/@*" mode="post-proces"/>
-        <xsl:apply-templates select="fo:flow/*[not(self::fo:page-sequence[not(preceding-sibling::*[not(fo:page-sequence)])])]" mode="post-proces"/>
-      </fo:flow>
-    </xsl:copy>
-  </xsl:template>
-  
-  <xsl:template match="post:consider-float-boundary" mode="post-proces">
-    <xsl:if test="parent::fo:flow and preceding-sibling::element()[not(@position='absolute') and not(self::fo:float)][1][not(self::fo:page-sequence) and not(@break-after!='auto')]">
-      <fo:float axf:float-x="end" axf:float-y="after" axf:float-move="keep-float" axf:float-reference="page"/>
-    </xsl:if>
-  </xsl:template>
-</xsl:stylesheet>