@etherisc/gif-next 0.0.2-ff282a4-523 → 0.0.2-ff3a8a0-504

package/contracts/registry/RegistryAdmin.sol

@@ -0,0 +1,191 @@
+// SPDX-License-Identifier: UNLICENSED
+pragma solidity ^0.8.20;
+
+import {IAuthorization} from "../authorization/IAuthorization.sol";
+import {IRegistry} from "./IRegistry.sol";
+import {IService} from "../shared/IService.sol";
+import {IStaking} from "../staking/IStaking.sol";
+
+import {AccessAdmin} from "../authorization/AccessAdmin.sol";
+import {AccessAdminLib} from "../authorization/AccessAdminLib.sol";
+import {AccessManagerCloneable} from "../authorization/AccessManagerCloneable.sol";
+import {ObjectType, REGISTRY} from "../type/ObjectType.sol";
+import {RoleId, RoleIdLib, GIF_MANAGER_ROLE, GIF_ADMIN_ROLE} from "../type/RoleId.sol";
+import {Str} from "../type/String.sol";
+import {VersionPart} from "../type/Version.sol";
+
+/*
+    1) GIF_MANAGER_ROLE
+        - can have arbitrary number of members
+        - responsible for release preparation
+        - responsible for services registrations
+        - responsible for token registration and activation
+
+    2) GIF_ADMIN_ROLE
+        - admin of GIF_MANAGER_ROLE
+        - MUST have 1 member at any time
+        - granted/revoked ONLY in transferAdminRole() -> consider lock out situations!!!
+        - responsible for creation, activation and locking/unlocking of releases
+*/
+
+/// @dev The RegistryAdmin contract implements the central authorization for the GIF core contracts.
+/// These are the release independent registry and staking contracts and their respective helper contracts.
+/// The RegistryAdmin also manages the access from service contracts to the GIF core contracts
+contract RegistryAdmin is
+    AccessAdmin
+{
+    /// @dev gif core roles
+    string public constant GIF_ADMIN_ROLE_NAME = "GifAdminRole";
+    string public constant GIF_MANAGER_ROLE_NAME = "GifManagerRole";
+
+    /// @dev gif core targets
+    string public constant REGISTRY_ADMIN_TARGET_NAME = "RegistryAdmin";
+    string public constant REGISTRY_TARGET_NAME = "Registry";
+    string public constant RELEASE_REGISTRY_TARGET_NAME = "ReleaseRegistry";
+    string public constant STAKING_TARGET_NAME = "Staking";
+    string public constant STAKING_TARGET_HANDLER_NAME = "TargetHandler";
+    string public constant STAKING_STORE_TARGET_NAME = "StakingStore";
+    string public constant STAKING_TH_TARGET_NAME = "StakingTH";
+    string public constant TOKEN_REGISTRY_TARGET_NAME = "TokenRegistry";
+    string public constant TOKEN_HANDLER_TARGET_NAME = "TokenHandler";
+
+    // completeSetup
+    error ErrorRegistryAdminNotRegistry(address registry);
+
+    address internal _registry;
+    address private _releaseRegistry;
+    address private _tokenRegistry;
+    address private _staking;
+    address private _stakingTargetHandler;
+    address private _stakingStore;
+
+    constructor() {
+        initialize(
+            address(new AccessManagerCloneable()),
+            "RegistryAdmin");
+    }
+
+
+    function completeSetup(
+        address registry,
+        address authorization,
+        VersionPart release,
+        address gifAdmin, 
+        address gifManager
+    )
+        public
+        virtual
+        reinitializer(type(uint8).max)
+        onlyDeployer()
+    {
+        // checks
+        AccessAdminLib.checkRegistry(registry);
+
+        AccessManagerCloneable(
+            authority()).completeSetup(
+                registry, 
+                release); 
+
+        _checkAuthorization(authorization, REGISTRY(), release, false, true);
+
+        _registry = registry;
+        _authorization = IAuthorization(authorization);
+
+        IRegistry registryContract = IRegistry(registry);
+        _releaseRegistry = registryContract.getReleaseRegistryAddress();
+        _tokenRegistry = registryContract.getTokenRegistryAddress();
+        _staking = registryContract.getStakingAddress();
+        _stakingTargetHandler = address(IStaking(_staking).getTargetHandler());
+        _stakingStore = address(IStaking(_staking).getStakingStore());
+
+        // link nft ownability to registry
+        _linkToNftOwnable(_registry);
+
+        // setup registry core targets
+        _createCoreTargets(_authorization.getMainTargetName());
+
+        // setup non-contract roles
+        _createRoles(_authorization);
+        _grantRoleToAccount(GIF_ADMIN_ROLE(), gifAdmin);
+        _grantRoleToAccount(GIF_MANAGER_ROLE(), gifManager);
+
+        // authorize functions of registry and staking contracts
+        _createTargetAuthorizations(_authorization);
+    }
+
+
+    function grantServiceRoleForAllVersions(
+        IService service, 
+        ObjectType domain
+    )
+        external
+        restricted()
+    {
+        _grantRoleToAccount( 
+            RoleIdLib.toGenericServiceRoleId(domain),
+            address(service)); 
+    }
+
+    //--- view functions ----------------------------------------------------//
+
+    function getGifAdminRole() external pure returns (RoleId) {
+        return GIF_ADMIN_ROLE();
+    }
+
+    function getGifManagerRole() external pure returns (RoleId) {
+        return GIF_MANAGER_ROLE();
+    }
+
+    //--- private initialization functions -------------------------------------------//
+
+    function _createRoles(IAuthorization authorization)
+        internal
+    {
+        RoleId[] memory roles = authorization.getRoles();
+
+        for(uint256 i = 0; i < roles.length; i++) {
+            RoleId roleId = roles[i];
+            RoleInfo memory roleInfo = authorization.getRoleInfo(roleId);
+
+            // create role if not exists
+            if (!roleExists(roleInfo.name.toString())) {
+                _createRole(
+                    roleId,
+                    roleInfo);
+            }
+        }
+    }
+
+
+    function _createCoreTargets(string memory registryTargetName)
+        internal
+    {
+        // registry
+        _createUncheckedTarget(_registry, registryTargetName, TargetType.Core);
+        _createUncheckedTarget(address(this), REGISTRY_ADMIN_TARGET_NAME, TargetType.Core);
+        _createUncheckedTarget(_releaseRegistry, RELEASE_REGISTRY_TARGET_NAME, TargetType.Core);
+        _createUncheckedTarget(_tokenRegistry, TOKEN_REGISTRY_TARGET_NAME, TargetType.Core);
+
+        // staking
+        _createUncheckedTarget(_staking, STAKING_TARGET_NAME, TargetType.Core);
+        _createUncheckedTarget(_stakingTargetHandler, STAKING_TARGET_HANDLER_NAME, TargetType.Core);
+        _createUncheckedTarget(_stakingStore, STAKING_STORE_TARGET_NAME, TargetType.Core);
+    }
+
+
+    function _createTargetAuthorizations(IAuthorization authorization)
+        internal
+    {
+        Str[] memory targets = authorization.getTargets();
+        Str target;
+
+        for(uint256 i = 0; i < targets.length; i++) {
+            target = targets[i];
+            RoleId[] memory authorizedRoles = authorization.getAuthorizedRoles(target);
+
+            for(uint256 j = 0; j < authorizedRoles.length; j++) {
+                _authorizeFunctions(authorization, target, authorizedRoles[j]);
+            }
+        }
+    }
+}

