@heyitsiveen/dotfiles 1.0.1 → 1.0.3

package/dotfiles/macos/.config/fish/functions/_tide_item_vi_mode.fish

@@ -0,0 +1,16 @@
+function _tide_item_vi_mode
+    test "$fish_key_bindings" != fish_default_key_bindings && switch $fish_bind_mode
+        case default
+            tide_vi_mode_bg_color=$tide_vi_mode_bg_color_default tide_vi_mode_color=$tide_vi_mode_color_default \
+                _tide_print_item vi_mode $tide_vi_mode_icon_default
+        case insert
+            tide_vi_mode_bg_color=$tide_vi_mode_bg_color_insert tide_vi_mode_color=$tide_vi_mode_color_insert \
+                _tide_print_item vi_mode $tide_vi_mode_icon_insert
+        case replace replace_one
+            tide_vi_mode_bg_color=$tide_vi_mode_bg_color_replace tide_vi_mode_color=$tide_vi_mode_color_replace \
+                _tide_print_item vi_mode $tide_vi_mode_icon_replace
+        case visual
+            tide_vi_mode_bg_color=$tide_vi_mode_bg_color_visual tide_vi_mode_color=$tide_vi_mode_color_visual \
+                _tide_print_item vi_mode $tide_vi_mode_icon_visual
+    end
+end

package/dotfiles/macos/.config/fish/functions/_tide_item_zig.fish

@@ -0,0 +1,6 @@
+function _tide_item_zig
+    if path is $_tide_parent_dirs/build.zig
+        zig version | string match -qr "(?<v>[\d.]+(-dev)?)"
+        _tide_print_item zig $tide_zig_icon' ' $v
+    end
+end

package/dotfiles/macos/.config/fish/functions/_tide_parent_dirs.fish

@@ -0,0 +1,10 @@
+function _tide_parent_dirs --on-variable PWD
+    set -g _tide_parent_dirs (
+        string escape (
+            for dir in (string split / -- $PWD)
+                set -fa parts $dir
+                string join / -- $parts
+            end
+        )
+    )
+end

package/dotfiles/macos/.config/fish/functions/_tide_print_item.fish

@@ -0,0 +1,22 @@
+function _tide_print_item -a item
+    v=tide_"$item"_bg_color set -f item_bg_color $$v
+
+    if set -e add_prefix
+        set_color $item_bg_color -b normal
+        v=tide_"$_tide_side"_prompt_prefix echo -ns $$v
+    else if test "$item_bg_color" = "$prev_bg_color"
+        v=tide_"$_tide_side"_prompt_separator_same_color echo -ns $_tide_color_separator_same_color$$v
+    else if test $_tide_side = left
+        set_color $prev_bg_color -b $item_bg_color
+        echo -ns $tide_left_prompt_separator_diff_color
+    else
+        set_color $item_bg_color -b $prev_bg_color
+        echo -ns $tide_right_prompt_separator_diff_color
+    end
+
+    v=tide_"$item"_color set_color $$v -b $item_bg_color
+
+    echo -ns $_tide_pad $argv[2..] $_tide_pad
+
+    set -g prev_bg_color $item_bg_color
+end

package/dotfiles/macos/.config/fish/functions/_tide_pwd.fish

