@mapvina-com/mapvina-react-native 1.0.0

package/ios/components/sources/geojson-source/MLRNGeoJSONSourceComponentView.mm

@@ -0,0 +1,168 @@
+#import "MLRNGeoJSONSourceComponentView.h"
+
+#import <react/renderer/components/MapVinaReactNativeSpec/ComponentDescriptors.h>
+#import <react/renderer/components/MapVinaReactNativeSpec/EventEmitters.h>
+#import <react/renderer/components/MapVinaReactNativeSpec/Props.h>
+#import <react/renderer/components/MapVinaReactNativeSpec/RCTComponentViewHelpers.h>
+
+#import "RCTFabricComponentsPlugins.h"
+
+#import <React/RCTConversions.h>
+#import "MLRNFollyConvert.h"
+#import "MLRNGeoJSONSource.h"
+
+using namespace facebook::react;
+
+// MARK: - MLRNGeoJSONSourceComponentView
+
+@interface MLRNGeoJSONSourceComponentView () <RCTMLRNGeoJSONSourceViewProtocol>
+
+@end
+
+@implementation MLRNGeoJSONSourceComponentView {
+  MLRNGeoJSONSource *_view;
+}
+
+- (instancetype)initWithFrame:(CGRect)frame {
+  if (self = [super initWithFrame:frame]) {
+    static const auto defaultProps = std::make_shared<const MLRNGeoJSONSourceProps>();
+    _props = defaultProps;
+    [self prepareView];
+  }
+
+  return self;
+}
+
+- (void)prepareView {
+  _view = [[MLRNGeoJSONSource alloc] init];
+
+  // Capture weak self reference to prevent retain cycle
+  __weak __typeof__(self) weakSelf = self;
+
+  [_view setOnPress:^(NSDictionary *event) {
+    __typeof__(self) strongSelf = weakSelf;
+    if (strongSelf != nullptr && strongSelf->_eventEmitter != nullptr) {
+      const auto eventEmitter =
+          std::static_pointer_cast<const MLRNGeoJSONSourceEventEmitter>(strongSelf->_eventEmitter);
+
+      facebook::react::MLRNGeoJSONSourceEventEmitter::OnPress data = {
+          .lngLat = convertIdToFollyDynamic(event[@"lngLat"]),
+          .point = convertIdToFollyDynamic(event[@"point"]),
+          .features = convertIdToFollyDynamic(event[@"features"]),
+      };
+
+      eventEmitter->onPress(data);
+    }
+  }];
+
+  self.contentView = _view;
+}
+
+- (MLRNGeoJSONSource *)geoJSONSource {
+  return _view;
+}
+
+#pragma mark - RCTComponentViewProtocol
+
++ (ComponentDescriptorProvider)componentDescriptorProvider {
+  return concreteComponentDescriptorProvider<MLRNGeoJSONSourceComponentDescriptor>();
+}
+
+- (void)updateProps:(const Props::Shared &)props oldProps:(const Props::Shared &)oldProps {
+  const auto &oldViewProps = *std::static_pointer_cast<const MLRNGeoJSONSourceProps>(_props);
+  const auto &newViewProps = *std::static_pointer_cast<const MLRNGeoJSONSourceProps>(props);
+
+  if (oldViewProps.id != newViewProps.id) {
+    _view.id = RCTNSStringFromString(newViewProps.id);
+  }
+
+  if (oldViewProps.data != newViewProps.data) {
+    [_view setReactData:RCTNSStringFromString(newViewProps.data)];
+  }
+
+  if (oldViewProps.cluster != newViewProps.cluster) {
+    _view.cluster = @(newViewProps.cluster);
+  }
+
+  if (oldViewProps.clusterRadius != newViewProps.clusterRadius) {
+    _view.clusterRadius = newViewProps.clusterRadius >= 0 ? @(newViewProps.clusterRadius) : nil;
+  }
+
+  if (oldViewProps.clusterMinPoints != newViewProps.clusterMinPoints) {
+    _view.clusterMinPoints =
+        newViewProps.clusterMinPoints >= 0 ? @(newViewProps.clusterMinPoints) : nil;
+  }
+
+  if (oldViewProps.clusterMaxZoom != newViewProps.clusterMaxZoom) {
+    _view.clusterMaxZoomLevel =
+        newViewProps.clusterMaxZoom >= 0 ? @(newViewProps.clusterMaxZoom) : nil;
+  }
+
+  if (oldViewProps.clusterProperties != newViewProps.clusterProperties) {
+    _view.clusterProperties =
+        (!newViewProps.clusterProperties.isNull() && newViewProps.clusterProperties.isObject())
+            ? convertFollyDynamicToId(newViewProps.clusterProperties)
+            : nil;
+  }
+
+  if (oldViewProps.maxzoom != newViewProps.maxzoom) {
+    _view.maxZoomLevel = newViewProps.maxzoom >= 0 ? @(newViewProps.maxzoom) : nil;
+  }
+
+  if (oldViewProps.buffer != newViewProps.buffer) {
+    _view.buffer = newViewProps.buffer >= 0 ? @(newViewProps.buffer) : nil;
+  }
+
+  if (oldViewProps.tolerance != newViewProps.tolerance) {
+    _view.tolerance = newViewProps.tolerance >= 0 ? @(newViewProps.tolerance) : nil;
+  }
+
+  if (oldViewProps.lineMetrics != newViewProps.lineMetrics) {
+    _view.lineMetrics = @(newViewProps.lineMetrics);
+  }
+
+  if (oldViewProps.hasOnPress != newViewProps.hasOnPress) {
+    _view.hasPressListener = newViewProps.hasOnPress;
+  }
+
+  if (oldViewProps.hitbox.top != newViewProps.hitbox.top ||
+      oldViewProps.hitbox.right != newViewProps.hitbox.right ||
+      oldViewProps.hitbox.bottom != newViewProps.hitbox.bottom ||
+      oldViewProps.hitbox.left != newViewProps.hitbox.left) {
+    _view.hitbox = @{
+      @"top" : @(newViewProps.hitbox.top),
+      @"right" : @(newViewProps.hitbox.right),
+      @"bottom" : @(newViewProps.hitbox.bottom),
+      @"left" : @(newViewProps.hitbox.left),
+    };
+  }
+
+  [super updateProps:props oldProps:oldProps];
+}
+
+- (void)mountChildComponentView:(UIView<RCTComponentViewProtocol> *)childComponentView
+                          index:(NSInteger)index {
+  if ([childComponentView isKindOfClass:[RCTViewComponentView class]] &&
+      ((RCTViewComponentView *)childComponentView).contentView) {
+    [_view insertReactSubview:(id<RCTComponent>)((RCTViewComponentView *)childComponentView)
+                                  .contentView
+                      atIndex:index];
+  }
+  [super mountChildComponentView:childComponentView index:index];
+}
+
+- (void)unmountChildComponentView:(UIView<RCTComponentViewProtocol> *)childComponentView
+                            index:(NSInteger)index {
+  if ([childComponentView isKindOfClass:[RCTViewComponentView class]] &&
+      ((RCTViewComponentView *)childComponentView).contentView) {
+    [_view removeReactSubview:(id<RCTComponent>)((RCTViewComponentView *)childComponentView)
+                                  .contentView];
+  }
+  [super unmountChildComponentView:childComponentView index:index];
+}
+
+Class<RCTComponentViewProtocol> MLRNGeoJSONSourceCls(void) {
+  return MLRNGeoJSONSourceComponentView.class;
+}
+
+@end

