@etherisc/gif-next 0.0.2-ed4dd55 → 0.0.2-edc084c-558

package/contracts/types/Key32.sol

@@ -0,0 +1,50 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {ObjectType} from "./ObjectType.sol";
+
+type Key32 is bytes32;
+type KeyId is bytes31;
+
+// type bindings
+using {
+    eqKey32 as ==, 
+    neKey32 as !=,
+    Key32Lib.toKeyId,
+    Key32Lib.toObjectType
+} for Key32 global;
+
+// @dev Returns true iff keys are identical
+function eqKey32(Key32 a, Key32 b) pure returns (bool isSame) {
+    return Key32.unwrap(a) == Key32.unwrap(b);
+}
+
+// @dev Returns true iff keys are different
+function neKey32(Key32 a, Key32 b) pure returns (bool isDifferent) {
+    return Key32.unwrap(a) != Key32.unwrap(b);
+}
+
+library Key32Lib {
+
+    uint8 public constant TYPE_SHIFT = 31 * 8;
+    uint8 public constant ID_SHIFT = uint8(32 * 8 - TYPE_SHIFT);
+    bytes32 public constant TYPE_MASK = bytes32(bytes1(type(uint8).max)); // first byte in bytes32
+    bytes32 public constant ID_MASK = bytes32(~TYPE_MASK); // remaining bytes in bytes32
+
+    function toKey32(ObjectType objectType, KeyId id) public pure returns (Key32) {
+        uint256 uintObjectType = ObjectType.unwrap(objectType);
+        uint256 uintId = uint248(KeyId.unwrap(id));
+        uint256 uintKey = (uintObjectType << TYPE_SHIFT) + uintId;
+        return Key32.wrap(bytes32(uintKey));
+    }
+
+    function toObjectType(Key32 key) public pure returns (ObjectType objectType) {
+        bytes32 key32 = Key32.unwrap(key);
+        objectType = ObjectType.wrap(uint8(uint256(key32 & TYPE_MASK) >> TYPE_SHIFT));
+    }
+
+    function toKeyId(Key32 key) public pure returns (KeyId id) {
+        bytes32 key32 = Key32.unwrap(key);
+        id = KeyId.wrap(bytes31((key32 & ID_MASK) << ID_SHIFT));
+    }
+}

package/contracts/types/NftId.sol

@@ -1,25 +1,80 @@
 // SPDX-License-Identifier: Apache-2.0
 pragma solidity ^0.8.19;
 
+import {Key32, KeyId, Key32Lib} from "./Key32.sol";
+import {ObjectType} from "./ObjectType.sol";
+
 // uint96 allows for chain ids up to 13 digits
 type NftId is uint96;
 
 // type bindings
 using {
-    eqNftId as ==,
-    neNftId as !=,
-    NftIdLib.toInt
+    eqNftId as ==, 
+    neNftId as !=, 
+    NftIdLib.toInt,
+    NftIdLib.gtz,
+    NftIdLib.eqz,
+    NftIdLib.toKeyId,
+    NftIdLib.toKey32
 } for NftId global;
 
 // general pure free functions
-function toNftId(uint256 id) pure returns(NftId) { return NftId.wrap(uint96(id)); }
-function gtz(NftId a) pure returns(bool) { return NftId.unwrap(a) > 0; }
+/// @dev Converts the uint256 to a NftId.
+function toNftId(uint256 id) pure returns (NftId) {
+    return NftId.wrap(uint96(id));
+}
+
+// TODO move to NftIdLib and rename to zero()
+/// @dev Return the NftId zero (0)
+function zeroNftId() pure returns (NftId) {
+    return NftId.wrap(0);
+}
 
 // pure free functions for operators
