@netwerk-digitaal-erfgoed/network-of-terms-catalog 5.1.3

package/catalog/queries/lookup/aat.rq

@@ -0,0 +1,49 @@
+PREFIX aat: <http://vocab.getty.edu/aat/>
+PREFIX dcterms: <http://purl.org/dc/terms/>
+PREFIX gvp: <http://vocab.getty.edu/ontology#>
+PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
+PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
+PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
+PREFIX skosxl: <http://www.w3.org/2008/05/skos-xl#>
+
+CONSTRUCT {
+    ?uri a skos:Concept ;
+        skos:prefLabel ?prefLabel ;
+        skos:altLabel ?altLabel ;
+        skos:scopeNote ?scopeNote ;
+        skos:broader ?broader_uri ;
+        skos:narrower ?narrower_uri .
+    ?broader_uri skos:prefLabel ?broader_prefLabel .
+    ?narrower_uri skos:prefLabel ?narrower_prefLabel .
+}
+WHERE {
+    # For example:
+    # Bicycles: <http://vocab.getty.edu/aat/300212636>
+    # Wars: <http://vocab.getty.edu/aat/300055314>
+    VALUES ?uri { ?uris }
+
+    ?uri skosxl:prefLabel ?prefLabel_uri .
+    ?prefLabel_uri dcterms:language aat:300388256 . # Dutch (language)
+    ?prefLabel_uri skosxl:literalForm ?prefLabel .
+    OPTIONAL {
+        ?uri skosxl:altLabel ?altLabel_uri .
+        ?altLabel_uri dcterms:language aat:300388256 .
+        ?altLabel_uri skosxl:literalForm ?altLabel .
+    }
+    OPTIONAL {
+        ?uri skos:scopeNote ?scopeNote_uri .
+        ?scopeNote_uri dcterms:language aat:300388256 . # Dutch (language)
+        ?scopeNote_uri rdf:value ?scopeNote .
+    }
+    OPTIONAL {
+        ?uri gvp:broaderPreferred/skosxl:prefLabel ?broader_uri .
+        ?broader_uri dcterms:language aat:300388256 . # Dutch (language)
+        ?broader_uri skosxl:literalForm ?broader_prefLabel .
+    }
+    OPTIONAL {
+        ?uri skos:narrower/skosxl:prefLabel ?narrower_uri .
+        ?narrower_uri dcterms:language aat:300388256 . # Dutch (language)
+        ?narrower_uri skosxl:literalForm ?narrower_prefLabel .
+    }
+}
+LIMIT 1000

package/catalog/queries/lookup/abr-cht.rq

@@ -0,0 +1,46 @@
+PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
+
+CONSTRUCT {
+    ?uri a skos:Concept ;
+        skos:prefLabel ?prefLabel ;
+        skos:altLabel ?altLabel ;
+        skos:hiddenLabel ?hiddenLabel ;
+        skos:scopeNote ?scopeNote ;
+        skos:broader ?broader_uri ;
+        skos:narrower ?narrower_uri .
+    ?broader_uri skos:prefLabel ?broader_prefLabel .
+    ?narrower_uri skos:prefLabel ?narrower_prefLabel .
+}
+WHERE {
+    # For example:
+    # Aardewerk: <https://data.cultureelerfgoed.nl/term/id/abr/71e411bf-8645-4420-98a4-b8746574b002>
+    # Aardewerk: <https://data.cultureelerfgoed.nl/term/id/cht/dfbf8107-09f9-49c9-8118-8e79b7613723>
+    VALUES ?uri { ?uris }
+    OPTIONAL {
+        ?uri skos:prefLabel ?prefLabel .
+        FILTER(LANG(?prefLabel) = "nl")
+    }
+    OPTIONAL {
+        ?uri skos:altLabel ?altLabel .
+        FILTER(LANG(?altLabel) = "nl")
+    }
+    OPTIONAL {
+        ?uri skos:hiddenLabel ?hiddenLabel .
+        FILTER(LANG(?hiddenLabel) = "nl")
+    }
+    OPTIONAL {
+        ?uri skos:scopeNote ?scopeNote .
+        FILTER(LANG(?scopeNote) = "nl")
+    }
+    OPTIONAL {
+        ?uri skos:broader ?broader_uri .
+        ?broader_uri skos:prefLabel ?broader_prefLabel .
+        FILTER(LANG(?broader_prefLabel) = "nl")
+    }
+    OPTIONAL {
+        ?uri skos:narrower ?narrower_uri .
+        ?narrower_uri skos:prefLabel ?narrower_prefLabel .
+        FILTER(LANG(?narrower_prefLabel) = "nl")
+    }
+}
+LIMIT 1000

