@rubeneschauzier/solidbench 2.1.0

package/templates/queries/interactive-complex-6.sparql

@@ -0,0 +1,41 @@
+# Tag co-occurrence
+PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
+PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
+PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
+PREFIX sn: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/data/>
+PREFIX snvoc: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/vocabulary/>
+PREFIX sntag: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/tag/>
+PREFIX foaf: <http://xmlns.com/foaf/0.1/>
+PREFIX dbpedia: <http://localhost:3000/dbpedia.org/resource/>
+PREFIX dbpedia-owl: <http://localhost:3000/dbpedia.org/ontology/>
+
+SELECT
+    (?tag2Name AS ?tagName)
+    (COUNT(?post) AS ?postCount)
+WHERE
+{
+    BIND($tagName AS ?tagNameParam)
+    {
+        SELECT DISTINCT
+            ?fr
+            ?frId
+        WHERE
+        {
+            ?rootPerson a snvoc:Person .
+            ?rootPerson snvoc:id ?rootId .
+            ?rootPerson ((snvoc:knows/snvoc:hasPerson)|^(snvoc:knows/snvoc:hasPerson))?/((snvoc:knows/snvoc:hasPerson)|^(snvoc:knows/snvoc:hasPerson)) ?fr .
+            ?fr snvoc:id ?frId .
+            FILTER(?frId != ?rootId)
+        }
+    } .
+    ?post a snvoc:Post .
+    ?post snvoc:hasCreator ?fr .
+    ?post snvoc:hasTag ?tag1 .
+    ?tag1 foaf:name ?tagNameParam .
+    ?post snvoc:hasTag ?tag2 .
+    ?tag2 foaf:name ?tag2Name .
+    FILTER (?tag2Name != ?tagNameParam) .
+}
+GROUP BY ?tag2Name
+ORDER BY DESC(?postCount) ?tag2Name
+LIMIT 10

package/templates/queries/interactive-complex-7.sparql

@@ -0,0 +1,84 @@
+# Recent likers
+PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
+PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
+PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
+PREFIX sn: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/data/>
+PREFIX snvoc: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/vocabulary/>
+PREFIX sntag: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/tag/>
+PREFIX foaf: <http://xmlns.com/foaf/0.1/>
+PREFIX dbpedia: <http://localhost:3000/dbpedia.org/resource/>
+PREFIX dbpedia-owl: <http://localhost:3000/dbpedia.org/ontology/>
+
+SELECT
+    ?personId
+    (?firstName AS ?personFirstName)
+    (?lastName AS ?personLastName)
+    ?likeCreationDate
+    (?minMessageId AS ?messageId)
+    (?content AS ?messageContent)
+    (?latency AS ?minutesLatency)
+    ?isNew
+WHERE
+{
+    {
+        SELECT
+            ?person
+            (MIN(?messageId) AS ?minMessageId)
+        WHERE
+        {
+            {
+                SELECT
+                    ?personId
+                    (MAX(?likeDate) AS ?mostRecentLikeDate)
+                WHERE
+                {
+                    {
+                        SELECT DISTINCT
+                            ?message
+                        WHERE
+                        {
+                            VALUES (?type) {(snvoc:Comment) (snvoc:Post)}
+                            ?rootPerson a snvoc:Person .
+                            ?message snvoc:hasCreator ?rootPerson .
+                            ?message a ?type
+                        }
+                    } .
+                    ?person a snvoc:Person .
+                    ?person snvoc:likes ?like .
+                    ?person snvoc:id ?personId .
+                    ?like snvoc:hasPost|snvoc:hasComment ?message .
+                    ?like snvoc:creationDate ?likeDate .
+                }
+                GROUP BY ?personId
+                ORDER BY DESC(?mostRecentLikeDate) ?personId
+                LIMIT 20
+            }
+            VALUES (?type) {(snvoc:Comment) (snvoc:Post)}
+            ?rootPerson a snvoc:Person .
+            ?message snvoc:hasCreator ?rootPerson .
+            ?message a ?type .
+            ?message snvoc:id ?messageId .
+            ?person a snvoc:Person .
+            ?person snvoc:id ?personId .
+            ?person snvoc:likes ?like .
+            ?like snvoc:hasPost|snvoc:hasComment ?message .
+            ?like snvoc:creationDate ?mostRecentLikeDate .
+        }
+        GROUP BY ?person
+    } .
+    ?person snvoc:id ?personId .
+    ?person snvoc:firstName ?firstName .
+    ?person snvoc:lastName ?lastName .
+    ?person snvoc:likes ?like .
+    ?like snvoc:hasPost|snvoc:hasComment ?message .
+    ?message snvoc:id ?minMessageId .
+    ?like snvoc:creationDate ?likeCreationDate .
+    ?message snvoc:creationDate ?messageCreationDate .
+    ?message snvoc:content|snvoc:imageFile ?content .
+    BIND( ?likeCreationDate - ?messageCreationDate AS ?latencyInDuration )
+    BIND( (DAY(?latencyInDuration) * 24 + HOURS(?latencyInDuration)) * 60 + MINUTES(?latencyInDuration) AS ?latency )
+    ?rootPerson a snvoc:Person .
+    BIND( NOT EXISTS { ?rootPerson (snvoc:knows/snvoc:hasPerson)|^(snvoc:knows/snvoc:hasPerson) ?person } AS ?isNew )
+}
+ORDER BY DESC(?likeCreationDate) ?personId
+

