@etherisc/gif-next 0.0.2-ff282a4-523 → 0.0.2-ff3a8a0-504

package/contracts/instance/InstanceAdmin.sol

@@ -0,0 +1,379 @@
+// SPDX-License-Identifier: UNLICENSED
+pragma solidity ^0.8.20;
+
+import {IAccess} from "../authorization/IAccess.sol";
+import {IAuthorization} from "../authorization/IAuthorization.sol";
+import {IInstanceLinkedComponent} from "../shared/IInstanceLinkedComponent.sol";
+import {IRegistry} from "../registry/IRegistry.sol";
+import {IInstance} from "./IInstance.sol";
+
+import {AccessAdmin} from "../authorization/AccessAdmin.sol";
+import {AccessAdminLib} from "../authorization/AccessAdminLib.sol";
+import {AccessManagerCloneable} from "../authorization/AccessManagerCloneable.sol";
+import {ObjectType, INSTANCE} from "../type/ObjectType.sol";
+import {RoleId, ADMIN_ROLE} from "../type/RoleId.sol";
+import {Str} from "../type/String.sol";
+import {VersionPart} from "../type/Version.sol";
+import {INSTANCE_TARGET_NAME, INSTANCE_ADMIN_TARGET_NAME, INSTANCE_STORE_TARGET_NAME, PRODUCT_STORE_TARGET_NAME, BUNDLE_SET_TARGET_NAME, RISK_SET_TARGET_NAME} from "./TargetNames.sol";
+
+
+contract InstanceAdmin is
+    AccessAdmin
+{
+    // onlyInstanceService
+    error ErrorInstanceAdminNotInstanceService(address caller);
+
+    // authorizeFunctions
+    error ErrorInstanceAdminNotComponentOrCustomTarget(address target);
+
+    IInstance internal _instance;
+    IRegistry internal _registry;
+    VersionPart internal _release;
+
+    uint64 internal _customRoleIdNext;
+
+    mapping(address target => RoleId roleId) internal _targetRoleId;
+    uint64 internal _components;
+
+
+    modifier onlyInstanceService() {
+        if (msg.sender != _registry.getServiceAddress(INSTANCE(), getRelease())) {
+            revert ErrorInstanceAdminNotInstanceService(msg.sender);
+        }
+        _;
+    }
+
+    /// @dev Only used for master instance admin.
+    constructor(address accessManager) {
+        initialize(
+            accessManager,
+            "MasterInstanceAdmin");
+    }
+
+
+    /// @dev Completes the initialization of this instance admin using the provided instance, registry and version.
+    /// Important: Initialization of instance admin is only complete after calling this function. 
+    /// Important: The instance MUST be registered and all instance supporting contracts must be wired to this instance.
+    function completeSetup(
+        address registry,
+        address authorization,
+        VersionPart release,
+        address instance
+    )
+        external
+        reinitializer(uint64(release.toInt()))
+        onlyDeployer()
+    {
+        // checks
+        AccessAdminLib.checkIsRegistered(registry, instance, INSTANCE());
+
+        AccessManagerCloneable(
+            authority()).completeSetup(
+                registry, 
+                release); 
+
+        _checkAuthorization(authorization, INSTANCE(), release, false, true);
+
+        // effects
+        _registry = IRegistry(registry);
+        _release = release;
+
+        _instance = IInstance(instance);
+        _authorization = IAuthorization(authorization);
+        _components = 0;
+        _customRoleIdNext = 0;
+
+        // link nft ownability to instance
+        _linkToNftOwnable(instance);
+
+        // setup instance targets
+        _createInstanceTargets(_authorization.getMainTargetName());
+
+        // setup non-contract roles
+        _setupServiceRoles(_authorization);
+        _createRoles(_authorization);
+
+        // authorize functions of instance contracts
+        _createTargetAuthorizations(_authorization);
+    }
+
+
+    /// @dev grants the service roles to the service addresses based on the authorization specification.
+    /// Service addresses used for the granting are determined by the registry and the release of this instance.
+    function _setupServiceRoles(IAuthorization authorization)
+        internal
+    {
+        ObjectType[] memory serviceDomains = authorization.getServiceDomains();
+
+        for(uint256 i = 0; i < serviceDomains.length; i++) {
+            ObjectType serviceDomain = serviceDomains[i];
+            RoleId serviceRoleId = authorization.getServiceRole(serviceDomain);
+            string memory serviceRoleName = authorization.getRoleName(serviceRoleId);
+
+            // create service role if missing
+            if (!roleExists(serviceRoleId)) {
+                _createRole(
+                    serviceRoleId, 
+                    AccessAdminLib.toRole(
+                        ADMIN_ROLE(), 
+                        IAccess.RoleType.Contract, 
+                        1, 
+                        serviceRoleName));
+            }
+
+            // grant service role to service
+            address service = _registry.getServiceAddress(serviceDomain, _release);
+            _grantRoleToAccount(
+                serviceRoleId,
+                service);
+        }
+    }
+
+
+    function _createInstanceTargets(string memory instanceTargetName)
+        internal
+    {
+        _createManagedTarget(address(_instance), instanceTargetName, TargetType.Instance); 
+        _createManagedTarget(address(this), INSTANCE_ADMIN_TARGET_NAME, TargetType.Instance); 
+        _createManagedTarget(address(_instance.getInstanceStore()), INSTANCE_STORE_TARGET_NAME, TargetType.Instance); 
+        _createManagedTarget(address(_instance.getProductStore()), PRODUCT_STORE_TARGET_NAME, TargetType.Instance);
+        _createManagedTarget(address(_instance.getBundleSet()), BUNDLE_SET_TARGET_NAME, TargetType.Instance); 
+        _createManagedTarget(address(_instance.getRiskSet()), RISK_SET_TARGET_NAME, TargetType.Instance); 
+    }
+
+
+    /// @dev Initializes the authorization for the specified component.
+    /// Important: The component MUST be registered.
+    function initializeComponentAuthorization(
+        address componentAddress,
+        ObjectType expectedType
+    )
+        external
+        restricted()
+    {
+        // checks
+        AccessAdminLib.checkIsRegistered(address(getRegistry()), componentAddress, expectedType);
+
+        IInstanceLinkedComponent component = IInstanceLinkedComponent(componentAddress);
+        IAuthorization authorization = component.getAuthorization();
+        _checkAuthorization(address(authorization), expectedType, getRelease(), false, false);
+
+        // effects
+        _createRoles(authorization);
+        _createManagedTarget(componentAddress, authorization.getMainTargetName(), TargetType.Component);
+        _createTargetAuthorizations(authorization);
+
+        // increase component count
+        _components++;
+    }
+
+    function getRelease()
+        public
+        view
+        override
+        returns (VersionPart release)
+    {
+        return _release;
+    }
+
+
+    /// @dev Creates a custom role.
+    function createRole(
+        string memory name,
+        RoleId adminRoleId,
+        uint32 maxMemberCount
+    )
+        external
+        restricted()
+        returns (RoleId roleId)
+    {
+        // check role does not yet exist
+        if (roleExists(name)) {
+            revert ErrorAccessAdminRoleAlreadyCreated(
+                getRoleForName(name),
+                name);
+        }
+
+        // create roleId
+        roleId = AccessAdminLib.getCustomRoleId(_customRoleIdNext++);
+
+        // create role
+        _createRole(
+            roleId, 
+            AccessAdminLib.toRole(
+                adminRoleId, 
+                IAccess.RoleType.Custom, 
+                maxMemberCount, 
+                name));
+    }
+
+
+    /// @dev Activtes/pauses the specified role.
+    function setRoleActive(RoleId roleId, bool active)
+        external
+        restricted()
+    {
+        _setRoleActive(roleId, active);
+    }
+
+
+    /// @dev Grants the provided role to the specified account
+    function grantRole(
+        RoleId roleId, 
+        address account)
+        external
+        restricted()
+    {
+        _grantRoleToAccount(roleId, account);
+    }
+
+
+    /// @dev Revokes the provided role from the specified account
+    function revokeRole(
+        RoleId roleId, 
+        address account)
+        external
+        restricted()
+    {
+        _revokeRoleFromAccount(roleId, account);
+    }
+
+
+    /// @dev Create a new custom target.
+    /// The target needs to be an access managed contract.
+    function createTarget(
+        address target, 
+        string memory name
+    )
+        external
+        restricted()
+        returns (RoleId contractRoleId)
+    {
+        return _createManagedTarget(
+            target, 
+            name, 
+            TargetType.Custom);
+    }
+
+
+    /// @dev Add function authorizations for the specified component or custom target.
+    function authorizeFunctions(
+        address target,
+        RoleId roleId,
+        IAccess.FunctionInfo[] memory functions
+    )
+        external
+        restricted()
+    {
+        _checkComponentOrCustomTarget(target);
+        _authorizeTargetFunctions(target, roleId, functions, true);
+    }
+
+
+    /// @dev Removes function authorizations for the specified component or custom target.
+    function unauthorizeFunctions(
+        address target,
+        IAccess.FunctionInfo[] memory functions
+    )
+        external
+        restricted()
+    {
+        _checkComponentOrCustomTarget(target);
+        _authorizeTargetFunctions(target, ADMIN_ROLE(), functions, false);
+    }
+
+
+    /// @dev locks the instance and all its releated targets including component and custom targets.
+    function setInstanceLocked(bool locked)
+        external
+        // not restricted(): need to operate on locked instances to unlock instance
+        onlyInstanceService()
+    {
+        AccessManagerCloneable accessManager = AccessManagerCloneable(authority());
+        accessManager.setLocked(locked);
+    }
+
+
+    function setTargetLocked(address target, bool locked) 
+        external 
+        // not restricted(): might need to operate on targets while instance is locked
+        onlyInstanceService()
+    {
+        _setTargetLocked(target, locked);
+    }
+
+
+    function setComponentLocked(address target, bool locked) 
+        external 
+        restricted()
+    {
+        _setTargetLocked(target, locked);
+    }
+
+    /// @dev Returns the number of components that have been registered with this instance.   
+    function components() 
+        external 
+        view 
+        returns (uint64)
+    {
+        return _components;
+    }
+
+    /// @dev Returns the instance authorization specification used to set up this instance admin.
+    function getInstanceAuthorization()
+        external
+        view
+        returns (IAuthorization instanceAuthorizaion)
+    {
+        return _authorization;
+    }
+
+    // ------------------- Internal functions ------------------- //
+
+    function _createRoles(IAuthorization authorization)
+        internal
+    {
+        RoleId[] memory roles = authorization.getRoles();
+        RoleId mainTargetRoleId = authorization.getTargetRole(
+            authorization.getMainTarget());
+
+        for(uint256 i = 0; i < roles.length; i++) {
+            RoleId roleId = roles[i];
+
+            // skip main target role, create role if not exists
+            if (roleId != mainTargetRoleId && !roleExists(roleId)) {
+                _createRole(
+                    roleId,
+                    authorization.getRoleInfo(roleId));
+            }
+        }
+    }
+
+
+    function _createTargetAuthorizations(IAuthorization authorization)
+        internal
+    {
+        Str[] memory targets = authorization.getTargets();
+        Str target;
+
+        for(uint256 i = 0; i < targets.length; i++) {
+            target = targets[i];
+            RoleId[] memory authorizedRoles = authorization.getAuthorizedRoles(target);
+
+            for(uint256 j = 0; j < authorizedRoles.length; j++) {
+                _authorizeFunctions(authorization, target, authorizedRoles[j]);
+            }
+        }
+    }
+
+
+    function _checkComponentOrCustomTarget(address target) 
+        internal
+        view
+    {
+        IAccess.TargetType targetType = getTargetInfo(target).targetType;
+        if (targetType != TargetType.Component && targetType != TargetType.Custom) {
+            revert ErrorInstanceAdminNotComponentOrCustomTarget(target);
+        }
+    }
+}