package/catalog/queries/lookup/brinkman-nta.rq

@@ -0,0 +1,66 @@
+# Do not remove this prefix - KB data uses old version of SKOS
+PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
+
+CONSTRUCT {
+    ?uri a skos:Concept ;
+        skos:prefLabel ?prefLabel ;
+        skos:prefLabel ?rdfs_label ;
+        skos:altLabel ?altLabel ;
+        skos:altLabel ?schema_alternateName ;
+        skos:altLabel ?schema_name ;
+        skos:hiddenLabel ?hiddenLabel ;
+        skos:scopeNote ?scopeNote ;
+        skos:scopeNote ?schema_description ;
+        skos:broader ?broader_uri ;
+        skos:narrower ?narrower_uri ;
+        skos:related ?related_uri .
+    ?broader_uri skos:prefLabel ?broader_prefLabel .
+    ?narrower_uri skos:prefLabel ?narrower_prefLabel .
+    ?related_uri skos:prefLabel ?related_prefLabel .
+}
+WHERE {
+    # For example:
+    # Concept in Brinkman: <http://data.bibliotheken.nl/id/thes/p317203789>
+    # Person in NTA: <http://data.bibliotheken.nl/id/thes/p06854796X>
+    VALUES ?uri { ?uris }
+
+    # For Brinkman
+    OPTIONAL {
+        ?uri skos:prefLabel ?prefLabel .
+        FILTER(LANG(?prefLabel) = "nl" )
+    }
+    OPTIONAL {
+        ?uri skos:altLabel ?altLabel .
+        FILTER(LANG(?altLabel) = "nl")
+    }
+    OPTIONAL {
+        ?uri skos:hiddenLabel ?hiddenLabel .
+        FILTER(LANG(?hiddenLabel) = "nl")
+    }
+    OPTIONAL {
+        ?uri skos:scopeNote ?scopeNote .
+        FILTER(LANG(?scopeNote) = "nl")
+    }
+    OPTIONAL {
+        ?uri skos:broader ?broader_uri .
+        ?broader_uri skos:prefLabel ?broader_prefLabel .
+        FILTER(LANG(?broader_prefLabel) = "nl")
+    }
+    OPTIONAL {
+        ?uri skos:narrower ?narrower_uri .
+        ?narrower_uri skos:prefLabel ?narrower_prefLabel .
+        FILTER(LANG(?narrower_prefLabel) = "nl")
+    }
+    OPTIONAL {
+        ?uri skos:related ?related_uri .
+        ?related_uri skos:prefLabel ?related_prefLabel .
+        FILTER(LANG(?related_prefLabel) = "nl")
+    }
+
+    # For NTA
+    OPTIONAL { ?uri rdfs:label ?rdfs_label }
+    OPTIONAL { ?uri schema:name ?schema_name }
+    OPTIONAL { ?uri schema:alternateName ?schema_alternateName }
+    OPTIONAL { ?uri schema:description ?schema_description }
+}
+LIMIT 1000

package/catalog/queries/lookup/gtaa.rq

