@netwerk-digitaal-erfgoed/network-of-terms-catalog 5.1.3

package/catalog/queries/search/cht.rq

@@ -0,0 +1,46 @@
+PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
+
+CONSTRUCT {
+    ?uri a skos:Concept ;
+        skos:prefLabel ?prefLabel ;
+        skos:altLabel ?altLabel ;
+        skos:hiddenLabel ?hiddenLabel ;
+        skos:scopeNote ?scopeNote .
+    ?uri skos:broader ?broader_uri .
+    ?broader_uri skos:prefLabel ?broader_prefLabel .
+    ?uri skos:narrower ?narrower_uri .
+    ?narrower_uri skos:prefLabel ?narrower_prefLabel .
+}
+WHERE {
+    ?uri ?predicate ?label .
+    VALUES ?predicate { skos:prefLabel skos:altLabel }
+    FILTER(LANG(?label) = "nl")
+    FILTER(CONTAINS(LCASE(?label), LCASE(?query)))
+    OPTIONAL {
+        ?uri skos:prefLabel ?prefLabel .
+        FILTER(LANG(?prefLabel) = "nl")
+    }
+    OPTIONAL {
+        ?uri skos:altLabel ?altLabel .
+        FILTER(LANG(?altLabel) = "nl")
+    }
+    OPTIONAL {
+        ?uri skos:hiddenLabel ?hiddenLabel .
+        FILTER(LANG(?hiddenLabel) = "nl")
+    }
+    OPTIONAL {
+        ?uri skos:scopeNote ?scopeNote .
+        FILTER(LANG(?scopeNote) = "nl")
+    }
+    OPTIONAL {
+        ?uri skos:broader ?broader_uri .
+        ?broader_uri skos:prefLabel ?broader_prefLabel .
+        FILTER(LANG(?broader_prefLabel) = "nl")
+    }
+    OPTIONAL {
+        ?uri skos:narrower ?narrower_uri .
+        ?narrower_uri skos:prefLabel ?narrower_prefLabel .
+        FILTER(LANG(?narrower_prefLabel) = "nl")
+    }
+}
+LIMIT 1000

package/catalog/queries/search/gtaa.rq

@@ -0,0 +1,55 @@
+PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
+
+CONSTRUCT {
+    ?uri a skos:Concept ;
+        skos:prefLabel ?prefLabel ;
+        skos:altLabel ?altLabel ;
+        skos:hiddenLabel ?hiddenLabel ;
+        skos:scopeNote ?scopeNote ;
+        skos:broader ?broader_uri ;
+        skos:narrower ?narrower_uri ;
+        skos:related ?related_uri .
+    ?broader_uri skos:prefLabel ?broader_prefLabel .
+    ?narrower_uri skos:prefLabel ?narrower_prefLabel .
+    ?related_uri skos:prefLabel ?related_prefLabel .
+}
+WHERE {
+    ?uri ?predicate ?label .
+    VALUES ?predicate { skos:prefLabel skos:altLabel }
+    FILTER(LANG(?label) = "nl")
+
+    # Replace query "A B" with "A AND B", leaving queries "A AND B" or "A OR B" unchanged.
+    FILTER (<bif:contains> (?label, REPLACE(?query, "(?<!AND)(?<!OR)[[:space:]]+(?!AND)(?!OR)", " AND ", "i")))
+    OPTIONAL {
+        ?uri skos:prefLabel ?prefLabel .
+        FILTER(LANG(?prefLabel) = "nl" )
+    }
+    OPTIONAL {
+        ?uri skos:altLabel ?altLabel .
+        FILTER(LANG(?altLabel) = "nl")
+    }
+    OPTIONAL {
+        ?uri skos:hiddenLabel ?hiddenLabel .
+        FILTER(LANG(?hiddenLabel) = "nl")
+    }
+    OPTIONAL {
+        ?uri skos:scopeNote ?scopeNote .
+        FILTER(LANG(?scopeNote) = "nl")
+    }
+    OPTIONAL {
+        ?uri skos:broader ?broader_uri .
+        ?broader_uri skos:prefLabel ?broader_prefLabel .
+        FILTER(LANG(?broader_prefLabel) = "nl")
+    }
+    OPTIONAL {
+        ?uri skos:narrower ?narrower_uri .
+        ?narrower_uri skos:prefLabel ?narrower_prefLabel .
+        FILTER(LANG(?narrower_prefLabel) = "nl")
+    }
+    OPTIONAL {
+        ?uri skos:related ?related_uri .
+        ?related_uri skos:prefLabel ?related_prefLabel .
+        FILTER(LANG(?related_prefLabel) = "nl")
+    }
+}
+LIMIT 1000

