@heyitsiveen/dotfiles 1.0.1 → 1.0.3

package/dist/index.mjs

@@ -200,11 +200,14 @@ async function uninstallGroups(groups) {
 	const errors = [];
 	for (const group of groups) {
 		const termDefault = TERMINAL_DEFAULTS[group.name];
-		for (const file of group.files) try {
-			if (await pathExists$2(file)) if (termDefault && file.endsWith(termDefault.file)) await writeFile(file, termDefault.content, "utf-8");
-			else await remove(file);
+		try {
+			if (termDefault) {
+				const configPath = group.files.find((f) => f.endsWith(termDefault.file));
+				if (configPath && await pathExists$2(configPath)) await writeFile(configPath, termDefault.content, "utf-8");
+				for (const file of group.files) if (file !== configPath && await pathExists$2(file)) await remove(file);
+			} else if (await pathExists$2(group.target)) await remove(group.target);
 		} catch (err) {
-			errors.push(`${file}: ${err instanceof Error ? err.message : String(err)}`);
+			errors.push(`${group.name}: ${err instanceof Error ? err.message : String(err)}`);
 		}
 	}
 	return errors;
@@ -255,7 +258,7 @@ function getDependencyTools(platform) {
 		{
 			name: "fastfetch",
 			binary: "fastfetch",
-			description: "System info terminal greeting",
+			description: "System info tool",
 			installCmd: "brew install fastfetch",
 			required: false
 		},
@@ -293,7 +296,7 @@ function getDependencyTools(platform) {
 		{
 			name: "fastfetch",
 			binary: "fastfetch",
-			description: "System info terminal greeting",
+			description: "System info tool",
 			installCmd: "winget install Fastfetch-cli.Fastfetch",
 			required: false
 		},
@@ -647,7 +650,7 @@ async function switchTideTheme(targetDir, theme) {
 	await writeFile(filePath, (await readFile(filePath, "utf-8")).replace(/^(set -l tide_default_palette )\S+$/m, `$1${tidePalettes[theme]}`), "utf-8");
 }
 async function switchOmpTheme(theme) {
-	const themeDir = join(homedir(), ".config", "dotfiles");
+	const themeDir = join(homedir(), MANIFEST_DIR, "oh-my-posh");
 	await ensureDir(themeDir);
 	await writeFile(join(themeDir, "prompt-theme.txt"), theme, "utf-8");
 }

package/dotfiles/macos/.config/fish/completions/fisher.fish

@@ -0,0 +1,7 @@
+complete --command fisher --exclusive --long help --description "Print help"
+complete --command fisher --exclusive --long version --description "Print version"
+complete --command fisher --exclusive --condition __fish_use_subcommand --arguments install --description "Install plugins"
+complete --command fisher --exclusive --condition __fish_use_subcommand --arguments update --description "Update installed plugins"
+complete --command fisher --exclusive --condition __fish_use_subcommand --arguments remove --description "Remove installed plugins"
+complete --command fisher --exclusive --condition __fish_use_subcommand --arguments list --description "List installed plugins matching regex"
+complete --command fisher --exclusive --condition "__fish_seen_subcommand_from update remove" --arguments "(fisher list)"

package/dotfiles/macos/.config/fish/completions/tide.fish

@@ -0,0 +1,13 @@
+complete tide --no-files
+
+set -l subcommands bug-report configure reload
+
+complete tide -x -n __fish_use_subcommand -a bug-report -d "Print info for use in bug reports"
+complete tide -x -n __fish_use_subcommand -a configure -d "Run the configuration wizard"
+complete tide -x -n __fish_use_subcommand -a reload -d "Reload tide configuration"
+
+complete tide -x -n "not __fish_seen_subcommand_from $subcommands" -s h -l help -d "Print help message"
+complete tide -x -n "not __fish_seen_subcommand_from $subcommands" -s v -l version -d "Print tide version"
+
+complete tide -x -n '__fish_seen_subcommand_from bug-report' -l clean -d "Run clean Fish instance and install Tide"
+complete tide -x -n '__fish_seen_subcommand_from bug-report' -l verbose -d "Print full Tide configuration"

package/dotfiles/macos/.config/fish/conf.d/_tide_init.fish

@@ -0,0 +1,44 @@
+function _tide_init_install --on-event _tide_init_install
+    set -U VIRTUAL_ENV_DISABLE_PROMPT true
+
+    source (functions --details _tide_sub_configure)
+    _load_config lean
+    _tide_finish
+
+    if status is-interactive
+        tide bug-report --check || sleep 4
+
+        if contains ilancosman/tide (string lower $_fisher_plugins)
+            set_color bryellow
+            echo "ilancosman/tide is a development branch. Please install from a release tag:"
+            _tide_fish_colorize "fisher install ilancosman/tide@v6"
+            sleep 3
+        end
+
+        switch (read --prompt-str="Configure tide prompt? [Y/n] " | string lower)
+            case y ye yes ''
+                tide configure
+            case '*'
+                echo -s \n 'Run ' (_tide_fish_colorize "tide configure") ' to customize your prompt.'
+        end
+    end
+end
+
+function _tide_init_update --on-event _tide_init_update
+    # Warn users who install from main branch
+    if contains ilancosman/tide (string lower $_fisher_plugins)
+        set_color bryellow
+        echo "ilancosman/tide is a development branch. Please install from a release tag:"
+        _tide_fish_colorize "fisher install ilancosman/tide@v6"
+        sleep 3
+    end
+
+    # Set (disable) the new jobs variable
+    set -q tide_jobs_number_threshold || set -U tide_jobs_number_threshold 1000
+end
+
+function _tide_init_uninstall --on-event _tide_init_uninstall
+    set -e VIRTUAL_ENV_DISABLE_PROMPT
+    set -e (set -U --names | string match --entire -r '^_?tide')
+    functions --erase (functions --all | string match --entire -r '^_?tide')
+end

package/dotfiles/macos/.config/fish/fish_plugins

@@ -0,0 +1,2 @@
+jorgebucaran/fisher
+ilancosman/tide@v6

package/dotfiles/macos/.config/fish/functions/_tide_1_line_prompt.fish

@@ -0,0 +1,19 @@
+function _tide_1_line_prompt
+    set -g add_prefix
+    _tide_side=left for item in $_tide_left_items
+        _tide_item_$item
+    end
+    set_color $prev_bg_color -b normal
+    echo $tide_left_prompt_suffix
+
+    set -g add_prefix
+    _tide_side=right for item in $_tide_right_items
+        _tide_item_$item
+    end
+    set_color $prev_bg_color -b normal
+    echo $tide_right_prompt_suffix
+end
+
+function _tide_item_pwd
+    _tide_print_item pwd @PWD@
+end

package/dotfiles/macos/.config/fish/functions/_tide_2_line_prompt.fish

@@ -0,0 +1,31 @@
+function _tide_2_line_prompt
+    set -g add_prefix
+    _tide_side=left for item in $_tide_left_items
+        _tide_item_$item
+    end
+    if not set -e add_prefix
+        set_color $prev_bg_color -b normal
+        echo $tide_left_prompt_suffix
+    end
+
+    echo
+
+    set -g add_prefix
+    _tide_side=right for item in $_tide_right_items
+        _tide_item_$item
+    end
+    if not set -e add_prefix
+        set_color $prev_bg_color -b normal
+        echo $tide_right_prompt_suffix
+    end
+end
+
+function _tide_item_pwd
+    _tide_print_item pwd @PWD@
+end
+
+function _tide_item_newline
+    set_color $prev_bg_color -b normal
+    v=tide_"$_tide_side"_prompt_suffix echo $$v
+    set -g add_prefix
+end

package/dotfiles/macos/.config/fish/functions/_tide_cache_variables.fish

@@ -0,0 +1,17 @@
+function _tide_cache_variables
+    # Same-color-separator color
+    set_color $tide_prompt_color_separator_same_color | read -gx _tide_color_separator_same_color
+
+    # git
+    contains git $_tide_left_items $_tide_right_items && set_color $tide_git_color_branch | read -gx _tide_location_color
+
+    # private_mode
+    if contains private_mode $_tide_left_items $_tide_right_items && test -n "$fish_private_mode"
+        set -gx _tide_private_mode
+    else
+        set -e _tide_private_mode
+    end
+
+    # item padding
+    test "$tide_prompt_pad_items" = true && set -gx _tide_pad ' ' || set -e _tide_pad
+end

package/dotfiles/macos/.config/fish/functions/_tide_detect_os.fish

@@ -0,0 +1,76 @@
+# Outputs icon, color, bg_color
+function _tide_detect_os
+    set -lx defaultColor 080808 CED7CF
+    switch (uname | string lower)
+        case darwin
+            printf %s\n  D6D6D6 333333 # from apple.com header
+        case freebsd openbsd dragonfly
+            printf %s\n  FFFFFF AB2B28 # https://freebsdfoundation.org/about-us/about-the-foundation/project/
+        case 'cygwin*' 'mingw*_nt*' 'msys_nt*'
+            printf %s\n  FFFFFF 00CCFF # https://answers.microsoft.com/en-us/windows/forum/all/what-is-the-official-windows-8-blue-rgb-or-hex/fd57144b-f69b-42d8-8c21-6ca911646e44
+        case linux
+            if test (uname -o) = Android
+                # https://developer.android.com/distribute/marketing-tools/brand-guidelines
+                printf %s\n  3DDC84 3C3F41 # fg is from above link, bg is from Android Studio default dark theme
+            else
+                _tide_detect_os_linux_cases /etc/os-release ID ||
+                    _tide_detect_os_linux_cases /etc/os-release ID_LIKE ||
+                    _tide_detect_os_linux_cases /etc/lsb-release DISTRIB_ID ||
+                    printf %s\n  $defaultColor
+            end
+        case '*'
+            echo -ns '?'
+    end
+end
+
+function _tide_detect_os_linux_cases -a file key
+    test -e $file || return
+    set -l split_file (string split '=' <$file)
+    set -l key_index (contains --index $key $split_file) || return
+    set -l value (string trim --chars='"' $split_file[(math $key_index + 1)])
+
+    # Anything which would have pure white background has been changed to D4D4D4
+    # It was just too bright otherwise
+    switch (string lower $value)
+        case alpine
+            printf %s\n  FFFFFF 0D597F # from alpine logo
+        case arch
+            printf %s\n  1793D1 4D4D4D # from arch wiki header
+        case centos
+            printf %s\n  000000 D4D4D4 # https://wiki.centos.org/ArtWork/Brand/Logo, monochromatic
+        case debian
+            printf %s\n  C70036 D4D4D4 # from debian logo https://www.debian.org/logos/openlogo-nd-100.png
+        case devuan
+            printf %s\n  $defaultColor # logo is monochromatic
+        case elementary
+            printf %s\n  000000 D4D4D4 # https://elementary.io/brand, encouraged to be monochromatic
+        case fedora
+            printf %s\n  FFFFFF 294172 # from logo https://fedoraproject.org/w/uploads/2/2d/Logo_fedoralogo.png
+        case gentoo
+            printf %s\n  FFFFFF 54487A # https://wiki.gentoo.org/wiki/Project:Artwork/Colors
+        case mageia
+            printf %s\n  FFFFFF 262F45 # https://wiki.mageia.org/en/Artwork_guidelines
+        case manjaro
+            printf %s\n  FFFFFF 35BF5C # from https://gitlab.manjaro.org/artwork/branding/logo/-/blob/master/logo.svg
+        case mint linuxmint
+            printf %s\n  FFFFFF 69B53F # extracted from https://linuxmint.com/web/img/favicon.ico
+        case nixos
+            printf %s\n  FFFFFF 5277C3 # https://github.com/NixOS/nixos-artwork/tree/master/logo
+        case opensuse-leap opensuse-tumbleweed opensuse-microos
+            printf %s\n  73BA25 173f4f # https://en.opensuse.org/openSUSE:Artwork_brand
+        case raspbian
+            printf %s\n  FFFFFF A22846 # https://static.raspberrypi.org/files/Raspberry_Pi_Visual_Guidelines_2020.pdf
+        case rhel
+            printf %s\n  EE0000 000000 # https://www.redhat.com/en/about/brand/standards/color
+        case sabayon
+            printf %s\n  $defaultColor # Can't find colors, and they are rebranding anyway
+        case slackware
+            printf %s\n  $defaultColor # Doesn't really have a logo, and the colors are too close to PWD blue anyway
+        case ubuntu
+            printf %s\n  E95420 D4D4D4 # https://design.ubuntu.com/brand/
+        case void
+            printf %s\n  FFFFFF 478061 # from https://alpha.de.repo.voidlinux.org/logos/void.svg
+        case '*'
+            return 1
+    end
+end

package/dotfiles/macos/.config/fish/functions/_tide_find_and_remove.fish

@@ -0,0 +1,3 @@
+function _tide_find_and_remove -a name list --no-scope-shadowing
+    contains --index $name $$list | read -l index && set -e "$list"[$index]
+end

package/dotfiles/macos/.config/fish/functions/_tide_fish_colorize.fish

@@ -0,0 +1,7 @@
+function _tide_fish_colorize
+    if command -q fish_indent
+        echo -ns "$argv" | fish_indent --ansi
+    else
+        echo -ns "$argv"
+    end
+end

package/dotfiles/macos/.config/fish/functions/_tide_item_aws.fish

@@ -0,0 +1,11 @@
+function _tide_item_aws
+    # AWS_PROFILE overrides AWS_DEFAULT_PROFILE, AWS_REGION overrides AWS_DEFAULT_REGION
+    set -q AWS_PROFILE && set -l AWS_DEFAULT_PROFILE $AWS_PROFILE
+    set -q AWS_REGION && set -l AWS_DEFAULT_REGION $AWS_REGION
+
+    if test -n "$AWS_DEFAULT_PROFILE" && test -n "$AWS_DEFAULT_REGION"
+        _tide_print_item aws $tide_aws_icon' ' "$AWS_DEFAULT_PROFILE/$AWS_DEFAULT_REGION"
+    else if test -n "$AWS_DEFAULT_PROFILE$AWS_DEFAULT_REGION"
+        _tide_print_item aws $tide_aws_icon' ' "$AWS_DEFAULT_PROFILE$AWS_DEFAULT_REGION"
+    end
+end

package/dotfiles/macos/.config/fish/functions/_tide_item_bun.fish

@@ -0,0 +1,6 @@
+function _tide_item_bun
+    if path is $_tide_parent_dirs/bun.lockb
+        bun --version | string match -qr "(?<v>.*)"
+        _tide_print_item bun $tide_bun_icon' ' $v
+    end
+end

package/dotfiles/macos/.config/fish/functions/_tide_item_character.fish

@@ -0,0 +1,17 @@
+function _tide_item_character
+    test $_tide_status = 0 && set_color $tide_character_color || set_color $tide_character_color_failure
+
+    set -q add_prefix || echo -ns ' '
+
+    test "$fish_key_bindings" = fish_default_key_bindings && echo -ns $tide_character_icon ||
+        switch $fish_bind_mode
+            case insert
+                echo -ns $tide_character_icon
+            case default
+                echo -ns $tide_character_vi_icon_default
+            case replace replace_one
+                echo -ns $tide_character_vi_icon_replace
+            case visual
+                echo -ns $tide_character_vi_icon_visual
+        end
+end

package/dotfiles/macos/.config/fish/functions/_tide_item_cmd_duration.fish

@@ -0,0 +1,12 @@
+function _tide_item_cmd_duration
+    test $CMD_DURATION -gt $tide_cmd_duration_threshold && t=(
+            math -s0 "$CMD_DURATION/3600000" # Hours
+            math -s0 "$CMD_DURATION/60000"%60 # Minutes
+            math -s$tide_cmd_duration_decimals "$CMD_DURATION/1000"%60) if test $t[1] != 0
+        _tide_print_item cmd_duration $tide_cmd_duration_icon' ' "$t[1]h $t[2]m $t[3]s"
+    else if test $t[2] != 0
+        _tide_print_item cmd_duration $tide_cmd_duration_icon' ' "$t[2]m $t[3]s"
+    else
+        _tide_print_item cmd_duration $tide_cmd_duration_icon' ' "$t[3]s"
+    end
+end

package/dotfiles/macos/.config/fish/functions/_tide_item_context.fish

@@ -0,0 +1,14 @@
+function _tide_item_context
+    if set -q SSH_TTY
+        set -fx tide_context_color $tide_context_color_ssh
+    else if test "$EUID" = 0
+        set -fx tide_context_color $tide_context_color_root
+    else if test "$tide_context_always_display" = true
+        set -fx tide_context_color $tide_context_color_default
+    else
+        return
+    end
+
+    string match -qr "^(?<h>(\.?[^\.]*){0,$tide_context_hostname_parts})" @$hostname
+    _tide_print_item context $USER$h
+end

package/dotfiles/macos/.config/fish/functions/_tide_item_crystal.fish

@@ -0,0 +1,6 @@
+function _tide_item_crystal
+    if path is $_tide_parent_dirs/shard.yml
+        crystal --version | string match -qr "(?<v>[\d.]+)"
+        _tide_print_item crystal $tide_crystal_icon' ' $v
+    end
+end

package/dotfiles/macos/.config/fish/functions/_tide_item_direnv.fish

@@ -0,0 +1,7 @@
+function _tide_item_direnv
+    set -q DIRENV_DIR || return
+    direnv status | string match -q 'Found RC allowed false' &&
+        set -lx tide_direnv_color $tide_direnv_color_denied &&
+        set -lx tide_direnv_bg_color $tide_direnv_bg_color_denied
+    _tide_print_item direnv $tide_direnv_icon
+end

package/dotfiles/macos/.config/fish/functions/_tide_item_distrobox.fish

@@ -0,0 +1,4 @@
+function _tide_item_distrobox
+    test -e /etc/profile.d/distrobox_profile.sh && test -e /run/.containerenv &&
+        _tide_print_item distrobox $tide_distrobox_icon' ' (string match -rg 'name="(.*)"' </run/.containerenv)
+end

package/dotfiles/macos/.config/fish/functions/_tide_item_docker.fish

@@ -0,0 +1,5 @@
+function _tide_item_docker
+    docker context inspect --format '{{.Name}}' | read -l context
+    contains -- "$context" $tide_docker_default_contexts ||
+        _tide_print_item docker $tide_docker_icon' ' $context
+end

package/dotfiles/macos/.config/fish/functions/_tide_item_elixir.fish

@@ -0,0 +1,4 @@
+function _tide_item_elixir
+    path is $_tide_parent_dirs/mix.exs &&
+        _tide_print_item elixir $tide_elixir_icon' ' (elixir --short-version)
+end

package/dotfiles/macos/.config/fish/functions/_tide_item_gcloud.fish

@@ -0,0 +1,8 @@
+function _tide_item_gcloud
+    set -q CLOUDSDK_CONFIG || set -l CLOUDSDK_CONFIG ~/.config/gcloud
+    path is $CLOUDSDK_CONFIG/active_config &&
+        read -l config <$CLOUDSDK_CONFIG/active_config &&
+        path is $CLOUDSDK_CONFIG/configurations/config_$config &&
+        string match -qr '^\s*project\s*=\s*(?<project>.*)' <$CLOUDSDK_CONFIG/configurations/config_$config &&
+        _tide_print_item gcloud $tide_gcloud_icon' ' $project
+end

package/dotfiles/macos/.config/fish/functions/_tide_item_git.fish

@@ -0,0 +1,72 @@
+function _tide_item_git
+    if git branch --show-current 2>/dev/null | string shorten -"$tide_git_truncation_strategy"m$tide_git_truncation_length | read -l location
+        git rev-parse --git-dir --is-inside-git-dir | read -fL gdir in_gdir
+        set location $_tide_location_color$location
+    else if test $pipestatus[1] != 0
+        return
+    else if git tag --points-at HEAD | string shorten -"$tide_git_truncation_strategy"m$tide_git_truncation_length | read location
+        git rev-parse --git-dir --is-inside-git-dir | read -fL gdir in_gdir
+        set location '#'$_tide_location_color$location
+    else
+        git rev-parse --git-dir --is-inside-git-dir --short HEAD | read -fL gdir in_gdir location
+        set location @$_tide_location_color$location
+    end
+
+    # Operation
+    if test -d $gdir/rebase-merge
+        # Turn ANY into ALL, via double negation
+        if not path is -v $gdir/rebase-merge/{msgnum,end}
+            read -f step <$gdir/rebase-merge/msgnum
+            read -f total_steps <$gdir/rebase-merge/end
+        end
+        test -f $gdir/rebase-merge/interactive && set -f operation rebase-i || set -f operation rebase-m
+    else if test -d $gdir/rebase-apply
+        if not path is -v $gdir/rebase-apply/{next,last}
+            read -f step <$gdir/rebase-apply/next
+            read -f total_steps <$gdir/rebase-apply/last
+        end
+        if test -f $gdir/rebase-apply/rebasing
+            set -f operation rebase
+        else if test -f $gdir/rebase-apply/applying
+            set -f operation am
+        else
+            set -f operation am/rebase
+        end
+    else if test -f $gdir/MERGE_HEAD
+        set -f operation merge
+    else if test -f $gdir/CHERRY_PICK_HEAD
+        set -f operation cherry-pick
+    else if test -f $gdir/REVERT_HEAD
+        set -f operation revert
+    else if test -f $gdir/BISECT_LOG
+        set -f operation bisect
+    end
+
+    # Git status/stash + Upstream behind/ahead
+    test $in_gdir = true && set -l _set_dir_opt -C $gdir/..
+    # Suppress errors in case we are in a bare repo or there is no upstream
+    set -l stat (git $_set_dir_opt --no-optional-locks status --porcelain 2>/dev/null)
+    string match -qr '(0|(?<stash>.*))\n(0|(?<conflicted>.*))\n(0|(?<staged>.*))
+(0|(?<dirty>.*))\n(0|(?<untracked>.*))(\n(0|(?<behind>.*))\t(0|(?<ahead>.*)))?' \
+        "$(git $_set_dir_opt stash list 2>/dev/null | count
+        string match -r ^UU $stat | count
+        string match -r ^[ADMR] $stat | count
+        string match -r ^.[ADMR] $stat | count
+        string match -r '^\?\?' $stat | count
+        git rev-list --count --left-right @{upstream}...HEAD 2>/dev/null)"
+
+    if test -n "$operation$conflicted"
+        set -g tide_git_bg_color $tide_git_bg_color_urgent
+    else if test -n "$staged$dirty$untracked"
+        set -g tide_git_bg_color $tide_git_bg_color_unstable
+    end
+
+    _tide_print_item git $_tide_location_color$tide_git_icon' ' (set_color white; echo -ns $location
+        set_color $tide_git_color_operation; echo -ns ' '$operation ' '$step/$total_steps
+        set_color $tide_git_color_upstream; echo -ns ' ⇣'$behind ' ⇡'$ahead
+        set_color $tide_git_color_stash; echo -ns ' *'$stash
+        set_color $tide_git_color_conflicted; echo -ns ' ~'$conflicted
+        set_color $tide_git_color_staged; echo -ns ' +'$staged
+        set_color $tide_git_color_dirty; echo -ns ' !'$dirty
+        set_color $tide_git_color_untracked; echo -ns ' ?'$untracked)
+end

package/dotfiles/macos/.config/fish/functions/_tide_item_go.fish

@@ -0,0 +1,6 @@
+function _tide_item_go
+    if path is $_tide_parent_dirs/go.mod
+        go version | string match -qr "(?<v>[\d.]+)"
+        _tide_print_item go $tide_go_icon' ' $v
+    end
+end

package/dotfiles/macos/.config/fish/functions/_tide_item_java.fish

@@ -0,0 +1,6 @@
+function _tide_item_java
+    if path is $_tide_parent_dirs/pom.xml
+        java -version &| string match -qr "(?<v>[\d.]+)"
+        _tide_print_item java $tide_java_icon' ' $v
+    end
+end

package/dotfiles/macos/.config/fish/functions/_tide_item_jobs.fish

@@ -0,0 +1,7 @@
+function _tide_item_jobs
+    set -q _tide_jobs && if test $_tide_jobs -ge $tide_jobs_number_threshold
+        _tide_print_item jobs $tide_jobs_icon' ' $_tide_jobs
+    else
+        _tide_print_item jobs $tide_jobs_icon
+    end
+end

package/dotfiles/macos/.config/fish/functions/_tide_item_kubectl.fish

@@ -0,0 +1,4 @@
+function _tide_item_kubectl
+    kubectl config view --minify --output 'jsonpath={.current-context}/{..namespace}' 2>/dev/null | read -l context &&
+        _tide_print_item kubectl $tide_kubectl_icon' ' (string replace -r '/(|default)$' '' $context)
+end

package/dotfiles/macos/.config/fish/functions/_tide_item_nix_shell.fish

@@ -0,0 +1,3 @@
+function _tide_item_nix_shell
+    set -q IN_NIX_SHELL && _tide_print_item nix_shell $tide_nix_shell_icon' ' $IN_NIX_SHELL
+end

package/dotfiles/macos/.config/fish/functions/_tide_item_node.fish

@@ -0,0 +1,6 @@
+function _tide_item_node
+    if path is $_tide_parent_dirs/package.json
+        node --version | string match -qr "v(?<v>.*)"
+        _tide_print_item node $tide_node_icon' ' $v
+    end
+end

package/dotfiles/macos/.config/fish/functions/_tide_item_os.fish

@@ -0,0 +1,3 @@
+function _tide_item_os
+    _tide_print_item os $tide_os_icon
+end

package/dotfiles/macos/.config/fish/functions/_tide_item_php.fish

@@ -0,0 +1,6 @@
+function _tide_item_php
+    if path is $_tide_parent_dirs/composer.json
+        php --version | string match -qr "(?<v>[\d.]+)"
+        _tide_print_item php $tide_php_icon' ' $v
+    end
+end

package/dotfiles/macos/.config/fish/functions/_tide_item_private_mode.fish

@@ -0,0 +1,3 @@
+function _tide_item_private_mode
+    set -q _tide_private_mode && _tide_print_item private_mode $tide_private_mode_icon
+end

package/dotfiles/macos/.config/fish/functions/_tide_item_pulumi.fish

@@ -0,0 +1,19 @@
+function _tide_item_pulumi
+    if path filter $_tide_parent_dirs/Pulumi.yaml | read -l yaml_path
+        if command -q sha1sum
+            echo -n "$yaml_path" | sha1sum | string match -qr "(?<path_hash>.{40})"
+        else if command -q shasum
+            echo -n "$yaml_path" | shasum | string match -qr "(?<path_hash>.{40})"
+        else
+            return
+        end
+
+        string match -qr 'name: *(?<project_name>.*)' <$yaml_path
+        set -l workspace_file "$HOME/.pulumi/workspaces/$project_name-$path_hash-workspace.json"
+
+        if test -e $workspace_file
+            string match -qr '"stack": *"(?<stack>.*)"' <$workspace_file
+            _tide_print_item pulumi $tide_pulumi_icon' ' $stack
+        end
+    end
+end

package/dotfiles/macos/.config/fish/functions/_tide_item_python.fish

@@ -0,0 +1,27 @@
+function _tide_item_python
+    if test -n "$VIRTUAL_ENV"
+        if command -q python3
+            python3 --version | string match -qr "(?<v>[\d.]+)"
+        else
+            python --version | string match -qr "(?<v>[\d.]+)"
+        end
+        string match -qr "^.*/(?<dir>.*)/(?<base>.*)" $VIRTUAL_ENV
+        # pipenv $VIRTUAL_ENV looks like /home/ilan/.local/share/virtualenvs/pipenv_project-EwRYuc3l
+        # Detect whether we are using pipenv by looking for 'virtualenvs'. If so, remove the hash at the end.
+        if test "$dir" = virtualenvs
+            string match -qr "(?<base>.*)-.*" $base
+            _tide_print_item python $tide_python_icon' ' "$v ($base)"
+        else if contains -- "$base" virtualenv venv .venv env # avoid generic names
+            _tide_print_item python $tide_python_icon' ' "$v ($dir)"
+        else
+            _tide_print_item python $tide_python_icon' ' "$v ($base)"
+        end
+    else if path is .python-version Pipfile __init__.py pyproject.toml requirements.txt setup.py
+        if command -q python3
+            python3 --version | string match -qr "(?<v>[\d.]+)"
+        else
+            python --version | string match -qr "(?<v>[\d.]+)"
+        end
+        _tide_print_item python $tide_python_icon' ' $v
+    end
+end

package/dotfiles/macos/.config/fish/functions/_tide_item_ruby.fish

@@ -0,0 +1,6 @@
+function _tide_item_ruby
+    if path is $_tide_parent_dirs/{*.gemspec,Gemfile,Rakefile,.ruby-version}
+        ruby --version | string match -qr "(?<v>[\d.]+)"
+        _tide_print_item ruby $tide_ruby_icon' ' $v
+    end
+end

package/dotfiles/macos/.config/fish/functions/_tide_item_rustc.fish

@@ -0,0 +1,6 @@
+function _tide_item_rustc
+    if path is $_tide_parent_dirs/Cargo.toml
+        rustc --version | string match -qr "(?<v>[\d.]+)"
+        _tide_print_item rustc $tide_rustc_icon' ' $v
+    end
+end

package/dotfiles/macos/.config/fish/functions/_tide_item_shlvl.fish

@@ -0,0 +1,4 @@
+function _tide_item_shlvl
+    # Non-interactive shells do not increment SHLVL, so we don't need to subtract 1
+    test $SHLVL -gt $tide_shlvl_threshold && _tide_print_item shlvl $tide_shlvl_icon' ' $SHLVL
+end

package/dotfiles/macos/.config/fish/functions/_tide_item_status.fish

@@ -0,0 +1,15 @@
+function _tide_item_status
+    if string match -qv 0 $_tide_pipestatus # If there is a failure anywhere in the pipestatus
+        if test "$_tide_pipestatus" = 1 # If simple failure
+            contains character $_tide_left_items || tide_status_bg_color=$tide_status_bg_color_failure \
+                tide_status_color=$tide_status_color_failure _tide_print_item status $tide_status_icon_failure' ' 1
+        else
+            fish_status_to_signal $_tide_pipestatus | string replace SIG '' | string join '|' | read -l out
+            test $_tide_status = 0 && _tide_print_item status $tide_status_icon' ' $out ||
+                tide_status_bg_color=$tide_status_bg_color_failure tide_status_color=$tide_status_color_failure \
+                    _tide_print_item status $tide_status_icon_failure' ' $out
+        end
+    else if not contains character $_tide_left_items
+        _tide_print_item status $tide_status_icon
+    end
+end

package/dotfiles/macos/.config/fish/functions/_tide_item_terraform.fish

@@ -0,0 +1,5 @@
+function _tide_item_terraform
+    path is $_tide_parent_dirs/.terraform &&
+        terraform workspace show | string match -v default | read -l w &&
+        _tide_print_item terraform $tide_terraform_icon' ' $w
+end

package/dotfiles/macos/.config/fish/functions/_tide_item_time.fish

@@ -0,0 +1,3 @@
+function _tide_item_time
+    _tide_print_item time (date +$tide_time_format)
+end

package/dotfiles/macos/.config/fish/functions/_tide_item_toolbox.fish

@@ -0,0 +1,4 @@
+function _tide_item_toolbox
+    test -e /run/.toolboxenv &&
+        _tide_print_item toolbox $tide_toolbox_icon' ' (string match -rg 'name="(.*)"' </run/.containerenv)
+end