@tangelo/tangelo-configuration-toolkit 1.6.0 → 1.8.0-beta.1

package/build/project/config/cmscustom/tangelo/default/pdf/root-download.xsl

@@ -1,20 +0,0 @@
-<xsl:stylesheet version="2.0"
-                xmlns:xs="http://www.w3.org/2001/XMLSchema"
-                xmlns:fo="http://www.w3.org/1999/XSL/Format"
-                xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
-                xmlns:tfn="http://www.tangelo.nl/xslt-functions"
-                exclude-result-prefixes="#all"
-                >
-
-  <!-- Include base stylesheets -->
-  <xsl:import href="pdf_base/base.xsl"/>
-
-  <!-- specify which config files should be used  -->
-  <xsl:import href="config/base.xsl"/>
-
-  <xsl:include href="_general-settings.xsl"/>
-
-  <xsl:param name="pdf-quality" as="xs:string" select="'low'"/>
-  <xsl:param name="pdf-colorspace" as="xs:string" select="'cmyk'"/>
-
-</xsl:stylesheet>

package/build/project/config/cmscustom/tangelo/default/pdf/root-print.xsl

@@ -1,21 +0,0 @@
-<xsl:stylesheet version="2.0"
-                       xmlns:xs="http://www.w3.org/2001/XMLSchema"
-                       xmlns:fo="http://www.w3.org/1999/XSL/Format"
-                       xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
-                       xmlns:tfn="http://www.tangelo.nl/xslt-functions"
-                       exclude-result-prefixes="#all"
-                       >
-
-  <!-- Include base stylesheets -->
-  <xsl:import href="pdf_base/base.xsl"/>
-
-  <!-- specify which config files should be used  -->
-  <xsl:import href="config/base.xsl"/>
-
-  <xsl:include href="_general-settings.xsl"/>
-
-  <!-- preset the parameters: (can still be overruled when set in Tangelo) -->
-  <xsl:param name="pdf-quality" as="xs:string" select="'high'"/>
-  <xsl:param name="pdf-colorspace" as="xs:string" select="'cmyk'"/>
-
-</xsl:stylesheet>

package/build/project/config/cmscustom/tangelo/default/pre-process/_auto_create_note_sectionlinks.xsl

@@ -1,49 +0,0 @@
-<xsl:stylesheet version="2.0" exclude-result-prefixes="#all"
-  xmlns:xs="http://www.w3.org/2001/XMLSchema"
-  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
-  xmlns:tfn="http://www.tangelo.nl/xslt-functions"
-  >
-
-  <xsl:variable name="txp-toc" as="element(toc)?" select="/*/page/toc"/>
-  <xsl:template match="td[@format='notes']/p//text()" priority="5">
-
-    <xsl:variable name="currentSectionId" as="xs:string" select="ancestor::node[1]/@sectionId"/>
-    <xsl:variable name="currentNode" as="element(node)?" select="
-      if ($txp-toc) then $txp-toc/descendant::node[@sectionId = $currentSectionId] (: Tangelo 4.2.2+ :)
-      else               ancestor::node[1]"/>
-
-    <xsl:choose>
-      <xsl:when test="$currentNode">
-        <xsl:analyze-string select="." regex="\d+(\.\d+)*">
-          <xsl:matching-substring>
-            <xsl:variable name="noteNumber" as="xs:string" select="."/>
-            <xsl:variable name="targetNode" as="element(node)?" select="($currentNode/descendant::node[@number=$noteNumber],$currentNode/following::node[@number=$noteNumber])[1]"/>
-            <xsl:choose>
-              <xsl:when test="$targetNode/@sectionId">
-                <sectionLink tanSectionId="{$targetNode/@sectionId}" show="text">
-                  <xsl:value-of select="."/>
-                  <tanSectionInfo>
-                    <xsl:for-each select="$targetNode/@*[name()=('id','name','pathName','path', 'number')]">
-                      <xsl:attribute name="node{concat(upper-case(substring(name(),1,1)),substring(name(), 2))}" select="."/>
-                    </xsl:for-each>
-                    <xsl:copy-of select="$targetNode/@sectionId"/>
-                  </tanSectionInfo>
-                </sectionLink>
-              </xsl:when>
-              <xsl:otherwise>
-                <xsl:value-of select="."/>
-              </xsl:otherwise>
-            </xsl:choose>
-          </xsl:matching-substring>
-          <xsl:non-matching-substring>
-            <xsl:value-of select="."/>
-          </xsl:non-matching-substring>
-        </xsl:analyze-string>
-      </xsl:when>
-      <xsl:otherwise>
-        <xsl:next-match/>
-      </xsl:otherwise>
-    </xsl:choose>
-  </xsl:template>
-
-</xsl:stylesheet>