-function eqNftId(NftId a, NftId b) pure returns(bool isSame) { return NftId.unwrap(a) == NftId.unwrap(b); }
-function neNftId(NftId a, NftId b) pure returns(bool isDifferent) { return NftId.unwrap(a) != NftId.unwrap(b); }
+function eqNftId(NftId a, NftId b) pure returns (bool isSame) {
+    return NftId.unwrap(a) == NftId.unwrap(b);
+}
+
+function neNftId(NftId a, NftId b) pure returns (bool isDifferent) {
+    return NftId.unwrap(a) != NftId.unwrap(b);
+}
 
 // library functions that operate on user defined type
 library NftIdLib {
-    function toInt(NftId nftId) internal pure returns(uint256) { return uint256(NftId.unwrap(nftId)); }
+
+    /// @dev the zero nft id
+    /// is never a valid nft id and implies a non-initialized value
+    function zero() public pure returns (NftId) {
+        return NftId.wrap(0);
+    }
+
+    /// @dev Converts the NftId to a uint256.
+    function toInt(NftId nftId) public pure returns (uint96) {
+        return uint96(NftId.unwrap(nftId));
+    }
+
+    /// @dev Returns true if the value is non-zero (> 0).
+    function gtz(NftId a) public pure returns (bool) {
+        return NftId.unwrap(a) > 0;
+    }
+
+    /// @dev Returns true if the value is zero (== 0).
+    function eqz(NftId a) public pure returns (bool) {
+        return NftId.unwrap(a) == 0;
+    }
+
+    /// @dev Returns true if the values are equal (==).
+    function eq(NftId a, NftId b) public pure returns (bool isSame) {
+        return eqNftId(a, b);
+    }
+
+    /// @dev Returns the key32 value for the specified nft id and object type.
+    function toKey32(NftId id, ObjectType objectType) public pure returns (Key32 key) {
+        return Key32Lib.toKey32(objectType, toKeyId(id));
+    }
+
+    /// @dev Returns the key id value for the specified nft id
+    function toKeyId(NftId id) public pure returns (KeyId keyId) {
+        return KeyId.wrap(bytes31(uint248(NftId.unwrap(id))));
+    }
 }

package/contracts/types/NftIdSet.sol

@@ -0,0 +1,62 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {NftId} from "../types/NftId.sol";
+
+// based on https://github.com/OpenZeppelin/openzeppelin-contracts/blob/master/contracts/utils/structs/EnumerableSet.sol
+library LibNftIdSet {
+
+    struct Set {
+        NftId[] ids;
+        mapping(NftId nftid => uint256 index) at;
+    }
+
+    error ErrorNftIdSetAlreadyAdded(NftId nftId);
+    error ErrorNftIdSetNotInSet(NftId nftId);
+
+
+    function add(Set storage set, NftId nftId) external {
+        if (set.at[nftId] > 0) {
+            revert ErrorNftIdSetAlreadyAdded(nftId);
+        }
+
+        set.ids.push(nftId);
+        set.at[nftId] = set.ids.length;
+    }
+
+    function remove(Set storage set, NftId nftId) external {
+        uint256 nftIdIndex = set.at[nftId];
+
+        if (nftIdIndex == 0) {
+            revert ErrorNftIdSetNotInSet(nftId);
+        }
+
+        uint256 toDeleteIndex = nftIdIndex - 1;
+        uint256 lastIndex = set.ids.length - 1;
+
+        if (lastIndex != toDeleteIndex) {
+            NftId lastId = set.ids[lastIndex];
+            set.ids[toDeleteIndex] = lastId;
+            set.at[lastId] = nftIdIndex; // Replace lastValue's index to valueIndex
+        }
+
+        set.ids.pop();
+        delete set.at[nftId];
+    }
+
+    function isEmpty(Set storage set) external view returns(bool empty) {
+        return set.ids.length == 0;
+    }
+
+    function contains(Set storage set, NftId nftId) external view returns(bool inSet) {
+        return set.at[nftId] > 0;
+    }
+
+    function size(Set storage set) external view returns(uint256 length) {
+        return set.ids.length;
+    }
+
+    function getElementAt(Set storage set, uint256 index) external view returns(NftId nftId) {
+        return set.ids[index];
+    }
+}

package/contracts/types/NumberId.sol