package/ios/components/sources/geojson-source/MLRNGeoJSONSourceModule.h

@@ -0,0 +1,4 @@
+#import <MapVinaReactNativeSpec/MapVinaReactNativeSpec.h>
+
+@interface MLRNGeoJSONSourceModule : NSObject <NativeGeoJSONSourceModuleSpec>
+@end

package/ios/components/sources/geojson-source/MLRNGeoJSONSourceModule.mm

@@ -0,0 +1,136 @@
+#import "MLRNGeoJSONSourceModule.h"
+
+#import <React/RCTUIManager.h>
+#import "FilterParser.h"
+#import "MLRNGeoJSONSource.h"
+#import "MLRNGeoJSONSourceComponentView.h"
+#import "MLRNUtils.h"
+#import "MLRNViewModuleUtils.h"
+
+@implementation MLRNGeoJSONSourceModule
+
+@synthesize viewRegistry_DEPRECATED = _viewRegistry_DEPRECATED;
+
++ (NSString *)moduleName {
+  return @"MLRNGeoJSONSourceModule";
+}
+
+- (std::shared_ptr<facebook::react::TurboModule>)getTurboModule:
+    (const facebook::react::ObjCTurboModule::InitParams &)params {
+  return std::make_shared<facebook::react::NativeGeoJSONSourceModuleSpecJSI>(params);
+}
+
+- (void)withShapeSource:(NSInteger)reactTag
+                  block:(void (^)(MLRNGeoJSONSource *))block
+                 reject:(RCTPromiseRejectBlock)reject
+             methodName:(NSString *)methodName {
+  [MLRNViewModuleUtils withView:self.viewRegistry_DEPRECATED
+                       reactTag:reactTag
+             componentViewClass:[MLRNGeoJSONSourceComponentView class]
+               contentViewClass:[MLRNGeoJSONSource class]
+                          block:^(UIView *view) {
+                            block((MLRNGeoJSONSource *)view);
+                          }
+                         reject:reject
+                     methodName:methodName];
+}
+
+- (MLNPointFeatureCluster *)clusterFromClusterId:(NSInteger)clusterId {
+  NSString *featureJSON =
+      [NSString stringWithFormat:@"{\"type\":\"Feature\",\"properties\":{\"cluster_id\":%ld},"
+                                 @"\"geometry\":{\"type\":\"Point\",\"coordinates\":[0,0]}}",
+                                 (long)clusterId];
+  MLNPointFeature *feature = (MLNPointFeature *)[MLRNUtils shapeFromGeoJSON:featureJSON];
+  return (MLNPointFeatureCluster *)feature;
+}
+
+- (void)getData:(NSInteger)reactTag
+         filter:(NSArray *)filter
+        resolve:(nonnull RCTPromiseResolveBlock)resolve
+         reject:(nonnull RCTPromiseRejectBlock)reject {
+  [self withShapeSource:reactTag
+                  block:^(MLRNGeoJSONSource *shapeSource) {
+                    NSPredicate *predicate = [FilterParser parse:filter];
+                    NSArray<id<MLNFeature>> *shapes =
+                        [shapeSource featuresMatchingPredicate:predicate];
+
+                    NSMutableArray<NSDictionary *> *features =
+                        [[NSMutableArray alloc] initWithCapacity:shapes.count];
+                    for (int i = 0; i < shapes.count; i++) {
+                      [features addObject:shapes[i].geoJSONDictionary];
+                    }
+
+                    resolve(@{@"type" : @"FeatureCollection", @"features" : features});
+                  }
+                 reject:reject
+             methodName:@"getData"];
+}
+
+- (void)getClusterExpansionZoom:(NSInteger)reactTag
+                      clusterId:(NSInteger)clusterId
+                        resolve:(nonnull RCTPromiseResolveBlock)resolve
+                         reject:(nonnull RCTPromiseRejectBlock)reject {
+  [self withShapeSource:reactTag
+                  block:^(MLRNGeoJSONSource *shapeSource) {
+                    MLNPointFeatureCluster *cluster = [self clusterFromClusterId:clusterId];
+                    double zoom = [shapeSource getClusterExpansionZoom:cluster];
+                    if (zoom == -1) {
+                      reject(@"zoom_error",
+                             [NSString stringWithFormat:@"Could not get zoom for cluster %ld",
+                                                        (long)clusterId],
+                             nil);
+                      return;
+                    }
+                    resolve(@(zoom));
+                  }
+                 reject:reject
+             methodName:@"getClusterExpansionZoom"];
+}
+
+- (void)getClusterLeaves:(NSInteger)reactTag
+               clusterId:(NSInteger)clusterId
+                   limit:(NSInteger)limit
+                  offset:(NSInteger)offset
+                 resolve:(nonnull RCTPromiseResolveBlock)resolve
+                  reject:(nonnull RCTPromiseRejectBlock)reject {
+  [self withShapeSource:reactTag
+                  block:^(MLRNGeoJSONSource *shapeSource) {
+                    MLNPointFeatureCluster *cluster = [self clusterFromClusterId:clusterId];
+                    NSArray<id<MLNFeature>> *shapes = [shapeSource getClusterLeaves:cluster
+                                                                             number:limit
+                                                                             offset:offset];
+
+                    NSMutableArray<NSDictionary *> *features =
+                        [[NSMutableArray alloc] initWithCapacity:shapes.count];
+                    for (int i = 0; i < shapes.count; i++) {
+                      [features addObject:shapes[i].geoJSONDictionary];
+                    }
+
+                    resolve(features);
+                  }
+                 reject:reject
+             methodName:@"getClusterLeaves"];
+}
+
+- (void)getClusterChildren:(NSInteger)reactTag
+                 clusterId:(NSInteger)clusterId
+                   resolve:(nonnull RCTPromiseResolveBlock)resolve
+                    reject:(nonnull RCTPromiseRejectBlock)reject {
+  [self withShapeSource:reactTag
+                  block:^(MLRNGeoJSONSource *shapeSource) {
+                    MLNPointFeatureCluster *cluster = [self clusterFromClusterId:clusterId];
+                    NSArray<id<MLNFeature>> *shapes = [shapeSource getClusterChildren:cluster];
+
+                    NSMutableArray<NSDictionary *> *features =
+                        [[NSMutableArray alloc] initWithCapacity:shapes.count];
+                    for (int i = 0; i < shapes.count; i++) {
+                      [features addObject:shapes[i].geoJSONDictionary];
+                    }
+
+                    resolve(features);
+                  }
+                 reject:reject
+             methodName:@"getClusterChildren"];
+}
+
+@end

