@sasjs/utils 2.49.0 → 2.49.1

package/macros/mp_retainedkey.sas

@@ -0,0 +1,247 @@
+/**
+  @file
+  @brief Generate and apply retained key values to a staging table
+  @details This macro will populate a staging table with a Retained Key based on
+  a business key and a base (target) table.
+
+  Definition of retained key ([source](
+    http://bukhantsov.org/2012/04/what-is-data-vault/)):
+
+  > The retained key is a key which is mapped to business key one-to-one. In
+  > comparison,  the surrogate key includes time and there can be many surrogate
+  > keys corresponding to one business key. This explains the name of the key,
+  > it is retained with insertion of a new version of a row while surrogate key
+  > is increasing.
+
+  This macro is designed to be used as part of a wider load / ETL process (such
+  as the one in [Data Controller for SAS](https://datacontroller.io)).
+
+  Specifically, the macro assumes that the base table has already been 'locked'
+  (eg with the mp_lockanytable.sas macro) prior to invocation.  Also, several
+  tables are assumed to exist (names are configurable):
+
+  @li work.staging_table - the staged data, minus the retained key element
+  @li permlib.base_table - the target table to be loaded (**not** loaded by this
+    macro)
+  @li permlib.maxkeytable - optional, used to store load metaadata.
+    The definition is available by running mp_coretable.sas as follows:
+    `mp_coretable(MAXKEYTABLE)`.
+  @li permlib.locktable - Necessary if maxkeytable is being populated. The
+    definition is available by running mp_coretable.sas as follows:
+    `mp_coretable(LOCKTABLE)`.
+
+
+  @param [in] base_lib= (WORK) Libref of the base (target) table.
+  @param [in] base_dsn= (BASETABLE) Name of the base (target) table.
+  @param [in] append_lib= (WORK) Libref of the staging table
+  @param [in] append_dsn= (APPENDTABLE) Name of the staging table
+  @param [in] retained_key= (DEFAULT_RK) Name of RK to generate (should exist on
+    base table)
+  @param [in] business_key= (PK1 PK2) Business key against which to generate
+    RK values.  Should be unique and not null on the staging table.
+  @param [in] check_uniqueness=(NO) Set to yes to perform a uniqueness check.
+    Recommended if there is a chance that the staging data is not unique on the
+    business key.
+  @param [in] maxkeytable= (0) Provide a maxkeytable libds reference here, to
+    store load metadata (maxkey val, load time).  Set to zero if metadata is not
+    required, eg, when preparing a 'dummy' load. Structure is described above.
+    See below for sample data.
+    |KEYTABLE:$32.|KEYCOLUMN:$32.|MAX_KEY:best.|PROCESSED_DTTM:E8601DT26.6|
+    |---|---|---|---|
+    |`DC487173.MPE_SELECTBOX `|`SELECTBOX_RK `|`55 `|`1950427787.8 `|
+    |`DC487173.MPE_FILTERANYTABLE `|`filter_rk `|`14 `|`1951053886.8 `|
+  @param [in] locktable= (0) If updating the maxkeytable, provide the libds
+    reference to the lock table (per mp_lockanytable.sas macro)
+  @param [in] filter_str= Apply a filter - useful for SCD2 or BITEMPORAL loads.
+    Example: `filter_str=%str( (where=( &now < &tech_to)) )`
+  @param [out] outds= (WORK.APPEND) Output table (staging table + retained key)
+
+  <h4> SAS Macros </h4>
+  @li mf_existvar.sas
+  @li mf_fmtdttm.sas
+  @li mf_getquotedstr.sas
+  @li mf_getuniquename.sas
+  @li mf_nobs.sas
+  @li mp_abort.sas
+  @li mp_lockanytable.sas
+
+  <h4> Related Macros </h4>
+  @li mp_filterstore.sas
+  @li mp_retainedkey.test.sas
+
+  @version 9.2
+
+**/
+
+%macro mp_retainedkey(
+  base_lib=WORK
+  ,base_dsn=BASETABLE
+  ,append_lib=WORK
+  ,append_dsn=APPENDTABLE
+  ,retained_key=DEFAULT_RK
+  ,business_key= PK1 PK2
+  ,check_uniqueness=NO
+  ,maxkeytable=0
+  ,locktable=0
+  ,outds=WORK.APPEND
+  ,filter_str=
+);
+%put &sysmacroname entry vars:;
+%put _local_;
+
+%local base_libds app_libds key_field check maxkey idx_pk newkey_cnt iserr
+  msg x tempds1 tempds2 comma_pk appnobs checknobs dropvar tempvar idx_val;
+%let base_libds=%upcase(&base_lib..&base_dsn);
+%let app_libds=%upcase(&append_lib..&append_dsn);
+%let tempds1=%mf_getuniquename();
+%let tempds2=%mf_getuniquename();
+%let comma_pk=%mf_getquotedstr(in_str=%str(&business_key),dlm=%str(,),quote=);
+%let outds=%sysfunc(ifc(%index(&outds,.)=0,work.&outds,&outds));
+/* validation checks */
+%let iserr=0;
+%if &syscc>0 %then %do;
+  %let iserr=1;
+  %let msg=%str(SYSCC=&syscc on macro entry);
+%end;
+%else %if %sysfunc(exist(&base_libds))=0 %then %do;
+  %let iserr=1;
+  %let msg=%str(Base LIBDS (&base_libds) expected but NOT FOUND);
+%end;
+%else %if %sysfunc(exist(&app_libds))=0 %then %do;
+  %let iserr=1;
+  %let msg=%str(Append LIBDS (&app_libds) expected but NOT FOUND);
+%end;
+%else %if &maxkeytable ne 0 and %sysfunc(exist(&maxkeytable))=0  %then %do;
+  %let iserr=1;
+  %let msg=%str(Maxkeytable (&maxkeytable) expected but NOT FOUND);
+%end;
+%else %if &maxkeytable ne 0 and %sysfunc(exist(&locktable))=0  %then %do;
+  %let iserr=1;
+  %let msg=%str(Locktable (&locktable) expected but NOT FOUND);
+%end;
+%else %if %length(&business_key)=0 %then %do;
+  %let iserr=1;
+  %let msg=%str(Business key (&business_key) expected but NOT FOUND);
+%end;
+
+%do x=1 %to %sysfunc(countw(&business_key));
+  /* check business key values exist */
+  %let key_field=%scan(&business_key,&x,%str( ));
+  %if not %mf_existvar(&app_libds,&key_field) %then %do;
+    %let iserr=1;
+    %let msg=Business key (&key_field) not found on &app_libds!;
+    %goto err;
+  %end;
+  %else %if not %mf_existvar(&base_libds,&key_field) %then %do;
+    %let iserr=1;
+    %let msg=Business key (&key_field) not found on &base_libds!;
+    %goto err;
+  %end;
+%end;
+%err:
+%if &iserr=1 %then %do;
+  /* err case so first perform an unlock of the base table before exiting */
+  %mp_lockanytable(
+    UNLOCK,lib=&base_lib,ds=&base_dsn,ref=%superq(msg),ctl_ds=&locktable
+  )
+%end;
+%mp_abort(iftrue=(&iserr=1),mac=mp_retainedkey,msg=%superq(msg))
+
+proc sql noprint;
+select sum(max(&retained_key),0) into: maxkey from &base_libds;
+
+/**
+  * get base table RK and bus field values for lookup
+  */
+proc sql noprint;
+create table &tempds1 as
+  select distinct &comma_pk,&retained_key
+  from &base_libds &filter_str
+  order by &comma_pk,&retained_key;
+
+%if &check_uniqueness=YES %then %do;
+  select count(*) into:checknobs
+    from (select distinct &comma_pk from &app_libds);
+  select count(*) into: appnobs from &app_libds; /* might be view */
+  %if &checknobs ne &appnobs %then %do;
+    %let msg=Source table &app_libds is not unique on (&business_key);
+    %let iserr=1;
+  %end;
+%end;
+%if &iserr=1 %then %do;
+  /* err case so first perform an unlock of the base table before exiting */
+  %mp_lockanytable(
+    UNLOCK,lib=&base_lib,ds=&base_dsn,ref=%superq(msg),ctl_ds=&locktable
+  )
+%end;
+%mp_abort(iftrue= (&iserr=1),mac=mp_retainedkey,msg=%superq(msg))
+
+%if %mf_existvar(&app_libds,&retained_key)
+%then %let dropvar=(drop=&retained_key);
+
+/* prepare interim table with retained key populated for matching keys */
+proc sql noprint;
+create table &tempds2 as
+  select b.&retained_key, a.*
+  from &app_libds &dropvar a
+  left join &tempds1 b
+  on 1
+  %do idx_pk=1 %to %sysfunc(countw(&business_key));
+    %let idx_val=%scan(&business_key,&idx_pk);
+    and a.&idx_val=b.&idx_val
+  %end;
+  order by &retained_key;
+
+/* identify the number of entries without retained keys (new records) */
+select count(*) into: newkey_cnt
+  from &tempds2
+  where missing(&retained_key);
+quit;
+
+/**
+  * Update maxkey table if link provided
+  */
+%if &maxkeytable ne 0 %then %do;
+  proc sql noprint;
+  select count(*) into: check from &maxkeytable
+    where upcase(keytable)="&base_libds";
+
+  %mp_lockanytable(LOCK
+    ,lib=%scan(&maxkeytable,1,.)
+    ,ds=%scan(&maxkeytable,2,.)
+    ,ref=Updating maxkeyvalues with mp_retainedkey
+    ,ctl_ds=&locktable
+  )
+  proc sql;
+  %if &check=0 %then %do;
+  insert into &maxkeytable
+    set keytable="&base_libds"
+      ,keycolumn="&retained_key"
+      ,max_key=%eval(&maxkey+&newkey_cnt)
+      ,processed_dttm="%sysfunc(datetime(),%mf_fmtdttm())"dt;
+  %end;
+  %else %do;
+  update &maxkeytable
+    set max_key=%eval(&maxkey+&newkey_cnt)
+      ,processed_dttm="%sysfunc(datetime(),%mf_fmtdttm())"dt
+    where keytable="&base_libds";
+  %end;
+  %mp_lockanytable(UNLOCK
+    ,lib=%scan(&maxkeytable,1,.)
+    ,ds=%scan(&maxkeytable,2,.)
+    ,ref=Updating maxkeyvalues with maxkey=%eval(&maxkey+&newkey_cnt)
+    ,ctl_ds=&locktable
+  )
+%end;
+
+/* fill in the missing retained key values */
+%let tempvar=%mf_getuniquename();
+data &outds(drop=&tempvar);
+  retain &tempvar %eval(&maxkey+1);
+  set &tempds2;
+  if &retained_key =. then &retained_key=&tempvar;
+  &tempvar=&tempvar+1;
+run;
+
+%mend mp_retainedkey;
+

