@etherisc/gif-next 0.0.2-fe77319 → 0.0.2-ff282a4-523

package/contracts/shared/Versionable.sol

@@ -0,0 +1,59 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Initializable} from "@openzeppelin/contracts-upgradeable/proxy/utils/Initializable.sol";
+
+import {IVersionable} from "./IVersionable.sol";
+import {Version, VersionLib} from "../type/Version.sol";
+
+
+abstract contract Versionable is 
+    Initializable,
+    IVersionable 
+{
+    constructor() {
+        _disableInitializers();
+    }
+
+    function initializeVersionable(
+        address activatedBy,
+        bytes memory data
+    )
+        public
+        initializer
+    {
+        _initialize(activatedBy, data);
+    }
+
+    function upgradeVersionable(
+        bytes memory data
+    )
+        external
+        reinitializer(VersionLib.toUint64(getVersion()))
+    {
+        _upgrade(data);
+    }
+
+    function getVersion() public pure virtual returns(Version);
+
+    // IMPORTANT each version must implement this function 
+    // each implementation MUST use onlyInitialising modifier
+    // each implementation MUST call intializers of all base contracts...
+    function _initialize(address owner, bytes memory data) 
+        internal
+        onlyInitializing
+        virtual 
+    {
+        revert();
+    }
+
+    // IMPORTANT each version except version "1" must implement this function 
+    // each implementation MUST use onlyInitialising modifier
+    function _upgrade(bytes memory data)
+        internal
+        onlyInitializing
+        virtual
+    {
+        revert();
+    }
+}

package/contracts/staking/IStaking.sol

@@ -0,0 +1,15 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IAccessManaged} from "@openzeppelin/contracts/access/manager/IAccessManaged.sol";
+
+import {IRegisterable} from "../shared/IRegisterable.sol";
+import {IVersionable} from "../shared/IVersionable.sol";
+import {ObjectType} from "../type/ObjectType.sol";
+
+interface IStaking is 
+    IRegisterable,
+    IVersionable,
+    IAccessManaged
+{
+}

package/contracts/staking/IStakingService.sol

@@ -0,0 +1,105 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {Amount} from "../type/Amount.sol";
+import {IService} from "../shared/IService.sol";
+import {IStaking} from "./IStaking.sol";
+import {NftId} from "../type/NftId.sol";
+import {ObjectType} from "../type/ObjectType.sol";
+import {Seconds} from "../type/Seconds.sol";
+import {Timestamp} from "../type/Timestamp.sol";
+
+
+interface IStakingService is IService
+{
+
+    error ErrorStakingServiceNotStaking(address stakingAddress);
+    error ErrorStakingServiceNotSupportingIStaking(address stakingAddress);
+
+    /// @dev create a new stake with amount DIP to the specified target
+    /// returns the id of the newly minted stake nft
+    /// permissionless function
+    function create(
+        NftId targetNftId,
+        Amount amount
+    )
+        external
+        returns (
+            NftId stakeNftId
+        );
+
+    /// @dev increase an existing stake by amount DIP
+    /// updates the staking reward amount
+    /// function restricted to the current stake owner
+    function stake(
+        NftId stakeNftId,
+        Amount amount
+    )
+        external;
+
+    /// @dev decrease an existing stake by amount DIP
+    /// updates the staking reward amount
+    /// function restricted to the current stake owner
+    function unstake(
+        NftId stakeNftId,
+        Amount amount
+    )
+        external;
+
+    /// @dev closes the specified stake
+    /// all related stakes and all accumulated reward DIP are transferred to the current stake holder
+    /// function restricted to the current stake owner
+    function close(
+        NftId stakeNftId
+    )
+        external;
+
+    /// @dev re-stakes the current staked DIP as well as all accumulated rewards to the new stake target.
+    /// all related stakes and all accumulated reward DIP are transferred to the current stake holder
+    /// function restricted to the current stake owner
+    function reStake(
+        NftId stakeNftId,
+        NftId newTargetNftId
+    )
+        external
+        returns (
+            NftId newStakeNftId,
+            Timestamp unlockedAt
+        );
+
+    /// @dev increases the total value locked amount for the specified target by the provided token amount.
+    /// function is called when a new policy is collateralized
+    /// function restricted to the pool service
+    function increaseTotalValueLocked(
+        NftId targetNftId,
+        address token,
+        Amount amount
+    )
+        external
+        returns (Amount totalValueLocked);
+
+
+    /// @dev decreases the total value locked amount for the specified target by the provided token amount.
+    /// function is called when a new policy is closed or payouts are executed
+    /// function restricted to the pool service
+    function decreaseTotalValueLocked(
+        NftId targetNftId,
+        address token,
+        Amount amount
+    )
+        external
+        returns (Amount totalValueLocked);
+
+    /// @dev sets total value locked data for a target contract on a different chain.
+    /// this is done via CCIP (cross chain communication) 
+    function setTotalValueLocked(
+        NftId targetNftId,
+        address token,
+        Amount amount
+    )
+        external;
+
+    function getStaking()
+        external
+        returns (IStaking staking);
+}