@@ -0,0 +1,52 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+// uint32 allows for 4'294'967'296 individual items
+type NumberId is uint32;
+
+// type bindings
+using {
+    eqNumberId as ==, 
+    neNumberId as !=, 
+    NumberIdLib.eqz,
+    NumberIdLib.gtz,
+    NumberIdLib.toInt
+} for NumberId global;
+
+
+// pure free functions for operators
+function eqNumberId(NumberId a, NumberId b) pure returns (bool isSame) {
+    return NumberId.unwrap(a) == NumberId.unwrap(b);
+}
+
+function neNumberId(NumberId a, NumberId b) pure returns (bool isDifferent) {
+    return NumberId.unwrap(a) != NumberId.unwrap(b);
+}
+
+// library functions that operate on user defined type
+library NumberIdLib {
+    /// @dev Converts the NumberId to a uint.
+    function zero() public pure returns (NumberId) {
+        return NumberId.wrap(0);
+    }
+
+    /// @dev Converts an uint into a NumberId.
+    function toNumberId(uint256 a) public pure returns (NumberId) {
+        return NumberId.wrap(uint32(a));
+    }
+
+    /// @dev Converts the NumberId to a uint.
+    function toInt(NumberId a) public pure returns (uint32) {
+        return uint32(NumberId.unwrap(a));
+    }
+
+    /// @dev Returns true if the value is non-zero (> 0).
+    function gtz(NumberId a) public pure returns (bool) {
+        return NumberId.unwrap(a) > 0;
+    }
+
+    /// @dev Returns true if the value is zero (== 0).
+    function eqz(NumberId a) public pure returns (bool) {
+        return NumberId.unwrap(a) == 0;
+    }
+}

package/contracts/types/ObjectType.sol

@@ -0,0 +1,157 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+type ObjectType is uint8;
+
+// type bindings
+using {
+    eqObjectType as ==,
+    neObjectType as !=,
+    ObjectTypeLib.toInt,
+    ObjectTypeLib.gtz
+} for ObjectType global;
+
+// general pure free functions
+
+function PROTOCOL() pure returns (ObjectType) {
+    return toObjectType(10);
+}
+
+function ROLE() pure returns (ObjectType) {
+    return toObjectType(20);
+}
+
+function TARGET() pure returns (ObjectType) {
+    return toObjectType(30);
+}
+
+function REGISTRY() pure returns (ObjectType) {
+    return toObjectType(40);
+}
+
+function TOKEN() pure returns (ObjectType) {
+    return toObjectType(50);
+}
+
+function SERVICE() pure returns (ObjectType) {
+    return toObjectType(60);
+}
+
+function INSTANCE() pure returns (ObjectType) {
+    return toObjectType(70);
+}
+
+function STAKE() pure returns (ObjectType) {
+    return toObjectType(80);
+}
+
+function COMPONENT() pure returns (ObjectType) {
+    return toObjectType(100);
+}
+
+// TODO replace by PRODUCT_SETUP
+function TREASURY() pure returns (ObjectType) {
+    return toObjectType(101);
+}
+
+function PRODUCT_SETUP() pure returns (ObjectType) {
+    return toObjectType(101);
+}
+
+function PRODUCT() pure returns (ObjectType) {
+    return toObjectType(110);
+}
+
+function DISTRIBUTION() pure returns (ObjectType) {
+    return toObjectType(120);
+}
+
+function DISTRIBUTOR_TYPE() pure returns (ObjectType) {
+    return toObjectType(121);
+}
+
+function DISTRIBUTOR() pure returns (ObjectType) {
+    return toObjectType(122);
+}
+
+function REFERRAL() pure returns (ObjectType) {
+    return toObjectType(123);
+}
+
+function ORACLE() pure returns (ObjectType) {
+    return toObjectType(130);
+}
+
+function POOL() pure returns (ObjectType) {
+    return toObjectType(140);
+}
+
+function RISK() pure returns (ObjectType) {
+    return toObjectType(200);
+}
+
+function APPLICATION() pure returns (ObjectType) {
+    return toObjectType(210);
+}
+
+function POLICY() pure returns (ObjectType) {
+    return toObjectType(211);
+}
+
+function CLAIM() pure returns (ObjectType) {
+    return toObjectType(212);
+}
+
+function BUNDLE() pure returns (ObjectType) {
+    return toObjectType(220);
+}
+
+function PAYOUT() pure returns (ObjectType) {
+    return toObjectType(212);
+}
+
+/// @dev Converts the uint8 to a ObjectType.
+function toObjectType(uint256 objectType) pure returns (ObjectType) {
+    return ObjectType.wrap(uint8(objectType));
+}
+
+// TODO move to ObjecTypeLib and rename to zero()
+/// @dev Return the ObjectType zero (0)
+function zeroObjectType() pure returns (ObjectType) {
+    return ObjectType.wrap(0);
+}
+
+// pure free functions for operators
+function eqObjectType(ObjectType a, ObjectType b) pure returns (bool isSame) {
+    return ObjectType.unwrap(a) == ObjectType.unwrap(b);
+}
+
+function neObjectType(
+    ObjectType a,
+    ObjectType b
+) pure returns (bool isDifferent) {
+    return ObjectType.unwrap(a) != ObjectType.unwrap(b);
+}
+
+// library functions that operate on user defined type
+library ObjectTypeLib {
+    /// @dev Converts the NftId to a uint256.
+    function toInt(ObjectType objectType) public pure returns (uint96) {
+        return uint96(ObjectType.unwrap(objectType));
+    }
+
+    /// @dev Returns true if the value is non-zero (> 0).
+    function gtz(ObjectType a) public pure returns (bool) {
+        return ObjectType.unwrap(a) > 0;
+    }
+
+    /// @dev Returns true if the value is zero (== 0).
+    function eqz(ObjectType a) public pure returns (bool) {
+        return ObjectType.unwrap(a) == 0;
+    }
+
+    /// @dev Returns true if the values are equal (==).
+    function eq(ObjectType a, ObjectType b) public pure returns (bool isSame) {
+        return eqObjectType(a, b);
+    }
+}