package/catalog/queries/search/muziekschatten-onderwerpen.rq

@@ -0,0 +1,45 @@
+PREFIX schema: <http://schema.org/>
+PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
+PREFIX som: <http://data.muziekschatten.nl/som/>
+
+CONSTRUCT {
+    ?uri a skos:Concept;
+        skos:prefLabel ?schema_name;
+        skos:scopeNote ?scopeNote;
+        skos:broader ?broader_uri .
+    ?broader_uri skos:prefLabel ?broader_schema_name .
+}
+WHERE {
+    ?uri a skos:Concept .
+    ?uri ?predicate ?label .
+    VALUES ?predicate { schema:name schema:keywords }
+
+    # A 'FILTER (<bif:contains>, ...)' currently does not work due to https://github.com/comunica/comunica/issues/844
+    ?label <bif:contains> ?query .
+
+    OPTIONAL {
+        ?uri schema:name ?schema_name .
+        FILTER(LANG(?schema_name) = "nl")
+    }
+    OPTIONAL {
+        ?uri skos:broader ?broader_uri .
+        ?broader_uri schema:name ?broader_schema_name .
+        FILTER(LANG(?broader_schema_name) = "nl")
+    }
+    OPTIONAL {
+        ?uri schema:keywords ?schema_keywords
+    }
+    OPTIONAL {
+        ?uri som:DC ?dc
+    }
+    BIND(
+        COALESCE(
+            IF(BOUND(?schema_keywords) && BOUND(?dc), CONCAT("Trefwoorden: ", ?schema_keywords, " | ", "Dewey: ", ?dc), ?noScopeNote),
+            IF(BOUND(?schema_keywords), CONCAT("Trefwoorden: ", ?schema_keywords), ?noScopeNote),
+            IF(BOUND(?dc), CONCAT("Dewey: ", ?dc), ?noScopeNote)
+        ) AS ?scopeNote
+    )
+
+    ?uri som:BASIS "1" .
+}
+LIMIT 1000

package/catalog/queries/search/muziekschatten-personen.rq

