@sasjs/utils 2.49.0 → 2.49.1

package/macros/mp_dictionary.sas

@@ -0,0 +1,52 @@
+/**
+  @file mp_dictionary.sas
+  @brief Creates a portal (libref) into the SQL Dictionary Views
+  @details Provide a libref and the macro will create a series of views against
+  each view in the special PROC SQL dictionary libref.
+
+  This is useful if you would like to visualise (navigate) the views in a SAS
+  client such as Base SAS, Enterprise Guide, or Studio (or [Data Controller](
+  https://datacontroller.io)).
+
+  It works by extracting the dictionary.dictionaries view into
+  YOURLIB.dictionaries, then uses that to create a YOURLIB.{viewName} for every
+  other dictionary.view, eg:
+
+      proc sql;
+      create view YOURLIB.columns as select * from dictionary.columns;
+
+  Usage:
+
+      libname demo "/lib/directory";
+      %mp_dictionary(lib=demo)
+
+  Or, to just create them in WORK:
+
+      %mp_dictionary()
+
+  If you'd just like to browse the dictionary data model, you can also check
+  out [this article](https://rawsas.com/dictionary-of-dictionaries/).
+
+  ![](https://user-images.githubusercontent.com/4420615/188278365-2987db97-0594-4a39-ac81-dbacdef5cdc8.png)
+
+  @param lib= (WORK) The libref in which to create the views
+
+  <h4> Related Files </h4>
+  @li mp_dictionary.test.sas
+
+  @version 9.2
+  @author Allan Bowe
+
+**/
+
+%macro mp_dictionary(lib=WORK)/*/STORE SOURCE*/;
+  %local list i mem;
+  proc sql noprint;
+  create view &lib..dictionaries as select * from dictionary.dictionaries;
+  select distinct memname into: list separated by ' '  from &lib..dictionaries;
+  %do i=1 %to %sysfunc(countw(&list,%str( )));
+    %let mem=%scan(&list,&i,%str( ));
+    create view &lib..&mem as select * from dictionary.&mem;
+  %end;
+  quit;
+%mend mp_dictionary;

package/macros/mp_dirlist.sas

