@pkmn/engine 0.1.0-dev.7b099504 → 0.1.0-dev.7c1336ac

package/src/lib/bindings/node.zig

@@ -0,0 +1,121 @@
+const js = @import("../common/js.zig");
+const pkmn = @import("../pkmn.zig");
+const std = @import("std");
+
+const assert = std.debug.assert;
+
+const c = @cImport({
+    @cDefine("NAPI_VERSION", "8");
+    @cInclude("node_api.h");
+});
+
+pub fn register(env: c.napi_env) c.napi_value {
+    const object = js.Object.init(env);
+    const properties = [_]c.napi_property_descriptor{
+        js.Property.init("options", .{ .value = options(env) }),
+        js.Property.init("bindings", .{ .value = bindings(env) }),
+    };
+    assert(c.napi_define_properties(env, object, properties.len, &properties) == c.napi_ok);
+    return object;
+}
+
+fn options(env: c.napi_env) c.napi_value {
+    const object = js.Object.init(env);
+    const properties = [_]c.napi_property_descriptor{
+        js.Property.init("showdown", .{ .value = js.Boolean.init(env, pkmn.options.showdown) }),
+        js.Property.init("log", .{ .value = js.Boolean.init(env, pkmn.options.log) }),
+        js.Property.init("chance", .{ .value = js.Boolean.init(env, pkmn.options.chance) }),
+        js.Property.init("calc", .{ .value = js.Boolean.init(env, pkmn.options.calc) }),
+    };
+    assert(c.napi_define_properties(env, object, properties.len, &properties) == c.napi_ok);
+    return object;
+}
+
+fn bindings(env: c.napi_env) c.napi_value {
+    const array = js.Array.init(env, .{ .length = 1 });
+    js.Array.set(env, array, 0, bind(env, pkmn.gen1));
+    return array;
+}
+
+fn bind(env: c.napi_env, gen: anytype) c.napi_value {
+    const choices_size: u32 = @intCast(gen.CHOICES_SIZE);
+    const logs_size: u32 = @intCast(gen.LOGS_SIZE);
+    const object = js.Object.init(env);
+    const properties = [_]c.napi_property_descriptor{
+        js.Property.init("CHOICES_SIZE", .{ .value = js.Number.init(env, choices_size) }),
+        js.Property.init("LOGS_SIZE", .{ .value = js.Number.init(env, logs_size) }),
+        js.Property.init("update", .{ .method = update(gen) }),
+        js.Property.init("choices", .{ .method = choices(gen) }),
+    };
+    assert(c.napi_define_properties(env, object, properties.len, &properties) == c.napi_ok);
+    return object;
+}
+
+fn update(gen: anytype) c.napi_callback {
+    return struct {
+        fn call(env: c.napi_env, info: c.napi_callback_info) callconv(.C) c.napi_value {
+            var argc: usize = 4;
+            var argv: [4]c.napi_value = undefined;
+            assert(c.napi_get_cb_info(env, info, &argc, &argv, null, null) == c.napi_ok);
+            assert(argc == 4);
+
+            var data: ?*anyopaque = undefined;
+            var len: usize = 0;
+            assert(c.napi_get_arraybuffer_info(env, argv[0], &data, &len) == c.napi_ok);
+            assert(len == @sizeOf(gen.Battle(gen.PRNG)));
+
+            var battle: *gen.Battle(gen.PRNG) = @alignCast(@ptrCast(data.?));
+            const c1: pkmn.Choice = @bitCast(js.Number.get(env, argv[1], u8));
+            const c2: pkmn.Choice = @bitCast(js.Number.get(env, argv[2], u8));
+
+            var vtype: c.napi_valuetype = undefined;
+            assert(c.napi_typeof(env, argv[3], &vtype) == c.napi_ok);
+            const result = switch (vtype) {
+                c.napi_undefined, c.napi_null => battle.update(c1, c2, &gen.NULL),
+                else => result: {
+                    assert(c.napi_get_arraybuffer_info(env, argv[3], &data, &len) == c.napi_ok);
+                    assert(len == gen.LOGS_SIZE);
+
+                    const buf = @as([*]u8, @ptrCast(data.?))[0..gen.LOGS_SIZE];
+                    var stream: pkmn.protocol.ByteStream = .{ .buffer = buf };
+                    // TODO: extract out
+                    var opts = pkmn.battle.options(
+                        pkmn.protocol.FixedLog{ .writer = stream.writer() },
+                        gen.chance.NULL,
+                        gen.calc.NULL,
+                    );
+                    break :result battle.update(c1, c2, &opts);
+                },
+            } catch unreachable;
+
+            return js.Number.init(env, @as(u8, @bitCast(result)));
+        }
+    }.call;
+}
+
+fn choices(gen: anytype) c.napi_callback {
+    return struct {
+        fn call(env: c.napi_env, info: c.napi_callback_info) callconv(.C) c.napi_value {
+            var argc: usize = 4;
+            var argv: [4]c.napi_value = undefined;
+            assert(c.napi_get_cb_info(env, info, &argc, &argv, null, null) == c.napi_ok);
+            assert(argc == 4);
+
+            var data: ?*anyopaque = undefined;
+            var len: usize = 0;
+            assert(c.napi_get_arraybuffer_info(env, argv[0], &data, &len) == c.napi_ok);
+            assert(len == @sizeOf(gen.Battle(gen.PRNG)));
+
+            var battle: *gen.Battle(gen.PRNG) = @alignCast(@ptrCast(data.?));
+            const player: pkmn.Player = @enumFromInt(js.Number.get(env, argv[1], u8));
+            const request: pkmn.Choice.Type = @enumFromInt(js.Number.get(env, argv[2], u8));
+
+            assert(c.napi_get_arraybuffer_info(env, argv[3], &data, &len) == c.napi_ok);
+            assert(len == gen.CHOICES_SIZE);
+
+            const out = @as([*]pkmn.Choice, @ptrCast(data.?))[0..gen.CHOICES_SIZE];
+            const n = battle.choices(player, request, out);
+            return js.Number.init(env, @as(u8, @bitCast(n)));
+        }
+    }.call;
+}