package/macros/mp_runddl.sas

@@ -0,0 +1,49 @@
+/**
+  @file mp_runddl.sas
+  @brief An opinionated way to execute DDL files in SAS.
+  @details When delivering projects there should be seperation between the DDL
+    used to generate the tables and the sample data used to populate them.
+
+  This macro expects certain folder structure - eg:
+
+    rootlib
+    |-- LIBREF1
+    |   |__ mytable.ddl
+    |   |__ someothertable.ddl
+    |-- LIBREF2
+    |   |__ table1.ddl
+    |   |__ table2.ddl
+    |-- LIBREF3
+        |__ table3.ddl
+        |__ table4.ddl
+
+  Only files with the .ddl suffix are executed.  The parent folder name is used
+  as the libref.
+  Files should NOT contain the `proc sql` statement - this is to prevent
+  statements being executed if there is an err condition.
+
+  Usage:
+
+    %mp_runddl(/some/rootlib)  * execute all libs ;
+
+    %mp_runddl(/some/rootlib, inc=LIBREF1 LIBREF2) * include only these libs;
+
+    %mp_runddl(/some/rootlib, exc=LIBREF3) * same as above ;
+
+
+  @param path location of the DDL folder structure
+  @param inc= list of librefs to include
+  @param exc= list of librefs to exclude (takes precedence over inc=)
+
+  @version 9.3
+  @author Allan Bowe
+  @source https://github.com/sasjs/core
+
+**/
+
+%macro mp_runddl(path, inc=, exc=
+)/*/STORE SOURCE*/;
+
+
+
+%mend mp_runddl;