@@ -0,0 +1,263 @@
+/**
+  @file
+  @brief Returns all files and subdirectories within a specified parent
+  @details When used with getattrs=NO, is not OS specific (uses dopen / dread).
+
+  Credit for the rename approach:
+  https://communities.sas.com/t5/SAS-Programming/SAS-Function-to-convert-string-to-Legal-SAS-Name/m-p/27375/highlight/true#M5003
+
+  Usage:
+
+      %mp_dirlist(path=/some/location, outds=myTable, maxdepth=MAX)
+
+      %mp_dirlist(outds=cwdfileprops, getattrs=YES)
+
+      %mp_dirlist(fref=MYFREF)
+
+  @warning In a Unix environment, the existence of a named pipe will cause this
+  macro to hang.  Therefore this tool should be used with caution in a SAS 9 web
+  application, as it can use up all available multibridge sessions if requests
+  are resubmitted.
+  If anyone finds a way to positively identify a named pipe using SAS (without
+  X CMD) do please raise an issue!
+
+
+  @param [in] path= (%sysfunc(pathname(work))) Path for which to return contents
+  @param [in] fref= (0) Provide a DISK engine fileref as an alternative to PATH
+  @param [in] maxdepth= (0) Set to a positive integer to indicate the level of
+    subdirectory scan recursion - eg 3, to go `./3/levels/deep`.  For unlimited
+    recursion, set to MAX.
+  @param [in] showparent= (NO) By default, the initial parent directory is not
+    part of the results.  Set to YES to include it.  For this record only,
+    directory=filepath.
+  @param [out] outds= (work.mp_dirlist) The output dataset to create
+  @param [out] getattrs= (NO)  If getattrs=YES then the doptname / foptname
+    functions are used to scan all properties - any characters that are not
+    valid in a SAS name (v7) are simply stripped, and the table is transposed
+    so theat each property is a column and there is one file per row.  An
+    attempt is made to get all properties whether a file or folder, but some
+    files/folders cannot be accessed, and so not all properties can / will be
+    populated.
+
+
+  @returns outds contains the following variables:
+    - directory (containing folder)
+    - file_or_folder (file / folder)
+    - filepath (path/to/file.name)
+    - filename (just the file name)
+    - ext (.extension)
+    - msg (system message if any issues)
+    - level (depth of folder)
+    - OS SPECIFIC variables, if <code>getattrs=</code> is used.
+
+  <h4> SAS Macros </h4>
+  @li mf_existds.sas
+  @li mf_getvarlist.sas
+  @li mf_wordsinstr1butnotstr2.sas
+  @li mp_dropmembers.sas
+
+  <h4> Related Macros </h4>
+  @li mp_dirlist.test.sas
+
+  @version 9.2
+**/
+
+%macro mp_dirlist(path=%sysfunc(pathname(work))
+    , fref=0
+    , outds=work.mp_dirlist
+    , getattrs=NO
+    , showparent=NO
+    , maxdepth=0
+    , level=0 /* The level of recursion to perform.  For internal use only. */
+)/*/STORE SOURCE*/;
+%let getattrs=%upcase(&getattrs)XX;
+
+/* temp table */
+%local out_ds;
+data;run;
+%let out_ds=%str(&syslast);
+
+/* drop main (top) table if it exists */
+%if &level=0 %then %do;
+  %mp_dropmembers(%scan(&outds,-1,.), libref=WORK)
+%end;
+
+data &out_ds(compress=no
+    keep=file_or_folder filepath filename ext msg directory level
+  );
+  length directory filepath $500 fref fref2 $8 file_or_folder $6 filename $80
+    ext $20 msg $200 foption $16;
+  if _n_=1 then call missing(of _all_);
+  retain level &level;
+  %if &fref=0 %then %do;
+    rc = filename(fref, "&path");
+  %end;
+  %else %do;
+    fref="&fref";
+    rc=0;
+  %end;
+  if rc = 0 then do;
+    did = dopen(fref);
+    if did=0 then do;
+      putlog "NOTE: This directory is empty, or does not exist - &path";
+      msg=sysmsg();
+      put msg;
+      put _all_;
+      stop;
+    end;
+    /* attribute is OS-dependent - could be "Directory" or "Directory Name" */
+    numopts=doptnum(did);
+    do i=1 to numopts;
+      foption=doptname(did,i);
+      if foption=:'Directory' then i=numopts;
+    end;
+    directory=dinfo(did,foption);
+    rc = filename(fref);
+  end;
+  else do;
+    msg=sysmsg();
+    put _all_;
+    stop;
+  end;
+  dnum = dnum(did);
+  do i = 1 to dnum;
+    filename = dread(did, i);
+    filepath=cats(directory,'/',filename);
+    rc = filename(fref2,filepath);
+    midd=dopen(fref2);
+    dmsg=sysmsg();
+    if did > 0 then file_or_folder='folder';
+    rc=dclose(midd);
+    midf=fopen(fref2);
+    fmsg=sysmsg();
+    if midf > 0 then file_or_folder='file';
+    rc=fclose(midf);
+
+    if index(fmsg,'File is in use') or index(dmsg,'is not a directory')
+      then file_or_folder='file';
+    else if index(fmsg,'Insufficient authorization') then file_or_folder='file';
+    else if file_or_folder='' then file_or_folder='locked';
+
+    if file_or_folder='file' then do;
+      ext = prxchange('s/.*\.{1,1}(.*)/$1/', 1, filename);
+      if filename = ext then ext = ' ';
+    end;
+    else do;
+      ext='';
+      file_or_folder='folder';
+    end;
+    output;
+  end;
+  rc = dclose(did);
+  %if &showparent=YES and &level=0 %then %do;
+    filepath=directory;
+    file_or_folder='folder';
+    ext='';
+    filename=scan(directory,-1,'/\');
+    msg='';
+    level=&level;
+    output;
+  %end;
+  stop;
+run;
+
+%if %substr(&getattrs,1,1)=Y %then %do;
+  data &out_ds;
+    set &out_ds;
+    length infoname infoval $60 fref $8;
+    if _n_=1 then call missing(fref);
+    rc=filename(fref,filepath);
+    drop rc infoname fid i close fref;
+    if file_or_folder='file' then do;
+      fid=fopen(fref);
+      if fid le 0 then do;
+        msg=sysmsg();
+        putlog "Could not open file:" filepath fid= ;
+        sasname='_MCNOTVALID_';
+        output;
+      end;
+      else do i=1 to foptnum(fid);
+        infoname=foptname(fid,i);
+        infoval=finfo(fid,infoname);
+        sasname=compress(infoname, '_', 'adik');
+        if anydigit(sasname)=1 then sasname=substr(sasname,anyalpha(sasname));
+        if upcase(sasname) ne 'FILENAME' then output;
+      end;
+      close=fclose(fid);
+    end;
+    else do;
+      fid=dopen(fref);
+      if fid le 0 then do;
+        msg=sysmsg();
+        putlog "Could not open folder:" filepath fid= ;
+        sasname='_MCNOTVALID_';
+        output;
+      end;
+      else do i=1 to doptnum(fid);
+        infoname=doptname(fid,i);
+        infoval=dinfo(fid,infoname);
+        sasname=compress(infoname, '_', 'adik');
+        if anydigit(sasname)=1 then sasname=substr(sasname,anyalpha(sasname));
+        if upcase(sasname) ne 'FILENAME' then output;
+      end;
+      close=dclose(fid);
+    end;
+  run;
+  proc sort;
+    by filepath sasname;
+  proc transpose data=&out_ds out=&out_ds(drop=_:);
+    id sasname;
+    var infoval;
+    by filepath file_or_folder filename ext ;
+  run;
+%end;
+
+data &out_ds;
+  set &out_ds(where=(filepath ne ''));
+run;
+
+/**
+  * The above transpose can mean that some updates create additional columns.
+  * This necessitates the occasional use of datastep over proc append.
+  */
+%if %mf_existds(&outds) %then %do;
+  %local basevars appvars newvars;
+  %let basevars=%mf_getvarlist(&outds);
+  %let appvars=%mf_getvarlist(&out_ds);
+  %let newvars=%length(%mf_wordsinstr1butnotstr2(Str1=&appvars,Str2=&basevars));
+  %if &newvars>0 %then %do;
+    data &outds;
+      set &outds &out_ds;
+    run;
+  %end;
+  %else %do;
+    proc append base=&outds data=&out_ds force nowarn;
+    run;
+  %end;
+%end;
+%else %do;
+  proc append base=&outds data=&out_ds;
+  run;
+%end;
+
+/* recursive call */
+%if &maxdepth>&level or &maxdepth=MAX %then %do;
+  data _null_;
+    set &out_ds;
+    where file_or_folder='folder';
+  %if &showparent=YES and &level=0 %then %do;
+    if filepath ne directory;
+  %end;
+    length code $10000;
+    code=cats('%nrstr(%mp_dirlist(path=',filepath,",outds=&outds"
+      ,",getattrs=&getattrs,level=%eval(&level+1),maxdepth=&maxdepth))");
+    put code=;
+    call execute(code);
+  run;
+%end;
+
+/* tidy up */
+proc sql;
+drop table &out_ds;
+
+%mend mp_dirlist;

package/macros/mp_distinctfmtvalues.sas

@@ -0,0 +1,50 @@
+/**
+  @file
+  @brief Creates a dataset containing distinct _formatted_ values
+  @details If no format is supplied, then the original value is used instead.
+    There is also a dependency on other macros within the Macro Core library.
+    Usage:
+
+        %mp_distinctfmtvalues(libds=sashelp.class,var=age,outvar=age,outds=test)
+
+  @param libds input dataset
+  @param var variable to get distinct values for
+  @param outvar variable to create.  Default:  `formatted_value`
+  @param outds dataset to create.  Default:  work.mp_distinctfmtvalues
+  @param varlen length of variable to create (default 200)
+
+  @version 9.2
+  @author Allan Bowe
+
+**/
+
+%macro mp_distinctfmtvalues(
+    libds=
+    ,var=
+    ,outvar=formatted_value
+    ,outds=work.mp_distinctfmtvalues
+    ,varlen=2000
+)/*/STORE SOURCE*/;
+
+  %local fmt vtype;
+  %let fmt=%mf_getvarformat(&libds,&var);
+  %let vtype=%mf_getvartype(&libds,&var);
+
+  proc sql;
+  create table &outds as
+    select distinct
+    %if &vtype=C & %trim(&fmt)=%str() %then %do;
+      &var
+    %end;
+    %else %if &vtype=C %then %do;
+      put(&var,&fmt)
+    %end;
+    %else %if %trim(&fmt)=%str() %then %do;
+        put(&var,32.)
+    %end;
+    %else %do;
+      put(&var,&fmt)
+    %end;
+        as &outvar length=&varlen
+    from &libds;
+%mend mp_distinctfmtvalues;

package/macros/mp_dropmembers.sas

@@ -0,0 +1,46 @@
+/**
+  @file
+  @brief Drops tables / views (if they exist) without warnings in the log
+  @details Useful for dropping tables when you're not sure they exist, or if
+  you are not sure whether they are a dataset or view.  Also efficient for
+  dropping multiple tables / views.
+
+  Example usage:
+
+      proc sql;
+      create table data1 as select * from sashelp.class;
+      create view view2 as select * from sashelp.class;
+      %mp_dropmembers(data1 view2, libref=WORK)
+
+
+  <h4> SAS Macros </h4>
+  @li mf_isblank.sas
+
+
+  @param [in] list space separated list of datasets / views, WITHOUT libref
+  @param [in] libref= (WORK) Note - you can only drop from one library at a time
+  @param [in] iftrue= (1=1) Conditionally drop tables, eg if &debug=N
+
+  @version 9.2
+  @author Allan Bowe
+
+**/
+
+%macro mp_dropmembers(
+    list /* space separated list of datasets / views */
+    ,libref=WORK  /* can only drop from a single library at a time */
+    ,iftrue=%str(1=1)
+)/*/STORE SOURCE*/;
+
+  %if not(%eval(%unquote(&iftrue))) %then %return;
+
+  %if %mf_isblank(&list) %then %do;
+    %put NOTE: nothing to drop!;
+    %return;
+  %end;
+
+  proc datasets lib=&libref nolist;
+    delete &list;
+    delete &list /mtype=view;
+  run;
+%mend mp_dropmembers;

package/macros/mp_ds2cards.sas

@@ -0,0 +1,291 @@
+/**
+  @file
+  @brief Create a CARDS file from a SAS dataset.
+  @details Uses dataset attributes to convert all data into datalines.
+    Running the generated file will rebuild the original dataset.  Includes
+    support for large decimals, binary data, PROCESSED_DTTM columns, and
+    alternative encoding.  If the input dataset is empty, the cards file will
+    still be created.
+
+    Additional support to generate a random sample and max rows.
+
+  Usage:
+
+      %mp_ds2cards(sashelp.class
+        , tgt_ds=work.class
+        , cards_file= "C:\temp\class.sas"
+        , showlog=NO
+        , maxobs=5
+      )
+
+  TODO:
+    - labelling the dataset
+    - explicity setting a unix LF
+    - constraints / indexes etc
+
+  @param [in] base_ds Should be two level - eg work.blah.  This is the table
+                  that is converted to a cards file.
+  @param [in] tgt_ds= Table that the generated cards file would create.
+    Optional - if omitted, will be same as BASE_DS.
+  @param [out] cards_file= ("%sysfunc(pathname(work))/cardgen.sas") Location in
+    which to write the (.sas) cards file
+  @param [in] maxobs= (max) To limit output to the first <code>maxobs</code>
+    observations, enter an integer here.
+  @param [in] random_sample= (NO) Set to YES to generate a random sample of
+    data.  Can be quite slow.
+  @param [in] showlog= (YES) Whether to show generated cards file in the SAS
+    log.  Valid values:
+    @li YES
+    @li NO
+  @param [in] outencoding= Provide encoding value for file statement (eg utf-8)
+  @param [in] append= (NO) If NO then will rebuild the cards file if it already
+    exists, otherwise will append to it.  Used by the mp_lib2cards.sas macro.
+
+  <h4> Related Macros </h4>
+  @li mp_lib2cards.sas
+  @li mp_ds2inserts.sas
+  @li mp_mdtablewrite.sas
+
+  @version 9.2
+  @author Allan Bowe
+  @cond
+**/
+
+%macro mp_ds2cards(base_ds, tgt_ds=
+    ,cards_file="%sysfunc(pathname(work))/cardgen.sas"
+    ,maxobs=max
+    ,random_sample=NO
+    ,showlog=YES
+    ,outencoding=
+    ,append=NO
+)/*/STORE SOURCE*/;
+%local i setds nvars;
+
+%if not %sysfunc(exist(&base_ds)) %then %do;
+  %put %str(WARN)ING:  &base_ds does not exist;
+  %return;
+%end;
+
+%if %index(&base_ds,.)=0 %then %let base_ds=WORK.&base_ds;
+%if (&tgt_ds = ) %then %let tgt_ds=&base_ds;
+%if %index(&tgt_ds,.)=0 %then %let tgt_ds=WORK.%scan(&base_ds,2,.);
+%if ("&outencoding" ne "") %then %let outencoding=encoding="&outencoding";
+%if ("&append" = "" or "&append" = "NO") %then %let append=;
+%else %let append=mod;
+
+/* get varcount */
+%let nvars=0;
+proc sql noprint;
+select count(*) into: nvars from dictionary.columns
+  where upcase(libname)="%scan(%upcase(&base_ds),1)"
+    and upcase(memname)="%scan(%upcase(&base_ds),2)";
+%if &nvars=0 %then %do;
+  %put %str(WARN)ING: Dataset &base_ds has no variables, will not be converted.;
+  %return;
+%end;
+
+/* get indexes */
+proc sort
+  data=sashelp.vindex(
+    where=(upcase(libname)="%scan(%upcase(&base_ds),1)"
+      and upcase(memname)="%scan(%upcase(&base_ds),2)")
+    )
+  out=_data_;
+  by indxname indxpos;
+run;
+
+%local indexes;
+data _null_;
+  set &syslast end=last;
+  if _n_=1 then call symputx('indexes','(index=(','l');
+  by indxname indxpos;
+  length vars $32767 nom uni $8;
+  retain vars;
+  if first.indxname then do;
+    idxcnt+1;
+    nom='';
+    uni='';
+    vars=name;
+  end;
+  else vars=catx(' ',vars,name);
+  if last.indxname then do;
+    if nomiss='yes' then nom='/nomiss';
+    if unique='yes' then uni='/unique';
+    call symputx('indexes'
+      ,catx(' ',symget('indexes'),indxname,'=(',vars,')',nom,uni)
+      ,'l');
+  end;
+  if last then call symputx('indexes',cats(symget('indexes'),'))'),'l');
+run;
+
+
+data;run;
+%let setds=&syslast;
+proc sql
+%if %datatyp(&maxobs)=NUMERIC %then %do;
+  outobs=&maxobs;
+%end;
+  ;
+  create table &setds as select * from &base_ds
+%if &random_sample=YES %then %do;
+  order by ranuni(42)
+%end;
+  ;
+reset outobs=max;
+create table datalines1 as
+  select name,type,length,varnum,format,label from dictionary.columns
+  where upcase(libname)="%upcase(%scan(&base_ds,1))"
+    and upcase(memname)="%upcase(%scan(&base_ds,2))";
+
+/**
+  Due to long decimals cannot use best. format
+  So - use bestd. format and then use character functions to strip trailing
+    zeros, if NOT an integer or missing!!  Cannot use int() as it upsets
+    note2err when there are missings.
+  resolved code = ifc( mod(coalesce(VARIABLE,0),1)=0
+    ,put(VARIABLE,best32.)
+    ,substrn(put(VARIABLE,bestd32.),1
+    ,findc(put(VARIABLE,bestd32.),'0','TBK')));
+**/
+
+data datalines_2;
+  format dataline $32000.;
+  set datalines1 (where=(upcase(name) not in
+    ('PROCESSED_DTTM','VALID_FROM_DTTM','VALID_TO_DTTM')));
+  if type='num' then dataline=
+    cats('ifc(mod(coalesce(',name,',0),1)=0
+      ,put(',name,',best32.-l)
+      ,substrn(put(',name,',bestd32.-l),1
+      ,findc(put(',name,',bestd32.-l),"0","TBK")))');
+  /**
+    * binary data must be converted, to store in text format.  It is identified
+    * by the presence of the $HEX keyword in the format.
+    */
+  else if upcase(format)=:'$HEX' then
+    dataline=cats('put(trim(',name,'),',format,')');
+  /**
+    * There is no easy way to store line breaks in a cards file.
+    * To discuss this, use: https://github.com/sasjs/core/issues/80
+    * Removing all nonprintables with kw (keep writeable)
+    */
+  else dataline=cats('compress(',name,', ,"kw")');
+run;
+
+proc sql noprint;
+select dataline into: datalines separated by ',' from datalines_2;
+
+%local
+  process_dttm_flg
+  valid_from_dttm_flg
+  valid_to_dttm_flg
+;
+%let process_dttm_flg = N;
+%let valid_from_dttm_flg = N;
+%let valid_to_dttm_flg = N;
+data _null_;
+  set datalines1 ;
+/* build attrib statement */
+  if type='char' then type2='$';
+  if strip(format) ne '' then format2=cats('format=',format);
+  if strip(label) ne '' then label2=cats('label=',quote(trim(label)));
+  str1=catx(' ',(put(name,$33.)||'length=')
+        ,put(cats(type2,length),$7.)||format2,label2);
+
+
+/* Build input statement */
+  if upcase(format)=:'$HEX' then type3=':'!!format;
+  else if type='char' then type3=':$char.';
+  str2=put(name,$33.)||type3;
+
+
+  if(upcase(name) = "PROCESSED_DTTM") then
+    call symputx("process_dttm_flg", "Y", "L");
+  if(upcase(name) = "VALID_FROM_DTTM") then
+    call symputx("valid_from_dttm_flg", "Y", "L");
+  if(upcase(name) = "VALID_TO_DTTM") then
+    call symputx("valid_to_dttm_flg", "Y", "L");
+
+
+  call symputx(cats("attrib_stmt_", put(_N_, 8.)), str1, "L");
+  call symputx(cats("input_stmt_", put(_N_, 8.))
+    , ifc(upcase(name) not in
+      ('PROCESSED_DTTM','VALID_FROM_DTTM','VALID_TO_DTTM'), str2, ""), "L");
+run;
+
+data _null_;
+  file &cards_file. &outencoding lrecl=32767 termstr=nl &append;
+  length __attrib $32767;
+  if _n_=1 then do;
+    put '/**';
+    put '  @file';
+    put "  @brief Datalines for %upcase(%scan(&base_ds,2)) dataset";
+    put "  @details Generated by %nrstr(%%)mp_ds2cards()";
+    put "    Source: https://github.com/sasjs/core";
+    put '  @cond ';
+    put '**/';
+    put "data &tgt_ds &indexes;";
+    put "attrib ";
+    %do i = 1 %to &nvars;
+      __attrib=symget("attrib_stmt_&i");
+      put __attrib;
+    %end;
+    put ";";
+
+    %if &process_dttm_flg. eq Y %then %do;
+      put 'retain PROCESSED_DTTM %sysfunc(datetime());';
+    %end;
+    %if &valid_from_dttm_flg. eq Y %then %do;
+      put 'retain VALID_FROM_DTTM &low_date;';
+    %end;
+    %if &valid_to_dttm_flg. eq Y %then %do;
+      put 'retain VALID_TO_DTTM &high_date;';
+    %end;
+    if __nobs=0 then do;
+      put 'call missing(of _all_);/* avoid uninitialised notes */';
+      put 'stop;';
+      put 'run;';
+    end;
+    else do;
+      put "infile cards dsd;";
+      put "input ";
+      %do i = 1 %to &nvars.;
+        %if(%length(&&input_stmt_&i..)) %then
+          put "  &&input_stmt_&i..";
+        ;
+      %end;
+      put ";";
+      put 'missing a b c d e f g h i j k l m n o p q r s t u v w x y z _;';
+      put "datalines4;";
+    end;
+  end;
+  set &setds end=__lastobs nobs=__nobs;
+/* remove all formats for write purposes - some have long underlying decimals */
+  format _numeric_ best30.29;
+  length __dataline $32767;
+  __dataline=catq('cqtmb',&datalines);
+  put __dataline;
+  if __lastobs then do;
+    put ';;;;';
+    put 'run;';
+    put '/** @endcond **/';
+    stop;
+  end;
+run;
+proc sql;
+  drop table &setds;
+quit;
+
+%if &showlog=YES %then %do;
+  data _null_;
+    infile &cards_file lrecl=32767;
+    input;
+    put _infile_;
+  run;
+%end;
+
+%put NOTE: CARDS FILE SAVED IN:;
+%put NOTE-;%put NOTE-;
+%put NOTE- %sysfunc(dequote(&cards_file.));
+%put NOTE-;%put NOTE-;
+%mend mp_ds2cards;
+/** @endcond **/