package/src/lib/bindings/wasm.zig

@@ -0,0 +1,59 @@
+const pkmn = @import("../pkmn.zig");
+const std = @import("std");
+
+const assert = std.debug.assert;
+
+const Enum = if (@hasField(std.builtin.Type, "enum")) .@"enum" else .Enum;
+const Strong = if (@hasField(std.builtin.GlobalLinkage, "strong")) .strong else .Strong;
+
+pub const options = pkmn.options;
+
+pub fn gen(comptime num: comptime_int) type {
+    const g = @field(pkmn, "gen" ++ std.fmt.comptimePrint("{d}", .{num}));
+    return struct {
+        pub const CHOICES_SIZE = size(g.CHOICES_SIZE);
+        pub const LOGS_SIZE = size(g.LOGS_SIZE);
+
+        pub fn update(
+            battle: *g.Battle(g.PRNG),
+            c1: pkmn.Choice,
+            c2: pkmn.Choice,
+            options_: ?[*]u8,
+        ) callconv(.C) pkmn.Result {
+            return (if (options_) |o| result: {
+                const buf = @as([*]u8, @ptrCast(o))[0..g.LOGS_SIZE];
+                var stream: pkmn.protocol.ByteStream = .{ .buffer = buf };
+                // TODO: extract out
+                var opts = pkmn.battle.options(
+                    pkmn.protocol.FixedLog{ .writer = stream.writer() },
+                    g.chance.NULL,
+                    g.calc.NULL,
+                );
+                break :result battle.update(c1, c2, &opts);
+            } else battle.update(c1, c2, &g.NULL)) catch unreachable;
+        }
+
+        pub fn choices(
+            battle: *g.Battle(g.PRNG),
+            player: u8,
+            request: u8,
+            buf: [*]u8,
+        ) callconv(.C) u8 {
+            assert(player <= @field(@typeInfo(pkmn.Player), @tagName(Enum)).fields.len);
+            assert(request <= @field(@typeInfo(pkmn.Choice.Type), @tagName(Enum)).fields.len);
+
+            const n = CHOICES_SIZE;
+            return battle.choices(@enumFromInt(player), @enumFromInt(request), @ptrCast(buf[0..n]));
+        }
+    };
+}
+
+pub fn exports() type {
+    @export(gen(1).update, .{ .name = "GEN1_update", .linkage = Strong });
+    @export(gen(1).choices, .{ .name = "GEN1_choices", .linkage = Strong });
+    return struct {};
+}
+
+fn size(n: usize) u32 {
+    return std.math.ceilPowerOfTwo(u32, @as(u32, @intCast(n))) catch unreachable;
+}

package/src/lib/common/array.zig