@@ -0,0 +1,55 @@
+PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
+
+CONSTRUCT {
+    ?uri a skos:Concept ;
+        skos:prefLabel ?prefLabel ;
+        skos:altLabel ?altLabel ;
+        skos:hiddenLabel ?hiddenLabel ;
+        skos:scopeNote ?scopeNote ;
+        skos:broader ?broader_uri ;
+        skos:narrower ?narrower_uri ;
+        skos:related ?related_uri .
+    ?broader_uri skos:prefLabel ?broader_prefLabel .
+    ?narrower_uri skos:prefLabel ?narrower_prefLabel .
+    ?related_uri skos:prefLabel ?related_prefLabel .
+}
+WHERE {
+    # For example:
+    # Concept: <http://data.beeldengeluid.nl/gtaa/25109>
+    # Geographical name: <http://data.beeldengeluid.nl/gtaa/33511>
+    # Genre: <http://data.beeldengeluid.nl/gtaa/30115>
+    VALUES ?uri { ?uris }
+
+    OPTIONAL {
+        ?uri skos:prefLabel ?prefLabel .
+        FILTER(LANG(?prefLabel) = "nl" )
+    }
+    OPTIONAL {
+        ?uri skos:altLabel ?altLabel .
+        FILTER(LANG(?altLabel) = "nl")
+    }
+    OPTIONAL {
+        ?uri skos:hiddenLabel ?hiddenLabel .
+        FILTER(LANG(?hiddenLabel) = "nl")
+    }
+    OPTIONAL {
+        ?uri skos:scopeNote ?scopeNote .
+        FILTER(LANG(?scopeNote) = "nl")
+    }
+    OPTIONAL {
+        ?uri skos:broader ?broader_uri .
+        ?broader_uri skos:prefLabel ?broader_prefLabel .
+        FILTER(LANG(?broader_prefLabel) = "nl")
+    }
+    OPTIONAL {
+        ?uri skos:narrower ?narrower_uri .
+        ?narrower_uri skos:prefLabel ?narrower_prefLabel .
+        FILTER(LANG(?narrower_prefLabel) = "nl")
+    }
+    OPTIONAL {
+        ?uri skos:related ?related_uri .
+        ?related_uri skos:prefLabel ?related_prefLabel .
+        FILTER(LANG(?related_prefLabel) = "nl")
+    }
+}
+LIMIT 1000

package/catalog/queries/lookup/muziekschatten.rq

@@ -0,0 +1,79 @@
+PREFIX schema: <http://schema.org/>
+PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
+PREFIX som: <http://data.muziekschatten.nl/som/>
+
+CONSTRUCT {
+    ?uri a skos:Concept ;
+        skos:prefLabel ?schema_name ;
+        skos:prefLabel ?prefLabel ;
+        skos:altLabel ?schema_alternateName ;
+        skos:scopeNote ?scopeNote ;
+        skos:scopeNote ?schema_hasOccupation ;
+        skos:broader ?uri_broader .
+    ?uri_broader skos:prefLabel ?broader_schema_name .
+}
+WHERE {
+    # For example:
+    # Subject: <https://data.muziekschatten.nl/som/d781655>
+    # Subject: <https://data.muziekschatten.nl/som/d78165>
+    # Person: <https://data.muziekschatten.nl/som/b7bc6d966287e0f0e0f491752ff65ba5>
+    # Person: <https://data.muziekschatten.nl/som/4275e51d7d94b224928da9b7707a170a>
+    VALUES ?uri { ?uris }
+
+    OPTIONAL {
+        ?uri schema:name ?schema_name .
+        FILTER(LANG(?schema_name) = "nl")
+    }
+
+    # For subjects
+    OPTIONAL {
+        ?uri a skos:Concept
+        OPTIONAL {
+            ?uri skos:broader ?uri_broader .
+            ?uri_broader schema:name ?broader_schema_name .
+            FILTER(LANG(?broader_schema_name) = "nl")
+        }
+        OPTIONAL {
+            ?uri schema:keywords ?schema_keywords
+        }
+        OPTIONAL {
+            ?uri som:DC ?dc
+        }
+        BIND(
+            COALESCE(
+                IF(BOUND(?schema_keywords) && BOUND(?dc), CONCAT("Trefwoorden: ", ?schema_keywords, " | ", "Dewey: ", ?dc), ?noScopeNote),
+                IF(BOUND(?schema_keywords), CONCAT("Trefwoorden: ", ?schema_keywords), ?noScopeNote),
+                IF(BOUND(?dc), CONCAT("Dewey: ", ?dc), ?noScopeNote)
+            ) AS ?scopeNote
+        )
+    }
+
+    # For persons
+    OPTIONAL {
+        ?uri a schema:Person
+        OPTIONAL { ?uri schema:alternateName ?schema_alternateName }
+        OPTIONAL { ?uri schema:hasOccupation ?schema_hasOccupation }
+        OPTIONAL { ?uri schema:familyName ?schema_familyName }
+        OPTIONAL { ?uri schema:givenName ?schema_givenName }
+        BIND(
+            COALESCE(
+                IF(BOUND(?schema_familyName) && BOUND(?schema_givenName), CONCAT(?schema_familyName, ", ", ?schema_givenName), ?noName),
+                ?schema_familyName,
+                ?schema_givenName,
+                ?schema_name # Fallback
+            ) AS ?name
+        )
+        OPTIONAL { ?uri som:GDAT ?som_birthYear }
+        OPTIONAL { ?uri som:SDAT ?som_deathYear }
+        BIND(
+            COALESCE(
+                IF(BOUND(?som_birthYear) && BOUND(?som_deathYear), CONCAT(?som_birthYear, "-", ?som_deathYear), ?noDate),
+                IF(BOUND(?som_birthYear), CONCAT(?som_birthYear, "-"), ?noDate),
+                IF(BOUND(?som_deathYear), CONCAT("-", ?som_deathYear), ?noDate),
+                ""
+            ) AS ?dates
+        )
+        BIND(CONCAT(?name, IF(?dates != "", CONCAT(" (", ?dates, ")"), "")) AS ?prefLabel)
+    }
+}
+LIMIT 1000