package/contracts/staking/Staking.sol

@@ -0,0 +1,64 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {AccessManagedUpgradeable} from "@openzeppelin/contracts-upgradeable/access/manager/AccessManagedUpgradeable.sol";
+import {IAccessManaged} from "@openzeppelin/contracts/access/manager/IAccessManaged.sol";
+
+import {ObjectType, REGISTRY, STAKING} from "../type/ObjectType.sol";
+import {NftId, zeroNftId} from "../type/NftId.sol";
+import {Version, VersionLib, VersionPartLib} from "../type/Version.sol";
+
+import {IStaking} from "./IStaking.sol";
+import {IVersionable} from "../shared/IVersionable.sol";
+import {Versionable} from "../shared/Versionable.sol";
+import {Registerable} from "../shared/Registerable.sol";
+
+import {IRegistry} from "../registry/IRegistry.sol";
+
+contract Staking is 
+    Registerable,
+    Versionable,
+    AccessManagedUpgradeable,
+    IStaking
+{
+
+    uint8 private constant GIF_MAJOR_VERSION = 3;
+
+    // from Versionable
+    function getVersion()
+        public 
+        pure 
+        virtual override (IVersionable, Versionable)
+        returns(Version)
+    {
+        return VersionLib.toVersion(GIF_MAJOR_VERSION,0,0);
+    }
+
+    function _initialize(
+        address owner, 
+        bytes memory data
+    )
+        internal
+        virtual override
+        initializer
+    {
+        (
+            address registryAddress,
+            address initialAuthority,
+            address initialOwner
+        ) = abi.decode(data, (address, address, address));
+
+        initializeRegisterable(
+            registryAddress, 
+            IRegistry(registryAddress).getNftId(), 
+            STAKING(), 
+            false, // is interceptor
+            initialOwner, 
+            ""); // data
+
+        __AccessManaged_init(initialAuthority);
+
+        registerInterface(type(IAccessManaged).interfaceId);
+        registerInterface(type(IStaking).interfaceId);
+    }
+}

package/contracts/staking/StakingManager.sol

@@ -0,0 +1,44 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IVersionable} from "../shared/IVersionable.sol";
+import {ProxyManager} from "../shared/ProxyManager.sol";
+import {Staking} from "./Staking.sol";
+
+contract StakingManager is
+    ProxyManager
+{
+
+    Staking private _staking;
+
+    /// @dev initializes proxy manager with service implementation 
+    constructor(
+        address registryAddress,
+        address initialAuthority
+    )
+        ProxyManager(registryAddress)
+    {
+        Staking stk = new Staking();
+        address initialOwner = msg.sender;
+
+        bytes memory data = abi.encode(
+            registryAddress, 
+            initialAuthority, 
+            initialOwner);
+
+        IVersionable versionable = deploy(
+            address(stk), 
+            data);
+
+        _staking = Staking(address(versionable));
+    }
+
+    //--- view functions ----------------------------------------------------//
+    function getStaking()
+        external
+        view
+        returns (Staking)
+    {
+        return _staking;
+    }
+}

