@etherisc/gif-next 0.0.2-fe77319 → 0.0.2-ff282a4-523

package/contracts/product/ProductService.sol

@@ -0,0 +1,210 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IRegistry} from "../registry/IRegistry.sol";
+import {IProductComponent} from "./IProductComponent.sol";
+import {Product} from "./Product.sol";
+import {IComponent} from "../shared/IComponent.sol";
+import {IPoolComponent} from "../pool/IPoolComponent.sol";
+import {IDistributionComponent} from "../distribution/IDistributionComponent.sol";
+import {IInstance} from "../instance/IInstance.sol";
+import {IPolicy} from "../instance/module/IPolicy.sol";
+import {IRisk} from "../instance/module/IRisk.sol";
+import {IBundle} from "../instance/module/IBundle.sol";
+import {IProductService} from "./IProductService.sol";
+import {ITreasury} from "../instance/module/ITreasury.sol";
+import {ISetup} from "../instance/module/ISetup.sol";
+
+import {TokenHandler} from "../shared/TokenHandler.sol";
+
+import {IVersionable} from "../shared/IVersionable.sol";
+import {Versionable} from "../shared/Versionable.sol";
+
+import {Timestamp, zeroTimestamp} from "../type/Timestamp.sol";
+import {UFixed, UFixedLib} from "../type/UFixed.sol";
+import {Blocknumber, blockNumber} from "../type/Blocknumber.sol";
+import {ObjectType, PRODUCT, POOL, POLICY} from "../type/ObjectType.sol";
+import {APPLIED, ACTIVE, KEEP_STATE} from "../type/StateId.sol";
+import {NftId, NftIdLib, zeroNftId} from "../type/NftId.sol";
+import {Fee, FeeLib} from "../type/Fee.sol";
+import {ReferralId} from "../type/Referral.sol";
+import {RiskId} from "../type/RiskId.sol";
+import {StateId} from "../type/StateId.sol";
+import {Version, VersionLib} from "../type/Version.sol";
+import {RoleId, PRODUCT_OWNER_ROLE} from "../type/RoleId.sol";
+
+import {IService} from "../shared/IService.sol";
+import {Service} from "../shared/Service.sol";
+import {ComponentService} from "../shared/ComponentService.sol";
+import {IProductService} from "./IProductService.sol";
+import {InstanceReader} from "../instance/InstanceReader.sol";
+import {IPoolService} from "../pool/PoolService.sol";
+
+// TODO or name this ProtectionService to have Product be something more generic (loan, savings account, ...)
+contract ProductService is ComponentService, IProductService {
+    using NftIdLib for NftId;
+
+    IPoolService internal _poolService;
+
+    event LogProductServiceSender(address sender);
+
+    function _initialize(
+        address owner, 
+        bytes memory data
+    )
+        internal
+        initializer
+        virtual override
+    {
+        address registryAddress;
+        address initialOwner;
+        (registryAddress, initialOwner) = abi.decode(data, (address, address));
+
+        initializeService(registryAddress, address(0), owner);
+
+        _poolService = IPoolService(getRegistry().getServiceAddress(POOL(), getVersion().toMajorPart()));
+
+        registerInterface(type(IProductService).interfaceId);
+    }
+
+
+    function register(address productAddress) 
+        external
+        returns(NftId productNftId)
+    {
+        (
+            IComponent component,
+            address owner,
+            IInstance instance,
+            NftId instanceNftId
+        ) = _checkComponentForRegistration(
+            productAddress,
+            PRODUCT(),
+            PRODUCT_OWNER_ROLE());
+
+        IProductComponent product = IProductComponent(productAddress);
+        IRegistry.ObjectInfo memory productInfo = getRegistryService().registerProduct(product, owner);
+        productNftId = productInfo.nftId;
+        _createProductSetup(
+            instance, 
+            product, 
+            productNftId);
+    }
+
+
+    function _createProductSetup(
+        IInstance instance, 
+        IProductComponent product, 
+        NftId productNftId 
+    )
+        internal
+        returns (string memory name)
+    {
+        // wire distribution and pool components to product component
+        ISetup.ProductSetupInfo memory setup = product.getSetupInfo();
+        IComponent distribution = IComponent(getRegistry().getObjectInfo(setup.distributionNftId).objectAddress);
+        IComponent pool = IComponent(getRegistry().getObjectInfo(setup.poolNftId).objectAddress);
+
+        distribution.setProductNftId(productNftId);
+        pool.setProductNftId(productNftId);
+        product.setProductNftId(productNftId);
+        product.linkToRegisteredNftId();
+
+        // create product setup in instance
+        instance.getInstanceStore().createProductSetup(productNftId, product.getSetupInfo());
+
+        bytes4[][] memory selectors = new bytes4[][](1);
+        selectors[0] = new bytes4[](1);
+        selectors[0][0] = IProductComponent.setFees.selector;
+
+        RoleId[] memory roles = new RoleId[](1);
+        roles[0] = PRODUCT_OWNER_ROLE();
+
+        // create target for instane access manager
+        getInstanceService().createGifTarget(
+            getRegistry().getNftId(address(instance)), 
+            address(product), 
+            product.getName(),
+            selectors,
+            roles);
+    }
+
+    function getDomain() public pure override returns(ObjectType) {
+        return PRODUCT();
+    }
+
+
+    function _decodeAndVerifyProductData(bytes memory data) 
+        internal 
+        returns(string memory name, ISetup.ProductSetupInfo memory setup)
+    {
+        (name, setup) = abi.decode(
+            data,
+            (string, ISetup.ProductSetupInfo)
+        );
+
+        // TODO add checks
+        // if(wallet == address(0)) {
+        //     revert WalletIsZero();
+        // }
+    }
+
+    function setFees(
+        Fee memory productFee,
+        Fee memory processingFee
+    )
+        external
+    {
+        // TODO check args 
+
+        (NftId productNftId,, IInstance instance) = _getAndVerifyCallingComponentAndInstance(PRODUCT());
+        InstanceReader instanceReader = instance.getInstanceReader();
+
+        ISetup.ProductSetupInfo memory productSetupInfo = instanceReader.getProductSetupInfo(productNftId);
+
+        productSetupInfo.productFee = productFee;
+        productSetupInfo.processingFee = processingFee;
+        
+        instance.getInstanceStore().updateProductSetup(productNftId, productSetupInfo, KEEP_STATE());
+    }
+
+    function createRisk(
+        RiskId riskId,
+        bytes memory data
+    )
+        external 
+        override
+    {
+        (NftId productNftId,, IInstance instance) = _getAndVerifyCallingComponentAndInstance(PRODUCT());
+        IRisk.RiskInfo memory riskInfo = IRisk.RiskInfo(productNftId, data);
+
+        instance.getInstanceStore().createRisk(
+            riskId,
+            riskInfo
+        );
+    }
+
+    function updateRisk(
+        RiskId riskId,
+        bytes memory data
+    )
+        external
+    {
+        (,, IInstance instance) = _getAndVerifyCallingComponentAndInstance(PRODUCT());
+        InstanceReader instanceReader = instance.getInstanceReader();
+
+        IRisk.RiskInfo memory riskInfo = instanceReader.getRiskInfo(riskId);
+        riskInfo.data = data;
+        instance.getInstanceStore().updateRisk(riskId, riskInfo, KEEP_STATE());
+    }
+
+    function updateRiskState(
+        RiskId riskId,
+        StateId state
+    )
+        external
+    {
+        (,, IInstance instance) = _getAndVerifyCallingComponentAndInstance(PRODUCT());
+        instance.getInstanceStore().updateRiskState(riskId, state);
+    }
+}