@@ -0,0 +1,77 @@
+const std = @import("std");
+
+const expectEqual = std.testing.expectEqual;
+const assert = std.debug.assert;
+
+const Int = if (@hasField(std.builtin.Type, "int")) .int else .Int;
+const Enum = if (@hasField(std.builtin.Type, "enum")) .@"enum" else .Enum;
+
+/// Helpers for working with bit-packed arrays of non-powers-of-2 types.
+/// NOTE: ziglang/zig#12547
+pub fn Array(comptime n: comptime_int, comptime U: type) type {
+    return struct {
+        const size = @bitSizeOf(U);
+        const options: std.builtin.Type.Int = .{ .signedness = .unsigned, .bits = size * n };
+        pub const T = @Type(if (@hasField(std.builtin.Type, "int"))
+            .{ .int = options }
+        else
+            .{ .Int = options });
+
+        /// Returns the value stored at index `i` in the array `a`.
+        pub fn get(a: T, i: usize) U {
+            assert(i < n);
+            const shift = i * size;
+            const mask: T = (1 << size) - 1;
+            const result = (a >> @intCast(shift)) & mask;
+            return switch (@typeInfo(U)) {
+                Enum => @enumFromInt(result),
+                Int => @intCast(result),
+                else => unreachable,
+            };
+        }
+
+        /// Sets the value at index `i` to `val` in the array `a`.
+        pub fn set(a: T, i: usize, val: U) T {
+            assert(i < n);
+            const v: T = switch (@typeInfo(U)) {
+                Enum => @intFromEnum(val),
+                Int => @intCast(val),
+                else => unreachable,
+            };
+            const shift = i * size;
+            const mask: T = @as(T, @intCast((1 << size) - 1)) << @intCast(shift);
+            const result: T = a & ~mask;
+            return result | (v << @intCast(shift));
+        }
+    };
+}
+
+test Array {
+    const A = Array(5, u8);
+    var a: A.T = 0;
+    try expectEqual(u40, @TypeOf(a));
+
+    a = A.set(a, 4, 241);
+    try expectEqual(@as(u8, 241), A.get(a, 4));
+    a = A.set(a, 4, 1);
+    try expectEqual(@as(u8, 1), A.get(a, 4));
+
+    for (0..5) |i| a = A.set(a, i, @intCast(i));
+    for (0..5) |i| try expectEqual(@as(u8, @intCast(i)), A.get(a, i));
+
+    const Optional = @import("optional.zig").Optional;
+
+    const B = Array(4, Optional(bool));
+    var b: B.T = 0;
+    try expectEqual(u8, @TypeOf(b));
+
+    b = B.set(b, 2, .true);
+    try expectEqual(Optional(bool).None, B.get(b, 1));
+    try expectEqual(Optional(bool).true, B.get(b, 2));
+    try expectEqual(@as(u8, 0b00100000), b);
+    b = B.set(b, 2, .None);
+    b = B.set(b, 0, .false);
+    try expectEqual(Optional(bool).None, B.get(b, 2));
+    try expectEqual(Optional(bool).false, B.get(b, 0));
+    try expectEqual(@as(u8, 0b0000001), b);
+}

package/src/lib/common/battle.zig

@@ -0,0 +1,17 @@
+/// Stores state required by optional features to the engine that can be passed to a generation's
+/// `Battle.update` function. All generations generically support protocol logging (enabled via
+/// `-Dlog`), chance actions and probability tracking (enabled via `-Dchance`), and damage
+/// computation and chance overrides (`-Dcalc`), though the concrete types for these features are
+/// generation dependent.
+pub fn Options(comptime Log: type, comptime Chance: type, comptime Calc: type) type {
+    return struct { log: Log, chance: Chance, calc: Calc };
+}
+
+/// Helper to create a battle `Options` object with the provided `log`, `chance`, and `calc`.
+pub fn options(
+    log: anytype,
+    chance: anytype,
+    calc: anytype,
+) Options(@TypeOf(log), @TypeOf(chance), @TypeOf(calc)) {
+    return .{ .log = log, .chance = chance, .calc = calc };
+}

package/src/lib/common/data.zig