package/contracts/instance/InstanceAuthorizationV3.sol

@@ -0,0 +1,275 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IAccess} from "../authorization/IAccess.sol";
+import {IInstance} from "../instance/Instance.sol";
+
+import {AccessAdminLib} from "../authorization/AccessAdminLib.sol";
+import {Authorization} from "../authorization/Authorization.sol";
+import {ACCOUNTING, ORACLE, POOL, INSTANCE, COMPONENT, DISTRIBUTION, APPLICATION, POLICY, CLAIM, BUNDLE, RISK} from "../../contracts/type/ObjectType.sol";
+import {BundleSet} from "../instance/BundleSet.sol";
+import {InstanceAdmin} from "../instance/InstanceAdmin.sol";
+import {InstanceStore} from "../instance/InstanceStore.sol";
+import {INSTANCE_TARGET_NAME, INSTANCE_ADMIN_TARGET_NAME, INSTANCE_STORE_TARGET_NAME, PRODUCT_STORE_TARGET_NAME, BUNDLE_SET_TARGET_NAME, RISK_SET_TARGET_NAME} from "./TargetNames.sol";
+import {ProductStore} from "../instance/ProductStore.sol";
+import {ADMIN_ROLE, INSTANCE_OWNER_ROLE, PUBLIC_ROLE} from "../type/RoleId.sol";
+import {RiskSet} from "../instance/RiskSet.sol"; 
+
+
+contract InstanceAuthorizationV3
+     is Authorization
+{
+
+     string public constant INSTANCE_ROLE_NAME = "InstanceRole";
+     string public constant INSTANCE_OWNER_ROLE_NAME = "InstanceOwnerRole";
+
+     constructor()
+          Authorization(
+               INSTANCE_TARGET_NAME, 
+               INSTANCE(), 
+               3, 
+               COMMIT_HASH,
+               false, 
+               false)
+     { }
+
+     function _setupServiceTargets() internal virtual override {
+          // service targets relevant to instance
+          _authorizeServiceDomain(INSTANCE(), address(10));
+          _authorizeServiceDomain(ACCOUNTING(), address(11));
+          _authorizeServiceDomain(COMPONENT(), address(12));
+          _authorizeServiceDomain(DISTRIBUTION(), address(13));
+          _authorizeServiceDomain(ORACLE(), address(14));
+          _authorizeServiceDomain(POOL(), address(15));
+          _authorizeServiceDomain(BUNDLE(), address(16));
+          _authorizeServiceDomain(RISK(), address(17));
+          _authorizeServiceDomain(APPLICATION(), address(18));
+          _authorizeServiceDomain(POLICY(), address(19));
+          _authorizeServiceDomain(CLAIM(), address(20));
+     }
+
+     function _setupRoles()
+          internal
+          override
+     {
+          _addRole(
+               INSTANCE_OWNER_ROLE(),
+               AccessAdminLib.toRole(
+                    ADMIN_ROLE(),
+                    RoleType.Custom,
+                    0, // max member count special case: instance nft owner is sole role owner
+                    INSTANCE_OWNER_ROLE_NAME));
+     }
+
+     function _setupTargets()
+          internal
+          override
+     {
+          // instance supporting targets
+          _addTarget(INSTANCE_ADMIN_TARGET_NAME);
+          _addTarget(INSTANCE_STORE_TARGET_NAME);
+          _addTarget(PRODUCT_STORE_TARGET_NAME);
+          _addTarget(BUNDLE_SET_TARGET_NAME);
+          _addTarget(RISK_SET_TARGET_NAME);
+     }
+
+
+     function _setupTargetAuthorizations()
+          internal
+          override
+     {
+          _setupInstanceAuthorization();
+          _setupInstanceAdminAuthorization();
+          _setupInstanceStoreAuthorization();
+          _setupProductStoreAuthorization();
+          _setupBundleSetAuthorization();
+          _setUpRiskSetAuthorization();
+     }
+
+
+     function _setupBundleSetAuthorization()
+          internal
+     {
+          IAccess.FunctionInfo[] storage functions;
+
+          // authorize bundle service role
+          functions = _authorizeForTarget(BUNDLE_SET_TARGET_NAME, getServiceRole(BUNDLE()));
+          _authorize(functions, BundleSet.add.selector, "add");
+          _authorize(functions, BundleSet.lock.selector, "lock");
+          _authorize(functions, BundleSet.unlock.selector, "unlock");
+
+          // authorize bundle service role
+          functions = _authorizeForTarget(BUNDLE_SET_TARGET_NAME, getServiceRole(POLICY()));
+          _authorize(functions, BundleSet.linkPolicy.selector, "linkPolicy");
+          _authorize(functions, BundleSet.unlinkPolicy.selector, "unlinkPolicy");
+     }
+
+     function _setUpRiskSetAuthorization()
+          internal
+     {
+          IAccess.FunctionInfo[] storage functions;
+
+          // authorize risk service role
+          functions = _authorizeForTarget(RISK_SET_TARGET_NAME, getServiceRole(RISK()));
+          _authorize(functions, RiskSet.add.selector, "add");
+          _authorize(functions, RiskSet.deactivate.selector, "deactivate");
+          _authorize(functions, RiskSet.activate.selector, "activate");
+
+          // authorize policy service role
+          functions = _authorizeForTarget(RISK_SET_TARGET_NAME, getServiceRole(POLICY()));
+          _authorize(functions, RiskSet.linkPolicy.selector, "linkPolicy");
+          _authorize(functions, RiskSet.unlinkPolicy.selector, "unlinkPolicy");
+     }
+
+
+     function _setupInstanceAuthorization()
+          internal
+     {
+          IAccess.FunctionInfo[] storage functions;
+
+          // authorize instance service role
+          functions = _authorizeForTarget(INSTANCE_TARGET_NAME, PUBLIC_ROLE());
+          _authorize(functions, IInstance.registerProduct.selector, "registerProduct");
+          _authorize(functions, IInstance.upgradeInstanceReader.selector, "upgradeInstanceReader");
+
+          // staking
+          _authorize(functions, IInstance.setStakingLockingPeriod.selector, "setStakingLockingPeriod");
+          _authorize(functions, IInstance.setStakingRewardRate.selector, "setStakingRewardRate");
+          _authorize(functions, IInstance.setStakingMaxAmount.selector, "setStakingMaxAmount");
+          _authorize(functions, IInstance.refillStakingRewardReserves.selector, "refillStakingRewardReserves");
+          _authorize(functions, IInstance.withdrawStakingRewardReserves.selector, "withdrawStakingRewardReserves");
+
+          // custom authz
+          _authorize(functions, IInstance.createRole.selector, "createRole");
+          _authorize(functions, IInstance.setRoleActive.selector, "setRoleActive");
+          _authorize(functions, IInstance.grantRole.selector, "grantRole");
+          _authorize(functions, IInstance.revokeRole.selector, "revokeRole");
+          _authorize(functions, IInstance.createTarget.selector, "createTarget");
+          _authorize(functions, IInstance.authorizeFunctions.selector, "authorizeFunctions");
+          _authorize(functions, IInstance.unauthorizeFunctions.selector, "unauthorizeFunctions");
+
+          // authorize instance service role
+          functions = _authorizeForTarget(INSTANCE_TARGET_NAME, getServiceRole(INSTANCE()));
+          _authorize(functions, IInstance.setInstanceReader.selector, "setInstanceReader");
+     }
+
+
+     function _setupInstanceAdminAuthorization()
+          internal
+     {
+          IAccess.FunctionInfo[] storage functions;
+
+          // authorize component service role
+          functions = _authorizeForTarget(INSTANCE_ADMIN_TARGET_NAME, getServiceRole(INSTANCE()));
+          _authorize(functions, InstanceAdmin.createRole.selector, "createRole");
+          _authorize(functions, InstanceAdmin.setRoleActive.selector, "setRoleActive");
+          _authorize(functions, InstanceAdmin.grantRole.selector, "grantRole");
+          _authorize(functions, InstanceAdmin.revokeRole.selector, "revokeRole");
+
+          _authorize(functions, InstanceAdmin.createTarget.selector, "createTarget");
+          _authorize(functions, InstanceAdmin.authorizeFunctions.selector, "authorizeFunctions");
+          _authorize(functions, InstanceAdmin.unauthorizeFunctions.selector, "unauthorizeFunctions");
+          _authorize(functions, InstanceAdmin.setTargetLocked.selector, "setTargetLocked");
+          _authorize(functions, InstanceAdmin.setInstanceLocked.selector, "setInstanceLocked");
+
+          // authorize component service role
+          functions = _authorizeForTarget(INSTANCE_ADMIN_TARGET_NAME, getServiceRole(COMPONENT()));
+          _authorize(functions, InstanceAdmin.initializeComponentAuthorization.selector, "initializeComponentAuthoriz");
+          _authorize(functions, InstanceAdmin.setComponentLocked.selector, "setComponentLocked");
+     }
+
+
+     function _setupInstanceStoreAuthorization()
+          internal
+     {
+          IAccess.FunctionInfo[] storage functions;
+
+          // authorize accounting service role
+          functions = _authorizeForTarget(INSTANCE_STORE_TARGET_NAME, getServiceRole(ACCOUNTING()));
+          _authorize(functions, InstanceStore.increaseBalance.selector, "increaseBalance");
+          _authorize(functions, InstanceStore.decreaseBalance.selector, "decreaseBalance");
+          _authorize(functions, InstanceStore.increaseFees.selector, "increaseFees");
+          _authorize(functions, InstanceStore.decreaseFees.selector, "decreaseFees");
+
+          // authorize component service role
+          functions = _authorizeForTarget(INSTANCE_STORE_TARGET_NAME, getServiceRole(COMPONENT()));
+          _authorize(functions, InstanceStore.createComponent.selector, "createComponent");
+          _authorize(functions, InstanceStore.updateComponent.selector, "updateComponent");
+          _authorize(functions, InstanceStore.createPool.selector, "createPool");
+          
+          // authorize distribution service role
+          functions = _authorizeForTarget(INSTANCE_STORE_TARGET_NAME, getServiceRole(DISTRIBUTION()));
+          _authorize(functions, InstanceStore.createDistributorType.selector, "createDistributorType");
+          _authorize(functions, InstanceStore.updateDistributorType.selector, "updateDistributorType");
+          _authorize(functions, InstanceStore.updateDistributorTypeState.selector, "updateDistributorTypeState");
+          _authorize(functions, InstanceStore.createDistributor.selector, "createDistributor");
+          _authorize(functions, InstanceStore.updateDistributor.selector, "updateDistributor");
+          _authorize(functions, InstanceStore.updateDistributorState.selector, "updateDistributorState");
+          _authorize(functions, InstanceStore.createReferral.selector, "createReferral");
+          _authorize(functions, InstanceStore.updateReferral.selector, "updateReferral");
+          _authorize(functions, InstanceStore.updateReferralState.selector, "updateReferralState");
+
+          // authorize oracle service role
+          functions = _authorizeForTarget(INSTANCE_STORE_TARGET_NAME, getServiceRole(ORACLE()));
+          _authorize(functions, InstanceStore.createRequest.selector, "createRequest");
+          _authorize(functions, InstanceStore.updateRequest.selector, "updateRequest");
+          _authorize(functions, InstanceStore.updateRequestState.selector, "updateRequestState");
+
+          // authorize pool service role
+          functions = _authorizeForTarget(INSTANCE_STORE_TARGET_NAME, getServiceRole(POOL()));
+          _authorize(functions, InstanceStore.updatePool.selector, "updatePool");
+
+          // authorize bundle service role
+          functions = _authorizeForTarget(INSTANCE_STORE_TARGET_NAME, getServiceRole(BUNDLE()));
+          _authorize(functions, InstanceStore.createBundle.selector, "createBundle");
+          _authorize(functions, InstanceStore.updateBundle.selector, "updateBundle");
+          _authorize(functions, InstanceStore.updateBundleState.selector, "updateBundleState");
+          _authorize(functions, InstanceStore.increaseLocked.selector, "increaseLocked");
+          _authorize(functions, InstanceStore.decreaseLocked.selector, "decreaseLocked");
+
+     }
+
+     function _setupProductStoreAuthorization()
+          internal
+     {
+          IAccess.FunctionInfo[] storage functions;
+
+          functions = _authorizeForTarget(PRODUCT_STORE_TARGET_NAME, getServiceRole(COMPONENT()));
+          _authorize(functions, ProductStore.createProduct.selector, "createProduct");
+          _authorize(functions, ProductStore.updateProduct.selector, "updateProduct");
+          _authorize(functions, ProductStore.createFee.selector, "createFee");
+          _authorize(functions, ProductStore.updateFee.selector, "updateFee");
+
+          // authorize application service role
+          functions = _authorizeForTarget(PRODUCT_STORE_TARGET_NAME, getServiceRole(APPLICATION()));
+          _authorize(functions, ProductStore.createApplication.selector, "createApplication");
+          _authorize(functions, ProductStore.updateApplication.selector, "updateApplication");
+          _authorize(functions, ProductStore.updateApplicationState.selector, "updateApplicationState");
+
+          // authorize policy service role
+          functions = _authorizeForTarget(PRODUCT_STORE_TARGET_NAME, getServiceRole(POLICY()));
+          _authorize(functions, ProductStore.updatePolicy.selector, "updatePolicy");
+          _authorize(functions, ProductStore.updatePolicyState.selector, "updatePolicyState");
+
+          // authorize policy service role
+          functions = _authorizeForTarget(PRODUCT_STORE_TARGET_NAME, getServiceRole(POLICY()));
+          _authorize(functions, ProductStore.createPremium.selector, "createPremium");
+          _authorize(functions, ProductStore.updatePremiumState.selector, "updatePremiumState");
+
+          // authorize risk service role
+          functions = _authorizeForTarget(PRODUCT_STORE_TARGET_NAME, getServiceRole(RISK()));
+          _authorize(functions, ProductStore.createRisk.selector, "createRisk");
+          _authorize(functions, ProductStore.updateRisk.selector, "updateRisk");
+          _authorize(functions, ProductStore.updateRiskState.selector, "updateRiskState");
+
+          // authorize claim service role
+          functions = _authorizeForTarget(PRODUCT_STORE_TARGET_NAME, getServiceRole(CLAIM()));
+          _authorize(functions, ProductStore.updatePolicyClaims.selector, "updatePolicyClaims");
+          _authorize(functions, ProductStore.createClaim.selector, "createClaim");
+          _authorize(functions, ProductStore.updateClaim.selector, "updateClaim");
+          _authorize(functions, ProductStore.createPayout.selector, "createPayout");
+          _authorize(functions, ProductStore.updatePayout.selector, "updatePayout");
+          _authorize(functions, ProductStore.updatePayoutState.selector, "updatePayoutState");
+     }
+}
+