@mapvina-com/mapvina-react-native 1.0.0

package/ios/components/sources/tile-sources/raster-dem-source/MLRNRasterDEMSourceComponentView.mm

@@ -0,0 +1,131 @@
+#import "MLRNRasterDEMSourceComponentView.h"
+
+#import <react/renderer/components/MapVinaReactNativeSpec/ComponentDescriptors.h>
+#import <react/renderer/components/MapVinaReactNativeSpec/EventEmitters.h>
+#import <react/renderer/components/MapVinaReactNativeSpec/Props.h>
+#import <react/renderer/components/MapVinaReactNativeSpec/RCTComponentViewHelpers.h>
+
+#import "RCTFabricComponentsPlugins.h"
+
+#import <MapVina/MapVina.h>
+#import <React/RCTConversions.h>
+#import "MLRNRasterDEMSource.h"
+
+using namespace facebook::react;
+
+// MARK: - MLRNRasterDEMSourceComponentView
+
+@interface MLRNRasterDEMSourceComponentView () <RCTMLRNRasterDEMSourceViewProtocol>
+
+@end
+
+@implementation MLRNRasterDEMSourceComponentView {
+  MLRNRasterDEMSource *_view;
+}
+
+- (instancetype)initWithFrame:(CGRect)frame {
+  if (self = [super initWithFrame:frame]) {
+    static const auto defaultProps = std::make_shared<const MLRNRasterDEMSourceProps>();
+    _props = defaultProps;
+    [self prepareView];
+  }
+
+  return self;
+}
+
+- (void)prepareView {
+  _view = [[MLRNRasterDEMSource alloc] init];
+  self.contentView = _view;
+}
+
+- (MLRNRasterDEMSource *)rasterDEMSource {
+  return _view;
+}
+
+#pragma mark - RCTComponentViewProtocol
+
++ (ComponentDescriptorProvider)componentDescriptorProvider {
+  return concreteComponentDescriptorProvider<MLRNRasterDEMSourceComponentDescriptor>();
+}
+
+- (void)updateProps:(const Props::Shared &)props oldProps:(const Props::Shared &)oldProps {
+  const auto &oldViewProps = *std::static_pointer_cast<const MLRNRasterDEMSourceProps>(_props);
+  const auto &newViewProps = *std::static_pointer_cast<const MLRNRasterDEMSourceProps>(props);
+
+  if (oldViewProps.id != newViewProps.id) {
+    _view.id = RCTNSStringFromString(newViewProps.id);
+  }
+
+  if (oldViewProps.url != newViewProps.url) {
+    _view.url = RCTNSStringFromStringNilIfEmpty(newViewProps.url);
+  }
+
+  if (oldViewProps.tiles != newViewProps.tiles) {
+    if (newViewProps.tiles.size() > 0) {
+      NSMutableArray *tiles = [NSMutableArray arrayWithCapacity:newViewProps.tiles.size()];
+      for (const auto &tile : newViewProps.tiles) {
+        [tiles addObject:RCTNSStringFromString(tile)];
+      }
+      _view.tileUrlTemplates = tiles;
+    } else {
+      _view.tileUrlTemplates = nil;
+    }
+  }
+
+  if (oldViewProps.minzoom != newViewProps.minzoom) {
+    _view.minZoomLevel = newViewProps.minzoom >= 0 ? @(newViewProps.minzoom) : nil;
+  }
+
+  if (oldViewProps.maxzoom != newViewProps.maxzoom) {
+    _view.maxZoomLevel = newViewProps.maxzoom >= 0 ? @(newViewProps.maxzoom) : nil;
+  }
+
+  if (oldViewProps.attribution != newViewProps.attribution) {
+    _view.attribution = RCTNSStringFromStringNilIfEmpty(newViewProps.attribution);
+  }
+
+  if (oldViewProps.tileSize != newViewProps.tileSize) {
+    _view.tileSize = newViewProps.tileSize >= 0 ? @(newViewProps.tileSize) : nil;
+  }
+
+  if (oldViewProps.encoding != newViewProps.encoding) {
+    switch (newViewProps.encoding) {
+      case MLRNRasterDEMSourceEncoding::Terrarium:
+        _view.encoding = @"terrarium";
+        break;
+      case MLRNRasterDEMSourceEncoding::Mapbox:
+      default:
+        _view.encoding = @"mapbox";
+        break;
+    }
+  }
+
+  [super updateProps:props oldProps:oldProps];
+}
+
+- (void)mountChildComponentView:(UIView<RCTComponentViewProtocol> *)childComponentView
+                          index:(NSInteger)index {
+  if ([childComponentView isKindOfClass:[RCTViewComponentView class]] &&
+      ((RCTViewComponentView *)childComponentView).contentView) {
+    [_view insertReactSubview:(id<RCTComponent>)((RCTViewComponentView *)childComponentView)
+                                  .contentView
+                      atIndex:index];
+  }
+  [super mountChildComponentView:childComponentView index:index];
+}
+
+- (void)unmountChildComponentView:(UIView<RCTComponentViewProtocol> *)childComponentView
+                            index:(NSInteger)index {
+  if ([childComponentView isKindOfClass:[RCTViewComponentView class]] &&
+      ((RCTViewComponentView *)childComponentView).contentView) {
+    [_view removeReactSubview:(id<RCTComponent>)((RCTViewComponentView *)childComponentView)
+                                  .contentView];
+  }
+  [super unmountChildComponentView:childComponentView index:index];
+}
+
+Class<RCTComponentViewProtocol> MLRNRasterDEMSourceCls(void) {
+  return MLRNRasterDEMSourceComponentView.class;
+}
+
+@end