package/macros/mp_searchcols.sas

@@ -0,0 +1,103 @@
+/**
+  @file mp_searchcols.sas
+  @brief Searches all columns in a library
+  @details
+  Scans a set of libraries and creates a dataset containing all source tables
+    containing one or more of a particular set of columns
+
+  Usage:
+
+      %mp_searchcols(libs=sashelp work, cols=name sex age)
+
+  @param libs=(SASHELP) Space separated list of libraries to search for columns
+  @param cols= Space separated list of column names to search for (not case
+    sensitive)
+  @param outds=(mp_searchcols) the table to create with the results.  Will have
+    one line per table match.
+  @param match=(ANY) The match type. Valid values:
+    @li ANY - The table contains at least one of the columns
+    @li WILD - The table contains a column with a name that partially matches
+
+  @version 9.2
+  @author Allan Bowe
+**/
+
+%macro mp_searchcols(libs=sashelp
+  ,cols=
+  ,outds=mp_searchcols
+  ,match=ANY
+)/*/STORE SOURCE*/;
+
+%put &sysmacroname process began at %sysfunc(datetime(),datetime19.);
+
+/* get the list of tables in the library */
+proc sql;
+create table _data_ as
+  select distinct upcase(libname) as libname
+    , upcase(memname) as memname
+    , upcase(name) as name
+  from dictionary.columns
+%if %sysevalf(%superq(libs)=,boolean)=0 %then %do;
+  where upcase(libname) in ("IMPOSSIBLE",
+  %local x;
+  %do x=1 %to %sysfunc(countw(&libs));
+    "%upcase(%scan(&libs,&x))"
+  %end;
+  )
+%end;
+  order by 1,2,3;
+
+%local tempds;
+%let tempds=&syslast;
+data &outds;
+  set &tempds;
+  length cols matchcols $32767;
+  cols=upcase(symget('cols'));
+  colcount=countw(cols);
+  by libname memname name;
+  if _n_=1 then do;
+    putlog "Searching libs: &libs";
+    putlog "Searching cols: " cols;
+  end;
+  if first.memname then do;
+    sumcols=0;
+    retain matchcols;
+    matchcols='';
+  end;
+%if &match=ANY %then %do;
+  if findw(cols,name,,'spit') then do;
+    sumcols+1;
+    matchcols=cats(matchcols)!!' '!!cats(name);
+  end;
+%end;
+%else %if &match=WILD %then %do;
+  if _n_=1 then do;
+    retain wcount;
+    wcount=countw(cols);
+    drop wcount;
+  end;
+  do i=1 to wcount;
+    length curword $32;
+    curword=scan(cols,i,' ');
+    drop curword;
+    if index(name,cats(curword)) then do;
+      sumcols+1;
+      matchcols=cats(matchcols)!!' '!!cats(curword);
+    end;
+  end;
+%end;
+
+  if last.memname then do;
+    if sumcols>0 then output;
+    if sumcols=colcount then putlog "Full Match: " libname memname;
+  end;
+  keep libname memname sumcols matchcols;
+run;
+
+proc sort; by descending sumcols memname libname; run;
+
+proc sql;
+drop table &tempds;
+%put &sysmacroname process finished at %sysfunc(datetime(),datetime19.);
+
+%mend mp_searchcols;

