@pkmn/engine 0.1.0-dev.77410aff → 0.1.0-dev.78dc891c

package/src/lib/bindings/wasm.zig

@@ -0,0 +1,51 @@
+const pkmn = @import("../pkmn.zig");
+const std = @import("std");
+const util = @import("../common/util.zig");
+
+const assert = std.debug.assert;
+
+pub const options = pkmn.options;
+
+pub fn gen(comptime num: comptime_int) type {
+    const g = @field(pkmn, "gen" ++ std.fmt.comptimePrint("{d}", .{num}));
+    return struct {
+        pub const CHOICES_SIZE = size(g.CHOICES_SIZE);
+        pub const LOGS_SIZE = size(g.LOGS_SIZE);
+
+        pub fn update(
+            battle: *g.Battle(g.PRNG),
+            c1: pkmn.Choice,
+            c2: pkmn.Choice,
+            options_: ?[*]u8,
+        ) callconv(.c) pkmn.Result {
+            return (if (options_) |o| result: {
+                const buf = @as([*]u8, @ptrCast(o))[0..g.LOGS_SIZE];
+                var writer: pkmn.protocol.Writer = .{ .buffer = buf };
+                // TODO: extract out
+                var opts = pkmn.battle.options(
+                    pkmn.protocol.FixedLog{ .writer = &writer },
+                    g.chance.NULL,
+                    g.calc.NULL,
+                );
+                break :result battle.update(c1, c2, &opts);
+            } else battle.update(c1, c2, &g.NULL)) catch unreachable;
+        }
+
+        pub fn choices(
+            battle: *g.Battle(g.PRNG),
+            player: u8,
+            request: u8,
+            buf: [*]u8,
+        ) callconv(.c) u8 {
+            assert(player <= util.EnumFieldsLen(pkmn.Player));
+            assert(request <= util.EnumFieldsLen(pkmn.Choice.Type));
+
+            const n = CHOICES_SIZE;
+            return battle.choices(@enumFromInt(player), @enumFromInt(request), @ptrCast(buf[0..n]));
+        }
+    };
+}
+
+fn size(n: usize) u32 {
+    return std.math.ceilPowerOfTwo(u32, @as(u32, @intCast(n))) catch unreachable;
+}

package/src/lib/common/array.zig

@@ -0,0 +1,70 @@
+const std = @import("std");
+
+const expectEqual = std.testing.expectEqual;
+const assert = std.debug.assert;
+
+/// Helpers for working with bit-packed arrays of non-powers-of-2 types.
+/// NOTE: ziglang/zig#12547
+pub fn Array(comptime n: comptime_int, comptime U: type) type {
+    return struct {
+        const size = @bitSizeOf(U);
+        pub const T = @Int(.unsigned, size * n);
+
+        /// Returns the value stored at index `i` in the array `a`.
+        pub fn get(a: T, i: usize) U {
+            assert(i < n);
+            const shift = i * size;
+            const mask: T = (1 << size) - 1;
+            const result = (a >> @intCast(shift)) & mask;
+            return switch (@typeInfo(U)) {
+                .@"enum" => @enumFromInt(result),
+                .int => @intCast(result),
+                else => unreachable,
+            };
+        }
+
+        /// Sets the value at index `i` to `val` in the array `a`.
+        pub fn set(a: T, i: usize, val: U) T {
+            assert(i < n);
+            const v: T = switch (@typeInfo(U)) {
+                .@"enum" => @intFromEnum(val),
+                .int => @intCast(val),
+                else => unreachable,
+            };
+            const shift = i * size;
+            const mask: T = @as(T, @intCast((1 << size) - 1)) << @intCast(shift);
+            const result: T = a & ~mask;
+            return result | (v << @intCast(shift));
+        }
+    };
+}
+
+test Array {
+    const A = Array(5, u8);
+    var a: A.T = 0;
+    try expectEqual(u40, @TypeOf(a));
+
+    a = A.set(a, 4, 241);
+    try expectEqual(@as(u8, 241), A.get(a, 4));
+    a = A.set(a, 4, 1);
+    try expectEqual(@as(u8, 1), A.get(a, 4));
+
+    for (0..5) |i| a = A.set(a, i, @intCast(i));
+    for (0..5) |i| try expectEqual(@as(u8, @intCast(i)), A.get(a, i));
+
+    const Optional = @import("optional.zig").Optional;
+
+    const B = Array(4, Optional(bool));
+    var b: B.T = 0;
+    try expectEqual(u8, @TypeOf(b));
+
+    b = B.set(b, 2, .true);
+    try expectEqual(Optional(bool).None, B.get(b, 1));
+    try expectEqual(Optional(bool).true, B.get(b, 2));
+    try expectEqual(@as(u8, 0b00100000), b);
+    b = B.set(b, 2, .None);
+    b = B.set(b, 0, .false);
+    try expectEqual(Optional(bool).None, B.get(b, 2));
+    try expectEqual(Optional(bool).false, B.get(b, 0));
+    try expectEqual(@as(u8, 0b0000001), b);
+}