package/ios/components/sources/tile-sources/raster-source/MLRNRasterSource.h

@@ -0,0 +1,9 @@
+#import "MLRNTileSource.h"
+
+#import <MapVina/MapVina.h>
+
+@interface MLRNRasterSource : MLRNTileSource
+
+@property (nonatomic, strong) NSNumber *tileSize;
+
+@end

package/ios/components/sources/tile-sources/raster-source/MLRNRasterSource.m

@@ -0,0 +1,31 @@
+#import "MLRNRasterSource.h"
+
+@implementation MLRNRasterSource
+
+- (nullable MLNSource *)makeSource {
+  if (self.url != nil) {
+    NSURL *url = [NSURL URLWithString:self.url];
+    if (self.tileSize != nil) {
+      return [[MLNRasterTileSource alloc] initWithIdentifier:self.id
+                                            configurationURL:url
+                                                    tileSize:[self.tileSize floatValue]];
+    }
+    return [[MLNRasterTileSource alloc] initWithIdentifier:self.id configurationURL:url];
+  }
+  return [[MLNRasterTileSource alloc] initWithIdentifier:self.id
+                                        tileURLTemplates:self.tileUrlTemplates
+                                                 options:[self getOptions]];
+}
+
+- (NSDictionary<MLNTileSourceOption, id> *)getOptions {
+  NSMutableDictionary<MLNTileSourceOption, id> *options =
+      [[NSMutableDictionary alloc] initWithDictionary:[super getOptions]];
+
+  if (self.tileSize != nil) {
+    options[MLNTileSourceOptionTileSize] = _tileSize;
+  }
+
+  return options;
+}
+
+@end

package/ios/components/sources/tile-sources/raster-source/MLRNRasterSourceComponentView.h

@@ -0,0 +1,9 @@
+#import <React/RCTViewComponentView.h>
+
+@class MLRNRasterSource;
+
+@interface MLRNRasterSourceComponentView : RCTViewComponentView
+
+@property (nonatomic, readonly) MLRNRasterSource *rasterSource;
+
+@end

package/ios/components/sources/tile-sources/raster-source/MLRNRasterSourceComponentView.mm