@@ -0,0 +1,66 @@
+PREFIX schema: <http://schema.org/>
+PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
+PREFIX som: <http://data.muziekschatten.nl/som/>
+
+# Persons for testing the query
+# No birth year:
+# <https://data.muziekschatten.nl/som/da6866c6ba20fb11f6e2617d4a971b91>
+# No death year:
+# <https://data.muziekschatten.nl/som/ae7b2de42c4158219176d464008dfd49>
+# No birth year, no death year:
+# <https://data.muziekschatten.nl/som/ed25d29466903394c982dd3dc185bd80>
+# Both a birth year and a death year:
+# <https://data.muziekschatten.nl/som/ff20e6a4c17dbb9cddbffedc97c292e0>
+# No family name:
+# <https://data.muziekschatten.nl/som/4275e51d7d94b224928da9b7707a170a>
+# No given name:
+# <https://data.muziekschatten.nl/som/b101ea3b20de7f9b40070ea9191d98bd>
+# No family name, no given name:
+# <https://data.muziekschatten.nl/som/c5f95197941d9bb4f68a1e25c379f081>
+# Both a family name and a given name:
+# <https://data.muziekschatten.nl/som/b7bc6d966287e0f0e0f491752ff65ba5>
+
+CONSTRUCT {
+    ?uri a skos:Concept;
+        skos:prefLabel ?prefLabel ;
+        skos:altLabel ?schema_alternateName ;
+        skos:scopeNote ?schema_hasOccupation .
+}
+WHERE {
+    ?uri a schema:Person .
+    # Require the presence of this property for quality purposes
+    ?uri som:NDEREC ?nderec .
+
+    ?uri ?predicate ?label .
+    VALUES ?predicate { schema:name schema:alternateName }
+
+    # A 'FILTER (<bif:contains>, ...)' currently does not work due to https://github.com/comunica/comunica/issues/844
+    ?label <bif:contains> ?query .
+
+    OPTIONAL { ?uri schema:name ?schema_name }
+    OPTIONAL { ?uri schema:alternateName ?schema_alternateName }
+    OPTIONAL { ?uri schema:hasOccupation ?schema_hasOccupation }
+
+    OPTIONAL { ?uri schema:familyName ?schema_familyName }
+    OPTIONAL { ?uri schema:givenName ?schema_givenName }
+    BIND(
+        COALESCE(
+            IF(BOUND(?schema_familyName) && BOUND(?schema_givenName), CONCAT(?schema_familyName, ", ", ?schema_givenName), ?noName),
+            ?schema_familyName,
+            ?schema_givenName,
+            ?schema_name # Fallback
+        ) AS ?name
+    )
+    OPTIONAL { ?uri som:GDAT ?som_birthYear }
+    OPTIONAL { ?uri som:SDAT ?som_deathYear }
+    BIND(
+        COALESCE(
+            IF(BOUND(?som_birthYear) && BOUND(?som_deathYear), CONCAT(?som_birthYear, "-", ?som_deathYear), ?noDate),
+            IF(BOUND(?som_birthYear), CONCAT(?som_birthYear, "-"), ?noDate),
+            IF(BOUND(?som_deathYear), CONCAT("-", ?som_deathYear), ?noDate),
+            ""
+        ) AS ?dates
+    )
+    BIND(CONCAT(?name, IF(?dates != "", CONCAT(" (", ?dates, ")"), "")) AS ?prefLabel)
+}
+LIMIT 1000

package/catalog/queries/search/mw-genresstijlen.rq

@@ -0,0 +1,31 @@
+PREFIX muziekweb: <https://data.muziekweb.nl/vocab/>
+PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
+PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
+
+CONSTRUCT {
+    ?uri a skos:Concept ;
+        skos:prefLabel ?rdfs_label ;
+        skos:scopeNote ?rdfs_comment .
+    ?uri skos:broader ?broader_uri .
+    ?broader_uri skos:prefLabel ?broader_prefLabel .
+    ?uri skos:narrower ?narrower_uri .
+    ?narrower_uri skos:prefLabel ?narrower_prefLabel .
+}
+WHERE {
+    ?uri a muziekweb:Genre .
+    ?uri rdfs:label ?rdfs_label .
+
+    # Replace query "A B" with "A AND B", leaving queries "A AND B" or "A OR B" unchanged.
+    FILTER (<bif:contains> (?rdfs_label, REPLACE(?query, "(?<!AND)(?<!OR)[[:space:]]+(?!AND)(?!OR)", " AND ", "i")))
+
+    OPTIONAL {
+        ?uri skos:broader ?broader_uri .
+        ?broader_uri rdfs:label ?broader_prefLabel
+    }
+    OPTIONAL {
+        ?uri skos:narrower ?narrower_uri .
+        ?narrower_uri rdfs:label ?narrower_prefLabel
+    }
+    OPTIONAL { ?uri rdfs:comment ?rdfs_comment }
+}
+LIMIT 1000

package/catalog/queries/search/mw-personengroepen.rq

@@ -0,0 +1,25 @@
+PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
+PREFIX schema: <http://schema.org/>
+PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
+
+CONSTRUCT {
+    ?uri a skos:Concept ;
+        skos:prefLabel ?prefLabel ;
+        skos:altLabel ?altLabel ;
+        skos:hiddenLabel ?hiddenLabel ;
+        skos:scopeNote ?schema_description .
+}
+WHERE {
+    ?uri a schema:MusicGroup .
+    ?uri ?predicate ?label .
+    VALUES ?predicate { skos:prefLabel skos:altLabel }
+
+    # Replace query "A B" with "A AND B", leaving queries "A AND B" or "A OR B" unchanged.
+    FILTER (<bif:contains> (?label, REPLACE(?query, "(?<!AND)(?<!OR)[[:space:]]+(?!AND)(?!OR)", " AND ", "i")))
+
+    OPTIONAL { ?uri skos:prefLabel ?prefLabel }
+    OPTIONAL { ?uri skos:altLabel ?altLabel }
+    OPTIONAL { ?uri skos:hiddenLabel ?hiddenLabel }
+    OPTIONAL { ?uri schema:description ?schema_description }
+}
+LIMIT 1000