package/templates/queries/interactive-complex-8.sparql

@@ -0,0 +1,36 @@
+# Recent replies
+PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
+PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
+PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
+PREFIX sn: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/data/>
+PREFIX snvoc: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/vocabulary/>
+PREFIX sntag: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/tag/>
+PREFIX foaf: <http://xmlns.com/foaf/0.1/>
+PREFIX dbpedia: <http://localhost:3000/dbpedia.org/resource/>
+PREFIX dbpedia-owl: <http://localhost:3000/dbpedia.org/ontology/>
+
+SELECT
+    ?personId
+    ?personFirstName
+    ?personLastName
+    ?commentCreationDate
+    ?commentId
+    ?commentContent
+WHERE
+{
+    VALUES (?type) {(snvoc:Comment) (snvoc:Post)}
+    ?rootPerson a snvoc:Person .
+    ?message snvoc:hasCreator ?rootPerson .
+    ?message a ?type .
+    ?comment a snvoc:Comment .
+    ?comment snvoc:replyOf ?message .
+    ?comment snvoc:creationDate ?commentCreationDate .
+    ?comment snvoc:id ?commentId .
+    ?comment snvoc:content ?commentContent .
+    ?comment snvoc:hasCreator ?person .
+    ?person snvoc:id ?personId .
+    ?person snvoc:firstName ?personFirstName .
+    ?person snvoc:lastName ?personLastName
+}
+ORDER BY DESC(?commentCreationDate) ?commentId
+LIMIT 20

package/templates/queries/interactive-complex-9.sparql

@@ -0,0 +1,45 @@
+# Recent messages by friends or friends of friends
+PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
+PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
+PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
+PREFIX sn: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/data/>
+PREFIX snvoc: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/vocabulary/>
+PREFIX sntag: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/tag/>
+PREFIX foaf: <http://xmlns.com/foaf/0.1/>
+PREFIX dbpedia: <http://localhost:3000/dbpedia.org/resource/>
+PREFIX dbpedia-owl: <http://localhost:3000/dbpedia.org/ontology/>
+
+SELECT
+    (?frId AS ?personId)
+    (?first AS ?personFirstName)
+    (?last AS ?personLastName)
+    ?messageId
+    (?content AS ?messageContent)
+    (?creationDate AS ?messageCreationDate)
+WHERE {
+    VALUES (?type) {(snvoc:Comment) (snvoc:Post)}
+    {
+        SELECT DISTINCT
+            ?fr
+            ?frId
+        WHERE
+        {
+            ?rootPerson a snvoc:Person .
+            ?rootPerson snvoc:id ?rootId .
+            ?rootPerson ((snvoc:knows/snvoc:hasPerson)|^(snvoc:knows/snvoc:hasPerson))?/((snvoc:knows/snvoc:hasPerson)|^(snvoc:knows/snvoc:hasPerson)) ?fr .
+            ?fr snvoc:id ?frId .
+            FILTER(?frId != ?rootId)
+        }
+    } .
+    ?message snvoc:hasCreator ?fr .
+    ?message a ?type .
+    ?message snvoc:creationDate ?creationDate .
+    FILTER(?creationDate < ?maxDate) .
+    ?message snvoc:content|snvoc:imageFile ?content .
+    ?message snvoc:id ?messageId .
+    ?fr snvoc:firstName ?first .
+    ?fr snvoc:lastName ?last .
+    ?fr snvoc:id ?frId
+}
+ORDER BY DESC(?creationDate) ?post
+LIMIT 20