@@ -0,0 +1,129 @@
+#import "MLRNRasterSourceComponentView.h"
+
+#import <react/renderer/components/MapVinaReactNativeSpec/ComponentDescriptors.h>
+#import <react/renderer/components/MapVinaReactNativeSpec/EventEmitters.h>
+#import <react/renderer/components/MapVinaReactNativeSpec/Props.h>
+#import <react/renderer/components/MapVinaReactNativeSpec/RCTComponentViewHelpers.h>
+
+#import "RCTFabricComponentsPlugins.h"
+
+#import <MapVina/MapVina.h>
+#import <React/RCTConversions.h>
+#import "MLRNRasterSource.h"
+
+using namespace facebook::react;
+
+// MARK: - MLRNRasterSourceComponentView
+
+@interface MLRNRasterSourceComponentView () <RCTMLRNRasterSourceViewProtocol>
+
+@end
+
+@implementation MLRNRasterSourceComponentView {
+  MLRNRasterSource *_view;
+}
+
+- (instancetype)initWithFrame:(CGRect)frame {
+  if (self = [super initWithFrame:frame]) {
+    static const auto defaultProps = std::make_shared<const MLRNRasterSourceProps>();
+    _props = defaultProps;
+    [self prepareView];
+  }
+
+  return self;
+}
+
+- (void)prepareView {
+  _view = [[MLRNRasterSource alloc] init];
+  self.contentView = _view;
+}
+
+- (MLRNRasterSource *)rasterSource {
+  return _view;
+}
+
+#pragma mark - RCTComponentViewProtocol
+
++ (ComponentDescriptorProvider)componentDescriptorProvider {
+  return concreteComponentDescriptorProvider<MLRNRasterSourceComponentDescriptor>();
+}
+
+- (void)updateProps:(const Props::Shared &)props oldProps:(const Props::Shared &)oldProps {
+  const auto &oldViewProps = *std::static_pointer_cast<const MLRNRasterSourceProps>(_props);
+  const auto &newViewProps = *std::static_pointer_cast<const MLRNRasterSourceProps>(props);
+
+  if (oldViewProps.id != newViewProps.id) {
+    _view.id = RCTNSStringFromString(newViewProps.id);
+  }
+
+  if (oldViewProps.url != newViewProps.url) {
+    _view.url = RCTNSStringFromStringNilIfEmpty(newViewProps.url);
+  }
+
+  if (oldViewProps.tiles != newViewProps.tiles) {
+    if (newViewProps.tiles.size() > 0) {
+      NSMutableArray *tiles = [NSMutableArray arrayWithCapacity:newViewProps.tiles.size()];
+      for (const auto &tile : newViewProps.tiles) {
+        [tiles addObject:RCTNSStringFromString(tile)];
+      }
+      _view.tileUrlTemplates = tiles;
+    } else {
+      _view.tileUrlTemplates = nil;
+    }
+  }
+
+  if (oldViewProps.minzoom != newViewProps.minzoom) {
+    _view.minZoomLevel = newViewProps.minzoom >= 0 ? @(newViewProps.minzoom) : nil;
+  }
+
+  if (oldViewProps.maxzoom != newViewProps.maxzoom) {
+    _view.maxZoomLevel = newViewProps.maxzoom >= 0 ? @(newViewProps.maxzoom) : nil;
+  }
+
+  if (oldViewProps.scheme != newViewProps.scheme) {
+    if (newViewProps.scheme == MLRNRasterSourceScheme::Tms) {
+      _view.scheme = @(MLNTileCoordinateSystemTMS);
+    } else if (newViewProps.scheme == MLRNRasterSourceScheme::Xyz) {
+      _view.scheme = @(MLNTileCoordinateSystemXYZ);
+    } else {
+      _view.scheme = nil;
+    }
+  }
+
+  if (oldViewProps.attribution != newViewProps.attribution) {
+    _view.attribution = RCTNSStringFromStringNilIfEmpty(newViewProps.attribution);
+  }
+
+  if (oldViewProps.tileSize != newViewProps.tileSize) {
+    _view.tileSize = newViewProps.tileSize >= 0 ? @(newViewProps.tileSize) : nil;
+  }
+
+  [super updateProps:props oldProps:oldProps];
+}
+
+- (void)mountChildComponentView:(UIView<RCTComponentViewProtocol> *)childComponentView
+                          index:(NSInteger)index {
+  if ([childComponentView isKindOfClass:[RCTViewComponentView class]] &&
+      ((RCTViewComponentView *)childComponentView).contentView) {
+    [_view insertReactSubview:(id<RCTComponent>)((RCTViewComponentView *)childComponentView)
+                                  .contentView
+                      atIndex:index];
+  }
+  [super mountChildComponentView:childComponentView index:index];
+}
+
+- (void)unmountChildComponentView:(UIView<RCTComponentViewProtocol> *)childComponentView
+                            index:(NSInteger)index {
+  if ([childComponentView isKindOfClass:[RCTViewComponentView class]] &&
+      ((RCTViewComponentView *)childComponentView).contentView) {
+    [_view removeReactSubview:(id<RCTComponent>)((RCTViewComponentView *)childComponentView)
+                                  .contentView];
+  }
+  [super unmountChildComponentView:childComponentView index:index];
+}
+
+Class<RCTComponentViewProtocol> MLRNRasterSourceCls(void) {
+  return MLRNRasterSourceComponentView.class;
+}
+
+@end