package/catalog/queries/lookup/muziekweb.rq

@@ -0,0 +1,40 @@
+PREFIX muziekweb: <https://data.muziekweb.nl/vocab/>
+PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
+PREFIX schema: <http://schema.org/>
+PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
+
+CONSTRUCT {
+    ?uri a skos:Concept ;
+        skos:prefLabel ?rdfs_label ;
+        skos:prefLabel ?prefLabel ;
+        skos:altLabel ?altLabel ;
+        skos:hiddenLabel ?hiddenLabel ;
+        skos:scopeNote ?rdfs_comment ;
+        skos:scopeNote ?schema_description ;
+        skos:broader ?broader_uri ;
+        skos:narrower ?narrower_uri .
+    ?broader_uri skos:prefLabel ?broader_prefLabel .
+    ?narrower_uri skos:prefLabel ?narrower_prefLabel .
+}
+WHERE {
+    # For example:
+    # Music group: <https://data.muziekweb.nl/Link/M00000034333>
+    # Music genre: <https://data.muziekweb.nl/Link/T00000000050>
+    VALUES ?uri { ?uris }
+
+    OPTIONAL { ?uri rdfs:label ?rdfs_label }
+    OPTIONAL { ?uri skos:prefLabel ?prefLabel }
+    OPTIONAL { ?uri skos:altLabel ?altLabel }
+    OPTIONAL { ?uri skos:hiddenLabel ?hiddenLabel }
+    OPTIONAL { ?uri rdfs:comment ?rdfs_comment }
+    OPTIONAL { ?uri schema:description ?schema_description }
+    OPTIONAL {
+        ?uri skos:broader ?broader_uri .
+        ?broader_uri rdfs:label ?broader_prefLabel
+    }
+    OPTIONAL {
+        ?uri skos:narrower ?narrower_uri .
+        ?narrower_uri rdfs:label ?narrower_prefLabel
+    }
+}
+LIMIT 1000

package/catalog/queries/lookup/nmvw.rq

@@ -0,0 +1,41 @@
+PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
+
+CONSTRUCT {
+    ?uri a skos:Concept ;
+        skos:prefLabel ?prefLabel ;
+        skos:altLabel ?altLabel ;
+        skos:hiddenLabel ?hiddenLabel ;
+        skos:scopeNote ?scopeNote ;
+        skos:broader ?broader_uri ;
+        skos:narrower ?narrower_uri .
+    ?broader_uri skos:prefLabel ?broader_prefLabel .
+    ?narrower_uri skos:prefLabel ?narrower_prefLabel .
+}
+WHERE {
+    # For example:
+    # Klassieke Balinese Periode: <https://hdl.handle.net/20.500.11840/termmaster4914>
+    # Luxemburg: <https://hdl.handle.net/20.500.11840/termmaster17499>
+    VALUES ?uri { ?uris }
+
+    OPTIONAL {
+        ?uri skos:prefLabel ?prefLabel .
+    }
+    OPTIONAL {
+        ?uri skos:altLabel ?altLabel .
+    }
+    OPTIONAL {
+        ?uri skos:hiddenLabel ?hiddenLabel .
+    }
+    OPTIONAL {
+        ?uri skos:scopeNote ?scopeNote .
+    }
+    OPTIONAL {
+        ?uri skos:broader ?broader_uri .
+        ?broader_uri skos:prefLabel ?broader_prefLabel .
+    }
+    OPTIONAL {
+        ?uri skos:narrower ?narrower_uri .
+        ?narrower_uri skos:prefLabel ?narrower_prefLabel .
+    }
+}
+LIMIT 1000