package/contracts/staking/StakingService.sol

@@ -0,0 +1,204 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {Amount} from "../type/Amount.sol";
+import {IPoolService} from "../pool/IPoolService.sol";
+import {IRegisterable} from "../shared/IRegisterable.sol";
+import {IRegistry} from "../registry/IRegistry.sol";
+import {IRegistryService} from "../registry/IRegistryService.sol";
+import {IStaking} from "./IStaking.sol";
+import {IStakingService} from "./IStakingService.sol";
+import {NftId} from "../type/NftId.sol";
+import {ObjectType, POOL, REGISTRY, STAKE, STAKING} from "../type/ObjectType.sol";
+import {Service} from "../shared/Service.sol";
+import {Timestamp} from "../type/Timestamp.sol";
+
+
+contract StakingService is 
+    Service, 
+    IStakingService
+{
+    // TODO decide and implement string spec for location calculation
+    // keccak256(abi.encode(uint256(keccak256("gif-next.contracts.shared.StakingService.sol")) - 1)) & ~bytes32(uint256(0xff));
+    bytes32 public constant STAKING_SERVICE_LOCATION_V1 = 0x6548005c3f4340f82f348c576c0ff69f7f529cadd5ad41f96aae61abceeaa300;
+
+    struct StakingServiceStorage {
+        IStaking _staking;
+    }
+
+    function getDomain() public pure override returns(ObjectType) {
+        return STAKING();
+    }
+
+
+    function create(
+        NftId targetNftId,
+        Amount amount
+    )
+        external
+        virtual
+        returns (
+            NftId stakeNftId
+        )
+    {
+
+    }
+
+
+    function stake(
+        NftId stakeNftId,
+        Amount amount
+    )
+        external
+        virtual
+    {
+
+    }
+
+
+    function unstake(
+        NftId stakeNftId,
+        Amount amount
+    )
+        external
+        virtual
+    {
+
+    }
+
+    function close(
+        NftId stakeNftId
+    )
+        external
+        virtual
+    {
+
+    }
+
+    function reStake(
+        NftId stakeNftId,
+        NftId newTargetNftId
+    )
+        external
+        virtual
+        returns (
+            NftId newStakeNftId,
+            Timestamp unlockedAt
+        )
+    {
+
+    }
+
+
+    function increaseTotalValueLocked(
+        NftId targetNftId,
+        address token,
+        Amount amount
+    )
+        external
+        virtual
+        returns (Amount totalValueLocked)
+    {
+
+    }
+
+
+    function decreaseTotalValueLocked(
+        NftId targetNftId,
+        address token,
+        Amount amount
+    )
+        external
+        virtual
+        returns (Amount totalValueLocked)
+    {
+
+    }
+
+
+    function setTotalValueLocked(
+        NftId targetNftId,
+        address token,
+        Amount amount
+    )
+        external
+        virtual
+    {
+
+    }
+
+    function getStaking()
+        external
+        virtual
+        returns (IStaking staking)
+    {
+        return _getStakingServiceStorage()._staking;
+    }
+
+
+    function _initialize(
+        address owner, 
+        bytes memory data
+    )
+        internal
+        virtual override
+        initializer()
+    {
+        (
+            address registryAddress,
+            address stakingAddress
+        ) = abi.decode(data, (address, address));
+
+        initializeService(registryAddress, address(0), owner);
+
+        StakingServiceStorage storage $ = _getStakingServiceStorage();
+        $._staking = _registerStaking(stakingAddress);
+
+        registerInterface(type(IStakingService).interfaceId);
+    }
+
+
+    function _registerStaking(
+        address stakingAddress
+    )
+        internal
+        returns (IStaking staking)
+    {
+        // check if provided staking contract is already registred
+        IRegistry.ObjectInfo memory stakingInfo = getRegistry().getObjectInfo(stakingAddress);
+        if (stakingInfo.nftId.gtz()) {
+            // registered object but wrong type
+            if (stakingInfo.objectType != STAKING()) {
+                revert ErrorStakingServiceNotStaking(stakingAddress);
+            }
+
+            // return correctly registered staking contract
+            return IStaking(stakingAddress);
+        }
+
+        // check that contract implements IStaking
+        if(!IStaking(stakingAddress).supportsInterface(type(IStaking).interfaceId)) {
+            revert ErrorStakingServiceNotSupportingIStaking(stakingAddress);
+        }
+
+        address owner = msg.sender;
+        IRegistryService(
+            _getServiceAddress(REGISTRY())).registerStaking(
+                IRegisterable(stakingAddress),
+                owner);
+
+        return IStaking(stakingAddress);
+    }
+
+
+    function _getServiceAddress(ObjectType domain) internal view returns (address) {
+        return getRegistry().getServiceAddress(domain, getVersion().toMajorPart());
+    }
+
+
+    function _getStakingServiceStorage() private pure returns (StakingServiceStorage storage $) {
+        assembly {
+            $.slot := STAKING_SERVICE_LOCATION_V1
+        }
+    }
+}