package/ios/components/sources/image-source/MLRNImageSource.h

@@ -0,0 +1,8 @@
+#import "MLRNSource.h"
+
+@interface MLRNImageSource : MLRNSource
+
+@property (nonatomic, copy) NSString *url;
+@property (nonatomic, copy) NSArray<NSArray<NSNumber *> *> *coordinates;
+
+@end

package/ios/components/sources/image-source/MLRNImageSource.m

@@ -0,0 +1,41 @@
+#import "MLRNImageSource.h"
+@import MapVina;
+
+@implementation MLRNImageSource
+
+- (void)setUrl:(NSString *)url {
+  _url = url;
+
+  if (self.source != nil) {
+    MLNImageSource *source = (MLNImageSource *)self.source;
+    source.URL = [NSURL URLWithString:_url];
+  }
+}
+
+- (void)setCoordinates:(NSArray<NSArray<NSNumber *> *> *)coordinates {
+  _coordinates = coordinates;
+  if (self.source != nil) {
+    MLNImageSource *source = (MLNImageSource *)self.source;
+    source.coordinates = [self _makeCoordQuad];
+  }
+}
+
+- (nullable MLNSource *)makeSource {
+  return [[MLNImageSource alloc] initWithIdentifier:self.id
+                                     coordinateQuad:[self _makeCoordQuad]
+                                                URL:[NSURL URLWithString:_url]];
+}
+
+- (MLNCoordinateQuad)_makeCoordQuad {
+  CLLocationCoordinate2D topLeft = CLLocationCoordinate2DMake([self.coordinates[0][1] floatValue],
+                                                              [self.coordinates[0][0] floatValue]);
+  CLLocationCoordinate2D topRight = CLLocationCoordinate2DMake([self.coordinates[1][1] floatValue],
+                                                               [self.coordinates[1][0] floatValue]);
+  CLLocationCoordinate2D bottomRight = CLLocationCoordinate2DMake(
+      [self.coordinates[2][1] floatValue], [self.coordinates[2][0] floatValue]);
+  CLLocationCoordinate2D bottomLeft = CLLocationCoordinate2DMake(
+      [self.coordinates[3][1] floatValue], [self.coordinates[3][0] floatValue]);
+  return MLNCoordinateQuadMake(topLeft, bottomLeft, bottomRight, topRight);
+}
+
+@end