package/catalog/queries/lookup/rkdartists.rq

@@ -0,0 +1,20 @@
+PREFIX schema: <http://schema.org/>
+PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
+
+CONSTRUCT {
+    ?uri a skos:Concept ;
+        skos:prefLabel ?schema_name ;
+        skos:altLabel ?schema_alternateName ;
+        skos:scopeNote ?schema_description .
+}
+WHERE {
+    # For example:
+    # Rembrandt: <https://data.rkd.nl/artists/66219>
+    # Vincent van Gogh: <https://data.rkd.nl/artists/32439>
+    VALUES ?uri { ?uris }
+
+    OPTIONAL { ?uri schema:name ?schema_name . }
+    OPTIONAL { ?uri schema:alternateName ?schema_alternateName . }
+    OPTIONAL { ?uri schema:description ?schema_description . }
+}
+LIMIT 1000

package/catalog/queries/lookup/wikidata.rq

@@ -0,0 +1,51 @@
+PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
+PREFIX schema: <http://schema.org/>
+PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
+PREFIX wdt: <http://www.wikidata.org/prop/direct/>
+
+CONSTRUCT {
+    ?uri a skos:Concept ;
+    	skos:prefLabel ?rdfs_label ;
+        skos:altLabel ?altLabel ;
+    	skos:altLabel ?altLabelStreetName ;
+    	skos:scopeNote ?schema_description .
+}
+WHERE {
+    # For example:
+    # Some entity (e.g. a painting): <http://www.wikidata.org/entity/Q185255>
+    # Person: <http://www.wikidata.org/entity/Q2696551>
+    # Place: <http://www.wikidata.org/entity/Q727>
+    # Street: <http://www.wikidata.org/entity/Q19573969>
+    VALUES ?uri { ?uris }
+
+    ?uri rdfs:label ?rdfs_label .
+    FILTER(LANG(?rdfs_label) = "nl")
+
+    OPTIONAL {
+        ?uri skos:altLabel ?altLabel .
+        FILTER(LANG(?altLabel) = "nl")
+    }
+    OPTIONAL {
+        ?uri schema:description ?schema_description
+        FILTER(LANG(?schema_description) = "nl")
+    }
+    # For streets
+    OPTIONAL {
+        ?uri wdt:P276/rdfs:label ?locationName .
+        FILTER(LANG(?locationName) = "nl")
+    }
+    # For streets
+    OPTIONAL {
+        ?uri wdt:P131/rdfs:label ?administrationName .
+        FILTER(LANG(?administrationName) = "nl")
+    }
+    # For streets
+    BIND(
+        COALESCE(
+            IF(BOUND(?locationName), CONCAT(?rdfs_label, " (", ?locationName, ")"), 1/0),
+            IF(BOUND(?administrationName), CONCAT(?rdfs_label, " (", ?administrationName, ")"), 1/0)
+        )
+        AS ?altLabelStreetName
+    )
+}
+LIMIT 1000

package/catalog/queries/lookup/wo2thesaurus.rq

@@ -0,0 +1,48 @@
+PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
+
+CONSTRUCT {
+    ?uri a skos:Concept ;
+        skos:prefLabel ?prefLabel ;
+        skos:altLabel ?altLabel ;
+        skos:hiddenLabel ?hiddenLabel ;
+        skos:scopeNote ?scopeNote ;
+        skos:broader ?broader_uri ;
+        skos:narrower ?narrower_uri .
+    ?broader_uri skos:prefLabel ?broader_prefLabel .
+    ?narrower_uri skos:prefLabel ?narrower_prefLabel .
+}
+WHERE {
+    # For example:
+    # Concept: <https://data.niod.nl/WO2_Thesaurus/3567>
+    # Event: <https://data.niod.nl/WO2_Thesaurus/events/5053>
+    # Organization: <https://data.niod.nl/WO2_Thesaurus/corporaties/5610>
+    VALUES ?uri { ?uris }
+
+    OPTIONAL {
+        ?uri skos:prefLabel ?prefLabel .
+        FILTER(LANG(?prefLabel) = "nl")
+    }
+    OPTIONAL {
+        ?uri skos:altLabel ?altLabel .
+        FILTER(LANG(?altLabel) = "nl")
+    }
+    OPTIONAL {
+        ?uri skos:hiddenLabel ?hiddenLabel .
+        FILTER(LANG(?hiddenLabel) = "nl")
+    }
+    OPTIONAL {
+        ?uri skos:scopeNote ?scopeNote .
+        FILTER(LANG(?scopeNote) = "nl")
+    }
+    OPTIONAL {
+        ?uri skos:broader ?broader_uri .
+        ?broader_uri skos:prefLabel ?broader_prefLabel .
+        FILTER(LANG(?broader_prefLabel) = "nl")
+    }
+    OPTIONAL {
+        ?uri skos:narrower ?narrower_uri .
+        ?narrower_uri skos:prefLabel ?narrower_prefLabel .
+        FILTER(LANG(?narrower_prefLabel) = "nl")
+    }
+}
+LIMIT 1000