package/templates/queries/interactive-discover-1.sparql

@@ -0,0 +1,23 @@
+# All posts of a person
+PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
+PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
+PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
+PREFIX sn: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/data/>
+PREFIX snvoc: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/vocabulary/>
+PREFIX sntag: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/tag/>
+PREFIX foaf: <http://xmlns.com/foaf/0.1/>
+PREFIX dbpedia: <http://localhost:3000/dbpedia.org/resource/>
+PREFIX dbpedia-owl: <http://localhost:3000/dbpedia.org/ontology/>
+
+SELECT
+    ?messageId
+    ?messageCreationDate
+    ?messageContent
+WHERE
+{
+    ?message snvoc:hasCreator ?person;
+        rdf:type snvoc:Post;
+        snvoc:content ?messageContent;
+        snvoc:creationDate ?messageCreationDate;
+        snvoc:id ?messageId.
+}

package/templates/queries/interactive-discover-2.sparql

@@ -0,0 +1,23 @@
+# All messages of a person
+PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
+PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
+PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
+PREFIX sn: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/data/>
+PREFIX snvoc: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/vocabulary/>
+PREFIX sntag: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/tag/>
+PREFIX foaf: <http://xmlns.com/foaf/0.1/>
+PREFIX dbpedia: <http://localhost:3000/dbpedia.org/resource/>
+PREFIX dbpedia-owl: <http://localhost:3000/dbpedia.org/ontology/>
+
+SELECT
+    ?messageId
+    ?messageCreationDate
+    ?messageContent
+WHERE
+{
+    ?message snvoc:hasCreator ?person;
+        snvoc:content ?messageContent;
+        snvoc:creationDate ?messageCreationDate;
+        snvoc:id ?messageId.
+    { ?message rdf:type snvoc:Post } UNION { ?message rdf:type snvoc:Comment }
+}

package/templates/queries/interactive-discover-3.sparql

@@ -0,0 +1,22 @@
+# Top tags in messages from a person
+PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
+PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
+PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
+PREFIX sn: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/data/>
+PREFIX snvoc: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/vocabulary/>
+PREFIX sntag: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/tag/>
+PREFIX foaf: <http://xmlns.com/foaf/0.1/>
+PREFIX dbpedia: <http://localhost:3000/dbpedia.org/resource/>
+PREFIX dbpedia-owl: <http://localhost:3000/dbpedia.org/ontology/>
+
+SELECT
+    ?tagName
+    (COUNT(?message) as ?messages)
+WHERE
+{
+    ?message snvoc:hasCreator ?person;
+        snvoc:hasTag ?tag.
+    ?tag foaf:name ?tagName.
+}
+GROUP BY ?tagName
+ORDER BY DESC(?messages)

package/templates/queries/interactive-discover-4.sparql

@@ -0,0 +1,23 @@
+# Top locations in comments from a person
+PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
+PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
+PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
+PREFIX sn: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/data/>
+PREFIX snvoc: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/vocabulary/>
+PREFIX sntag: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/tag/>
+PREFIX foaf: <http://xmlns.com/foaf/0.1/>
+PREFIX dbpedia: <http://localhost:3000/dbpedia.org/resource/>
+PREFIX dbpedia-owl: <http://localhost:3000/dbpedia.org/ontology/>
+
+SELECT
+    ?locationName
+    (COUNT(?message) as ?messages)
+WHERE
+{
+    ?message snvoc:hasCreator ?person;
+        rdf:type snvoc:Comment;
+        snvoc:isLocatedIn ?location.
+    ?location foaf:name ?locationName.
+}
+GROUP BY ?locationName
+ORDER BY DESC(?messages)

package/templates/queries/interactive-discover-5.sparql