@@ -9,12 +9,12 @@ pub const Player = enum(u1) {
     P2,
 
     /// Returns a player's opponent.
-    pub inline fn foe(self: Player) Player {
-        return @intToEnum(Player, ~@enumToInt(self));
+    pub fn foe(self: Player) Player {
+        return @enumFromInt(~@intFromEnum(self));
     }
 
     /// Return's an identifier for the player's Pokémon at the one-indexed `id`.
-    pub inline fn ident(self: Player, id: u3) ID {
+    pub fn ident(self: Player, id: u3) ID {
         assert(id > 0 and id <= 6);
         return .{ .id = id, .player = self };
     }
@@ -22,42 +22,38 @@ pub const Player = enum(u1) {
 
 test Player {
     try expectEqual(Player.P2, Player.P1.foe());
-    try expectEqual(@as(u8, 0b0001), @bitCast(u8, Player.P1.ident(1)));
-    try expectEqual(@as(u8, 0b1101), @bitCast(u8, Player.P2.ident(5)));
+    try expectEqual(@as(u8, 0b0001), @as(u8, @bitCast(Player.P1.ident(1))));
+    try expectEqual(@as(u8, 0b1101), @as(u8, @bitCast(Player.P2.ident(5))));
 }
 
 /// An identifier for a specific Pokémon in battle.
-pub const ID = packed struct {
+pub const ID = packed struct(u8) {
     /// The one-indexed team slot of the Pokémon
     id: u3 = 0,
     /// The Pokémon's trainer.
     player: Player = .P1,
     _: u4 = 0,
 
-    comptime {
-        assert(@sizeOf(ID) == 1);
-    }
-
     /// Converts the identifier into a number.
-    pub inline fn int(self: ID) u4 {
-        return @intCast(u4, @bitCast(u8, self));
+    pub fn int(self: ID) u4 {
+        return @intCast(@as(u8, @bitCast(self)));
     }
 
     /// Decodes the identifier from a number.
-    pub inline fn from(id: u4) ID {
-        return @bitCast(ID, @as(u8, id));
+    pub fn from(id: u4) ID {
+        return @bitCast(@as(u8, id));
     }
 };
 
 test ID {
-    try expectEqual(@as(u8, 0b0001), @bitCast(u8, ID{ .player = .P1, .id = 1 }));
-    try expectEqual(@as(u8, 0b1101), @bitCast(u8, ID{ .player = .P2, .id = 5 }));
-    const id = ID{ .player = .P2, .id = 4 };
+    try expectEqual(@as(u8, 0b0001), @as(u8, @bitCast(ID{ .player = .P1, .id = 1 })));
+    try expectEqual(@as(u8, 0b1101), @as(u8, @bitCast(ID{ .player = .P2, .id = 5 })));
+    const id: ID = .{ .player = .P2, .id = 4 };
     try expectEqual(id, ID.from(id.int()));
 }
 
 /// A choice made by a player during battle.
-pub const Choice = packed struct {
+pub const Choice = packed struct(u8) {
     /// The choice type.
     type: Choice.Type = .Pass,
     /// The choice data:
@@ -73,10 +69,6 @@ pub const Choice = packed struct {
         Move,
         Switch,
     };
-
-    comptime {
-        assert(@sizeOf(Choice) == 1);
-    }
 };
 
 test Choice {
@@ -84,12 +76,12 @@ test Choice {
     const p2: Choice = .{ .type = .Switch, .data = 5 };
     try expectEqual(5, p2.data);
     try expectEqual(Choice.Type.Move, p1.type);
-    try expectEqual(0b0001_0001, @bitCast(u8, p1));
-    try expectEqual(0b0001_0110, @bitCast(u8, p2));
+    try expectEqual(@as(u8, 0b0001_0001), @as(u8, @bitCast(p1)));
+    try expectEqual(@as(u8, 0b0001_0110), @as(u8, @bitCast(p2)));
 }
 
 /// The result of the battle - all results other than 'None' should be considered terminal.
-pub const Result = packed struct {
+pub const Result = packed struct(u8) {
     /// The type of result from the perspective of Player 1.
     /// `Error` is not possible when in Pokémon Showdown compatibility mode.
     type: Result.Type = .None,
@@ -117,13 +109,9 @@ pub const Result = packed struct {
     pub const Error: Result = .{ .type = .Error };
     /// The default result.
     pub const Default: Result = .{ .p1 = .Move, .p2 = .Move };
-
-    comptime {
-        assert(@sizeOf(Result) == 1);
-    }
 };
 
 test Result {
-    try expectEqual(0b0101_0000, @bitCast(u8, Result.Default));
-    try expectEqual(0b1000_0000, @bitCast(u8, Result{ .p2 = .Switch }));
+    try expectEqual(@as(u8, 0b0101_0000), @as(u8, @bitCast(Result.Default)));
+    try expectEqual(@as(u8, 0b1000_0000), @as(u8, @bitCast(Result{ .p2 = .Switch })));
 }

package/src/lib/common/debug.zig

@@ -3,25 +3,44 @@ const std = @import("std");
 const debug = std.debug;
 const io = std.io;
 
+const Array = if (@hasField(std.builtin.Type, "array")) .array else .Array;
+const Enum = if (@hasField(std.builtin.Type, "enum")) .@"enum" else .Enum;
+const Optional = if (@hasField(std.builtin.Type, "optional")) .optional else .Optional;
+const Pointer = if (@hasField(std.builtin.Type, "pointer")) .pointer else .Pointer;
+const Struct = if (@hasField(std.builtin.Type, "struct")) .@"struct" else .Struct;
+const Union = if (@hasField(std.builtin.Type, "union")) .@"union" else .Union;
+
 pub fn print(value: anytype) void {
-    debug.getStderrMutex().lock();
-    defer debug.getStderrMutex().unlock();
+    if (@hasDecl(debug, "lockStdErr")) debug.lockStdErr() else debug.getStderrMutex().lock();
+    defer if (@hasDecl(debug, "unlockStdErr"))
+        debug.unlockStdErr()
+    else
+        debug.getStderrMutex().unlock();
     const stderr = io.getStdErr().writer();
 
     nosuspend {
         stderr.writeAll("\x1b[41m") catch return;
-        switch (@typeInfo(@TypeOf(value))) {
-            .Struct => |info| {
-                if (info.is_tuple) {
-                    inline for (info.fields, 0..) |f, i| {
-                        inspect(@field(value, f.name));
-                        if (i < info.fields.len - 1) stderr.writeAll(" ") catch return;
+        if (@TypeOf(@src()) == @TypeOf(value)) {
+            stderr.print("{s} ({s}:{d}:{d})", .{
+                value.fn_name,
+                value.file,
+                value.line,
+                value.column,
+            }) catch return;
+        } else {
+            switch (@typeInfo(@TypeOf(value))) {
+                Struct => |info| {
+                    if (info.is_tuple) {
+                        inline for (info.fields, 0..) |f, i| {
+                            inspect(@field(value, f.name));
+                            if (i < info.fields.len - 1) stderr.writeAll(" ") catch return;
+                        }
+                    } else {
+                        inspect(value);
                     }
-                } else {
-                    inspect(value);
-                }
-            },
-            else => inspect(value),
+                },
+                else => inspect(value),
+            }
         }
         stderr.writeAll("\x1b[K\x1b[0m\n") catch return;
     }
@@ -33,17 +52,17 @@ fn inspect(value: anytype) void {
     nosuspend {
         const err = "Unable to format type '" ++ @typeName(@TypeOf(value)) ++ "'";
         switch (@typeInfo(@TypeOf(value))) {
-            .Array => |info| {
+            Array => |info| {
                 if (info.child == u8) return stderr.print("{s}", .{value}) catch return;
                 @compileError(err);
             },
-            .Pointer => |ptr_info| switch (ptr_info.size) {
+            Pointer => |ptr_info| switch (ptr_info.size) {
                 .One => switch (@typeInfo(ptr_info.child)) {
-                    .Array => |info| {
+                    Array => |info| {
                         if (info.child == u8) return stderr.print("{s}", .{value}) catch return;
                         @compileError(err);
                     },
-                    .Enum, .Union, .Struct => return inspect(value.*),
+                    Enum, Union, Struct => return inspect(value.*),
                     else => @compileError(err),
                 },
                 .Many, .C => {
@@ -58,8 +77,29 @@ fn inspect(value: anytype) void {
                     @compileError(err);
                 },
             },
-            .Optional => stderr.print("{?}", .{value}) catch return,
+            Optional => stderr.print("{?}", .{value}) catch return,
             else => stderr.print("{}", .{value}) catch return,
         }
     }
 }
+
+const showdown = @import("./options.zig").showdown;
+const Result = @import("./data.zig").Result;
+const Choice = @import("./data.zig").Choice;
+
+pub fn dump(gen: u8, battle: anytype, frame: ?struct { Result, Choice, Choice }) void {
+    const file = std.fs.cwd().createFile("logs/dump.bin", .{}) catch return;
+    defer file.close();
+    var w = file.writer();
+    w.writeByte(@intFromBool(showdown)) catch return;
+    w.writeByte(gen) catch return;
+    w.writeInt(i16, 0, .little) catch return;
+    w.writeInt(i32, 0, .little) catch return;
+    w.writeStruct(battle) catch return;
+    w.writeStruct(battle) catch return;
+    if (frame) |f| {
+        w.writeStruct(f[0]) catch return;
+        w.writeStruct(f[1]) catch return;
+        w.writeStruct(f[2]) catch return;
+    }
+}

package/src/lib/common/js.zig

@@ -0,0 +1,120 @@
+const std = @import("std");
+
+const assert = std.debug.assert;
+
+const Int = if (@hasField(std.builtin.Type, "int")) .int else .Int;
+
+const c = @cImport({
+    @cDefine("NAPI_VERSION", "8");
+    @cInclude("node_api.h");
+});
+
+pub const Array = struct {
+    pub fn init(env: c.napi_env, o: struct { length: ?usize }) c.napi_value {
+        var result: c.napi_value = undefined;
+        assert(c.napi_ok == if (o.length) |n|
+            c.napi_create_array_with_length(env, n, &result)
+        else
+            c.napi_create_array(env, &result));
+        return result;
+    }
+
+    pub fn set(env: c.napi_env, array: c.napi_value, index: u32, value: c.napi_value) void {
+        assert(c.napi_set_element(env, array, index, value) == c.napi_ok);
+    }
+};
+
+pub const Boolean = struct {
+    pub fn init(env: c.napi_env, value: bool) c.napi_value {
+        var result: c.napi_value = undefined;
+        assert(c.napi_get_boolean(env, value, &result) == c.napi_ok);
+        return result;
+    }
+};
+
+pub const Number = struct {
+    pub fn init(env: c.napi_env, value: anytype) c.napi_value {
+        const T = @TypeOf(value);
+        var result: c.napi_value = undefined;
+        assert(c.napi_ok == switch (@typeInfo(T)) {
+            Int => |info| switch (info.bits) {
+                0...32 => switch (info.signedness) {
+                    .signed => c.napi_create_int32(env, @as(i32, value), &result),
+                    .unsigned => c.napi_create_uint32(env, @as(u32, value), &result),
+                },
+                33...52 => c.napi_create_int64(env, @as(i64, value), &result),
+                else => @compileError("int can't be represented as JS number"),
+            },
+            else => @compileError("expected number, got: " ++ @typeName(T)),
+        });
+        return result;
+    }
+
+    pub fn get(env: c.napi_env, value: c.napi_value, comptime T: type) T {
+        switch (@typeInfo(T)) {
+            Int => |info| switch (info.bits) {
+                0...32 => switch (info.signedness) {
+                    .signed => {
+                        var result: i32 = undefined;
+                        assert(c.napi_get_value_int32(env, value, &result) == c.napi_ok);
+                        return if (info.bits == 32) result else @intCast(result);
+                    },
+                    .unsigned => {
+                        var result: u32 = undefined;
+                        assert(c.napi_get_value_uint32(env, value, &result) == c.napi_ok);
+                        return if (info.bits == 32) result else @intCast(result);
+                    },
+                },
+                33...63 => {
+                    var result: i64 = undefined;
+                    assert(c.napi_get_value_int64(env, value, &result) == c.napi_ok);
+                    return @intCast(result);
+                },
+                else => {
+                    var result: i64 = undefined;
+                    assert(c.napi_get_value_int64(env, value, &result) == c.napi_ok);
+                    return switch (info.signedness) {
+                        .signed => value,
+                        .unsigned => if (0 <= value) @intCast(value) else unreachable,
+                    };
+                },
+            },
+            else => @compileError("expected number, got: " ++ @typeName(T)),
+        }
+    }
+};
+
+pub const Object = struct {
+    pub fn init(env: c.napi_env) c.napi_value {
+        var result: c.napi_value = undefined;
+        assert(c.napi_create_object(env, &result) == c.napi_ok);
+        return result;
+    }
+};
+
+pub const Property = union(enum) {
+    method: c.napi_callback,
+    value: c.napi_value,
+
+    pub fn init(comptime name: [:0]const u8, property: Property) c.napi_property_descriptor {
+        return .{
+            .utf8name = name,
+            .name = null,
+            .method = switch (property) {
+                .method => |m| m,
+                .value => null,
+            },
+            .getter = null,
+            .setter = null,
+            .value = switch (property) {
+                .method => null,
+                .value => |v| v,
+            },
+            .attributes = switch (property) {
+                .method => c.napi_default,
+                .value => c.napi_enumerable,
+            },
+            .data = null,
+        };
+    }
+};