@@ -0,0 +1,42 @@
+set_color -o $tide_pwd_color_anchors | read -l color_anchors
+set_color $tide_pwd_color_truncated_dirs | read -l color_truncated
+set -l reset_to_color_dirs (set_color normal -b $tide_pwd_bg_color; set_color $tide_pwd_color_dirs)
+
+set -l unwritable_icon $tide_pwd_icon_unwritable' '
+set -l home_icon $tide_pwd_icon_home' '
+set -l pwd_icon $tide_pwd_icon' '
+
+eval "function _tide_pwd
+    if set -l split_pwd (string replace -r '^$HOME' '~' -- \$PWD | string split /)
+        test -w . && set -f split_output \"$pwd_icon\$split_pwd[1]\" \$split_pwd[2..] ||
+            set -f split_output \"$unwritable_icon\$split_pwd[1]\" \$split_pwd[2..]
+        set split_output[-1] \"$color_anchors\$split_output[-1]$reset_to_color_dirs\"
+    else
+        set -f split_output \"$home_icon$color_anchors~\"
+    end
+
+    string join / -- \$split_output | string length -V | read -g _tide_pwd_len
+
+    i=1 for dir_section in \$split_pwd[2..-2]
+        string join -- / \$split_pwd[..\$i] | string replace '~' $HOME | read -l parent_dir # Uses i before increment
+
+        math \$i+1 | read i
+
+        if path is \$parent_dir/\$dir_section/\$tide_pwd_markers
+            set split_output[\$i] \"$color_anchors\$dir_section$reset_to_color_dirs\"
+        else if test \$_tide_pwd_len -gt \$dist_btwn_sides
+            string match -qr \"(?<trunc>\..|.)\" \$dir_section
+
+            set -l glob \$parent_dir/\$trunc*/
+            set -e glob[(contains -i \$parent_dir/\$dir_section/ \$glob)] # This is faster than inverse string match
+
+            while string match -qr \"^\$parent_dir/\$(string escape --style=regex \$trunc)\" \$glob &&
+                    string match -qr \"(?<trunc>\$(string escape --style=regex \$trunc).)\" \$dir_section
+            end
+            test -n \"\$trunc\" && set split_output[\$i] \"$color_truncated\$trunc$reset_to_color_dirs\" &&
+                string join / \$split_output | string length -V | read _tide_pwd_len
+        end
+    end
+
+    string join -- / \"$reset_to_color_dirs\$split_output[1]\" \$split_output[2..]
+end"

package/dotfiles/macos/.config/fish/functions/_tide_remove_unusable_items.fish

@@ -0,0 +1,25 @@
+function _tide_remove_unusable_items
+    # Remove tool-specific items for tools the machine doesn't have installed
+    set -l removed_items
+    for item in aws bun crystal direnv distrobox docker elixir gcloud git go java kubectl nix_shell node php pulumi python ruby rustc terraform toolbox zig
+        contains $item $tide_left_prompt_items $tide_right_prompt_items || continue
+
+        set -l cli_names $item
+        switch $item
+            case distrobox # there is no 'distrobox' command inside the container
+                set cli_names distrobox-export # 'distrobox-export' and 'distrobox-host-exec' are available
+            case nix_shell
+                set cli_names nix nix-shell
+            case python
+                set cli_names python python3
+        end
+        type --query $cli_names || set -a removed_items $item
+    end
+
+    set -U _tide_left_items (for item in $tide_left_prompt_items
+        contains $item $removed_items || echo $item
+    end)
+    set -U _tide_right_items (for item in $tide_right_prompt_items
+        contains $item $removed_items || echo $item
+    end)
+end

package/dotfiles/macos/.config/fish/functions/_tide_sub_bug-report.fish