package/catalog/queries/search/nmvw.rq

@@ -0,0 +1,42 @@
+PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
+
+CONSTRUCT {
+    ?uri a skos:Concept ;
+        skos:prefLabel ?prefLabel ;
+        skos:altLabel ?altLabel ;
+        skos:hiddenLabel ?hiddenLabel ;
+        skos:scopeNote ?scopeNote .
+    ?uri skos:broader ?broader_uri .
+    ?broader_uri skos:prefLabel ?broader_prefLabel .
+    ?uri skos:narrower ?narrower_uri .
+    ?narrower_uri skos:prefLabel ?narrower_prefLabel .
+}
+WHERE {
+    ?uri ?predicate ?label .
+    VALUES ?predicate { skos:prefLabel skos:altLabel }
+
+    # Replace query "A B" with "A AND B", leaving queries "A AND B" or "A OR B" unchanged.
+    FILTER (<bif:contains> (?label, REPLACE(?query, "(?<!AND)(?<!OR)[[:space:]]+(?!AND)(?!OR)", " AND ", "i")))
+
+    OPTIONAL {
+        ?uri skos:prefLabel ?prefLabel .
+    }
+    OPTIONAL {
+        ?uri skos:scopeNote ?scopeNote .
+    }
+    OPTIONAL {
+        ?uri skos:altLabel ?altLabel .
+    }
+    OPTIONAL {
+        ?uri skos:hiddenLabel ?hiddenLabel .
+    }
+    OPTIONAL {
+        ?uri skos:broader ?broader_uri .
+        ?broader_uri skos:prefLabel ?broader_prefLabel .
+    }
+    OPTIONAL {
+        ?uri skos:narrower ?narrower_uri .
+        ?narrower_uri skos:prefLabel ?narrower_prefLabel .
+    }
+}
+LIMIT 1000

package/catalog/queries/search/nta.rq

@@ -0,0 +1,23 @@
+PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
+
+CONSTRUCT {
+    ?uri a skos:Concept ;
+        skos:prefLabel ?rdfs_label ;
+        skos:altLabel ?schema_name ;
+        skos:altLabel ?schema_alternateName ;
+        skos:scopeNote ?schema_description .
+}
+WHERE {
+    ?uri schema:mainEntityOfPage/schema:isPartOf <http://data.bibliotheken.nl/id/dataset/persons> .
+    ?uri ?predicate ?label .
+    VALUES ?predicate { rdfs:label schema:name schema:alternateName }
+
+    # Replace query "A B" with "A AND B", leaving queries "A AND B" or "A OR B" unchanged.
+    FILTER (<bif:contains> (?label, REPLACE(?query, "(?<!AND)(?<!OR)[[:space:]]+(?!AND)(?!OR)", " AND ", "i")))
+
+    OPTIONAL { ?uri rdfs:label ?rdfs_label }
+    OPTIONAL { ?uri schema:name ?schema_name }
+    OPTIONAL { ?uri schema:alternateName ?schema_alternateName }
+    OPTIONAL { ?uri schema:description ?schema_description }
+}
+LIMIT 1000

package/catalog/queries/search/rkdartists.rq