package/build/project/config/cmscustom/tangelo/default/pre-process/_auto_prefix_to_number.xsl

@@ -1,64 +0,0 @@
-<xsl:stylesheet version="2.0" exclude-result-prefixes="#all"
-  xmlns:xs="http://www.w3.org/2001/XMLSchema"
-  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
-  xmlns:tfn="http://www.tangelo.nl/xslt-functions"
-  >
-
-  <xsl:variable name="numberingRegex" as="xs:string" select="'^\s?(([a-zA-Z]|\d){1,1}(\.([a-zA-Z]|\d){1,3})*\.?)(\s|&#160;)(.*)$'"/>
-  <!-- '^\s?(([a-zA-Z]|\d){1,3}(\.([a-zA-Z]|\d){1,3})*\.?)(\s|&#160;)(.*)$'
-    matches:
-    2.2 title
-    2.2. title
-    A. title
-    does not match numberprefixes like 'chapter 2.2 title'
-    You could add a numberPrefix recognition like: ([Cc]hapter|[Aa]ppendix) and strip that from the title and add it as attribute to the paragraphCode element
-
-    See also https://regex101.com:
-    $1 is the paragraphCode (first capturing group): (([a-zA-Z]|\d){1,3}(\.([a-zA-Z]|\d){1,3})*\.?)
-    $6 is the rest of the text (sixth capturing group): (.*)
-  -->
-  <xsl:variable name="numberingRegex.number"    as="xs:string" select="'$1'"/>
-  <xsl:variable name="numberingRegex.restText"  as="xs:string" select="'$6'"/>
-
-  <xsl:template match="node[not(@number)]">
-    <xsl:copy>
-      <xsl:if test="matches(*[1]/title/node()[1],$numberingRegex)">
-        <xsl:attribute name="number" select="replace(normalize-space(replace(*[1]/title/node()[1],$numberingRegex, $numberingRegex.number)),'&#160;','')"/>
-      </xsl:if>
-      <xsl:apply-templates select="@*|node()"/>
-    </xsl:copy>
-  </xsl:template>
-
-  <xsl:template match="node[not(@number)]/*[1]/title">
-    <xsl:copy>
-      <xsl:choose>
-        <xsl:when test="matches(node()[1][self::text()],$numberingRegex)">
-          <xsl:apply-templates select="@*"/>
-          <xsl:value-of select="replace(text()[1],$numberingRegex, $numberingRegex.restText)"/>
-          <xsl:apply-templates select="node()[position() gt 1]"/>
-        </xsl:when>
-        <xsl:otherwise>
-          <xsl:apply-templates select="@*|node()"/>
-        </xsl:otherwise>
-      </xsl:choose>
-    </xsl:copy>
-  </xsl:template>
-
-  <xsl:template match="tanSectionInfo[not(@nodeNumber)]">
-    <xsl:copy>
-      <xsl:if test="matches(@nodeName,$numberingRegex)">
-        <xsl:attribute name="nodeNumber" select="replace(normalize-space(replace(@nodeName,$numberingRegex, $numberingRegex.number)),'&#160;','')"/>
-      </xsl:if>
-      <xsl:apply-templates select="@*|node()"/>
-    </xsl:copy>
-  </xsl:template>
-
-  <xsl:template match="tanSectionInfo[not(@nodeNumber)]/@nodeName">
-    <xsl:attribute name="{name()}">
-      <xsl:if test="matches(.,$numberingRegex)">
-        <xsl:value-of select="replace(.,$numberingRegex, $numberingRegex.restText)"/>
-      </xsl:if>
-    </xsl:attribute>
-  </xsl:template>
-
-</xsl:stylesheet>