package/contracts/product/ProductServiceManager.sol

@@ -0,0 +1,54 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IVersionable} from "../shared/IVersionable.sol";
+import {ProxyManager} from "../shared/ProxyManager.sol";
+import {ProductService} from "./ProductService.sol";
+import {Registry} from "../registry/Registry.sol";
+import {RegistryService} from "../registry/RegistryService.sol";
+import {VersionLib} from "../type/Version.sol";
+
+contract ProductServiceManager is ProxyManager {
+
+    ProductService private _productService;
+
+    /// @dev initializes proxy manager with product service implementation 
+    constructor(
+        address registryAddress
+    )
+        ProxyManager(registryAddress)
+    {
+        ProductService svc = new ProductService();
+        bytes memory data = abi.encode(registryAddress, address(this));
+        IVersionable versionable = deploy(
+            address(svc), 
+            data);
+
+        _productService = ProductService(address(versionable));
+
+        // Registry registry = Registry(registryAddress);
+        // address registryServiceAddress = registry.getServiceAddress("RegistryService", VersionLib.toVersion(3, 0, 0).toMajorPart());
+        // RegistryService registryService = RegistryService(registryServiceAddress);
+        // TODO this must have a role or own nft to register service
+        //registryService.registerService(_productService);
+        
+        // TODO no nft to link yet
+        // link ownership of instance service manager ot nft owner of instance service
+        //_linkToNftOwnable(
+        //    address(registryAddress),
+        //    address(_productService));
+
+        // implies that after this constructor call only upgrade functionality is available
+        // _isDeployed = true;
+    }
+
+    //--- view functions ----------------------------------------------------//
+    function getProductService()
+        external
+        view
+        returns (ProductService productService)
+    {
+        return _productService;
+    }
+
+}

