@pkmn/engine 0.1.0-dev.a324c50f → 0.1.0-dev.a93847b2

package/src/lib/common/data.zig

@@ -27,17 +27,13 @@ test Player {
 }
 
 /// An identifier for a specific Pokémon in battle.
-pub const ID = packed struct {
+pub const ID = packed struct(u8) {
     /// The one-indexed team slot of the Pokémon
     id: u3 = 0,
     /// The Pokémon's trainer.
     player: Player = .P1,
     _: u4 = 0,
 
-    comptime {
-        assert(@sizeOf(ID) == 1);
-    }
-
     /// Converts the identifier into a number.
     pub inline fn int(self: ID) u4 {
         return @intCast(@as(u8, @bitCast(self)));
@@ -52,12 +48,12 @@ pub const ID = packed struct {
 test ID {
     try expectEqual(@as(u8, 0b0001), @as(u8, @bitCast(ID{ .player = .P1, .id = 1 })));
     try expectEqual(@as(u8, 0b1101), @as(u8, @bitCast(ID{ .player = .P2, .id = 5 })));
-    const id = ID{ .player = .P2, .id = 4 };
+    const id: ID = .{ .player = .P2, .id = 4 };
     try expectEqual(id, ID.from(id.int()));
 }
 
 /// A choice made by a player during battle.
-pub const Choice = packed struct {
+pub const Choice = packed struct(u8) {
     /// The choice type.
     type: Choice.Type = .Pass,
     /// The choice data:
@@ -73,10 +69,6 @@ pub const Choice = packed struct {
         Move,
         Switch,
     };
-
-    comptime {
-        assert(@sizeOf(Choice) == 1);
-    }
 };
 
 test Choice {
@@ -89,7 +81,7 @@ test Choice {
 }
 
 /// The result of the battle - all results other than 'None' should be considered terminal.
-pub const Result = packed struct {
+pub const Result = packed struct(u8) {
     /// The type of result from the perspective of Player 1.
     /// `Error` is not possible when in Pokémon Showdown compatibility mode.
     type: Result.Type = .None,
@@ -117,10 +109,6 @@ pub const Result = packed struct {
     pub const Error: Result = .{ .type = .Error };
     /// The default result.
     pub const Default: Result = .{ .p1 = .Move, .p2 = .Move };
-
-    comptime {
-        assert(@sizeOf(Result) == 1);
-    }
 };
 
 test Result {

package/src/lib/common/js.zig

@@ -0,0 +1,118 @@
+const std = @import("std");
+
+const assert = std.debug.assert;
+
+const c = @cImport({
+    @cDefine("NAPI_VERSION", "8");
+    @cInclude("node_api.h");
+});
+
+pub const Array = struct {
+    pub fn init(env: c.napi_env, o: struct { length: ?usize }) c.napi_value {
+        var result: c.napi_value = undefined;
+        assert(c.napi_ok == if (o.length) |n|
+            c.napi_create_array_with_length(env, n, &result)
+        else
+            c.napi_create_array(env, &result));
+        return result;
+    }
+
+    pub fn set(env: c.napi_env, array: c.napi_value, index: u32, value: c.napi_value) void {
+        assert(c.napi_set_element(env, array, index, value) == c.napi_ok);
+    }
+};
+
+pub const Boolean = struct {
+    pub fn init(env: c.napi_env, value: bool) c.napi_value {
+        var result: c.napi_value = undefined;
+        assert(c.napi_get_boolean(env, value, &result) == c.napi_ok);
+        return result;
+    }
+};
+
+pub const Number = struct {
+    pub fn init(env: c.napi_env, value: anytype) c.napi_value {
+        const T = @TypeOf(value);
+        var result: c.napi_value = undefined;
+        assert(c.napi_ok == switch (@typeInfo(T)) {
+            .Int => |info| switch (info.bits) {
+                0...32 => switch (info.signedness) {
+                    .signed => c.napi_create_int32(env, @as(i32, value), &result),
+                    .unsigned => c.napi_create_uint32(env, @as(u32, value), &result),
+                },
+                33...52 => c.napi_create_int64(env, @as(i64, value), &result),
+                else => @compileError("int can't be represented as JS number"),
+            },
+            else => @compileError("expected number, got: " ++ @typeName(T)),
+        });
+        return result;
+    }
+
+    pub fn get(env: c.napi_env, value: c.napi_value, comptime T: type) T {
+        switch (@typeInfo(T)) {
+            .Int => |info| switch (info.bits) {
+                0...32 => switch (info.signedness) {
+                    .signed => {
+                        var result: i32 = undefined;
+                        assert(c.napi_get_value_int32(env, value, &result) == c.napi_ok);
+                        return if (info.bits == 32) result else @intCast(result);
+                    },
+                    .unsigned => {
+                        var result: u32 = undefined;
+                        assert(c.napi_get_value_uint32(env, value, &result) == c.napi_ok);
+                        return if (info.bits == 32) result else @intCast(result);
+                    },
+                },
+                33...63 => {
+                    var result: i64 = undefined;
+                    assert(c.napi_get_value_int64(env, value, &result) == c.napi_ok);
+                    return @intCast(result);
+                },
+                else => {
+                    var result: i64 = undefined;
+                    assert(c.napi_get_value_int64(env, value, &result) == c.napi_ok);
+                    return switch (info.signedness) {
+                        .signed => value,
+                        .unsigned => if (0 <= value) @intCast(value) else unreachable,
+                    };
+                },
+            },
+            else => @compileError("expected number, got: " ++ @typeName(T)),
+        }
+    }
+};
+
+pub const Object = struct {
+    pub fn init(env: c.napi_env) c.napi_value {
+        var result: c.napi_value = undefined;
+        assert(c.napi_create_object(env, &result) == c.napi_ok);
+        return result;
+    }
+};
+
+pub const Property = union(enum) {
+    method: c.napi_callback,
+    value: c.napi_value,
+
+    pub fn init(comptime name: [:0]const u8, property: Property) c.napi_property_descriptor {
+        return .{
+            .utf8name = name,
+            .name = null,
+            .method = switch (property) {
+                .method => |m| m,
+                .value => null,
+            },
+            .getter = null,
+            .setter = null,
+            .value = switch (property) {
+                .method => null,
+                .value => |v| v,
+            },
+            .attributes = switch (property) {
+                .method => c.napi_default,
+                .value => c.napi_enumerable,
+            },
+            .data = null,
+        };
+    }
+};

package/src/lib/common/optional.zig

@@ -0,0 +1,67 @@
+const std = @import("std");
+
+const expect = std.testing.expect;
+const assert = std.debug.assert;
+
+// TODO: ziglang/zig#104
+pub fn Optional(comptime T: type) type {
+    const fields = std.meta.fields(switch (@typeInfo(T)) {
+        .Bool => enum { false, true },
+        else => T,
+    });
+
+    var enumFields: [fields.len + 1]std.builtin.Type.EnumField = undefined;
+    var decls = [_]std.builtin.Type.Declaration{};
+
+    enumFields[0] = .{ .name = "None", .value = 0 };
+
+    inline for (fields, 1..) |field, i| {
+        assert(!std.mem.eql(u8, field.name, "None"));
+        enumFields[i] = .{
+            .name = field.name,
+            .value = i,
+        };
+    }
+
+    return @Type(.{
+        .Enum = .{
+            .tag_type = std.math.IntFittingRange(0, fields.len),
+            .fields = &enumFields,
+            .decls = &decls,
+            .is_exhaustive = true,
+        },
+    });
+}
+
+test Optional {
+    try expect(@bitSizeOf(Optional(bool)) == 2);
+
+    const a: Optional(bool) = .true;
+    try expect(a != .None);
+    try expect(a == .true);
+    try expect(a != .false);
+
+    const b: Optional(bool) = .None;
+    try expect(b == .None);
+    try expect(b != .true);
+    try expect(b != .false);
+
+    const Player = @import("./data.zig").Player;
+    try expect(@bitSizeOf(Optional(Player)) == 2);
+
+    const p: Optional(Player) = .P2;
+    try expect(p != .None);
+    try expect(p != .P1);
+    try expect(p == .P2);
+
+    const q: Optional(Player) = .None;
+    try expect(q == .None);
+    try expect(q != .P1);
+    try expect(q != .P2);
+
+    const Three = enum(u2) { A, B, C };
+    try expect(@bitSizeOf(Optional(Three)) == 2);
+
+    const Four = enum(u2) { A, B, C, D };
+    try expect(@bitSizeOf(Optional(Four)) == 3);
+}