package/ios/components/sources/tile-sources/vector-source/MLRNVectorSource.h

@@ -0,0 +1,11 @@
+#import "MLRNTileSource.h"
+
+#import <MapVina/MapVina.h>
+
+@interface MLRNVectorSource : MLRNTileSource
+
+- (nonnull NSArray<id<MLNFeature>> *)
+    featuresInSourceLayersWithIdentifiers:(nonnull NSSet<NSString *> *)sourceLayerIdentifiers
+                                predicate:(nullable NSPredicate *)predicate;
+
+@end

package/ios/components/sources/tile-sources/vector-source/MLRNVectorSource.m

@@ -0,0 +1,23 @@
+#import "MLRNVectorSource.h"
+
+@implementation MLRNVectorSource
+
+- (nullable MLNSource *)makeSource {
+  if (self.url != nil) {
+    return [[MLNVectorTileSource alloc] initWithIdentifier:self.id configurationURLString:self.url];
+  }
+  return [[MLNVectorTileSource alloc] initWithIdentifier:self.id
+                                        tileURLTemplates:self.tileUrlTemplates
+                                                 options:[self getOptions]];
+}
+
+- (nonnull NSArray<id<MLNFeature>> *)
+    featuresInSourceLayersWithIdentifiers:(nonnull NSSet<NSString *> *)sourceLayerIdentifiers
+                                predicate:(nullable NSPredicate *)predicate {
+  MLNVectorTileSource *vectorSource = (MLNVectorTileSource *)self.source;
+
+  return [vectorSource featuresInSourceLayersWithIdentifiers:sourceLayerIdentifiers
+                                                   predicate:predicate];
+}
+
+@end

package/ios/components/sources/tile-sources/vector-source/MLRNVectorSourceComponentView.h

@@ -0,0 +1,9 @@
+#import <React/RCTViewComponentView.h>
+
+@class MLRNVectorSource;
+
+@interface MLRNVectorSourceComponentView : RCTViewComponentView
+
+@property (nonatomic, readonly) MLRNVectorSource *vectorSource;
+
+@end

package/ios/components/sources/tile-sources/vector-source/MLRNVectorSourceComponentView.mm