@@ -0,0 +1,19 @@
+# All IPs a person has messaged from
+PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
+PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
+PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
+PREFIX sn: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/data/>
+PREFIX snvoc: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/vocabulary/>
+PREFIX sntag: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/tag/>
+PREFIX foaf: <http://xmlns.com/foaf/0.1/>
+PREFIX dbpedia: <http://localhost:3000/dbpedia.org/resource/>
+PREFIX dbpedia-owl: <http://localhost:3000/dbpedia.org/ontology/>
+
+SELECT
+DISTINCT
+    ?locationIp
+WHERE
+{
+    ?message snvoc:hasCreator ?person;
+        snvoc:locationIP ?locationIp.
+}

package/templates/queries/interactive-discover-6.sparql

@@ -0,0 +1,22 @@
+# All fora a person messaged on
+PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
+PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
+PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
+PREFIX sn: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/data/>
+PREFIX snvoc: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/vocabulary/>
+PREFIX sntag: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/tag/>
+PREFIX foaf: <http://xmlns.com/foaf/0.1/>
+PREFIX dbpedia: <http://localhost:3000/dbpedia.org/resource/>
+PREFIX dbpedia-owl: <http://localhost:3000/dbpedia.org/ontology/>
+
+SELECT
+DISTINCT
+    ?forumId
+    ?forumTitle
+WHERE
+{
+    ?message snvoc:hasCreator ?person.
+    ?forum snvoc:containerOf ?message;
+            snvoc:id ?forumId;
+            snvoc:title ?forumTitle.
+}

package/templates/queries/interactive-discover-7.sparql

@@ -0,0 +1,23 @@
+# All moderators in fora a person messaged on
+PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
+PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
+PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
+PREFIX sn: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/data/>
+PREFIX snvoc: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/vocabulary/>
+PREFIX sntag: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/tag/>
+PREFIX foaf: <http://xmlns.com/foaf/0.1/>
+PREFIX dbpedia: <http://localhost:3000/dbpedia.org/resource/>
+PREFIX dbpedia-owl: <http://localhost:3000/dbpedia.org/ontology/>
+
+SELECT
+DISTINCT
+    ?firstName
+    ?lastName
+WHERE
+{
+    ?message snvoc:hasCreator ?person.
+    ?forum snvoc:containerOf ?message;
+        snvoc:hasModerator ?moderator.
+    ?moderator snvoc:firstName ?firstName .
+    ?moderator snvoc:lastName ?lastName .
+}

package/templates/queries/interactive-discover-8.sparql

@@ -0,0 +1,22 @@
+# Other messages created by people that a person likes messages from
+PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
+PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
+PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
+PREFIX sn: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/data/>
+PREFIX snvoc: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/vocabulary/>
+PREFIX sntag: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/tag/>
+PREFIX foaf: <http://xmlns.com/foaf/0.1/>
+PREFIX dbpedia: <http://localhost:3000/dbpedia.org/resource/>
+PREFIX dbpedia-owl: <http://localhost:3000/dbpedia.org/ontology/>
+
+SELECT
+DISTINCT
+    ?creator
+    ?messageContent
+WHERE
+{
+    ?person snvoc:likes [ snvoc:hasPost|snvoc:hasComment ?message ].
+    ?message snvoc:hasCreator ?creator.
+    ?otherMessage snvoc:hasCreator ?creator;
+        snvoc:content ?messageContent.
+} LIMIT 10

package/templates/queries/interactive-short-1-nocity.sparql

@@ -0,0 +1,33 @@
+# Profile of a person, without lookup to the city id
+PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
+PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
+PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
+PREFIX sn: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/data/>
+PREFIX snvoc: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/vocabulary/>
+PREFIX sntag: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/tag/>
+PREFIX foaf: <http://xmlns.com/foaf/0.1/>
+PREFIX dbpedia: <http://localhost:3000/dbpedia.org/resource/>
+PREFIX dbpedia-owl: <http://localhost:3000/dbpedia.org/ontology/>
+
+SELECT
+    ?firstName
+    ?lastName
+    ?birthday
+    ?locationIP
+    ?browserUsed
+    ?cityId
+    ?gender
+    ?creationDate
+WHERE
+{
+    ?person a snvoc:Person .
+    ?person snvoc:id ?personId .
+    ?person snvoc:firstName ?firstName .
+    ?person snvoc:lastName ?lastName .
+    ?person snvoc:gender ?gender .
+    ?person snvoc:birthday ?birthday .
+    ?person snvoc:creationDate ?creationDate .
+    ?person snvoc:locationIP ?locationIP .
+    ?person snvoc:isLocatedIn ?city .
+    ?person snvoc:browserUsed ?browserUsed .
+}