package/macros/mp_searchdata.sas

@@ -0,0 +1,131 @@
+/**
+  @file
+  @brief Searches all data in a library
+  @details
+  Scans an entire library and creates a copy of any table
+    containing a specific string OR numeric value.  Only
+    matching records are written out.
+    If both a string and numval are provided, the string
+    will take precedence.
+
+  Usage:
+
+      %mp_searchdata(lib=sashelp, string=Jan)
+      %mp_searchdata(lib=sashelp, ds=bird, numval=1)
+      %mp_searchdata(lib=sashelp, ds=class, string=l,outobs=5)
+
+
+  Outputs zero or more tables to an MPSEARCH library with specific records.
+
+  @param [in] lib=  The libref to search (should be already assigned)
+  @param [in] ds= The dataset to search (leave blank to search entire library)
+  @param [in] string= String value to search (case sensitive, can be partial)
+  @param [in] numval= Numeric value to search (must be exact)
+  @param [out] outloc= (0) Optionally specify the directory in which to
+    create the the output datasets with matching rows.  By default it will
+    write them to a temporary subdirectory within the WORK folder.
+  @param [out] outlib= (MPSEARCH) Assign a different libref to the output
+    library containing the matching datasets / records
+  @param [in] outobs= set to a positive integer to restrict the number of
+    observations
+  @param [in] filter_text= (1=1) Add a (valid) filter clause to further filter
+    the results.
+
+  <h4> SAS Macros </h4>
+  @li mf_getuniquename.sas
+  @li mf_getvarlist.sas
+  @li mf_getvartype.sas
+  @li mf_mkdir.sas
+  @li mf_nobs.sas
+
+  @version 9.2
+  @author Allan Bowe
+**/
+
+%macro mp_searchdata(lib=
+  ,ds=
+  ,string= /* the query will use a contains (?) operator */
+  ,numval= /* numeric must match exactly */
+  ,outloc=0
+  ,outlib=MPSEARCH
+  ,outobs=-1
+  ,filter_text=%str(1=1)
+)/*/STORE SOURCE*/;
+
+%local table_list table table_num table colnum col start_tm check_tm vars type
+  coltype;
+%put process began at %sysfunc(datetime(),datetime19.);
+
+%if &syscc ge 4 %then %do;
+  %put %str(WAR)NING: SYSCC=&syscc on macro entry;
+  %return;
+%end;
+
+%if &string = %then %let type=N;
+%else %let type=C;
+
+%if "&outloc"="0" %then %do;
+  %let outloc=%sysfunc(pathname(work))/%mf_getuniquename();
+%end;
+
+%mf_mkdir(&outloc)
+libname &outlib "&outloc";
+
+/* get the list of tables in the library */
+proc sql noprint;
+select distinct memname into: table_list separated by ' '
+  from dictionary.tables
+  where upcase(libname)="%upcase(&lib)"
+%if &ds ne %then %do;
+  and upcase(memname)=%upcase("&ds")
+%end;
+  ;
+/* check that we have something to check */
+%if %length(&table_list)=0 %then %put library &lib contains no tables!;
+/* loop through each table */
+%else %do table_num=1 %to %sysfunc(countw(&table_list,%str( )));
+  %let table=%scan(&table_list,&table_num,%str( ));
+  %let vars=%mf_getvarlist(&lib..&table);
+  %if %length(&vars)=0 %then %do;
+    %put NO COLUMNS IN &lib..&table!  This will be skipped.;
+  %end;
+  %else %do;
+    %let check_tm=%sysfunc(datetime());
+    /* prep input */
+    data &outlib..&table;
+      set &lib..&table;
+      where %unquote(&filter_text) and ( 0
+    /* loop through columns */
+    %do colnum=1 %to %sysfunc(countw(&vars,%str( )));
+      %let col=%scan(&vars,&colnum,%str( ));
+      %let coltype=%mf_getvartype(&lib..&table,&col);
+      %if &type=C and &coltype=C %then %do;
+        /* if a char column, see if it contains the string */
+        or ("&col"n ? "&string")
+      %end;
+      %else %if &type=N and &coltype=N %then %do;
+        /* if numeric match exactly */
+        or ("&col"n = &numval)
+      %end;
+    %end;
+      );
+    %if &outobs>-1 %then %do;
+      if _n_ > &outobs then stop;
+    %end;
+    run;
+    %put Search query for &table took
+      %sysevalf(%sysfunc(datetime())-&check_tm) seconds;
+    %if &syscc ne 0 %then %do;
+      %put %str(ERR)ROR: SYSCC=&syscc when processing &lib..&table;
+      %return;
+    %end;
+    %if %mf_nobs(&outlib..&table)=0 %then %do;
+      proc sql;
+      drop table &outlib..&table;
+    %end;
+  %end;
+%end;
+
+%put process finished at %sysfunc(datetime(),datetime19.);
+
+%mend mp_searchdata;