package/catalog/queries/search/aat.rq

@@ -0,0 +1,50 @@
+PREFIX aat: <http://vocab.getty.edu/aat/>
+PREFIX dcterms: <http://purl.org/dc/terms/>
+PREFIX gvp: <http://vocab.getty.edu/ontology#>
+PREFIX luc: <http://www.ontotext.com/owlim/lucene#>
+PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
+PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
+PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
+PREFIX skosxl: <http://www.w3.org/2008/05/skos-xl#>
+
+CONSTRUCT {
+    ?uri a skos:Concept ;
+        skos:prefLabel ?prefLabel ;
+        skos:altLabel ?altLabel ;
+        skos:scopeNote ?scopeNote .
+    ?uri skos:broader ?broader_uri .
+    ?broader_uri skos:prefLabel ?broader_prefLabel .
+    ?uri skos:narrower ?narrower_uri .
+    ?narrower_uri skos:prefLabel ?narrower_prefLabel .
+}
+WHERE {
+    ?uri luc:term ?query ;
+        a ?type ;
+        void:inDataset <http://vocab.getty.edu/dataset/aat>  .
+    ?type rdfs:subClassOf gvp:Subject .
+    FILTER (?type != gvp:Subject) .
+    ?uri skosxl:prefLabel ?prefLabel_uri .
+    ?prefLabel_uri dcterms:language aat:300388256 . # Dutch (language)
+    ?prefLabel_uri skosxl:literalForm ?prefLabel .
+    OPTIONAL {
+        ?uri skosxl:altLabel ?altLabel_uri .
+        ?altLabel_uri dcterms:language aat:300388256 .
+        ?altLabel_uri skosxl:literalForm ?altLabel .
+    }
+    OPTIONAL {
+        ?uri skos:scopeNote ?scopeNote_uri .
+        ?scopeNote_uri dcterms:language aat:300388256 . # Dutch (language)
+        ?scopeNote_uri rdf:value ?scopeNote .
+    }
+    OPTIONAL {
+        ?uri gvp:broaderPreferred/skosxl:prefLabel ?broader_uri .
+        ?broader_uri dcterms:language aat:300388256 . # Dutch (language)
+        ?broader_uri skosxl:literalForm ?broader_prefLabel .
+    }
+    OPTIONAL {
+        ?uri skos:narrower/skosxl:prefLabel ?narrower_uri .
+        ?narrower_uri dcterms:language aat:300388256 . # Dutch (language)
+        ?narrower_uri skosxl:literalForm ?narrower_prefLabel .
+    }
+}
+LIMIT 1000

package/catalog/queries/search/abr.rq