@@ -0,0 +1,23 @@
+PREFIX schema: <http://schema.org/>
+PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
+
+CONSTRUCT {
+    ?uri a skos:Concept ;
+    skos:prefLabel ?schema_name ;
+    skos:altLabel ?schema_alternateName ;
+    skos:scopeNote ?schema_description .
+}
+WHERE {
+    ?uri a ?type .
+    VALUES ?type { schema:Person schema:Organization }
+    ?uri ?name ?label .
+    VALUES ?name { schema:name schema:alternateName }
+
+    # Replace query "A B" with "A AND B", leaving queries "A AND B" or "A OR B" unchanged.
+    FILTER (<bif:contains> (?label, REPLACE(?query, "(?<!AND)(?<!OR)[[:space:]]+(?!AND)(?!OR)", " AND ", "i")))
+
+    OPTIONAL { ?uri schema:name ?schema_name . }
+    OPTIONAL { ?uri schema:alternateName ?schema_alternateName . }
+    OPTIONAL { ?uri schema:description ?schema_description . }
+}
+LIMIT 1000

package/catalog/queries/search/wikidata-entities-all.rq

@@ -0,0 +1,34 @@
+PREFIX bd: <http://www.bigdata.com/rdf#>
+PREFIX mwapi: <https://www.mediawiki.org/ontology#API/>
+PREFIX schema: <http://schema.org/>
+PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
+PREFIX wikibase: <http://wikiba.se/ontology#>
+
+CONSTRUCT {
+    # Wikidata seems to have a problem with the short syntax for construct queries
+    # so always use full syntax: "?s ?p ?o ." else you end up with an empty result list!
+    ?item a skos:Concept .
+    ?item skos:prefLabel ?rdfs_label .
+    ?item skos:altLabel ?altLabel .
+    ?item skos:scopeNote ?schema_description .
+}
+WHERE {
+    SERVICE wikibase:mwapi {
+        bd:serviceParam wikibase:endpoint "www.wikidata.org" .
+        bd:serviceParam wikibase:api "EntitySearch" .
+        bd:serviceParam mwapi:language "nl" .
+        bd:serviceParam mwapi:search ?query .
+        ?item wikibase:apiOutputItem mwapi:item .
+    }
+    ?item rdfs:label ?rdfs_label .
+    FILTER(LANG(?rdfs_label) = "nl")
+    OPTIONAL {
+        ?item skos:altLabel ?altLabel .
+        FILTER(LANG(?altLabel) = "nl")
+    }
+    OPTIONAL {
+        ?item schema:description ?schema_description
+        FILTER(LANG(?schema_description) = "nl")
+    }
+}
+LIMIT 1000

package/catalog/queries/search/wikidata-entities-persons.rq

@@ -0,0 +1,44 @@
+PREFIX bd: <http://www.bigdata.com/rdf#>
+PREFIX mwapi: <https://www.mediawiki.org/ontology#API/>
+PREFIX schema: <http://schema.org/>
+PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
+PREFIX wikibase: <http://wikiba.se/ontology#>
+PREFIX wdt: <http://www.wikidata.org/prop/direct/>
+PREFIX wd: <http://www.wikidata.org/entity/>
+
+CONSTRUCT {
+    # Wikidata seems to have a problem with the short syntax for construct queries
+    # so always use full syntax: "?s ?p ?o ." else you end up with an empty result list!
+    ?item a skos:Concept .
+    ?item skos:prefLabel ?prefLabel .
+    ?item skos:altLabel ?altLabel .
+    ?item skos:scopeNote ?description .
+}
+WHERE {
+    SERVICE wikibase:mwapi {
+        bd:serviceParam wikibase:endpoint "www.wikidata.org" .
+        # Instead of using the "EntitySearch" API we use a more generic text search option
+        # To avoid noise we will filter the resultset on the occurence of the search string
+        # in either prefLabel or altLabel
+        bd:serviceParam wikibase:api "Search" .
+        bd:serviceParam mwapi:language "nl" .
+        bd:serviceParam mwapi:srsearch ?query .
+        ?item wikibase:apiOutputItem mwapi:title .
+    }
+    # Only select instances of type "human"
+    ?item wdt:P31 wd:Q5 .
+
+    ?item rdfs:label ?prefLabel .
+    FILTER(LANG(?prefLabel) = "nl")
+    OPTIONAL {
+        ?item skos:altLabel ?altLabel .
+        FILTER(LANG(?altLabel) = "nl"||LANG(?altLabel) = "en")
+    }
+    OPTIONAL {
+        ?item schema:description ?description
+        FILTER(LANG(?description) = "nl")
+    }
+    # limit the result set to matches in the prefLabels or altLabels
+    FILTER(CONTAINS(LCASE(?prefLabel),LCASE(?query))||CONTAINS(LCASE(?altLabel),LCASE(?query)))
+}
+LIMIT 1000