package/src/lib/common/data.zig

@@ -76,8 +76,8 @@ test Choice {
     const p2: Choice = .{ .type = .Switch, .data = 5 };
     try expectEqual(5, p2.data);
     try expectEqual(Choice.Type.Move, p1.type);
-    try expectEqual(0b0001_0001, @as(u8, @bitCast(p1)));
-    try expectEqual(0b0001_0110, @as(u8, @bitCast(p2)));
+    try expectEqual(@as(u8, 0b0001_0001), @as(u8, @bitCast(p1)));
+    try expectEqual(@as(u8, 0b0001_0110), @as(u8, @bitCast(p2)));
 }
 
 /// The result of the battle - all results other than 'None' should be considered terminal.
@@ -112,6 +112,6 @@ pub const Result = packed struct(u8) {
 };
 
 test Result {
-    try expectEqual(0b0101_0000, @as(u8, @bitCast(Result.Default)));
-    try expectEqual(0b1000_0000, @as(u8, @bitCast(Result{ .p2 = .Switch })));
+    try expectEqual(@as(u8, 0b0101_0000), @as(u8, @bitCast(Result.Default)));
+    try expectEqual(@as(u8, 0b1000_0000), @as(u8, @bitCast(Result{ .p2 = .Switch })));
 }

package/src/lib/common/debug.zig

@@ -1,17 +1,20 @@
+const builtin = @import("builtin");
 const std = @import("std");
 
 const debug = std.debug;