package/contracts/types/PayoutId.sol

@@ -0,0 +1,54 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+// uint24 allows for 65'535 claims with 255 payouts each per policy
+type PayoutId is uint24;
+
+// type bindings
+using {
+    eqPayoutId as ==, 
+    nePayoutId as !=, 
+    PayoutIdLib.eqz,
+    PayoutIdLib.gtz,
+    PayoutIdLib.toInt
+} for PayoutId global;
+
+
+// pure free functions for operators
+function eqPayoutId(PayoutId a, PayoutId b) pure returns (bool isSame) {
+    return PayoutId.unwrap(a) == PayoutId.unwrap(b);
+}
+
+function nePayoutId(PayoutId a, PayoutId b) pure returns (bool isDifferent) {
+    return PayoutId.unwrap(a) != PayoutId.unwrap(b);
+}
+
+// TODO come up with a way to code claim id into payout id
+// eg payoutId.getClaimId(), payoutId.getPayoutNo()
+// library functions that operate on user defined type
+library PayoutIdLib {
+    /// @dev Converts the PayoutId to a uint.
+    function zero() public pure returns (PayoutId) {
+        return PayoutId.wrap(0);
+    }
+
+    /// @dev Converts an uint into a PayoutId.
+    function toPayoutId(uint256 a) public pure returns (PayoutId) {
+        return PayoutId.wrap(uint24(a));
+    }
+
+    /// @dev Converts the PayoutId to a uint.
+    function toInt(PayoutId a) public pure returns (uint24) {
+        return uint24(PayoutId.unwrap(a));
+    }
+
+    /// @dev Returns true if the value is non-zero (> 0).
+    function gtz(PayoutId a) public pure returns (bool) {
+        return PayoutId.unwrap(a) > 0;
+    }
+
+    /// @dev Returns true if the value is zero (== 0).
+    function eqz(PayoutId a) public pure returns (bool) {
+        return PayoutId.unwrap(a) == 0;
+    }
+}

package/contracts/types/Referral.sol