package/contracts/staking/StakingServiceManager.sol

@@ -0,0 +1,41 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IRegistry} from "../registry/IRegistry.sol";
+import {IVersionable} from "../shared/IVersionable.sol";
+import {ProxyManager} from "../shared/ProxyManager.sol";
+import {StakingService} from "./StakingService.sol";
+
+contract StakingServiceManager is
+    ProxyManager
+{
+
+    StakingService private _stakingService;
+
+    /// @dev initializes proxy manager with service implementation 
+    constructor(
+        address registryAddress
+    )
+        ProxyManager(registryAddress)
+    {
+        StakingService svc = new StakingService();
+        bytes memory data = abi.encode(
+            registryAddress, 
+            IRegistry(registryAddress).getStakingAddress());
+
+        IVersionable versionable = deploy(
+            address(svc), 
+            data);
+
+        _stakingService = StakingService(address(versionable));
+    }
+
+    //--- view functions ----------------------------------------------------//
+    function getStakingService()
+        external
+        view
+        returns (StakingService)
+    {
+        return _stakingService;
+    }
+}

package/contracts/type/AddressSet.sol

@@ -0,0 +1,58 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+// based on https://github.com/OpenZeppelin/openzeppelin-contracts/blob/master/contracts/utils/structs/EnumerableSet.sol
+library LibAddressSet {
+
+    struct Set {
+        address[] elements;
+        mapping(address element => uint256 index) at;
+    }
+
+    function add(Set storage set, address element) external returns(bool added) {
+        if (set.at[element] == 0) {
+            set.elements.push(element);
+            set.at[element] = set.elements.length;
+            return true;
+        } else {
+            return false;
+        }
+    }
+
+    function remove(Set storage set, address element) external returns(bool removed) {
+        uint256 elementIndex = set.at[element];
+
+        if (elementIndex > 0) {
+            uint256 toDeleteIndex = elementIndex - 1;
+            uint256 lastIndex = set.elements.length - 1;
+
+            if (lastIndex != toDeleteIndex) {
+                address lastElement = set.elements[lastIndex];
+                set.elements[toDeleteIndex] = lastElement;
+                set.at[lastElement] = elementIndex; // Replace lastValue's index to valueIndex
+            }
+
+            set.elements.pop();
+            delete set.at[element];
+            return true;
+        }
+        
+        return false;
+    }
+
+    function isEmpty(Set storage set) external view returns(bool empty) {
+        return set.elements.length == 0;
+    }
+
+    function contains(Set storage set, address element) external view returns(bool inSet) {
+        return set.at[element] > 0;
+    }
+
+    function getLength(Set storage set) external view returns(uint256 length) {
+        return set.elements.length;
+    }
+
+    function getElementAt(Set storage set, uint256 index) external view returns(address element) {
+        return set.elements[index];
+    }
+}