package/build/project/config/cmscustom/tangelo/default/pre-process/_item-numbering.xsl

@@ -1,87 +0,0 @@
-<xsl:stylesheet version="2.0" xmlns:xs="http://www.w3.org/2001/XMLSchema"
-  xmlns:fo="http://www.w3.org/1999/XSL/Format"
-  xmlns:tpp="http://www.tangelo.nl/pre-process"
-  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
-  xmlns:tfn="http://www.tangelo.nl/xslt-functions" exclude-result-prefixes="#all">
-
-  <!-- set numbering mode to either: hierarchical (numbering prefixed with first ancestor numbered node/@number) or continuous (numbering is unrelated to node numbering)
-       You also need to set the same setting in the prepare xincludes
-  -->
-  <xsl:variable name="itemNumbering.mode" as="xs:string" select="'hierarchical'"/>
-
-  <!-- itemNumbering.figureElements = 'figure','chart' will number both chart's and figure's as they are all figures;
-       itemNumbering.figureElements = 'figure' will number figures separately from charts; (hence you get figure 1, chart 1 instead of figure 1, figure 2)
-  -->
-  <xsl:variable name="itemNumbering.figureElements" as="xs:string*" select="'figure','chart'"/>
-
-  <xsl:template match="table/@numbering[.='true'] | chart/@numbering[.='true'] | figure/@numbering[.='true']">
-    <xsl:copy/>
-
-    <xsl:variable name="itemNumber" as="xs:string">
-      <xsl:apply-templates select="." mode="item-numbering"/>
-    </xsl:variable>
-
-    <xsl:attribute name="tpp:itemNumber" select="$itemNumber"/>
-  </xsl:template>
-
-  <xsl:template match="@numbering[.='true']" mode="item-numbering" priority="10">
-    <xsl:variable name="elementName" select="parent::*/name()"/>
-    <xsl:variable name="elementNumbering" as="element()*" select="
-      if ($elementName = $itemNumbering.figureElements) then ancestor::node[1]/*[1]/itemNumbering/element()[name()=$itemNumbering.figureElements]
-      else ancestor::node[1]/*[1]/itemNumbering/element()[name()=$elementName]"/>
-
-    <xsl:choose>
-      <xsl:when test="not($elementNumbering)"/>
-      <xsl:otherwise>
-        <xsl:next-match>
-          <xsl:with-param name="elementName"      as="xs:string"  tunnel="yes" select="$elementName"/>
-          <xsl:with-param name="elementNumbering" as="element()*" tunnel="yes" select="$elementNumbering"/>
-        </xsl:next-match>
-      </xsl:otherwise>
-    </xsl:choose>
-  </xsl:template>
-
-  <xsl:template match="@numbering[.='true']" mode="item-numbering">
-    <xsl:param name="elementNumbering" as="element()*" tunnel="yes"/>
-    <xsl:param name="elementName"      as="xs:string" tunnel="yes"/>
-
-    <xsl:variable name="nodeId" select="ancestor::node[1]/@id"/>
-    <xsl:variable name="firstAncestorNumberedNode" as="element(node)?" select="ancestor::node[@number][1]"/>
-
-    <xsl:variable name="previous-sections-item-count" as="xs:integer" select="xs:integer(sum($elementNumbering))"/>
-
-    <xsl:variable name="this-section-item-count" as="xs:integer">
-      <xsl:variable name="cnt">
-        <xsl:apply-templates select="." mode="this-section-item-count"/>
-      </xsl:variable>
-      <xsl:value-of select="if ($cnt castable as xs:integer) then xs:integer($cnt) else 0"/>
-    </xsl:variable>
-
-    <xsl:value-of select="
-      if ($itemNumbering.mode='hierarchical' and $firstAncestorNumberedNode)
-      then  concat($firstAncestorNumberedNode/@number, '.', $previous-sections-item-count + $this-section-item-count)
-      else  $previous-sections-item-count + $this-section-item-count"/>
-
-  </xsl:template>
-
-  <xsl:template match="@numbering[.='true']" mode="this-section-item-count">
-    <xsl:param name="elementName" as="xs:string" tunnel="yes"/>
-
-    <xsl:choose>
-      <xsl:when test="$elementName = $itemNumbering.figureElements">
-        <xsl:number
-          count="element()[name()=$itemNumbering.figureElements][@numbering[.='true']]"
-          from="section" level="any"/>
-      </xsl:when>
-      <xsl:otherwise>
-        <xsl:number
-          count="element()[name()=$elementName][@numbering[.='true']]"
-          from="section" level="any"/>
-      </xsl:otherwise>
-    </xsl:choose>
-  </xsl:template>
-
-  <xsl:template match="@numbering[.='false']" mode="item-numbering"/>
-  <xsl:template match="itemNumbering"><!-- remove itemNumbering --></xsl:template>
-
-</xsl:stylesheet>

package/build/project/config/cmscustom/tangelo/default/pre-process/_table_add_structure.xsl

@@ -1,169 +0,0 @@
-<?xml version="1.0" encoding="UTF-8"?>
-<xsl:stylesheet
-  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
-  xmlns:tfn="http://www.tangelo.nl/xslt-functions"
-  xmlns:xs="http://www.w3.org/2001/XMLSchema"
-  exclude-result-prefixes="#all"
-  version="2.0">
-
-  <xsl:template match="table" priority="100">
-    <xsl:variable name="table.structure" as="element()">
-      <xsl:apply-templates select="." mode="configuration"/>
-    </xsl:variable>
-    <xsl:next-match>
-      <xsl:with-param name="table.structure" select="$table.structure" as="element()" tunnel="yes"/>
-    </xsl:next-match>
-  </xsl:template>
-
-  <xsl:template match="tr" priority="100">
-    <xsl:variable name="row.pos"  as="xs:integer" select="count(preceding-sibling::tr) + 1"/>
-    <xsl:next-match>
-      <xsl:with-param name="row.pos" as="xs:integer" tunnel="yes" select="$row.pos"/>
-    </xsl:next-match>
-  </xsl:template>
-
-  <xsl:template match="td | th" priority="100">
-    <xsl:param name="row.pos"         as="xs:integer" tunnel="yes"/>
-    <xsl:param name="table.structure" as="element()?"  tunnel="yes"/>
-
-    <xsl:variable name="startPos" select="tfn:get-column-number(.,$table.structure/r[position()=$row.pos])"/>
-    <xsl:copy>
-      <xsl:attribute name="startCol" select="$startPos"/>
-      <xsl:attribute name="endCol"   select="$startPos + (if (@colspan castable as xs:integer) then xs:integer(@colspan) - 1 else 0)"/>
-
-      <xsl:next-match/>
-    </xsl:copy>
-  </xsl:template>
-
-  <xsl:template match="td | th" priority="0">
-    <xsl:apply-templates select="@* | node()"/>
-  </xsl:template>
-
-
-  <xsl:template match="table" mode="configuration">
-    <!-- Create table configuration element 't': -->
-    <xsl:element name="t">
-      <!-- Create configuration row for row 1, initialize row-configuration:
-          Next rows are applied within template match of first row -->
-      <xsl:apply-templates select="tr[1]" mode="configuration">
-        <xsl:with-param name="row-config" select="tfn:initialize-row-config(tr[1])"/>
-      </xsl:apply-templates>
-    </xsl:element>
-  </xsl:template>
-  <xsl:template match="tr" mode="configuration">
-    <xsl:param name="row-config"/>
-
-    <!-- Copy the row cofiguration; The number of c-elements is invariant and equal to the number of columns -->
-    <xsl:copy-of select="$row-config"/>
-
-    <!-- Apply next row, with updated row-configuration -->
-    <xsl:if test="following-sibling::tr[1]">
-      <xsl:apply-templates select="following-sibling::tr[1]" mode="configuration">
-        <xsl:with-param name="row-config" select="tfn:update-row-config($row-config,following-sibling::tr[1])"/>
-      </xsl:apply-templates>
-    </xsl:if>
-  </xsl:template>
-
-  <xsl:function name="tfn:initialize-row-config">
-    <xsl:param name="tr" as="element(tr)"/>
-    <!-- Create row element 'r' -->
-    <xsl:element name="r">
-      <!-- For each cell in $tr create a c-element -->
-      <xsl:for-each select="$tr/(td|th)">
-        <xsl:variable name="position" as="xs:integer" select="position()"/>
-        <xsl:variable name="rowspan"  as="xs:integer" select="xs:integer((@rowspan,1)[1])"/>
-        <xsl:variable name="colspan"  as="xs:integer" select="xs:integer((@colspan,1)[1])"/>
-
-        <xsl:element name="c">
-          <!-- Set additional (custom), rowspan and colspan attributes. Because this is the first row of the table this is quite simple -->
-          <xsl:attribute name="rs" select="$rowspan"/>
-          <xsl:attribute name="cs" select="$colspan"/>
-        </xsl:element>
-        <!-- Create c-elements for column-spanned cells. These c-elements are virtual cells representing a part of the original $tr/cell.
-               For these c-elements colspan is set to '0', meaning they are not showed / they are virtual
-               the creation of these cells causes that the number of c-elements created in this initialize function is equal to the number of table-columns
-        -->
-        <xsl:if test="$colspan &gt; 1">
-          <xsl:for-each select="
-            for $i in 1 to $colspan - 1
-            return $i
-            ">
-            <xsl:element name="c">
-              <xsl:attribute name="rs" select="$rowspan"/>
-              <xsl:attribute name="cs" select="'0'"/><!-- virtual cell; hence colspan=0 -->
-            </xsl:element>
-          </xsl:for-each>
-        </xsl:if>
-      </xsl:for-each>
-    </xsl:element>
-  </xsl:function>
-
-  <xsl:function name="tfn:update-row-config">
-    <!-- Invariant: number of c-elements = number of table-columns -->
-    <xsl:param name="old-row-config" as="element(r)"/>
-    <xsl:param name="tr" as="element(tr)"/>
-
-    <xsl:element name="r">
-      <xsl:for-each select="$old-row-config/c">
-        <xsl:variable name="position" select="position()"/>
-
-        <xsl:variable name="c-position" select="
-          if (@rs=1) then count(preceding-sibling::c[@rs=1])+1 (: cell position as if no colspan occurs in $tr :)
-          else -1
-          "/>
-
-        <!-- cell representing current c-element, empty if does not exist -->
-        <xsl:variable name="cell"           as="element()?"
-          select="$tr/element()[count(preceding-sibling::element())+sum(preceding-sibling::element()/(@colspan - 1)) + 1=$c-position]"/>
-
-        <!-- All cells before the cell representing this c-element, if this c-element is virual then the last cell includes (due to colspan) this c-element -->
-        <xsl:variable name="previous-cells" as="element()*"
-          select="$tr/element()[count(preceding-sibling::element())+sum(preceding-sibling::element()/(@colspan - 1)) + 1&lt;$c-position]"/>
-
-        <!-- Last cell of preceding-sibling-cells; note that: if this c-element is virual then the variable 'previous-cell'  represents the cell that includes (due to colspan) this c-element-->
-        <xsl:variable name="preceding-cell"  as="element()?"
-          select="$tr/element()[count(preceding-sibling::element())+sum(preceding-sibling::element()/(@colspan - 1)) + 1&lt;$c-position][last()]"/>
-
-        <!-- Position of $cell in $tr (= position in the actual table-xml) -->
-        <xsl:variable name="tr-position" as="xs:integer" select="
-          if ($cell) then count($cell/preceding-sibling::element())+1
-          else -1
-          "/>
-
-        <xsl:element name="c">
-          <xsl:attribute name="rs" select="
-            if      (@rs[xs:integer(.) gt 1]) then xs:integer(@rs) - 1      (: If cell is part of a previous rowspan, lower rs with 1 :)
-            else if ($cell/@rowspan)          then $cell/@rowspan           (: If cell is starts a rowspan, set rowspan :)
-            else if ($preceding-cell/@rowspan[xs:integer(.) gt 1] and $preceding-cell/@colspan[xs:integer(.) gt 1] and count($previous-cells) + sum($previous-cells/(@colspan - 1)) + 1 gt $c-position)
-                                              then $preceding-cell/@rowspan (: If previous-sibling cell has both rowspan and colspan, and this virtual cell is part of that previous-sibling cell, copy the rowspan of the previous-cell :)
-            else                              1                             (: no rowspan :)
-            "/>
-          <xsl:attribute name="cs" select="
-            if      ($tr-position=-1)         then 0              (: If virtual cell then  cs=0 :)
-            else if (@rs[xs:integer(.) gt 1]) then 0              (: If virtual cell then  cs=0 :)
-            else if ($cell/@colspan)          then $cell/@colspan (: If cell starts a colspan, copy colspan :)
-            else                                   1
-            "/>
-        </xsl:element>
-      </xsl:for-each>
-    </xsl:element>
-  </xsl:function>
-
-  <xsl:function name="tfn:get-column-number">
-    <xsl:param name="cell" as="element()"/>
-    <xsl:param name="row-config" as="element(r)"/>
-
-    <xsl:variable name="cell-position-in-row" as="xs:integer">
-      <xsl:value-of select="count($cell/preceding-sibling::element())+1"/>
-    </xsl:variable>
-    <xsl:variable name="preceding-cell-colspan" as="xs:integer">
-      <xsl:value-of select="sum($cell/preceding-sibling::element()[@colspan[xs:integer(.) gt 0]]/(xs:integer(@colspan) - 1))"/>
-    </xsl:variable>
-
-    <xsl:variable name="corresponding-cell-in-row-config" as="element()?" select="$row-config/c[sum(preceding-sibling::c/@cs)=($cell-position-in-row+$preceding-cell-colspan)-1][@cs[xs:integer(.) gt 0]][1]"/>
-
-    <!-- Return column-number: -->
-    <xsl:value-of select="count($corresponding-cell-in-row-config/preceding-sibling::c) + 1"/>
-
-  </xsl:function>
-</xsl:stylesheet>

package/build/project/config/cmscustom/tangelo/default/pre-process/base.xsl

@@ -1,60 +0,0 @@
-<xsl:stylesheet version="2.0" exclude-result-prefixes="#all"
-  xmlns:xs="http://www.w3.org/2001/XMLSchema"
-  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
-  xmlns:tfn="http://www.tangelo.nl/xslt-functions"
-  xmlns:fn="http://www.w3.org/2005/xpath-functions"
-  xmlns:tpp="http://www.tangelo.nl/pre-process"
-  >
-
-  <!-- TDI PRE-PROCESSING -->
-  <xsl:include href="../../../tdi/pre-process/_pre-process.xsl"/>
-
-  <!-- PARAMETERS -->
-  <xsl:param name="preProcess.output" as="xs:string" select="'all'">
-    <!-- 'all' matches all possible values set in XSD @output and no elements will be removed;
-          set to value in XSD @output to keep only those elements
-    -->
-  </xsl:param>
-  <xsl:param name="preProcess.removeTrackchanges" as="xs:boolean" select="true()">
-    <!-- remove processing-instructions (read: trackchanges) from XML;
-         Will be set to false() in PDF-preproces if customer want to show processing instructions
-    -->
-  </xsl:param>
-  <xsl:param name="preProcess.removeAnnotations" as="xs:boolean" select="true()">
-    <!-- remove processing-instructions for Fonto annotations/comments from XML;
-         Will be set to false() in PDF-preproces if customer want to show the Fonto annotations/comments
-    -->
-  </xsl:param>
-
-  <!-- CUSTOM PRE-PROCES CODE -->
-  <xsl:template match="section/@xml:space"/><!-- Remove xml:space attribute -->
-
-  <!--<xsl:include href="_auto_prefix_to_number.xsl"/>--><!-- To recognize manual typed paragraph codes -->
-  <xsl:include href="_auto_create_note_sectionlinks.xsl"/>
-  <xsl:include href="_table_add_structure.xsl"/>
-  <xsl:include href="_item-numbering.xsl"/>
-
-  <!--<xsl:template match="/">
-    <xsl:call-template name="output-xml">
-      <xsl:with-param name="xmlNode" select="*"/>
-      <xsl:with-param name="filename" select="'pre-proces - input.xml'"/>
-    </xsl:call-template>
-    <xsl:apply-templates/>
-  </xsl:template>-->
-
-  <!-- Create xml output file -->
-  <xsl:output name="output-file" indent="yes" omit-xml-declaration="yes" encoding="utf-8" method="xml"/>
-  <xsl:template name="output-xml">
-    <xsl:param name="xmlNode" select="node()"/>
-    <xsl:param name="filename" select="'output'"/>
-    <xsl:variable name="output-path" select="substring-after(tfn:substringBeforeLast(fn:static-base-uri(),'/'),'file:')"/>
-    <xsl:result-document href="{$output-path}/out/{$filename}-{generate-id()}.xml" format="output-file">
-      <xsl:copy-of select="$xmlNode"/>
-    </xsl:result-document>
-  </xsl:template>
-
-  <xsl:function name="tfn:path">
-    <xsl:param name="target" as="element()"/>
-    <xsl:value-of select="for $step in $target/ancestor-or-self::* return concat(name($step), '[', count($step/preceding-sibling::*[name() = name($step)]) + 1, ']')" separator="/"/>
-  </xsl:function>
-</xsl:stylesheet>

package/build/project/config/cmscustom/tangelo/default/prepare_xincludes.xsl

@@ -1,56 +0,0 @@
-<?xml version="1.0" encoding="UTF-8"?>
-<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xi="http://www.w3.org/2001/XInclude">
-  <xsl:include href="../../tdi/prepare_xincludes.xsl"/>
-
-  <xsl:template match="section">
-    <xsl:copy>
-      <xsl:choose>
-        <xsl:when test="$vaWebsite and $params/q">
-          <xsl:variable name="q">
-            <xsl:call-template name="replace">
-              <xsl:with-param name="text" select="$params/q"/>
-              <xsl:with-param name="search">'</xsl:with-param>
-              <xsl:with-param name="replace">''</xsl:with-param>
-            </xsl:call-template>
-          </xsl:variable>
-          <xsl:variable name="p">
-            <xsl:choose>
-              <xsl:when test="$params/p">
-                <xsl:value-of select="$params/p"/>
-              </xsl:when>
-              <xsl:otherwise>1</xsl:otherwise>
-            </xsl:choose>
-          </xsl:variable>
-          <xi:include plsqlcall="tanapi.xml_search.search(p_txd_search=>'Y',p_txd_document_versions=>{$documentVersionId},p_expression=>'{$q}',p_page=>{$p},p_page_results=>10)"/>
-        </xsl:when>
-        <xsl:otherwise>
-          <xsl:apply-templates select="@*|node()"/>
-        </xsl:otherwise>
-      </xsl:choose>
-      <!--<xi:include plsqlcall="tlo.tlo_include.get_item_numbering(p_node_id=>{$nodeId}, p_mode=>'hierarchical')"/>-->
-      <xsl:if test="$vaPdfBranch or $vaPdfNode">
-        <!--<xi:include plsqlcall="tanapi.xml_include.node_extract({$nodeId},{$documentVersionId},'*/footerText','R',null,'Y','N')"/>-->
-        <xi:include plsqlcall="tanapi.xml_include.node_extract({$nodeId},{$documentVersionId},'*/@columnCount[.!=''auto'']','A',null,'Y','N')"/>
-        <!--<xi:include plsqlcall="tanapi.xml_include.node_extract({$nodeId},{$documentVersionId},'*/@orientation[.!=''auto'']','A',null,'Y','N')"/>-->
-      </xsl:if>
-      <xsl:if test="($vaPdfBranch or $vaPdfNode) and $sectionTypeName='CONTENTS'">
-        <xsl:element name="exportContents">
-          <xi:include plsqlcall="tanapi.xml_include.document({$documentVersionId},false)"/>
-        </xsl:element>
-      </xsl:if>
-    </xsl:copy>
-  </xsl:template>
-
-  <!-- for sectionlinks showing the section number -->
-  <xsl:template match="*[@tanSectionId][contains(@show,'chapter-nr')]">
-    <xsl:copy>
-      <xsl:apply-templates select="@*|node()"/>
-      <xsl:if test="@tanSectionId!='0'">
-        <xi:include
-          plsqlcall="tanapi.xml_include.section_link(p_section_id=>{@tanSectionId},p_link_document_id=>{$documentId},p_link_document_version_id=>{$documentVersionId})"
-        />
-      </xsl:if>
-    </xsl:copy>
-  </xsl:template>
-
-</xsl:stylesheet>