package/catalog/queries/search/wikidata-entities-places.rq

@@ -0,0 +1,67 @@
+PREFIX bd: <http://www.bigdata.com/rdf#>
+PREFIX mwapi: <https://www.mediawiki.org/ontology#API/>
+PREFIX schema: <http://schema.org/>
+PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
+PREFIX wikibase: <http://wikiba.se/ontology#>
+PREFIX wdt: <http://www.wikidata.org/prop/direct/>
+PREFIX wd: <http://www.wikidata.org/entity/>
+
+CONSTRUCT {
+    # Wikidata seems to have a problem with the short syntax for construct queries
+    # so always use full syntax: "?s ?p ?o ." else you end up with an empty result list!
+    ?item a skos:Concept .
+    ?item skos:prefLabel ?prefLabel .
+    ?item skos:altLabel ?altLabel .
+    ?item skos:scopeNote ?schema_description .
+}
+WHERE {
+    SERVICE wikibase:mwapi {
+        bd:serviceParam wikibase:endpoint "www.wikidata.org" .
+        # The search seems to be done with a "starts with" function,
+        # where by default the English pref and alt labels are searched.
+        # Setting the required language to something else than "en"
+        # results in an additional search in the pref and alt labels for this language.
+        bd:serviceParam wikibase:api "EntitySearch" .
+        bd:serviceParam mwapi:language "nl" .
+        bd:serviceParam mwapi:search ?query .
+        ?item wikibase:apiOutputItem mwapi:item .
+    }
+    # We are looking for places; because there are many types possible (cities, villages, etc) we filter
+    # on instances (P31) or subclasses (P279) of "human settlement" (Q486972)
+    ?item wdt:P31/wdt:P279* wd:Q486972 .
+
+    {
+        # Select places in the Netherlands (Q55)
+        ?item wdt:P17 wd:Q55 .
+
+        # Filter out Dutch municipalities
+        FILTER NOT EXISTS { ?item wdt:P31 wd:Q2039348 }
+    }
+    UNION {
+        # Select places in Belgium
+        ?item wdt:P17 wd:Q31 .
+
+        # Filter out Belgian municipalities
+        FILTER NOT EXISTS { ?item wdt:P31 wd:Q493522}
+    }
+
+    # Filter out agglomerations
+    FILTER NOT EXISTS { ?item wdt:P31 wd:Q159313 }
+
+    # Filter out neighborhoods
+    FILTER NOT EXISTS { ?item wdt:P31 wd:Q123705 }
+
+    ?item rdfs:label ?prefLabel .
+
+    # select only the Dutch pref/altLabels and description
+    FILTER(LANG(?prefLabel) = "nl")
+    OPTIONAL {
+        ?item skos:altLabel ?altLabel .
+        FILTER(LANG(?altLabel) = "nl")
+    }
+    OPTIONAL {
+        ?item schema:description ?schema_description
+        FILTER(LANG(?schema_description) = "nl")
+    }
+}
+LIMIT 1000

package/catalog/queries/search/wikidata-entities-streets.rq