package/contracts/registry/RegistryAuthorization.sol

@@ -0,0 +1,336 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IAccess} from "../authorization/IAccess.sol";
+import {IRegistry} from "../registry/IRegistry.sol";
+import {IStaking} from "../staking/IStaking.sol";
+
+import {Authorization} from "../authorization/Authorization.sol";
+import {COMPONENT, POOL, REGISTRY, STAKING} from "../../contracts/type/ObjectType.sol";
+import {PUBLIC_ROLE} from "../type/RoleId.sol";
+import {ReleaseRegistry} from "./ReleaseRegistry.sol";
+import {RegistryAdmin} from "./RegistryAdmin.sol";
+import {RoleIdLib, ADMIN_ROLE, GIF_ADMIN_ROLE, GIF_MANAGER_ROLE} from "../type/RoleId.sol";
+import {StakingStore} from "../staking/StakingStore.sol";
+import {TargetHandler} from "../staking/TargetHandler.sol";
+import {TokenHandler} from "../shared/TokenHandler.sol";
+import {TokenRegistry} from "../registry/TokenRegistry.sol";
+import {VersionPartLib} from "../type/Version.sol";
+
+
+contract RegistryAuthorization
+     is Authorization
+{
+     /// @dev gif core roles
+     string public constant GIF_ADMIN_ROLE_NAME = "GifAdminRole";
+     string public constant GIF_MANAGER_ROLE_NAME = "GifManagerRole";
+     string public constant RELEASE_REGISTRY_ROLE_NAME = "ReleaseRegistryRole";
+     string public constant STAKING_ROLE_NAME = "StakingRole";
+
+     /// @dev gif roles for external contracts
+     string public constant REGISTRY_SERVICE_ROLE_NAME = "RegistryServiceRole";
+     string public constant COMPONENT_SERVICE_ROLE_NAME = "ComponentServiceRole";
+     string public constant POOL_SERVICE_ROLE_NAME = "PoolServiceRole";
+     string public constant STAKING_SERVICE_ROLE_NAME = "StakingServiceRole";
+
+     /// @dev gif core targets
+     string public constant REGISTRY_ADMIN_TARGET_NAME = "RegistryAdmin";
+     string public constant REGISTRY_TARGET_NAME = "Registry";
+     string public constant RELEASE_REGISTRY_TARGET_NAME = "ReleaseRegistry";
+     string public constant TOKEN_REGISTRY_TARGET_NAME = "TokenRegistry";
+
+     string public constant STAKING_TARGET_NAME = "Staking";
+     string public constant STAKING_TARGET_HANDLER_NAME = "TargetHandler";
+     string public constant STAKING_STORE_TARGET_NAME = "StakingStore";
+     string public constant STAKING_TH_TARGET_NAME = "StakingTh";
+
+     constructor(string memory commitHash)
+          Authorization(
+               REGISTRY_TARGET_NAME, 
+               REGISTRY(), 
+               3, 
+               commitHash, 
+               false, // isComponent
+               false) // includeTokenHandler
+     { }
+
+     /// @dev Sets up the GIF admin and manager roles.
+     function _setupRoles() internal override {
+
+          // max number of versioned contracts per generic service
+          uint32 maxReleases = uint32(VersionPartLib.releaseMax().toInt());
+
+          // service roles (for all releases)
+          _addRole(
+               RoleIdLib.toGenericServiceRoleId(REGISTRY()), 
+               _toRoleInfo({
+                    adminRoleId: ADMIN_ROLE(),
+                    roleType: RoleType.Core,
+                    maxMemberCount: maxReleases, 
+                    name: REGISTRY_SERVICE_ROLE_NAME}));
+
+          _addRole(
+               RoleIdLib.toGenericServiceRoleId(STAKING()), 
+               _toRoleInfo({
+                    adminRoleId: ADMIN_ROLE(),
+                    roleType: RoleType.Core,
+                    maxMemberCount: maxReleases, 
+                    name: STAKING_SERVICE_ROLE_NAME}));
+
+          _addRole(
+               RoleIdLib.toGenericServiceRoleId(COMPONENT()), 
+               _toRoleInfo({
+                    adminRoleId: ADMIN_ROLE(),
+                    roleType: RoleType.Core,
+                    maxMemberCount: maxReleases, 
+                    name: COMPONENT_SERVICE_ROLE_NAME}));
+
+          _addRole(
+               RoleIdLib.toGenericServiceRoleId(POOL()), 
+               _toRoleInfo({
+                    adminRoleId: ADMIN_ROLE(),
+                    roleType: RoleType.Core,
+                    maxMemberCount: maxReleases, 
+                    name: POOL_SERVICE_ROLE_NAME}));
+
+          // gif admin role
+          _addRole(
+               GIF_ADMIN_ROLE(),
+               _toRoleInfo({
+                    adminRoleId: ADMIN_ROLE(),
+                    roleType: RoleType.Core,
+                    maxMemberCount: 2, // TODO decide on max member count
+                    name: GIF_ADMIN_ROLE_NAME}));
+
+          // gif manager role
+          _addRole(
+               GIF_MANAGER_ROLE(), 
+               _toRoleInfo({
+                    adminRoleId: ADMIN_ROLE(),
+                    roleType: RoleType.Core,
+                    maxMemberCount: 1, // TODO decide on max member count
+                    name: GIF_MANAGER_ROLE_NAME}));
+
+     }
+
+     /// @dev Sets up the relevant (non-service) targets for the registry.
+     function _setupTargets() internal override {
+          _addGifTarget(REGISTRY_ADMIN_TARGET_NAME);
+          _addGifTarget(RELEASE_REGISTRY_TARGET_NAME);
+          _addGifTarget(TOKEN_REGISTRY_TARGET_NAME);
+
+          _addGifTarget(STAKING_TARGET_NAME);
+          _addGifTarget(STAKING_TARGET_HANDLER_NAME);
+          _addGifTarget(STAKING_STORE_TARGET_NAME);
+          _addGifTarget(STAKING_TH_TARGET_NAME);
+     }
+
+
+     function _setupTargetAuthorizations()
+          internal
+          override
+     {
+          // registry
+          _setupRegistryAuthorization();
+          _setupRegistryAdminAuthorization();
+          _setupReleaseRegistryAuthorization();
+          _setupTokenRegistryAuthorization();
+
+          // staking
+          _setupStakingAuthorization();
+          _setupStakingTargetHandlerAuthorization();
+          _setupStakingStoreAuthorization();
+          _setupStakingThAuthorization();
+     }
+
+     event LogAccessAdminDebug(string message, string custom, uint256 value);
+
+     function _setupRegistryAuthorization() internal {
+          IAccess.FunctionInfo[] storage functions;
+
+          // gif admin role
+          functions = _authorizeForTarget(REGISTRY_TARGET_NAME, GIF_ADMIN_ROLE());
+          _authorize(functions, IRegistry.registerRegistry.selector, "registerRegistry");
+
+          // registry service role
+          functions = _authorizeForTarget(
+               REGISTRY_TARGET_NAME, 
+               RoleIdLib.toGenericServiceRoleId(REGISTRY()));
+
+          _authorize(functions, IRegistry.register.selector, "register");
+          _authorize(functions, IRegistry.registerWithCustomType.selector, "registerWithCustomType");
+          
+          // release registry role
+          functions = _authorizeForTarget(
+               REGISTRY_TARGET_NAME, 
+               getTargetRole(getTarget(RELEASE_REGISTRY_TARGET_NAME)));
+
+          _authorize(functions, IRegistry.registerService.selector, "registerService");
+     }
+
+
+     function _setupRegistryAdminAuthorization() internal {
+          IAccess.FunctionInfo[] storage functions;
+
+          // release registry role
+          functions = _authorizeForTarget(
+               REGISTRY_ADMIN_TARGET_NAME, 
+               getTargetRole(getTarget(RELEASE_REGISTRY_TARGET_NAME)));
+
+          _authorize(functions, RegistryAdmin.grantServiceRoleForAllVersions.selector, "grantServiceRoleForAllVersions");
+     }
+
+
+     function _setupReleaseRegistryAuthorization() internal {
+          IAccess.FunctionInfo[] storage functions;
+
+          functions = _authorizeForTarget(RELEASE_REGISTRY_TARGET_NAME, GIF_ADMIN_ROLE());
+          _authorize(functions, ReleaseRegistry.createNextRelease.selector, "createNextRelease");
+          _authorize(functions, ReleaseRegistry.activateNextRelease.selector, "activateNextRelease");
+          _authorize(functions, ReleaseRegistry.setActive.selector, "setActive");
+
+          functions = _authorizeForTarget(RELEASE_REGISTRY_TARGET_NAME, GIF_MANAGER_ROLE());
+          _authorize(functions, ReleaseRegistry.prepareNextRelease.selector, "prepareNextRelease");
+          _authorize(functions, ReleaseRegistry.registerService.selector, "registerService");
+     }
+
+
+     function _setupTokenRegistryAuthorization() internal {
+          IAccess.FunctionInfo[] storage functions;
+
+          // gif manager role
+          functions = _authorizeForTarget(TOKEN_REGISTRY_TARGET_NAME, GIF_MANAGER_ROLE());
+          _authorize(functions, TokenRegistry.registerToken.selector, "registerToken");
+          _authorize(functions, TokenRegistry.registerRemoteToken.selector, "registerRemoteToken");
+          _authorize(functions, TokenRegistry.setActive.selector, "setActive");
+          _authorize(functions, TokenRegistry.setActiveForVersion.selector, "setActiveForVersion");
+          // TODO find a better way (only needed for testing)
+          _authorize(functions, TokenRegistry.setActiveWithVersionCheck.selector, "setActiveWithVersionCheck");
+     }
+
+
+     function _setupStakingAuthorization() internal {
+          IAccess.FunctionInfo[] storage functions;
+
+          // staking public role (protected by owner)
+          functions = _authorizeForTarget(
+               STAKING_TARGET_NAME,
+               PUBLIC_ROLE());
+
+          // unpermissioned functions
+          _authorize(functions, IStaking.updateTargetLimit.selector, "updateTargetLimit");
+          _authorize(functions, IStaking.createStake.selector, "createStake");
+
+          // owner functions (permissioned to staking owner)
+          _authorize(functions, IStaking.setSupportInfo.selector, "setSupportInfo");
+          _authorize(functions, IStaking.setUpdateTriggers.selector, "setUpdateTriggers");
+          _authorize(functions, IStaking.setProtocolLockingPeriod.selector, "setProtocolLockingPeriod");
+          _authorize(functions, IStaking.setProtocolRewardRate.selector, "setProtocolRewardRate");
+          _authorize(functions, IStaking.setStakingRate.selector, "setStakingRate");
+          _authorize(functions, IStaking.setStakingService.selector, "setStakingService");
+          _authorize(functions, IStaking.setStakingReader.selector, "setStakingReader");
+          _authorize(functions, IStaking.addToken.selector, "addToken");
+          
+          // target owner functions (permissioned to target owner)
+          _authorize(functions, IStaking.setTargetLimits.selector, "setTargetLimits");
+
+          // staker functions (may be permissioned to nft holders)
+          _authorize(functions, IStaking.stake.selector, "stake");
+          _authorize(functions, IStaking.unstake.selector, "unstake");
+          _authorize(functions, IStaking.restake.selector, "restake");
+          _authorize(functions, IStaking.updateRewards.selector, "updateRewards");
+          _authorize(functions, IStaking.claimRewards.selector, "claimRewards");
+
+          // reward reserve functions and token handler
+          _authorize(functions, IStaking.approveTokenHandler.selector, "approveTokenHandler");
+          _authorize(functions, IStaking.refillRewardReserves.selector, "refillRewardReserves");
+          _authorize(functions, IStaking.withdrawRewardReserves.selector, "withdrawRewardReserves");
+
+          // staking service role
+          functions = _authorizeForTarget(
+               STAKING_TARGET_NAME, 
+               RoleIdLib.toGenericServiceRoleId(STAKING()));
+
+          _authorize(functions, IStaking.registerTarget.selector, "registerTarget");
+          _authorize(functions, IStaking.setLockingPeriod.selector, "setLockingPeriod");
+          _authorize(functions, IStaking.setRewardRate.selector, "setRewardRate");
+          _authorize(functions, IStaking.setMaxStakedAmount.selector, "setMaxStakedAmount");
+          _authorize(functions, IStaking.refillRewardReservesByService.selector, "refillRewardReservesByService");
+          _authorize(functions, IStaking.withdrawRewardReservesByService.selector, "withdrawRewardReservesByService");
+
+          // pool service role
+          functions = _authorizeForTarget(
+               STAKING_TARGET_NAME, 
+               RoleIdLib.toGenericServiceRoleId(COMPONENT()));
+
+          _authorize(functions, IStaking.addTargetToken.selector, "addTargetToken");
+
+          // pool service role
+          functions = _authorizeForTarget(
+               STAKING_TARGET_NAME, 
+               RoleIdLib.toGenericServiceRoleId(POOL()));
+
+          _authorize(functions, IStaking.increaseTotalValueLocked.selector, "increaseTotalValueLocked");
+          _authorize(functions, IStaking.decreaseTotalValueLocked.selector, "decreaseTotalValueLocked");
+     }
+
+
+     function _setupStakingTargetHandlerAuthorization() internal {
+          IAccess.FunctionInfo[] storage functions;
+
+          // staking service role
+          functions = _authorizeForTarget(
+               STAKING_TARGET_HANDLER_NAME,
+               getTargetRole(getTarget(STAKING_TARGET_NAME)));
+
+          _authorize(functions, TargetHandler.setUpdateTriggers.selector, "setUpdateTriggers");
+     }
+
+
+     function _setupStakingStoreAuthorization() internal {
+          IAccess.FunctionInfo[] storage functions;
+
+          // release registry role
+          functions = _authorizeForTarget(
+               STAKING_STORE_TARGET_NAME, 
+               getTargetRole(getTarget(STAKING_TARGET_NAME)));
+
+          _authorize(functions, StakingStore.setTargetLimits.selector, "setTargetLimits");
+          _authorize(functions, StakingStore.updateTargetLimit.selector, "updateTargetLimit");
+          _authorize(functions, StakingStore.setStakingReader.selector, "setStakingReader");
+          _authorize(functions, StakingStore.setTargetLimitHandler.selector, "setTargetLimitHandler");
+          _authorize(functions, StakingStore.setSupportInfo.selector, "setSupportInfo");
+          _authorize(functions, StakingStore.addToken.selector, "addToken");
+          _authorize(functions, StakingStore.addTargetToken.selector, "addTargetToken");
+          _authorize(functions, StakingStore.setStakingRate.selector, "setStakingRate");
+          _authorize(functions, StakingStore.createTarget.selector, "createTarget");
+          _authorize(functions, StakingStore.setLockingPeriod.selector, "setLockingPeriod");
+          _authorize(functions, StakingStore.setRewardRate.selector, "setRewardRate");
+          _authorize(functions, StakingStore.setMaxStakedAmount.selector, "setMaxStakedAmount");
+          _authorize(functions, StakingStore.refillRewardReserves.selector, "refillRewardReserves");
+          _authorize(functions, StakingStore.withdrawRewardReserves.selector, "withdrawRewardReserves");
+          _authorize(functions, StakingStore.increaseTotalValueLocked.selector, "increaseTotalValueLocked");
+          _authorize(functions, StakingStore.decreaseTotalValueLocked.selector, "decreaseTotalValueLocked");
+          _authorize(functions, StakingStore.createStake.selector, "createStake");
+          _authorize(functions, StakingStore.stake.selector, "stake");
+          _authorize(functions, StakingStore.unstake.selector, "unstake");
+          _authorize(functions, StakingStore.updateRewards.selector, "updateRewards");
+          _authorize(functions, StakingStore.restakeRewards.selector, "restakeRewards");
+          _authorize(functions, StakingStore.claimRewards.selector, "claimRewards");
+     }
+
+
+     function _setupStakingThAuthorization() internal {
+          IAccess.FunctionInfo[] storage functions;
+
+          // staking service role
+          functions = _authorizeForTarget(
+               STAKING_TH_TARGET_NAME,
+               RoleIdLib.toGenericServiceRoleId(STAKING()));
+
+          _authorize(functions, TokenHandler.approve.selector, "approve");
+          _authorize(functions, TokenHandler.pullToken.selector, "pullToken");
+          _authorize(functions, TokenHandler.pushToken.selector, "pushToken");
+     }
+}
+