@@ -0,0 +1,162 @@
+#import "MLRNVectorSourceComponentView.h"
+
+#import <react/renderer/components/MapVinaReactNativeSpec/ComponentDescriptors.h>
+#import <react/renderer/components/MapVinaReactNativeSpec/EventEmitters.h>
+#import <react/renderer/components/MapVinaReactNativeSpec/Props.h>
+#import <react/renderer/components/MapVinaReactNativeSpec/RCTComponentViewHelpers.h>
+
+#import "RCTFabricComponentsPlugins.h"
+
+#import <MapVina/MapVina.h>
+#import <React/RCTConversions.h>
+#import "MLRNFollyConvert.h"
+#import "MLRNVectorSource.h"
+
+using namespace facebook::react;
+
+// MARK: - MLRNVectorSourceComponentView
+
+@interface MLRNVectorSourceComponentView () <RCTMLRNVectorSourceViewProtocol>
+
+@end
+
+@implementation MLRNVectorSourceComponentView {
+  MLRNVectorSource *_view;
+}
+
+- (instancetype)initWithFrame:(CGRect)frame {
+  if (self = [super initWithFrame:frame]) {
+    static const auto defaultProps = std::make_shared<const MLRNVectorSourceProps>();
+    _props = defaultProps;
+    [self prepareView];
+  }
+
+  return self;
+}
+
+- (void)prepareView {
+  _view = [[MLRNVectorSource alloc] init];
+
+  // Capture weak self reference to prevent retain cycle
+  __weak __typeof__(self) weakSelf = self;
+
+  [_view setOnPress:^(NSDictionary *event) {
+    __typeof__(self) strongSelf = weakSelf;
+    if (strongSelf != nullptr && strongSelf->_eventEmitter != nullptr) {
+      const auto eventEmitter =
+          std::static_pointer_cast<const MLRNVectorSourceEventEmitter>(strongSelf->_eventEmitter);
+
+      facebook::react::MLRNVectorSourceEventEmitter::OnPress data = {
+          .lngLat = convertIdToFollyDynamic(event[@"lngLat"]),
+          .point = convertIdToFollyDynamic(event[@"point"]),
+          .features = convertIdToFollyDynamic(event[@"features"]),
+      };
+
+      eventEmitter->onPress(data);
+    }
+  }];
+
+  self.contentView = _view;
+}
+
+- (MLRNVectorSource *)vectorSource {
+  return _view;
+}
+
+#pragma mark - RCTComponentViewProtocol
+
++ (ComponentDescriptorProvider)componentDescriptorProvider {
+  return concreteComponentDescriptorProvider<MLRNVectorSourceComponentDescriptor>();
+}
+
+- (void)updateProps:(const Props::Shared &)props oldProps:(const Props::Shared &)oldProps {
+  const auto &oldViewProps = *std::static_pointer_cast<const MLRNVectorSourceProps>(_props);
+  const auto &newViewProps = *std::static_pointer_cast<const MLRNVectorSourceProps>(props);
+
+  if (oldViewProps.id != newViewProps.id) {
+    _view.id = RCTNSStringFromString(newViewProps.id);
+  }
+
+  if (oldViewProps.url != newViewProps.url) {
+    _view.url = RCTNSStringFromStringNilIfEmpty(newViewProps.url);
+  }
+
+  if (oldViewProps.tiles != newViewProps.tiles) {
+    if (newViewProps.tiles.size() > 0) {
+      NSMutableArray *tiles = [NSMutableArray arrayWithCapacity:newViewProps.tiles.size()];
+      for (const auto &tile : newViewProps.tiles) {
+        [tiles addObject:RCTNSStringFromString(tile)];
+      }
+      _view.tileUrlTemplates = tiles;
+    } else {
+      _view.tileUrlTemplates = nil;
+    }
+  }
+
+  if (oldViewProps.minzoom != newViewProps.minzoom) {
+    _view.minZoomLevel = newViewProps.minzoom >= 0 ? @(newViewProps.minzoom) : nil;
+  }
+
+  if (oldViewProps.maxzoom != newViewProps.maxzoom) {
+    _view.maxZoomLevel = newViewProps.maxzoom >= 0 ? @(newViewProps.maxzoom) : nil;
+  }
+
+  if (oldViewProps.scheme != newViewProps.scheme) {
+    if (newViewProps.scheme == MLRNVectorSourceScheme::Tms) {
+      _view.scheme = @(MLNTileCoordinateSystemTMS);
+    } else if (newViewProps.scheme == MLRNVectorSourceScheme::Xyz) {
+      _view.scheme = @(MLNTileCoordinateSystemXYZ);
+    } else {
+      _view.scheme = nil;
+    }
+  }
+
+  if (oldViewProps.attribution != newViewProps.attribution) {
+    _view.attribution = RCTNSStringFromStringNilIfEmpty(newViewProps.attribution);
+  }
+
+  if (oldViewProps.hasOnPress != newViewProps.hasOnPress) {
+    _view.hasPressListener = newViewProps.hasOnPress;
+  }
+
+  if (oldViewProps.hitbox.top != newViewProps.hitbox.top ||
+      oldViewProps.hitbox.right != newViewProps.hitbox.right ||
+      oldViewProps.hitbox.bottom != newViewProps.hitbox.bottom ||
+      oldViewProps.hitbox.left != newViewProps.hitbox.left) {
+    _view.hitbox = @{
+      @"top" : @(newViewProps.hitbox.top),
+      @"right" : @(newViewProps.hitbox.right),
+      @"bottom" : @(newViewProps.hitbox.bottom),
+      @"left" : @(newViewProps.hitbox.left),
+    };
+  }
+
+  [super updateProps:props oldProps:oldProps];
+}
+
+- (void)mountChildComponentView:(UIView<RCTComponentViewProtocol> *)childComponentView
+                          index:(NSInteger)index {
+  if ([childComponentView isKindOfClass:[RCTViewComponentView class]] &&
+      ((RCTViewComponentView *)childComponentView).contentView) {
+    [_view insertReactSubview:(id<RCTComponent>)((RCTViewComponentView *)childComponentView)
+                                  .contentView
+                      atIndex:index];
+  }
+  [super mountChildComponentView:childComponentView index:index];
+}
+
+- (void)unmountChildComponentView:(UIView<RCTComponentViewProtocol> *)childComponentView
+                            index:(NSInteger)index {
+  if ([childComponentView isKindOfClass:[RCTViewComponentView class]] &&
+      ((RCTViewComponentView *)childComponentView).contentView) {
+    [_view removeReactSubview:(id<RCTComponent>)((RCTViewComponentView *)childComponentView)
+                                  .contentView];
+  }
+  [super unmountChildComponentView:childComponentView index:index];
+}
+
+Class<RCTComponentViewProtocol> MLRNVectorSourceCls(void) {
+  return MLRNVectorSourceComponentView.class;
+}
+
+@end