package/macros/mp_setkeyvalue.sas

@@ -0,0 +1,55 @@
+/**
+  @file
+  @brief Logs a key value pair a control dataset
+  @details If the dataset does not exist, it is created.  Usage:
+
+      %mp_setkeyvalue(someindex,22,type=N)
+      %mp_setkeyvalue(somenewindex,somevalue)
+
+  <h4> SAS Macros </h4>
+  @li mf_existds.sas
+
+  <h4> Related Macros </h4>
+  @li mf_getvalue.sas
+
+  @param [in] key Provide a key on which to perform the lookup
+  @param [in] value Provide a value
+  @param [in] type= either C or N will populate valc and valn respectively.
+    C is default.
+  @param [out] libds= define the target table to hold the parameters
+
+  @version 9.2
+  @author Allan Bowe
+  @source https://github.com/sasjs/core
+
+**/
+
+%macro mp_setkeyvalue(key,value,type=C,libds=work.mp_setkeyvalue
+)/*/STORE SOURCE*/;
+
+  %if not (%mf_existds(&libds)) %then %do;
+    data &libds (index=(key/unique));
+      length key $64 valc $2048 valn 8 type $1;
+      call missing(of _all_);
+      stop;
+    run;
+  %end;
+
+  proc sql;
+    delete from &libds
+      where key=symget('key');
+    insert into &libds
+      set key=symget('key')
+  %if &type=C %then %do;
+        ,valc=symget('value')
+        ,type='C'
+  %end;
+  %else %do;
+        ,valn=symgetn('value')
+        ,type='N'
+  %end;
+  ;
+
+  quit;
+
+%mend mp_setkeyvalue;