package/ios/components/sources/image-source/MLRNImageSourceComponentView.h

@@ -0,0 +1,9 @@
+#import <React/RCTViewComponentView.h>
+
+@class MLRNImageSource;
+
+@interface MLRNImageSourceComponentView : RCTViewComponentView
+
+@property (nonatomic, readonly) MLRNImageSource *imageSource;
+
+@end

package/ios/components/sources/image-source/MLRNImageSourceComponentView.mm

@@ -0,0 +1,95 @@
+#import "MLRNImageSourceComponentView.h"
+
+#import <react/renderer/components/MapVinaReactNativeSpec/ComponentDescriptors.h>
+#import <react/renderer/components/MapVinaReactNativeSpec/EventEmitters.h>
+#import <react/renderer/components/MapVinaReactNativeSpec/Props.h>
+#import <react/renderer/components/MapVinaReactNativeSpec/RCTComponentViewHelpers.h>
+
+#import "RCTFabricComponentsPlugins.h"
+
+#import <React/RCTConversions.h>
+#import "MLRNFollyConvert.h"
+#import "MLRNImageSource.h"
+
+using namespace facebook::react;
+
+// MARK: - MLRNImageSourceComponentView
+
+@interface MLRNImageSourceComponentView () <RCTMLRNImageSourceViewProtocol>
+
+@end
+
+@implementation MLRNImageSourceComponentView {
+  MLRNImageSource *_view;
+}
+
+- (instancetype)initWithFrame:(CGRect)frame {
+  if (self = [super initWithFrame:frame]) {
+    static const auto defaultProps = std::make_shared<const MLRNImageSourceProps>();
+    _props = defaultProps;
+    [self prepareView];
+  }
+
+  return self;
+}
+
+- (void)prepareView {
+  _view = [[MLRNImageSource alloc] init];
+  self.contentView = _view;
+}
+
+- (MLRNImageSource *)imageSource {
+  return _view;
+}
+
+#pragma mark - RCTComponentViewProtocol
+
++ (ComponentDescriptorProvider)componentDescriptorProvider {
+  return concreteComponentDescriptorProvider<MLRNImageSourceComponentDescriptor>();
+}
+
+- (void)updateProps:(const Props::Shared &)props oldProps:(const Props::Shared &)oldProps {
+  const auto &oldViewProps = *std::static_pointer_cast<const MLRNImageSourceProps>(_props);
+  const auto &newViewProps = *std::static_pointer_cast<const MLRNImageSourceProps>(props);
+
+  if (oldViewProps.id != newViewProps.id) {
+    _view.id = RCTNSStringFromString(newViewProps.id);
+  }
+
+  if (oldViewProps.url != newViewProps.url) {
+    _view.url = RCTNSStringFromStringNilIfEmpty(newViewProps.url);
+  }
+
+  if (oldViewProps.coordinates != newViewProps.coordinates) {
+    _view.coordinates = convertFollyDynamicToId(newViewProps.coordinates);
+  }
+
+  [super updateProps:props oldProps:oldProps];
+}
+
+- (void)mountChildComponentView:(UIView<RCTComponentViewProtocol> *)childComponentView
+                          index:(NSInteger)index {
+  if ([childComponentView isKindOfClass:[RCTViewComponentView class]] &&
+      ((RCTViewComponentView *)childComponentView).contentView) {
+    [_view insertReactSubview:(id<RCTComponent>)((RCTViewComponentView *)childComponentView)
+                                  .contentView
+                      atIndex:index];
+  }
+  [super mountChildComponentView:childComponentView index:index];
+}
+
+- (void)unmountChildComponentView:(UIView<RCTComponentViewProtocol> *)childComponentView
+                            index:(NSInteger)index {
+  if ([childComponentView isKindOfClass:[RCTViewComponentView class]] &&
+      ((RCTViewComponentView *)childComponentView).contentView) {
+    [_view removeReactSubview:(id<RCTComponent>)((RCTViewComponentView *)childComponentView)
+                                  .contentView];
+  }
+  [super unmountChildComponentView:childComponentView index:index];
+}
+
+Class<RCTComponentViewProtocol> MLRNImageSourceCls(void) {
+  return MLRNImageSourceComponentView.class;
+}
+
+@end