package/ios/components/sources/tile-sources/vector-source/MLRNVectorSourceModule.h

@@ -0,0 +1,4 @@
+#import <MapVinaReactNativeSpec/MapVinaReactNativeSpec.h>
+
+@interface MLRNVectorSourceModule : NSObject <NativeVectorSourceModuleSpec>
+@end

package/ios/components/sources/tile-sources/vector-source/MLRNVectorSourceModule.mm

@@ -0,0 +1,65 @@
+#import "MLRNVectorSourceModule.h"
+
+#import <React/RCTUIManager.h>
+#import "FilterParser.h"
+#import "MLRNVectorSource.h"
+#import "MLRNVectorSourceComponentView.h"
+#import "MLRNViewModuleUtils.h"
+
+@implementation MLRNVectorSourceModule
+
+@synthesize viewRegistry_DEPRECATED = _viewRegistry_DEPRECATED;
+
++ (NSString *)moduleName {
+  return @"MLRNVectorSourceModule";
+}
+
+- (std::shared_ptr<facebook::react::TurboModule>)getTurboModule:
+    (const facebook::react::ObjCTurboModule::InitParams &)params {
+  return std::make_shared<facebook::react::NativeVectorSourceModuleSpecJSI>(params);
+}
+
+- (void)withVectorSource:(NSInteger)reactTag
+                   block:(void (^)(MLRNVectorSource *))block
+                  reject:(RCTPromiseRejectBlock)reject
+              methodName:(NSString *)methodName {
+  [MLRNViewModuleUtils withView:self.viewRegistry_DEPRECATED
+                       reactTag:reactTag
+             componentViewClass:[MLRNVectorSourceComponentView class]
+               contentViewClass:[MLRNVectorSource class]
+                          block:^(UIView *view) {
+                            block((MLRNVectorSource *)view);
+                          }
+                         reject:reject
+                     methodName:methodName];
+}
+
+- (void)querySourceFeatures:(NSInteger)reactTag
+                sourceLayer:(NSString *)sourceLayer
+                     filter:(NSArray *)filter
+                    resolve:(nonnull RCTPromiseResolveBlock)resolve
+                     reject:(nonnull RCTPromiseRejectBlock)reject {
+  [self withVectorSource:reactTag
+                   block:^(MLRNVectorSource *vectorSource) {
+                     NSSet *layerIDSet = nil;
+                     if (sourceLayer != nil && sourceLayer.length > 0) {
+                       layerIDSet = [NSSet setWithObject:sourceLayer];
+                     }
+                     NSPredicate *predicate = [FilterParser parse:filter];
+                     NSArray<id<MLNFeature>> *shapes =
+                         [vectorSource featuresInSourceLayersWithIdentifiers:layerIDSet
+                                                                   predicate:predicate];
+
+                     NSMutableArray<NSDictionary *> *features =
+                         [[NSMutableArray alloc] initWithCapacity:shapes.count];
+                     for (int i = 0; i < shapes.count; i++) {
+                       [features addObject:shapes[i].geoJSONDictionary];
+                     }
+
+                     resolve(features);
+                   }
+                  reject:reject
+              methodName:@"querySourceFeatures"];
+}
+
+@end