@@ -0,0 +1,89 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {Key32, KeyId, Key32Lib} from "./Key32.sol";
+import {NftId} from "./NftId.sol";
+import {REFERRAL} from "./ObjectType.sol";
+
+type ReferralId is bytes8;
+type ReferralStatus is uint8;
+
+// type bindings
+using {
+    eqReferralId as ==, 
+    neReferralId as !=,
+    ReferralLib.toKey32
+} for ReferralId global;
+
+using {
+    eqReferralStatus as ==, 
+    neReferralStatus as !=
+} for ReferralStatus global;
+
+// general pure free functions
+
+// @dev Returns true iff a and b are identical
+function eqReferralId(ReferralId a, ReferralId b) pure returns (bool isSame) {
+    return ReferralId.unwrap(a) == ReferralId.unwrap(b);
+}
+
+// @dev Returns true iff a and b are different
+function neReferralId(ReferralId a, ReferralId b) pure returns (bool isDifferent) {
+    return ReferralId.unwrap(a) != ReferralId.unwrap(b);
+}
+
+// @dev Returns true iff a and b are identical
+function eqReferralStatus(ReferralStatus a, ReferralStatus b) pure returns (bool isSame) {
+    return ReferralStatus.unwrap(a) == ReferralStatus.unwrap(b);
+}
+
+// @dev Returns true iff a and b are different
+function neReferralStatus(ReferralStatus a, ReferralStatus b) pure returns (bool isDifferent) {
+    return ReferralStatus.unwrap(a) != ReferralStatus.unwrap(b);
+}
+
+function REFERRAL_OK() pure returns (ReferralStatus) {
+    return ReferralStatus.wrap(10);
+}
+
+function REFERRAL_ERROR_UNKNOWN() pure returns (ReferralStatus) {
+    return ReferralStatus.wrap(100);
+}
+
+function REFERRAL_ERROR_EXPIRED() pure returns (ReferralStatus) {
+    return ReferralStatus.wrap(110);
+}
+
+function REFERRAL_ERROR_EXHAUSTED() pure returns (ReferralStatus) {
+    return ReferralStatus.wrap(120);
+}
+
+library ReferralLib {
+
+    function zero() public pure returns (ReferralId) {
+        return ReferralId.wrap(bytes8(0));
+    }
+
+    // @dev Converts a referral string into an id.
+    function toReferralId(NftId distributionNftId, string memory referral) public pure returns (ReferralId) {
+        return ReferralId.wrap(bytes8(keccak256(abi.encode(distributionNftId, referral))));
+    }
+
+    function toReferralStatus(uint8 status) public pure returns (ReferralStatus) {
+        return ReferralStatus.wrap(status);
+    }
+
+    /// @dev Returns the key32 value for the specified nft id and object type.
+    function toKey32(ReferralId id) public pure returns (Key32 key) {
+        return Key32Lib.toKey32(REFERRAL(), toKeyId(id));
+    }
+
+    /// @dev Returns the key id value for the specified nft id
+    function toKeyId(ReferralId id) public pure returns (KeyId keyId) {
+        return KeyId.wrap(bytes31(ReferralId.unwrap(id)));
+    }
+
+    function eqz(ReferralId id) public pure returns (bool) {
+        return eqReferralId(id, zero());
+    }
+}

package/contracts/types/RiskId.sol

@@ -0,0 +1,43 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {Key32, KeyId, Key32Lib} from "./Key32.sol";
+import {RISK} from "./ObjectType.sol";
+
+type RiskId is bytes8;
+
+// type bindings
+using {
+    eqRiskId as ==, 
+    neRiskId as !=,
+    RiskIdLib.toKey32
+} for RiskId global;
+
+// general pure free functions
+
+// @dev Returns true iff risk ids a and b are identical
+function eqRiskId(RiskId a, RiskId b) pure returns (bool isSame) {
+    return RiskId.unwrap(a) == RiskId.unwrap(b);
+}
+
+// @dev Returns true iff risk ids a and b are different
+function neRiskId(RiskId a, RiskId b) pure returns (bool isDifferent) {
+    return RiskId.unwrap(a) != RiskId.unwrap(b);
+}
+
+library RiskIdLib {
+    // @dev Converts a role string into a role id.
+    function toRiskId(string memory risk) public pure returns (RiskId) {
+        return RiskId.wrap(bytes8(keccak256(abi.encode(risk))));
+    }
+
+    /// @dev Returns the key32 value for the specified nft id and object type.
+    function toKey32(RiskId id) public pure returns (Key32 key) {
+        return Key32Lib.toKey32(RISK(), toKeyId(id));
+    }
+
+    /// @dev Returns the key id value for the specified nft id
+    function toKeyId(RiskId id) public pure returns (KeyId keyId) {
+        return KeyId.wrap(bytes31(RiskId.unwrap(id)));
+    }
+}

package/contracts/types/RoleId.sol