package/ios/components/sources/tile-sources/MLRNTileSource.h

@@ -0,0 +1,18 @@
+#import "MLRNSource.h"
+
+#import <MapVina/MapVina.h>
+
+@interface MLRNTileSource : MLRNSource
+
+@property (nonatomic, copy) NSString *url;
+@property (nonatomic, strong) NSArray<NSString *> *tileUrlTemplates;
+@property (nonatomic, copy) NSString *attribution;
+
+@property (nonatomic, strong) NSNumber *minZoomLevel;
+@property (nonatomic, strong) NSNumber *maxZoomLevel;
+
+@property (nonatomic, strong) NSNumber *scheme;
+
+- (NSDictionary<MLNTileSourceOption, id> *)getOptions;
+
+@end

package/ios/components/sources/tile-sources/MLRNTileSource.m

@@ -0,0 +1,26 @@
+#import "MLRNTileSource.h"
+
+@implementation MLRNTileSource
+
+- (NSDictionary<MLNTileSourceOption, id> *)getOptions {
+  NSMutableDictionary<MLNTileSourceOption, id> *options = [[NSMutableDictionary alloc] init];
+
+  if (self.maxZoomLevel != nil) {
+    options[MLNTileSourceOptionMaximumZoomLevel] = self.maxZoomLevel;
+  }
+
+  if (self.minZoomLevel != nil) {
+    options[MLNTileSourceOptionMinimumZoomLevel] = self.minZoomLevel;
+  }
+
+  if (self.scheme != nil) {
+    options[MLNTileSourceOptionTileCoordinateSystem] = self.scheme;
+  }
+
+  if (self.attribution != nil) {
+    options[MLNTileSourceOptionAttributionHTMLString] = self.attribution;
+  }
+
+  return options;
+}
+@end