package/build/project/config/cmscustom/tangelo/default/schema/fonto.json

@@ -1,36 +0,0 @@
-{
-  "rootSchemas": {
-    "xsd/document.xsd": {
-      "packageName": "sx-shell-document",
-      "locations": ["tangelo/default/schema/xsd/document.xsd"]
-    },
-    "xsd/cover.xsd": {
-      "packageName": "sx-shell-cover",
-      "locations": ["tangelo/default/schema/xsd/cover.xsd"]
-    },
-    "xsd/chapter.xsd": {
-      "packageName": "sx-shell-chapter",
-      "locations": ["tangelo/default/schema/xsd/chapter.xsd"]
-    },
-    "xsd/paragraph.xsd": {
-      "packageName": "sx-shell-paragraph",
-      "locations": ["tangelo/default/schema/xsd/paragraph.xsd"]
-    },
-    "xsd/glossary.xsd": {
-      "packageName": "sx-shell-glossary",
-      "locations": ["tangelo/default/schema/xsd/glossary.xsd"]
-    },
-    "xsd/newsitem.xsd": {
-      "packageName": "sx-shell-newsitem",
-      "locations": ["tangelo/default/schema/xsd/newsitem.xsd"]
-    },
-    "xsd/faqitem.xsd": {
-      "packageName": "sx-shell-faqitem",
-      "locations": ["tangelo/default/schema/xsd/faqitem.xsd"]
-    },
-    "xsd/fileitem.xsd": {
-      "packageName": "sx-shell-fileitem",
-      "locations": ["tangelo/default/schema/xsd/fileitem.xsd"]
-    }
-  }
-}