package/contracts/type/Amount.sol

@@ -0,0 +1,109 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {UFixed, UFixedLib} from "./UFixed.sol";
+
+type Amount is uint96;
+
+using {
+    addAmount as +,
+    subAmount as -,
+    eqAmount as ==,
+    ltAmount as <,
+    gtAmount as >,
+    AmountLib.eq,
+    AmountLib.eqz,
+    AmountLib.gtz,
+    AmountLib.toInt,
+    AmountLib.add,
+    AmountLib.toUFixed
+} for Amount global;
+
+function addAmount(Amount a, Amount b) pure returns (Amount) {
+    return AmountLib.add(a, b);
+}
+
+function subAmount(Amount a, Amount b) pure returns (Amount) {
+    return AmountLib.sub(a, b);
+}
+
+function eqAmount(Amount a, Amount b) pure returns (bool) {
+    return AmountLib.eq(a, b);
+}
+
+function ltAmount(Amount a, Amount b) pure returns (bool) {
+    return AmountLib.lt(a, b);
+}
+
+function gtAmount(Amount a, Amount b) pure returns (bool) {
+    return AmountLib.gt(a, b);
+}
+
+library AmountLib {
+
+    error ErrorAmountLibValueTooBig(uint256 amount);
+
+    function zero() public pure returns (Amount) {
+        return Amount.wrap(0);
+    }
+
+    function max() public pure returns (Amount) {
+        return Amount.wrap(_max());
+    }
+
+    /// @dev converts the uint amount into Amount
+    /// function reverts if value is exceeding max Amount value
+    function toAmount(uint256 amount) public pure returns (Amount) {
+        if(amount > _max()) {
+            revert ErrorAmountLibValueTooBig(amount);
+        }
+
+        return Amount.wrap(uint96(amount));
+    }
+
+    /// @dev return true if amount equals 0
+    function eqz(Amount amount) public pure returns (bool) {
+        return Amount.unwrap(amount) == 0;
+    }
+
+    /// @dev return true if amount1 equals amount2
+    function eq(Amount amount1, Amount amount2) public pure returns (bool) {
+        return Amount.unwrap(amount1) == Amount.unwrap(amount2);
+    }
+
+    /// @dev return true if amount a1 is smaller than a2
+    function lt(Amount a1, Amount a2) public pure returns (bool) {
+        return Amount.unwrap(a1) < Amount.unwrap(a2);
+    }
+
+    /// @dev return true if amount a1 is larger than a2
+    function gt(Amount a1, Amount a2) public pure returns (bool) {
+        return Amount.unwrap(a1) > Amount.unwrap(a2);
+    }
+
+    /// @dev return true if amount is larger than 0
+    function gtz(Amount amount) public pure returns (bool) {
+        return Amount.unwrap(amount) > 0;
+    }
+
+    function add(Amount a1, Amount a2) public pure returns (Amount) {
+        return Amount.wrap(Amount.unwrap(a1) + Amount.unwrap(a2));
+    }
+
+    function sub(Amount a1, Amount a2) public pure returns (Amount) {
+        return Amount.wrap(Amount.unwrap(a1) - Amount.unwrap(a2));
+    }
+
+    function toInt(Amount amount) public pure returns (uint256) {
+        return uint256(uint96(Amount.unwrap(amount)));
+    }
+
+    function toUFixed(Amount amount) public pure returns (UFixed) {
+        return UFixedLib.toUFixed(Amount.unwrap(amount));
+    }
+
+    function _max() internal pure returns (uint96) {
+        // IMPORTANT: type nees to match with actual definition for Amount
+        return type(uint96).max;
+    }
+}