package/templates/queries/interactive-short-1.sparql

@@ -0,0 +1,34 @@
+# Profile of a person
+PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
+PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
+PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
+PREFIX sn: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/data/>
+PREFIX snvoc: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/vocabulary/>
+PREFIX sntag: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/tag/>
+PREFIX foaf: <http://xmlns.com/foaf/0.1/>
+PREFIX dbpedia: <http://localhost:3000/dbpedia.org/resource/>
+PREFIX dbpedia-owl: <http://localhost:3000/dbpedia.org/ontology/>
+
+SELECT
+    ?firstName
+    ?lastName
+    ?birthday
+    ?locationIP
+    ?browserUsed
+    ?cityId
+    ?gender
+    ?creationDate
+WHERE
+{
+    ?person a snvoc:Person .
+    ?person snvoc:id ?personId .
+    ?person snvoc:firstName ?firstName .
+    ?person snvoc:lastName ?lastName .
+    ?person snvoc:gender ?gender .
+    ?person snvoc:birthday ?birthday .
+    ?person snvoc:creationDate ?creationDate .
+    ?person snvoc:locationIP ?locationIP .
+    ?person snvoc:isLocatedIn ?city .
+    ?city snvoc:id ?cityId .
+    ?person snvoc:browserUsed ?browserUsed .
+}

package/templates/queries/interactive-short-2.sparql

@@ -0,0 +1,39 @@
+# Recent messages of a person
+PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
+PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
+PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
+PREFIX sn: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/data/>
+PREFIX snvoc: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/vocabulary/>
+PREFIX sntag: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/tag/>
+PREFIX foaf: <http://xmlns.com/foaf/0.1/>
+PREFIX dbpedia: <http://localhost:3000/dbpedia.org/resource/>
+PREFIX dbpedia-owl: <http://localhost:3000/dbpedia.org/ontology/>
+
+SELECT
+    ?messageId
+    ?messageContent
+    ?messageCreationDate
+    ?originalPostId
+    ?originalPostAuthorId
+    ?originalPostAuthorFirstName
+    ?originalPostAuthorLastName
+WHERE {
+    ?person a snvoc:Person .
+    ?person snvoc:id ?personId .
+    ?message snvoc:hasCreator ?person .
+    ?message snvoc:content|snvoc:imageFile ?messageContent .
+    ?message snvoc:creationDate ?messageCreationDate .
+    ?message snvoc:id ?messageId .
+    OPTIONAL {
+        ?message snvoc:replyOf* ?originalPostInner .
+        ?originalPostInner a snvoc:Post .
+    } .
+    BIND( COALESCE(?originalPostInner, ?message) AS ?originalPost ) .
+    ?originalPost snvoc:id ?originalPostId .
+    ?originalPost snvoc:hasCreator ?creator .
+    ?creator snvoc:firstName ?originalPostAuthorFirstName .
+    ?creator snvoc:lastName ?originalPostAuthorLastName .
+    ?creator snvoc:id ?originalPostAuthorId .
+}
+LIMIT 10
+

package/templates/queries/interactive-short-3-unidir.sparql

@@ -0,0 +1,27 @@
+# Friends of a person (unidirectional)
+PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
+PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
+PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
+PREFIX sn: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/data/>
+PREFIX snvoc: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/vocabulary/>
+PREFIX sntag: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/tag/>
+PREFIX foaf: <http://xmlns.com/foaf/0.1/>
+PREFIX dbpedia: <http://localhost:3000/dbpedia.org/resource/>
+PREFIX dbpedia-owl: <http://localhost:3000/dbpedia.org/ontology/>
+
+SELECT
+    ?personId
+    ?firstName
+    ?lastName
+    ?friendshipCreationDate
+WHERE
+{
+    ?rootPerson a snvoc:Person .
+    ?rootPerson snvoc:id ?rootId .
+        ?rootPerson snvoc:knows ?knows .
+        ?knows snvoc:hasPerson ?person .
+    ?knows snvoc:creationDate ?friendshipCreationDate .
+    ?person snvoc:firstName ?firstName .
+    ?person snvoc:lastName ?lastName .
+    ?person snvoc:id ?personId .
+}