package/contracts/registry/ChainNft.sol

@@ -0,0 +1,216 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {ERC721, ERC721Enumerable} from "@openzeppelin/contracts/token/ERC721/extensions/ERC721Enumerable.sol";
+import {IERC721} from "@openzeppelin/contracts/token/ERC721/IERC721.sol";
+
+import {ITransferInterceptor} from "./ITransferInterceptor.sol";
+
+contract ChainNft is ERC721Enumerable {
+
+    // constants
+    string public constant NAME = "Dezentralized Insurance Protocol NFT";
+    string public constant SYMBOL = "DIPNFT";
+
+    uint256 public constant PROTOCOL_NFT_ID = 1101;
+    uint256 public constant GLOBAL_REGISTRY_ID = 2101;
+
+    // custom errors
+    error CallerNotRegistry(address caller);
+    error RegistryAddressZero();
+    error NftUriEmpty();
+    error NftUriAlreadySet();
+
+    // contract state
+
+    // remember interceptors
+    mapping(uint256 tokenId => address interceptor) private _interceptor;
+
+    // remember token uri
+    mapping(uint256 tokenId => string uri) private _uri;
+
+    // remember registry
+    address private _registry;
+
+    // only used for _getNextTokenId
+    uint256 internal _chainIdInt;
+    uint256 internal _chainIdDigits;
+    uint256 internal _chainIdMultiplier;
+    uint256 internal _idNext;
+    uint256 internal _totalMinted;
+
+    modifier onlyRegistry() {
+        if (msg.sender != _registry) { revert CallerNotRegistry(msg.sender); }
+        _;
+    }
+
+    constructor(address registry) ERC721(NAME, SYMBOL) {
+        if (registry == address(0)) { revert RegistryAddressZero(); }
+
+        _registry = registry;
+        _chainIdInt = block.chainid;
+        _chainIdDigits = 0;
+
+        // count digis
+        uint256 num = _chainIdInt;
+        while (num != 0) {
+            _chainIdDigits++;
+            num /= 10;
+        }
+
+        _chainIdMultiplier = 10 ** _chainIdDigits;
+
+        // the first object registered through normal registration starts with id 4
+        // 1 -> protocol
+        // 2 -> registry
+        // 3 -> staking
+        // >= 4 -> all other objects
+        _idNext = 4;
+    }
+
+    /**
+    * @dev mints a token for a specified token id
+    * not part of the IRegistry interface only needed for
+    * initial registry setup (protocol and global registry objects)
+    */
+    function mint(address to, uint256 tokenId) external onlyRegistry {
+        _totalMinted++;
+        _safeMint(to, tokenId);
+    }
+
+
+    /**
+    * @dev mints the next token to register new objects
+    * non-zero transferInterceptors are recorded and called during nft token transfers.
+    * the contract receiving such a notification may decides to revert or record the transfer
+    */
+    function mint(
+        address to,
+        address interceptor,
+        string memory uri
+    ) public onlyRegistry returns (uint256 tokenId) {
+        tokenId = _getNextTokenId();
+
+        if (interceptor != address(0)) {
+            _interceptor[tokenId] = interceptor;
+        }
+
+        if (bytes(uri).length > 0) {
+            _uri[tokenId] = uri;
+        }
+
+        _totalMinted++;
+        _safeMint(to, tokenId);
+
+        if(interceptor != address(0)) {
+            ITransferInterceptor(interceptor).nftMint(to, tokenId);
+        }
+    }
+
+
+    /**
+     * @dev amend the open zeppelin transferFrom function by an interceptor call if such an interceptor is defined for the nft token id
+     * this allows distribution, product and pool components to be notified when distributors, policies and bundles are transferred.
+     */
+    function transferFrom(address from, address to, uint256 tokenId) public override (ERC721, IERC721) {
+        super.transferFrom(from, to, tokenId);
+
+        if (_interceptor[tokenId] != address(0)) {
+            ITransferInterceptor(_interceptor[tokenId]).nftTransferFrom(from, to, tokenId);
+        }
+    }
+
+
+    function burn(uint256 tokenId) external onlyRegistry {
+        _requireOwned(tokenId);
+        _burn(tokenId);
+        delete _uri[tokenId];
+    }
+
+    function setURI(
+        uint256 tokenId,
+        string memory uri
+    ) external onlyRegistry {
+        if (bytes(uri).length == 0) { revert NftUriEmpty(); }
+        if (bytes(_uri[tokenId]).length > 0) { revert NftUriAlreadySet(); }
+
+        _requireOwned(tokenId);
+        _uri[tokenId] = uri;
+    }
+
+    function exists(uint256 tokenId) external view returns (bool) {
+        return _ownerOf(tokenId) != address(0);
+    }
+
+    function tokenURI(
+        uint256 tokenId
+    ) public view override returns (string memory) {
+        // gif generally does not revert for view functions
+        // this is an exception to keep the openzeppelin nft semantics
+        _requireOwned(tokenId);
+        return _uri[tokenId];
+    }
+
+    function getInterceptor(uint256 tokenId) external view returns (address) {
+        return _interceptor[tokenId];
+    }
+
+    function getRegistryAddress() external view returns (address) {
+        return _registry;
+    }
+
+    function totalMinted() external view returns (uint256) {
+        return _totalMinted;
+    }
+
+    /**
+    * @dev token id calculation based on an index value that is supposed
+    * to increase with every minted token
+    *
+    * requirement: each chain registry produces token ids that
+    * are guaranteed to not collide with any token id genereated
+    * on a different chain
+    *
+    * format concat(counter,chainid,2 digits for len-of-chain-id)
+    * restriction chainid up to 99 digits
+    * decode: from right to left:
+    * - 2 right most digits encode length of chainid
+    * - move number of digits to left as determined above (-> chainid)
+    * - the reminder to the left is the counter
+    *
+    * special cases
+    * 1101 -> decentralized insurance protocol
+    * 2102 -> global registry
+    * 2xxxxx -> chain registry, where xxxxx = <chain-part> 
+    *
+    * examples
+    * 1101
+    * ^^ ^
+    * || +- 1-digit chain id
+    * |+-- chain id = 1 (mainnet)
+    * +-- 1st token id on mainnet
+    * (1 * 10 ** 1 + 1) * 100 + 1
+    * 42987654321010
+    * ^ ^          ^
+    * | |          +- 10-digit chain id
+    * | +-- chain id = 9876543210 (hypothetical chainid)
+    * +-- 42nd token id on this chain
+    * (42 * 10 ** 10 + 9876543210) * 100 + 10
+    * (index * 10 ** digits + chainid) * 100 + digits (1 < digits < 100)
+    */
+    function calculateTokenId(uint256 idIndex) public view returns (uint256 id) {
+        id =
+            (idIndex * _chainIdMultiplier + _chainIdInt) *
+            100 +
+            _chainIdDigits;
+    }
+
+    function getNextTokenId() external view returns (uint256) {
+        return calculateTokenId(_idNext);
+    }
+
+    function _getNextTokenId() private returns (uint256 id) {
+        id = calculateTokenId(_idNext);
+        _idNext++;
+    }
+}