@@ -0,0 +1,73 @@
+function _tide_sub_bug-report
+    argparse c/clean v/verbose check -- $argv
+
+    set -l fish_path (status fish-path)
+
+    if set -q _flag_clean
+        HOME=(mktemp -d) $fish_path --init-command "curl --silent \
+        https://raw.githubusercontent.com/jorgebucaran/fisher/main/functions/fisher.fish |
+        source && fisher install ilancosman/tide@v6"
+    else if set -q _flag_verbose
+        set --long | string match -r "^_?tide.*" | # Get only tide variables
+            string match -r --invert "^_tide_prompt_var.*" # Remove _tide_prompt_var
+    else
+        $fish_path --version | string match -qr "fish, version (?<fish_version>.*)"
+        _tide_check_version Fish fish-shell/fish-shell "(?<v>[\d.]+)" $fish_version || return
+
+        tide --version | string match -qr "tide, version (?<tide_version>.*)"
+        _tide_check_version Tide IlanCosman/tide "v(?<v>[\d.]+)" $tide_version || return
+
+        if command --query git
+            test (path sort (git --version) "git version 2.22.0")[1] = "git version 2.22.0"
+            _tide_check_condition \
+                "Your git version is too old." \
+                "Tide requires at least version 2.22." \
+                "Please update before submitting a bug report." || return
+        end
+
+        # Check that omf is not installed
+        not functions --query omf
+        _tide_check_condition \
+            "Tide does not work with oh-my-fish installed." \
+            "Please uninstall it before submitting a bug report." || return
+
+        if not set -q _flag_check
+            $fish_path -ic "time $fish_path -c exit" 2>|
+                string match -rg "Executed in(.*)fish" |
+                string trim | read -l fish_startup_time
+
+            read -l --prompt-str "What operating system are you using? (e.g Ubuntu 20.04): " os
+            read -l --prompt-str "What terminal emulator are you using? (e.g Kitty): " terminal_emulator
+
+            printf '%b\n' "\nPlease copy the following information into the issue:\n" \
+                "fish version: $fish_version" \
+                "tide version: $tide_version" \
+                "term: $TERM" \
+                "os: $os" \
+                "terminal emulator: $terminal_emulator" \
+                "fish startup: $fish_startup_time" \
+                "fisher plugins: $_fisher_plugins"
+        end
+    end
+end
+
+function _tide_check_version -a program_name repo_name regex_to_get_v installed_version
+    curl -sL https://github.com/$repo_name/releases/latest |
+        string match -qr "https://github.com/$repo_name/releases/tag/$regex_to_get_v"
+
+    string match -qr "^$v" "$installed_version" # Allow git versions, e.g 3.3.1-701-gceade1629
+    _tide_check_condition \
+        "Your $program_name version is out of date." \
+        "The latest is $v. You have $installed_version." \
+        "Please update before submitting a bug report."
+end
+
+function _tide_check_condition
+    if test "$status" != 0
+        set_color red
+        printf '%s\n' $argv
+        set_color normal
+        return 1
+    end
+    return 0
+end

package/dotfiles/macos/.config/fish/functions/_tide_sub_configure.fish