package/ios/components/sources/tile-sources/raster-dem-source/MLRNRasterDEMSource.h

@@ -0,0 +1,10 @@
+#import "MLRNTileSource.h"
+
+#import <MapVina/MapVina.h>
+
+@interface MLRNRasterDEMSource : MLRNTileSource
+
+@property (nonatomic, strong) NSNumber *tileSize;
+@property (nonatomic, copy) NSString *encoding;
+
+@end

package/ios/components/sources/tile-sources/raster-dem-source/MLRNRasterDEMSource.m

@@ -0,0 +1,39 @@
+#import "MLRNRasterDEMSource.h"
+
+@implementation MLRNRasterDEMSource
+
+- (nullable MLNSource *)makeSource {
+  if (self.url != nil) {
+    NSURL *url = [NSURL URLWithString:self.url];
+    if (self.tileSize != nil) {
+      return [[MLNRasterDEMSource alloc] initWithIdentifier:self.id
+                                           configurationURL:url
+                                                   tileSize:[self.tileSize floatValue]];
+    }
+    return [[MLNRasterDEMSource alloc] initWithIdentifier:self.id configurationURL:url];
+  }
+  return [[MLNRasterDEMSource alloc] initWithIdentifier:self.id
+                                       tileURLTemplates:self.tileUrlTemplates
+                                                options:[self getOptions]];
+}
+
+- (NSDictionary<MLNTileSourceOption, id> *)getOptions {
+  NSMutableDictionary<MLNTileSourceOption, id> *options =
+      [[NSMutableDictionary alloc] initWithDictionary:[super getOptions]];
+
+  if (self.tileSize != nil) {
+    options[MLNTileSourceOptionTileSize] = _tileSize;
+  }
+
+  if (self.encoding != nil) {
+    MLNDEMEncoding demEncoding = MLNDEMEncodingMapbox;
+    if ([self.encoding isEqualToString:@"terrarium"]) {
+      demEncoding = MLNDEMEncodingTerrarium;
+    }
+    options[MLNTileSourceOptionDEMEncoding] = @(demEncoding);
+  }
+
+  return options;
+}
+
+@end

package/ios/components/sources/tile-sources/raster-dem-source/MLRNRasterDEMSourceComponentView.h

@@ -0,0 +1,9 @@
+#import <React/RCTViewComponentView.h>
+
+@class MLRNRasterDEMSource;
+
+@interface MLRNRasterDEMSourceComponentView : RCTViewComponentView
+
+@property (nonatomic, readonly) MLRNRasterDEMSource *rasterDEMSource;
+
+@end