package/ios/components/user-location/MLRNNativeUserLocation.h

@@ -0,0 +1,11 @@
+#import <React/RCTComponent.h>
+#import <UIKit/UIKit.h>
+
+@class MLRNMapView;
+
+@interface MLRNNativeUserLocation : UIView
+
+@property (nonatomic, strong) MLRNMapView *map;
+@property (nonatomic) BOOL showsUserHeadingIndicator;
+
+@end

package/ios/components/user-location/MLRNNativeUserLocation.m

@@ -0,0 +1,38 @@
+#import "MLRNNativeUserLocation.h"
+#import "CameraStop.h"
+#import "CameraUpdateQueue.h"
+#import "MLRNEvent.h"
+#import "MLRNEventTypes.h"
+#import "MLRNLocation.h"
+#import "MLRNLocationManager.h"
+#import "MLRNUtils.h"
+
+@implementation MLRNNativeUserLocation {
+}
+
+- (void)setMap:(MLRNMapView *)map {
+  if (map == nil && _map) {
+    _map.useNativeUserLocationAnnotationView = NO;
+    _map.showsUserLocation = NO;
+    _map.showsUserHeadingIndicator = NO;
+  } else if (map) {
+    map.useNativeUserLocationAnnotationView = YES;
+    // Toggle off/on showsUserLocation in order for MapVina Native to invalidate the
+    // current (hidden) user location annotation view. See also: HiddenUserLocationAnnotationView
+    map.showsUserLocation = NO;
+    map.showsUserLocation = YES;
+    map.showsUserHeadingIndicator = self.showsUserHeadingIndicator;
+  }
+
+  _map = map;
+}
+
+- (void)setShowsUserHeadingIndicator:(BOOL)showsUserHeadingIndicator {
+  _showsUserHeadingIndicator = showsUserHeadingIndicator;
+
+  if (_map) {
+    _map.showsUserHeadingIndicator = showsUserHeadingIndicator;
+  }
+}
+
+@end

package/ios/components/user-location/MLRNNativeUserLocationComponentView.h

@@ -0,0 +1,10 @@
+#import <React/RCTViewComponentView.h>
+#import <UIKit/UIKit.h>
+
+NS_ASSUME_NONNULL_BEGIN
+
+@interface MLRNNativeUserLocationComponentView : RCTViewComponentView
+
+@end
+
+NS_ASSUME_NONNULL_END