-const io = std.io;
 
 pub fn print(value: anytype) void {
-    debug.getStderrMutex().lock();
-    defer debug.getStderrMutex().unlock();
-    const stderr = io.getStdErr().writer();
+    if (builtin.target.os.tag == .freestanding) return;
+
+    var buffer: [4096]u8 = undefined;
+    const stderr = debug.lockStderr(&buffer);
+    defer debug.unlockStderr();
+    var fw = stderr.file_writer;
 
     nosuspend {
-        stderr.writeAll("\x1b[41m") catch return;
+        fw.interface.writeAll("\x1b[41m") catch return;
         if (@TypeOf(@src()) == @TypeOf(value)) {
-            stderr.print("{s} ({s}:{d}:{d})", .{
+            fw.interface.print("{s} ({s}:{d}:{d})", .{
                 value.fn_name,
                 value.file,
                 value.line,
@@ -19,56 +22,69 @@ pub fn print(value: anytype) void {
             }) catch return;
         } else {
             switch (@typeInfo(@TypeOf(value))) {
-                .Struct => |info| {
+                .@"struct" => |info| {
                     if (info.is_tuple) {
-                        inline for (info.fields, 0..) |f, i| {
-                            inspect(@field(value, f.name));
-                            if (i < info.fields.len - 1) stderr.writeAll(" ") catch return;
+                        if (@hasField(@TypeOf(info), "fields")) {
+                            inline for (info.fields, 0..) |f, i| {
+                                inspect(fw, @field(value, f.name));
+                                if (i < info.fields.len - 1) {
+                                    fw.interface.writeAll(" ") catch return;
+                                }
+                            }
+                        } else {
+                            inline for (info.field_names, 0..) |name, i| {
+                                inspect(fw, @field(value, name));
+                                if (i < info.field_names.len - 1) {
+                                    fw.interface.writeAll(" ") catch return;
+                                }
+                            }
                         }
                     } else {
-                        inspect(value);
+                        inspect(fw, value);
                     }
                 },
-                else => inspect(value),
+                else => inspect(fw, value),
             }
         }
-        stderr.writeAll("\x1b[K\x1b[0m\n") catch return;
+        fw.interface.writeAll("\x1b[K\x1b[0m\n") catch return;
     }
 }
 
-fn inspect(value: anytype) void {
-    const stderr = io.getStdErr().writer();
-
+fn inspect(w: anytype, value: anytype) void {
     nosuspend {
         const err = "Unable to format type '" ++ @typeName(@TypeOf(value)) ++ "'";
         switch (@typeInfo(@TypeOf(value))) {
-            .Array => |info| {
-                if (info.child == u8) return stderr.print("{s}", .{value}) catch return;
+            .array => |info| {
+                if (info.child == u8) return w.interface.print("{s}", .{value}) catch return;
                 @compileError(err);
             },
-            .Pointer => |ptr_info| switch (ptr_info.size) {
-                .One => switch (@typeInfo(ptr_info.child)) {
-                    .Array => |info| {
-                        if (info.child == u8) return stderr.print("{s}", .{value}) catch return;
+            .pointer => |ptr_info| switch (ptr_info.size) {
+                .one => switch (@typeInfo(ptr_info.child)) {
+                    .array => |info| {
+                        if (info.child == u8) {
+                            return w.interface.print("{s}", .{value}) catch return;
+                        }
                         @compileError(err);
                     },
-                    .Enum, .Union, .Struct => return inspect(value.*),
+                    .@"enum", .@"union", .@"struct" => return inspect(value.*),
                     else => @compileError(err),
                 },
-                .Many, .C => {
+                .many, .c => {
                     if (ptr_info.sentinel) |_| return inspect(std.mem.span(value));
                     if (ptr_info.child == u8) {
-                        return stderr.print("{s}", .{std.mem.span(value)}) catch return;
+                        return w.interface.print("{s}", .{std.mem.span(value)}) catch return;
                     }
                     @compileError(err);
                 },
-                .Slice => {
-                    if (ptr_info.child == u8) return stderr.print("{s}", .{value}) catch return;
+                .slice => {
+                    if (ptr_info.child == u8) {
+                        return w.interface.print("{s}", .{value}) catch return;
+                    }
                     @compileError(err);
                 },
             },
-            .Optional => stderr.print("{?}", .{value}) catch return,
-            else => stderr.print("{}", .{value}) catch return,
+            .optional => w.interface.print("{?}", .{value}) catch return,
+            else => w.interface.print("{}", .{value}) catch return,
         }
     }
 }

package/src/lib/common/js.zig

@@ -1,12 +1,8 @@
 const std = @import("std");
+const c = @import("napi");
 
 const assert = std.debug.assert;
 
-const c = @cImport({
-    @cDefine("NAPI_VERSION", "8");
-    @cInclude("node_api.h");
-});
-
 pub const Array = struct {
     pub fn init(env: c.napi_env, o: struct { length: ?usize }) c.napi_value {
         var result: c.napi_value = undefined;
@@ -35,7 +31,7 @@ pub const Number = struct {
         const T = @TypeOf(value);
         var result: c.napi_value = undefined;
         assert(c.napi_ok == switch (@typeInfo(T)) {
-            .Int => |info| switch (info.bits) {
+            .int => |info| switch (info.bits) {
                 0...32 => switch (info.signedness) {
                     .signed => c.napi_create_int32(env, @as(i32, value), &result),
                     .unsigned => c.napi_create_uint32(env, @as(u32, value), &result),
@@ -50,7 +46,7 @@ pub const Number = struct {
 
     pub fn get(env: c.napi_env, value: c.napi_value, comptime T: type) T {
         switch (@typeInfo(T)) {
-            .Int => |info| switch (info.bits) {
+            .int => |info| switch (info.bits) {
                 0...32 => switch (info.signedness) {
                     .signed => {
                         var result: i32 = undefined;

package/src/lib/common/optional.zig

@@ -3,34 +3,38 @@ const std = @import("std");
 const expect = std.testing.expect;
 const assert = std.debug.assert;
 
-// TODO: ziglang/zig#104
+/// Optimized optional representation which stores the empty None value as a sentinel.
+/// NOTE: ziglang/zig#104
 pub fn Optional(comptime T: type) type {
-    const fields = std.meta.fields(switch (@typeInfo(T)) {
-        .Bool => enum { false, true },
-        else => T,
-    });
+    const names = if (@hasDecl(std.meta, "fieldNames"))
+        std.meta.fieldNames(switch (@typeInfo(T)) {
+            .bool => enum { false, true },
+            else => T,
+        })
+    else blk: {
+        const fields = std.meta.fields(switch (@typeInfo(T)) {
+            .bool => enum { false, true },
+            else => T,
+        });
+        var ns: [fields.len][:0]const u8 = undefined;
+        inline for (fields, 0..) |f, i| ns[i] = f.name;
+        break :blk &ns;
+    };
 
-    var enumFields: [fields.len + 1]std.builtin.Type.EnumField = undefined;
-    var decls = [_]std.builtin.Type.Declaration{};
+    const TagType = std.math.IntFittingRange(0, names.len);
+    var fieldNames: [names.len + 1][]const u8 = undefined;
+    var fieldValues: [names.len + 1]TagType = undefined;
 
-    enumFields[0] = .{ .name = "None", .value = 0 };
+    fieldNames[0] = "None";
+    fieldValues[0] = 0;
 
-    inline for (fields, 1..) |field, i| {
-        assert(!std.mem.eql(u8, field.name, "None"));
-        enumFields[i] = .{
-            .name = field.name,
-            .value = i,
-        };
+    inline for (names, 1..) |name, i| {
+        assert(!std.mem.eql(u8, name, "None"));
+        fieldNames[i] = name;
+        fieldValues[i] = i;
     }
 
-    return @Type(.{
-        .Enum = .{
-            .tag_type = std.math.IntFittingRange(0, fields.len),
-            .fields = &enumFields,
-            .decls = &decls,
-            .is_exhaustive = true,
-        },
-    });
+    return @Enum(TagType, .exhaustive, &fieldNames, &fieldValues);
 }
 
 test Optional {
@@ -46,7 +50,7 @@ test Optional {
     try expect(b != .true);
     try expect(b != .false);
 
-    const Player = @import("./data.zig").Player;
+    const Player = @import("data.zig").Player;
     try expect(@bitSizeOf(Optional(Player)) == 2);
 
     const p: Optional(Player) = .P2;

package/src/lib/common/options.zig

@@ -7,9 +7,12 @@ pub const Options = struct {
     log: ?bool = null,
     chance: ?bool = null,
     calc: ?bool = null,
+    mod: ?bool = null,
     advance: ?bool = null,
     ebc: ?bool = null,
     key: ?bool = null,
+    miss: ?bool = null,
+    overwrite: ?bool = null,
     internal: ?bool = null,
 };
 
@@ -22,9 +25,12 @@ pub const chance = get("chance", false);
 /// Whether or not damage calculator support is enabled.
 pub const calc = get("calc", false);
 
+pub const mod = showdown or get("mod", false);
 pub const advance = get("advance", true);
 pub const ebc = get("ebc", true);
 pub const key = get("key", false);
+pub const miss = get("miss", true);
+pub const overwrite = get("overwrite", true);
 pub const internal = get("internal", false);
 
 fn get(comptime name: []const u8, default: bool) bool {