@@ -0,0 +1,68 @@
+PREFIX bd: <http://www.bigdata.com/rdf#>
+PREFIX mwapi: <https://www.mediawiki.org/ontology#API/>
+PREFIX schema: <http://schema.org/>
+PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
+PREFIX wikibase: <http://wikiba.se/ontology#>
+PREFIX wdt: <http://www.wikidata.org/prop/direct/>
+PREFIX wd: <http://www.wikidata.org/entity/>
+
+CONSTRUCT {
+    # Wikidata seems to have a problem with the short syntax for construct queries
+    # so always use full syntax: "?s ?p ?o ." else you end up with an empty result list!
+    ?item a skos:Concept .
+    ?item skos:prefLabel ?streetName .
+    ?item skos:altLabel ?fullName .
+    ?item skos:altLabel ?altLabel .
+    ?item skos:scopeNote ?description .
+}
+WHERE {
+    SERVICE wikibase:mwapi {
+        bd:serviceParam wikibase:endpoint "www.wikidata.org" .
+        # The search seems to be done with a "starts with" function,
+        # where by default the English pref and alt labels are searched.
+        # Setting the required language to something else than "en"
+        # results in an additional search in the pref and alt labels for this language.
+        bd:serviceParam wikibase:api "EntitySearch" .
+        bd:serviceParam mwapi:language "nl" .
+        bd:serviceParam mwapi:search ?query .
+        ?item wikibase:apiOutputItem mwapi:item .
+    }
+    {
+      # select Streets
+      ?item wdt:P31 wd:Q79007 
+    }
+    UNION 
+    {
+      # select Squares
+      ?item wdt:P31 wd:Q174782
+    }
+    ?item wdt:P17 wd:Q55 .
+    ?item wdt:P131 ?administration .
+    OPTIONAL {
+      ?item wdt:P276 ?location .
+      ?location rdfs:label ?locationName .
+      FILTER LANGMATCHES(LANG(?locationName),"nl")
+    }
+    OPTIONAL {
+        ?item schema:description ?description
+        FILTER(LANG(?description) = "nl")
+    }
+    OPTIONAL {
+        ?item skos:altLabel ?altLabel
+        FILTER(LANG(?altLabel) = "nl")
+    }
+    ?item rdfs:label ?streetName .
+    ?administration rdfs:label ?administrationName .
+    FILTER LANGMATCHES(LANG(?streetName),"nl")
+    FILTER LANGMATCHES(LANG(?administrationName),"nl")
+    FILTER (STRSTARTS(LCASE(?streetName),LCASE(?query))||STRSTARTS(LCASE(?altLabel),LCASE(?query)))
+    BIND(
+      IF(
+        BOUND(?locationName),
+          CONCAT(?streetName," (",?locationName,")"),
+          CONCAT(?streetName," (",?administrationName,")")
+      )
+      as ?fullName 
+    )
+}
+LIMIT 1000

package/catalog/queries/search/wo2thesaurus.rq

@@ -0,0 +1,46 @@
+PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
+
+CONSTRUCT {
+    ?uri a skos:Concept ;
+        skos:prefLabel ?prefLabel ;
+        skos:altLabel ?altLabel ;
+        skos:hiddenLabel ?hiddenLabel ;
+        skos:scopeNote ?scopeNote ;
+        skos:broader ?broader_uri ;
+        skos:narrower ?narrower_uri .
+    ?broader_uri skos:prefLabel ?broader_prefLabel .
+    ?narrower_uri skos:prefLabel ?narrower_prefLabel .
+}
+WHERE {
+    ?uri ?predicate ?label .
+    VALUES ?predicate { skos:prefLabel skos:altLabel }
+    FILTER(LANG(?label) = "nl")
+    FILTER(CONTAINS(LCASE(?label), LCASE(?query)))
+    OPTIONAL {
+        ?uri skos:prefLabel ?prefLabel .
+        FILTER(LANG(?prefLabel) = "nl" )
+    }
+    OPTIONAL {
+        ?uri skos:scopeNote ?scopeNote .
+        FILTER(LANG(?scopeNote) = "nl")
+    }
+    OPTIONAL {
+        ?uri skos:altLabel ?altLabel .
+        FILTER(LANG(?altLabel) = "nl")
+    }
+    OPTIONAL {
+        ?uri skos:hiddenLabel ?hiddenLabel .
+        FILTER(LANG(?hiddenLabel) = "nl")
+    }
+    OPTIONAL {
+        ?uri skos:broader ?broader_uri .
+        ?broader_uri skos:prefLabel ?broader_prefLabel .
+        FILTER(LANG(?broader_prefLabel) = "nl")
+    }
+    OPTIONAL {
+        ?uri skos:narrower ?narrower_uri .
+        ?narrower_uri skos:prefLabel ?narrower_prefLabel .
+        FILTER(LANG(?narrower_prefLabel) = "nl")
+    }
+}
+LIMIT 1000