@@ -0,0 +1,156 @@
+set -g _tide_color_dark_blue 0087AF
+set -g _tide_color_dark_green 5FAF00
+set -g _tide_color_gold D7AF00
+set -g _tide_color_green 5FD700
+set -g _tide_color_light_blue 00AFFF
+
+# Create an empty fake function for each item
+for func in _fake(functions --all | string match --entire _tide_item)
+    function $func
+    end
+end
+
+for file in (status dirname)/tide/configure/{choices, functions}/**.fish
+    source $file
+end
+
+function _tide_sub_configure
+    set -l choices (path basename (status dirname)/tide/configure/choices/**.fish | path change-extension '')
+    argparse auto $choices= -- $argv
+
+    for var in (set -l --names | string match -e _flag)
+        set -x $var $$var
+    end
+
+    if set -q _flag_auto
+        set -fx _flag_finish 'Overwrite your current tide config'
+    else if test $COLUMNS -lt 55 -o $LINES -lt 21
+        echo 'Terminal size too small; must be at least 55 x 21'
+        return 1
+    end
+
+    _tide_detect_os | read -g --line os_branding_icon os_branding_color os_branding_bg_color
+
+    set -g fake_columns $COLUMNS
+    test $fake_columns -gt 90 && set fake_columns 90
+    set -g fake_lines $LINES
+
+    set -g _tide_selected_option
+    _next_choice all/style
+end
+
+function _next_choice -a nextChoice
+    set -q _tide_selected_option || return 0
+    set -l cmd (string split '/' $nextChoice)[2]
+    $cmd
+end
+
+function _tide_title -a text
+    set -q _flag_auto && return
+
+    command -q clear && clear
+    set_color -o
+    string pad --width (math --scale=0 "$fake_columns/2" + (string length $text)/2) $text
+    set_color normal
+
+    set -g _tide_configure_first_option_after_title
+end
+
+function _tide_option -a symbol text
+    set -ga _tide_symbol_list $symbol
+    set -ga _tide_option_list $text
+
+    if not set -q _flag_auto
+        set -g _tide_configure_first_prompt_after_option
+
+        set_color -o
+        set -e _tide_configure_first_option_after_title || echo
+        echo "($symbol) $text"
+        set_color normal
+    end
+end
+
+function _tide_menu -a func
+    if set -q _flag_auto
+        set -l flag_var_name _flag_$func
+        set -g _tide_selected_option $$flag_var_name
+
+        if test -z "$_tide_selected_option"
+            echo "Missing input for choice '$func'"
+            _tide_exit_configure
+        else if not contains $_tide_selected_option $_tide_option_list
+            echo "Invalid input '$_tide_selected_option' for choice '$func'"
+            _tide_exit_configure
+        else
+            set -e _tide_symbol_list
+            set -e _tide_option_list
+        end
+        return
+    end
+
+    argparse no-restart -- $argv # Add no-restart option for first menu
+
+    echo
+    if not set -q _flag_no_restart
+        set -f r r
+        echo '(r) Restart from the beginning'
+    end
+    echo '(q) Quit and do nothing'\n
+
+    while read --nchars 1 --prompt-str \
+            "$(set_color -o)Choice [$(string join '/' $_tide_symbol_list $r q)] $(set_color normal)" input
+        switch $input
+            case r
+                set -q _flag_no_restart && continue
+                set -e _tide_symbol_list
+                set -e _tide_option_list
+                _next_choice all/style
+                break
+            case q
+                _tide_exit_configure
+                set -e _tide_symbol_list
+                set -e _tide_option_list
+                command -q clear && clear
+                break
+            case $_tide_symbol_list
+                set -g _tide_selected_option $_tide_option_list[(contains -i $input $_tide_symbol_list)]
+                test "$func" != finish &&
+                    set -a _tide_configure_current_options --$func=(string escape $_tide_selected_option)
+                set -e _tide_symbol_list
+                set -e _tide_option_list
+                break
+        end
+    end
+end
+
+function _tide_display_prompt
+    set -q _flag_auto && return
+
+    _fake_tide_cache_variables
+    set -l prompt (_fake_tide_prompt)
+
+    set -l bottom_left_prompt_string_length (string length --visible $prompt[-1])
+    set -l right_prompt_string (string pad --width (math $fake_columns-$bottom_left_prompt_string_length) $prompt[1])
+    set -l prompt[-1] "$prompt[-1]$right_prompt_string"
+
+    if set -q _configure_transient
+        if contains newline $fake_tide_left_prompt_items
+            string unescape $prompt[3..]
+        else
+            _fake_tide_item_character
+            echo
+        end
+    else
+        if not set -q _tide_configure_first_prompt_after_option
+            test "$fake_tide_prompt_add_newline_before" = true && echo
+        end
+        string unescape $prompt[2..]
+    end
+
+    set -e _tide_configure_first_prompt_after_option
+    set_color normal
+end
+
+function _tide_exit_configure
+    set -e _tide_selected_option # Skip through all switch and _next_choice
+end

package/dotfiles/macos/.config/fish/functions/_tide_sub_reload.fish

@@ -0,0 +1,3 @@
+function _tide_sub_reload
+    source (functions --details fish_prompt)
+end

package/dotfiles/macos/.config/fish/functions/fish_greeting.fish

@@ -1,5 +1,2 @@
-function fish_greeting -d "Custom greeting with fastfetch"
-    if type -q fastfetch
-        fastfetch
-    end
+function fish_greeting -d "Disable default greeting"
 end

package/dotfiles/macos/.config/fish/functions/fish_mode_prompt.fish

@@ -0,0 +1 @@
+# Disable default vi prompt

package/dotfiles/macos/.config/fish/functions/fish_prompt.fish

@@ -0,0 +1,170 @@
+function fish_prompt
+end # In case this file gets loaded non-interactively, e.g by conda
+status is-interactive || exit
+
+_tide_remove_unusable_items
+_tide_cache_variables
+_tide_parent_dirs
+source (functions --details _tide_pwd)
+
+set -l prompt_var _tide_prompt_$fish_pid
+set -U $prompt_var # Set var here so if we erase $prompt_var, bg job won't set a uvar
+
+set_color normal | read -l color_normal
+status fish-path | read -l fish_path
+
+# _tide_repaint prevents us from creating a second background job
+function _tide_refresh_prompt --on-variable $prompt_var --on-variable COLUMNS
+    set -g _tide_repaint
+    commandline -f repaint
+end
+
+if contains newline $_tide_left_items # two line prompt initialization
+    test "$tide_prompt_add_newline_before" = true && set -l add_newline '\n'
+
+    set_color $tide_prompt_color_frame_and_connection -b normal | read -l prompt_and_frame_color
+
+    set -l column_offset 5
+    test "$tide_left_prompt_frame_enabled" = true &&
+        set -l top_left_frame "$prompt_and_frame_color╭─" &&
+        set -l bot_left_frame "$prompt_and_frame_color╰─" &&
+        set column_offset 3
+    test "$tide_right_prompt_frame_enabled" = true &&
+        set -l top_right_frame "$prompt_and_frame_color─╮" &&
+        set -l bot_right_frame "$prompt_and_frame_color─╯" &&
+        set column_offset (math $column_offset-2)
+
+    if test "$tide_prompt_transient_enabled" = true
+        eval "
+function fish_prompt
+    _tide_status=\$status _tide_pipestatus=\$pipestatus if not set -e _tide_repaint
+        jobs -q && jobs -p | count | read -lx _tide_jobs
+        $fish_path -c \"set _tide_pipestatus \$_tide_pipestatus
+set _tide_parent_dirs \$_tide_parent_dirs
+PATH=\$(string escape \"\$PATH\") CMD_DURATION=\$CMD_DURATION fish_bind_mode=\$fish_bind_mode set $prompt_var (_tide_2_line_prompt)\" &
+        builtin disown
+
+        command kill \$_tide_last_pid 2>/dev/null
+        set -g _tide_last_pid \$last_pid
+    end
+
+    if not set -q _tide_transient
+        math \$COLUMNS-(string length -V \"\$$prompt_var[1][1]\$$prompt_var[1][3]\")+$column_offset | read -lx dist_btwn_sides
+
+        echo -n $add_newline'$top_left_frame'(string replace @PWD@ (_tide_pwd) \"\$$prompt_var[1][1]\")'$prompt_and_frame_color'
+        string repeat -Nm(math max 0, \$dist_btwn_sides-\$_tide_pwd_len) '$tide_prompt_icon_connection'
+
+        echo \"\$$prompt_var[1][3]$top_right_frame\"
+    end
+    echo -n \e\[0J\"$bot_left_frame\$$prompt_var[1][2]$color_normal \"
+end
+
+function fish_right_prompt
+    set -e _tide_transient || string unescape \"\$$prompt_var[1][4]$bot_right_frame$color_normal\"
+end"
+    else
+        eval "
+function fish_prompt
+    _tide_status=\$status _tide_pipestatus=\$pipestatus if not set -e _tide_repaint
+        jobs -q && jobs -p | count | read -lx _tide_jobs
+        $fish_path -c \"set _tide_pipestatus \$_tide_pipestatus
+set _tide_parent_dirs \$_tide_parent_dirs
+PATH=\$(string escape \"\$PATH\") CMD_DURATION=\$CMD_DURATION fish_bind_mode=\$fish_bind_mode set $prompt_var (_tide_2_line_prompt)\" &
+        builtin disown
+
+        command kill \$_tide_last_pid 2>/dev/null
+        set -g _tide_last_pid \$last_pid
+    end
+
+    math \$COLUMNS-(string length -V \"\$$prompt_var[1][1]\$$prompt_var[1][3]\")+$column_offset | read -lx dist_btwn_sides
+
+    echo -ns $add_newline'$top_left_frame'(string replace @PWD@ (_tide_pwd) \"\$$prompt_var[1][1]\")'$prompt_and_frame_color'
+    string repeat -Nm(math max 0, \$dist_btwn_sides-\$_tide_pwd_len) '$tide_prompt_icon_connection'
+    echo -ns \"\$$prompt_var[1][3]$top_right_frame\"\n\"$bot_left_frame\$$prompt_var[1][2]$color_normal \"
+end
+
+function fish_right_prompt
+    string unescape \"\$$prompt_var[1][4]$bot_right_frame$color_normal\"
+end"
+    end
+else # one line prompt initialization
+    test "$tide_prompt_add_newline_before" = true && set -l add_newline '\0'
+
+    math 5 -$tide_prompt_min_cols | read -l column_offset
+    test $column_offset -ge 0 && set column_offset "+$column_offset"
+
+    if test "$tide_prompt_transient_enabled" = true
+        eval "
+function fish_prompt
+    set -lx _tide_status \$status
+    _tide_pipestatus=\$pipestatus if not set -e _tide_repaint
+        jobs -q && jobs -p | count | read -lx _tide_jobs
+        $fish_path -c \"set _tide_pipestatus \$_tide_pipestatus
+set _tide_parent_dirs \$_tide_parent_dirs
+PATH=\$(string escape \"\$PATH\") CMD_DURATION=\$CMD_DURATION fish_bind_mode=\$fish_bind_mode set $prompt_var (_tide_1_line_prompt)\" &
+        builtin disown
+
+        command kill \$_tide_last_pid 2>/dev/null
+        set -g _tide_last_pid \$last_pid
+    end
+
+    if set -q _tide_transient
+        echo -n \e\[0J
+        add_prefix= _tide_item_character
+        echo -n '$color_normal '
+    else
+        math \$COLUMNS-(string length -V \"\$$prompt_var[1][1]\$$prompt_var[1][2]\")$column_offset | read -lx dist_btwn_sides
+        string replace @PWD@ (_tide_pwd) $add_newline \$$prompt_var[1][1]'$color_normal '
+    end
+end
+
+function fish_right_prompt
+    set -e _tide_transient || string unescape \"\$$prompt_var[1][2]$color_normal\"
+end"
+    else
+        eval "
+function fish_prompt
+    _tide_status=\$status _tide_pipestatus=\$pipestatus if not set -e _tide_repaint
+        jobs -q && jobs -p | count | read -lx _tide_jobs
+        $fish_path -c \"set _tide_pipestatus \$_tide_pipestatus
+set _tide_parent_dirs \$_tide_parent_dirs
+PATH=\$(string escape \"\$PATH\") CMD_DURATION=\$CMD_DURATION fish_bind_mode=\$fish_bind_mode set $prompt_var (_tide_1_line_prompt)\" &
+        builtin disown
+
+        command kill \$_tide_last_pid 2>/dev/null
+        set -g _tide_last_pid \$last_pid
+    end
+
+    math \$COLUMNS-(string length -V \"\$$prompt_var[1][1]\$$prompt_var[1][2]\")$column_offset | read -lx dist_btwn_sides
+    string replace @PWD@ (_tide_pwd) $add_newline \$$prompt_var[1][1]'$color_normal '
+end
+
+function fish_right_prompt
+    string unescape \"\$$prompt_var[1][2]$color_normal\"
+end"
+    end
+end
+
+# Inheriting instead of evaling because here load time is more important than runtime
+function _tide_on_fish_exit --on-event fish_exit --inherit-variable prompt_var
+    set -e $prompt_var
+end
+
+if test "$tide_prompt_transient_enabled" = true
+    function _tide_enter_transient
+        # If the commandline will be executed or is empty, and the pager is not open
+        # Pager open usually means selecting, not running
+        # Can be untrue, but it's better than the alternative
+        if commandline --is-valid || test -z "$(commandline)" && not commandline --paging-mode
+            set -g _tide_transient
+            set -g _tide_repaint
+            commandline -f repaint
+        end
+        commandline -f execute
+    end
+
+    bind \r _tide_enter_transient
+    bind \n _tide_enter_transient
+    bind -M insert \r _tide_enter_transient
+    bind -M insert \n _tide_enter_transient
+end