package/macros/mp_sortinplace.sas

@@ -0,0 +1,122 @@
+/**
+  @file
+  @brief Sorts a SAS dataset in place, preserving constraints
+  @details Generally if a dataset contains indexes, then it is not necessary to
+  sort it before performing operations such as merges / joins etc.
+  That said, there are a few edge cases where it can be desirable:
+
+    @li To allow adjacent records to be viewed directly in the dataset
+    @li To apply compression, or to remove deleted records
+    @li To improve performance for specific queries
+
+  This macro will only work for BASE (V9) engine libraries.  It works by
+  creating a copy of the dataset (without data, WITH constraints) in the same
+  library, appending a sorted view into it, and finally - renaming it.
+
+  Example usage:
+
+      proc sql;
+      create table work.example as
+        select * from sashelp.class;
+      alter table work.example
+        add constraint pk primary key(name);
+      %mp_sortinplace(work.example)
+
+  @param [in] libds The libref.datasetname that needs to be sorted
+
+  <h4> SAS Macros </h4>
+  @li mf_existds.sas
+  @li mf_getengine.sas
+  @li mf_getquotedstr.sas
+  @li mf_getuniquename.sas
+  @li mf_getvarlist.sas
+  @li mf_nobs.sas
+  @li mp_abort.sas
+  @li mp_getpk.sas
+
+  <h4> Related Macros </h4>
+  @li mp_sortinplace.test.sas
+
+  @version 9.2
+  @author Allan Bowe
+
+**/
+
+%macro mp_sortinplace(libds
+)/*/STORE SOURCE*/;
+
+%local lib ds tempds1 tempds2 tempvw sortkey;
+
+/* perform validations */
+%mp_abort(iftrue=(%sysfunc(countc(&libds,.)) ne 1)
+  ,mac=mp_sortinplace
+  ,msg=%str(LIBDS (&libds) should have LIBREF.DATASET format)
+)
+%mp_abort(iftrue=(%mf_existds(&libds)=0)
+  ,mac=mp_sortinplace
+  ,msg=%str(&libds does not exist)
+)
+
+%let lib=%scan(&libds,1,.);
+%let ds=%scan(&libds,2,.);
+%mp_abort(iftrue=(%mf_getengine(&lib) ne V9)
+  ,mac=mp_sortinplace
+  ,msg=%str(&lib is not a BASE engine library)
+)
+
+/* grab a copy of the constraints so we know what to sort by */
+%let tempds1=%mf_getuniquename(prefix=&sysmacroname);
+%mp_getpk(lib=&lib,ds=&ds,outds=work.&tempds1)
+
+%if %mf_nobs(work.&tempds1)=0 %then %do;
+  %put &sysmacroname: No PK found in &lib..&ds;
+  %put Sorting will not take place;
+  %return;
+%end;
+
+/* fallback sortkey is all fields */
+%let sortkey=%mf_getvarlist(&libds);
+
+/* overlay actual sort key if it exists */
+data _null_;
+  set work.&tempds1;
+  call symputx('sortkey',coalescec(pk_fields,symget('sortkey')));
+run;
+
+
+/* create empty copy, with ALL constraints, in the same library */
+%let tempds2=%mf_getuniquename(prefix=&sysmacroname);
+proc append base=&lib..&tempds2 data=&libds(obs=0);
+run;
+
+/* create sorted view */
+%let tempvw=%mf_getuniquename(prefix=&sysmacroname);
+proc sql;
+create view work.&tempvw as select * from &lib..&ds
+order by %mf_getquotedstr(&sortkey,quote=N);
+
+/* append sorted data */
+proc append base=&lib..&tempds2 data=work.&tempvw;
+run;
+
+/* do validations */
+%mp_abort(iftrue=(&syscc ne 0)
+  ,mac=mp_sortinplace
+  ,msg=%str(syscc=&syscc prior to replace operation)
+)
+%mp_abort(iftrue=(%mf_nobs(&lib..&tempds2) ne %mf_nobs(&lib..&ds))
+  ,mac=mp_sortinplace
+  ,msg=%str(new dataset has a different number of logical obs to the old)
+)
+
+/* drop old dataset */
+proc sql;
+drop table &lib..&ds;
+
+/* rename the new dataset */
+proc datasets library=&lib;
+  change &tempds2=&ds;
+run;
+
+
+%mend mp_sortinplace;