package/contracts/registry/IRegistry.sol

@@ -1,66 +1,110 @@
 // SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
+pragma solidity ^0.8.20;
 
-interface IOwnable {
-    function getOwner() external view returns(address owner);
-}
+import {IERC165} from "@openzeppelin/contracts/utils/introspection/IERC165.sol";
 
-interface IRegistryLinked {
+import {NftId} from "../type/NftId.sol";
+import {ObjectType} from "../type/ObjectType.sol";
+import {VersionPart} from "../type/Version.sol";
+import {Timestamp} from "../type/Timestamp.sol";
 
-    event LogDebug(uint256 idx, address module, string comment);
+interface IRegistry is IERC165 {
 
-    function getRegistry() external view returns(IRegistry registry);
-}
+    event LogRegistration(NftId nftId, NftId parentNftId, ObjectType objectType, bool isInterceptor, address objectAddress, address initialOwner);
+    event LogServiceRegistration(VersionPart majorVersion, ObjectType domain);
 
-interface IRegisterable is 
-    IOwnable,
-    IRegistryLinked
-{
+    // registerService()
+    error CallerNotReleaseManager();
+    error ServiceAlreadyRegistered(address service);
 
-    function register() external returns(uint256 nftId);
-    
-    function getNftId() external view returns(uint256 nftId);
-    function getParentNftId() external view returns(uint256 parentNftId);
-    function getType() external view returns(uint256 objectType);
-    function getData() external view returns(bytes memory data);
-    function isRegisterable() external pure returns(bool);
-    function getInitialOwner() external view returns(address initialOwner);
+    // register()
+    error CallerNotRegistryService();
+    error ServiceRegistration();
 
-    function isRegistered() external view returns(bool);
-}
+    // registerWithCustomTypes()
+    error CoreTypeRegistration();
 
+    // _register()
+    error ZeroParentAddress();
+    error InvalidTypesCombination(ObjectType objectType, ObjectType parentType);
+    error ContractAlreadyRegistered(address objectAddress);
 
-interface IRegistry {
+    // _registerStaking()
+    error StakingAlreadyRegistered(address stakingAddress);
 
-    struct RegistryInfo {
-        uint256 nftId;
-        uint256 parentNftId;
-        uint256 objectType;
+    struct ObjectInfo {
+        NftId nftId;
+        NftId parentNftId;
+        ObjectType objectType;
+        bool isInterceptor;
         address objectAddress;
         address initialOwner;
+        bytes data;
     }
 
-    function TOKEN() external pure returns(uint256);
-    function INSTANCE() external pure returns(uint256);
-    function PRODUCT() external pure returns(uint256);
-    function ORACLE() external pure returns(uint256);
-    function POOL() external pure returns(uint256);
-    function POLICY() external pure returns(uint256);
-    function BUNDLE() external pure returns(uint256);
-
-    function register(address objectAddress) external returns(uint256 nftId);
-    function registerObjectForInstance(
-        uint256 parentNftid,
-        uint256 objectType,
-        address initialOwner
-    )
-        external returns(uint256 nftId);
-
-    function transfer(uint256 nftId, address newOwner) external;
-
-    function getNftId(address objectAddress) external view returns(uint256 nftId);
-    function getInfo(uint256 nftId) external view returns(RegistryInfo memory info);
-    function getOwner(uint256 nftId) external view returns(address ownerAddress);
-
-    function isRegistered(address objectAddress) external view returns(bool);
-}
+    struct ReleaseInfo {
+        ObjectType[] domains;
+        Timestamp createdAt;
+        //Timestamp updatedAt;
+    }
+
+    function registerStaking(
+        address stakingAddress,
+        address stakingOwner
+    ) external returns(NftId nftId);
+
+    function registerService(
+        ObjectInfo memory serviceInfo, 
+        VersionPart serviceVersion, 
+        ObjectType serviceDomain
+    ) external returns(NftId nftId);
+
+    function register(ObjectInfo memory info) external returns (NftId nftId);
+
+    function registerWithCustomType(ObjectInfo memory info) external returns (NftId nftId);
+
+    function getInitialVersion() external view returns (VersionPart);
+
+    function getNextVersion() external view returns (VersionPart);
+
+    function getLatestVersion() external view returns (VersionPart);
+
+    function getReleaseInfo(VersionPart version) external view returns (ReleaseInfo memory);
+
+    function getObjectCount() external view returns (uint256);
+
+    function getNftId() external view returns (NftId nftId);
+
+    function getNftId(address objectAddress) external view returns (NftId nftId);
+
+    function ownerOf(NftId nftId) external view returns (address);
+
+    function ownerOf(address contractAddress) external view returns (address);
+
+    function getObjectInfo(NftId nftId) external view returns (ObjectInfo memory info);
+
+    function getObjectInfo(address object) external view returns (ObjectInfo memory info);
+
+    function isRegistered(NftId nftId) external view returns (bool);
+
+    function isRegistered(address contractAddress) external view returns (bool);
+
+    function isRegisteredService(address contractAddress) external view returns (bool);
+
+    function isRegisteredComponent(address object) external view returns (bool);
+
+    function isValidRelease(VersionPart version) external view returns (bool);
+
+    function getServiceAddress(
+        ObjectType serviceDomain, 
+        VersionPart releaseVersion
+    ) external view returns (address serviceAddress);
+
+    function getStakingAddress() external view returns (address staking);
+
+    function getReleaseManagerAddress() external view returns (address);
+
+    function getChainNftAddress() external view returns (address);
+
+    function getOwner() external view returns (address);
+}