@@ -0,0 +1,51 @@
+PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
+
+CONSTRUCT {
+    ?uri a skos:Concept ;
+        skos:prefLabel ?prefLabel ;
+        skos:altLabel ?altLabel ;
+        skos:hiddenLabel ?hiddenLabel ;
+        skos:scopeNote ?scopeNote ;
+        skos:exactMatch ?skos_exactMatch ;
+        skos:broader ?broader_uri ;
+        skos:narrower ?narrower_uri .
+    ?broader_uri skos:prefLabel ?broader_prefLabel .
+    ?narrower_uri skos:prefLabel ?narrower_prefLabel .
+}
+WHERE {
+    ?uri a <https://data.cultureelerfgoed.nl/vocab/id/abr#AbrConcept> .
+    ?uri ?predicate ?label .
+    VALUES ?predicate { skos:prefLabel skos:altLabel }
+    FILTER(LANG(?label) = "nl")
+    FILTER(CONTAINS(LCASE(?label), LCASE(?query)))
+    OPTIONAL {
+        ?uri skos:prefLabel ?prefLabel .
+        FILTER(LANG(?prefLabel) = "nl")
+    }
+    OPTIONAL {
+        ?uri skos:altLabel ?altLabel .
+        FILTER(LANG(?altLabel) = "nl")
+    }
+    OPTIONAL {
+        ?uri skos:scopeNote ?scopeNote .
+        FILTER(LANG(?scopeNote) = "nl")
+    }
+    OPTIONAL {
+        ?uri skos:hiddenLabel ?hiddenLabel .
+        FILTER(LANG(?hiddenLabel) = "nl")
+    }
+    OPTIONAL {
+        ?uri skos:broader ?broader_uri .
+        ?broader_uri skos:prefLabel ?broader_prefLabel .
+        FILTER(LANG(?broader_prefLabel) = "nl")
+    }
+    OPTIONAL {
+        ?uri skos:narrower ?narrower_uri .
+        ?narrower_uri skos:prefLabel ?narrower_prefLabel .
+        FILTER(LANG(?narrower_prefLabel) = "nl")
+    }
+    OPTIONAL {
+        ?uri skos:exactMatch ?skos_exactMatch .
+    }
+}
+LIMIT 1000

package/catalog/queries/search/brinkman.rq

@@ -0,0 +1,61 @@
+# Do not remove this prefix - KB data uses old version of SKOS
+PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
+
+CONSTRUCT {
+    ?uri a skos:Concept ;
+        skos:prefLabel ?prefLabel ;
+        skos:altLabel ?altLabel ;
+        skos:hiddenLabel ?hiddenLabel ;
+        skos:scopeNote ?scopeNote ;
+        skos:broader ?broader_uri ;
+        skos:narrower ?narrower_uri ;
+        skos:related ?related_uri ;
+        skos:exactMatch ?exactMatch .
+    ?broader_uri skos:prefLabel ?broader_prefLabel .
+    ?narrower_uri skos:prefLabel ?narrower_prefLabel .
+    ?related_uri skos:prefLabel ?related_prefLabel .
+}
+WHERE {
+    ?uri a skos:Concept .
+    ?uri skos:inScheme <http://data.bibliotheken.nl/id/scheme/brinkman> .
+    ?uri ?predicate ?label .
+    VALUES ?predicate { skos:prefLabel skos:altLabel }
+    FILTER(LANG(?label) = "nl")
+
+    # Replace query "A B" with "A AND B", leaving queries "A AND B" or "A OR B" unchanged.
+    FILTER (<bif:contains> (?label, REPLACE(?query, "(?<!AND)(?<!OR)[[:space:]]+(?!AND)(?!OR)", " AND ", "i")))
+
+    OPTIONAL {
+        ?uri skos:prefLabel ?prefLabel .
+        FILTER(LANG(?prefLabel) = "nl" )
+    }
+    OPTIONAL {
+        ?uri skos:altLabel ?altLabel .
+        FILTER(LANG(?altLabel) = "nl")
+    }
+    OPTIONAL {
+        ?uri skos:hiddenLabel ?hiddenLabel .
+        FILTER(LANG(?hiddenLabel) = "nl")
+    }
+    OPTIONAL {
+        ?uri skos:scopeNote ?scopeNote .
+        FILTER(LANG(?scopeNote) = "nl")
+    }
+    OPTIONAL {
+        ?uri skos:broader ?broader_uri .
+        ?broader_uri skos:prefLabel ?broader_prefLabel .
+        FILTER(LANG(?broader_prefLabel) = "nl")
+    }
+    OPTIONAL {
+        ?uri skos:narrower ?narrower_uri .
+        ?narrower_uri skos:prefLabel ?narrower_prefLabel .
+        FILTER(LANG(?narrower_prefLabel) = "nl")
+    }
+    OPTIONAL {
+        ?uri skos:related ?related_uri .
+        ?related_uri skos:prefLabel ?related_prefLabel .
+        FILTER(LANG(?related_prefLabel) = "nl")
+    }
+    OPTIONAL { ?uri skos:exactMatch ?exactMatch }
+}
+LIMIT 1000