package/templates/queries/interactive-short-3.sparql

@@ -0,0 +1,32 @@
+# Friends of a person
+PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
+PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
+PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
+PREFIX sn: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/data/>
+PREFIX snvoc: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/vocabulary/>
+PREFIX sntag: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/tag/>
+PREFIX foaf: <http://xmlns.com/foaf/0.1/>
+PREFIX dbpedia: <http://localhost:3000/dbpedia.org/resource/>
+PREFIX dbpedia-owl: <http://localhost:3000/dbpedia.org/ontology/>
+
+SELECT
+    ?personId
+    ?firstName
+    ?lastName
+    ?friendshipCreationDate
+WHERE
+{
+    ?rootPerson a snvoc:Person .
+    ?rootPerson snvoc:id ?rootId .
+    {
+        ?rootPerson snvoc:knows ?knows .
+        ?knows snvoc:hasPerson ?person .
+    } UNION {
+        ?person snvoc:knows ?knows .
+        ?knows snvoc:hasPerson ?rootPerson .
+    }
+    ?knows snvoc:creationDate ?friendshipCreationDate .
+    ?person snvoc:firstName ?firstName .
+    ?person snvoc:lastName ?lastName .
+    ?person snvoc:id ?personId .
+}

package/templates/queries/interactive-short-4-creator.sparql

@@ -0,0 +1,21 @@
+# Content of a message, based on a creator
+PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
+PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
+PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
+PREFIX sn: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/data/>
+PREFIX snvoc: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/vocabulary/>
+PREFIX sntag: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/tag/>
+PREFIX foaf: <http://xmlns.com/foaf/0.1/>
+PREFIX dbpedia: <http://localhost:3000/dbpedia.org/resource/>
+PREFIX dbpedia-owl: <http://localhost:3000/dbpedia.org/ontology/>
+
+SELECT
+    ?messageCreationDate
+    ?messageContent
+WHERE
+{
+    ?message snvoc:id ?messageId .
+    ?message snvoc:creationDate ?messageCreationDate .
+    ?message snvoc:content|snvoc:imageFile ?messageContent .
+    ?message snvoc:hasCreator ?creator .
+}

package/templates/queries/interactive-short-4.sparql

@@ -0,0 +1,20 @@
+# Content of a message
+PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
+PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
+PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
+PREFIX sn: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/data/>
+PREFIX snvoc: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/vocabulary/>
+PREFIX sntag: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/tag/>
+PREFIX foaf: <http://xmlns.com/foaf/0.1/>
+PREFIX dbpedia: <http://localhost:3000/dbpedia.org/resource/>
+PREFIX dbpedia-owl: <http://localhost:3000/dbpedia.org/ontology/>
+
+SELECT
+    ?messageCreationDate
+    ?messageContent
+WHERE
+{
+    ?message snvoc:id ?messageId .
+    ?message snvoc:creationDate ?messageCreationDate .
+    ?message snvoc:content|snvoc:imageFile ?messageContent .
+}

package/templates/queries/interactive-short-5.sparql

@@ -0,0 +1,23 @@
+# Creator of a message
+PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
+PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
+PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
+PREFIX sn: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/data/>
+PREFIX snvoc: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/vocabulary/>
+PREFIX sntag: <http://localhost:3000/www.ldbc.eu/ldbc_socialnet/1.0/tag/>
+PREFIX foaf: <http://xmlns.com/foaf/0.1/>
+PREFIX dbpedia: <http://localhost:3000/dbpedia.org/resource/>
+PREFIX dbpedia-owl: <http://localhost:3000/dbpedia.org/ontology/>
+
+SELECT
+    ?personId
+    ?firstName
+    ?lastName
+WHERE
+{
+    ?message snvoc:id ?messageId .
+    ?message snvoc:hasCreator ?creator .
+    ?creator snvoc:id ?personId .
+    ?creator snvoc:firstName ?firstName .
+    ?creator snvoc:lastName ?lastName .
+}