@@ -0,0 +1,97 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {Key32, KeyId, Key32Lib} from "./Key32.sol";
+import {ROLE} from "./ObjectType.sol";
+
+type RoleId is uint64;
+
+// type bindings
+using {
+    eqRoleId as ==, 
+    neRoleId as !=,
+    RoleIdLib.eqz,
+    RoleIdLib.gtz,
+    RoleIdLib.toInt,
+    RoleIdLib.toKey32
+} for RoleId global;
+
+
+/// @dev role id needs to match with oz AccessManager.ADMIN_ROLE
+function ADMIN_ROLE() pure returns (RoleId) { return RoleIdLib.toRoleId(type(uint64).min); }
+
+/// @dev role id needs to match with oz AccessManager.PUBLIC_ROLE
+function PUBLIC_ROLE() pure returns (RoleId) { return RoleIdLib.toRoleId(type(uint64).max); }
+
+// general pure free functions
+function DISTRIBUTION_OWNER_ROLE_NAME() pure returns (string memory) { return "DistributionOwnerRole"; }
+function ORACLE_OWNER_ROLE_NAME() pure returns (string memory) { return "OracleOwnerRole"; }
+function POOL_OWNER_ROLE_NAME() pure returns (string memory) { return "PoolOwnerRole"; }
+function PRODUCT_OWNER_ROLE_NAME() pure returns (string memory) { return "ProductOwnerRole"; }
+
+function DISTRIBUTION_OWNER_ROLE() pure returns (RoleId) { return RoleIdLib.toRoleId(2); }
+function ORACLE_OWNER_ROLE() pure returns (RoleId) { return RoleIdLib.toRoleId(3); }
+function POOL_OWNER_ROLE() pure returns (RoleId) { return RoleIdLib.toRoleId(4); }
+function PRODUCT_OWNER_ROLE() pure returns (RoleId) { return RoleIdLib.toRoleId(5); }
+
+function INSTANCE_OWNER_ROLE() pure returns (RoleId) { return RoleIdLib.toRoleId(1900); }
+function INSTANCE_SERVICE_ROLE() pure returns (RoleId) { return RoleIdLib.toRoleId(2000); }
+function DISTRIBUTION_SERVICE_ROLE() pure returns (RoleId) { return RoleIdLib.toRoleId(2100); }
+function POOL_SERVICE_ROLE() pure returns (RoleId) { return RoleIdLib.toRoleId(2200); }
+function PRODUCT_SERVICE_ROLE() pure returns (RoleId) { return RoleIdLib.toRoleId(2300); }
+function APPLICATION_SERVICE_ROLE() pure returns (RoleId) { return RoleIdLib.toRoleId(2400); }
+function POLICY_SERVICE_ROLE() pure returns (RoleId) { return RoleIdLib.toRoleId(2410); }
+function CLAIM_SERVICE_ROLE() pure returns (RoleId) { return RoleIdLib.toRoleId(2420); }
+function BUNDLE_SERVICE_ROLE() pure returns (RoleId) { return RoleIdLib.toRoleId(2500); }
+function INSTANCE_ROLE() pure returns (RoleId) { return RoleIdLib.toRoleId(2600); }
+
+function GIF_ADMIN_ROLE() pure returns (RoleId) { return RoleIdLib.toRoleId(1500); } 
+function GIF_MANAGER_ROLE() pure returns (RoleId) { return RoleIdLib.toRoleId(1600); } 
+function RELEASE_MANAGER_ROLE() pure returns (RoleId) { return RoleIdLib.toRoleId(1700); } 
+
+// @dev Returns true iff role ids a and b are identical
+function eqRoleId(RoleId a, RoleId b) pure returns (bool isSame) {
+    return RoleId.unwrap(a) == RoleId.unwrap(b);
+}
+
+// @dev Returns true iff role ids a and b are different
+function neRoleId(RoleId a, RoleId b) pure returns (bool isDifferent) {
+    return RoleId.unwrap(a) != RoleId.unwrap(b);
+}
+
+library RoleIdLib {
+/// @dev Converts the RoleId to a uint.
+    function zero() public pure returns (RoleId) {
+        return RoleId.wrap(0);
+    }
+
+    /// @dev Converts an uint into a RoleId.
+    function toRoleId(uint256 a) public pure returns (RoleId) {
+        return RoleId.wrap(uint64(a));
+    }
+
+    /// @dev Converts the RoleId to a uint.
+    function toInt(RoleId a) public pure returns (uint64) {
+        return uint64(RoleId.unwrap(a));
+    }
+
+    /// @dev Returns true if the value is non-zero (> 0).
+    function gtz(RoleId a) public pure returns (bool) {
+        return RoleId.unwrap(a) > 0;
+    }
+
+    /// @dev Returns true if the value is zero (== 0).
+    function eqz(RoleId a) public pure returns (bool) {
+        return RoleId.unwrap(a) == 0;
+    }
+
+    /// @dev Returns the key32 value for the specified id and object type.
+    function toKey32(RoleId a) public pure returns (Key32 key) {
+        return Key32Lib.toKey32(ROLE(), toKeyId(a));
+    }
+
+    /// @dev Returns the key id value for the specified id
+    function toKeyId(RoleId a) public pure returns (KeyId keyId) {
+        return KeyId.wrap(bytes31(uint248(RoleId.unwrap(a))));
+    }
+}