@etherisc/gif-next 0.0.2-ed4dd55 → 0.0.2-edc084c-558

package/contracts/instance/module/IPolicy.sol

@@ -0,0 +1,72 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {NftId} from "../../types/NftId.sol";
+import {ClaimId} from "../../types/ClaimId.sol";
+import {ReferralId} from "../../types/Referral.sol";
+import {RiskId} from "../../types/RiskId.sol";
+import {Seconds} from "../../types/Seconds.sol";
+import {Timestamp} from "../../types/Timestamp.sol";
+
+interface IPolicy {
+
+    struct Premium {
+        // this is the net premium calculated by the product 
+        uint256 netPremiumAmount;
+        // fullPremium = netPremium + all fixed amounts + all variable amounts (excl commission and minDistribtuionOwnerFee variable part)
+        uint256 fullPremiumAmount;
+        // premium = fullPremium - discount
+        uint256 premiumAmount;
+        uint256 productFeeFixAmount;
+        uint256 poolFeeFixAmount;
+        uint256 bundleFeeFixAmount;
+        uint256 distributionFeeFixAmount;
+        uint256 productFeeVarAmount;
+        uint256 poolFeeVarAmount;
+        uint256 bundleFeeVarAmount;
+        uint256 distributionFeeVarAmount;
+        uint256 distributionOwnerFeeFixAmount;
+        // this is the remaining amount when the commission and discount are subtracted from the distribution fee variable part (must be at least the minDistributionOwnerFee)
+        uint256 distributionOwnerFeeVarAmount;
+        // this value is based on distributor type referenced in the referral 
+        uint256 commissionAmount;
+        // this is based on referral used
+        uint256 discountAmount;
+    }
+
+    /// @dev policy data for the full policy lifecycle
+    struct PolicyInfo {
+        NftId productNftId;
+        NftId bundleNftId;
+        ReferralId referralId;
+        RiskId riskId;
+        uint256 sumInsuredAmount;
+        uint256 premiumAmount;
+        uint256 premiumPaidAmount;
+        Seconds lifetime;
+        bytes applicationData;
+        bytes policyData;
+        uint16 claimsCount;
+        uint16 openClaimsCount;
+        uint256 payoutAmount;
+        Timestamp activatedAt; // time of underwriting
+        Timestamp expiredAt; // no new claims (activatedAt + lifetime)
+        Timestamp closedAt; // no locked capital (or declinedAt)
+    }
+
+    // claimId neeeds to be encoded policyNftId:claimId combination
+    struct ClaimInfo {
+        uint256 claimAmount;
+        uint256 paidAmount;
+        bytes data;
+        Timestamp closedAt; // payoment of confirmed claim amount (or declinedAt)
+    }
+
+    // claimId neeeds to be encoded policyNftId:claimId combination
+    struct PayoutInfo {
+        ClaimId claimId;
+        uint256 amount;
+        bytes data;
+        Timestamp paidAt; // payoment of confirmed claim amount (or declinedAt)
+    }
+}

package/contracts/instance/module/IRisk.sol

@@ -0,0 +1,11 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {NftId} from "../../types/NftId.sol";
+
+interface IRisk {
+    struct RiskInfo {
+        NftId productNftId;
+        bytes data;
+    }
+}

package/contracts/instance/module/ISetup.sol

@@ -0,0 +1,33 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+
+import {Fee} from "../../types/Fee.sol";
+import {NftId} from "../../types/NftId.sol";
+import {RoleId} from "../../types/RoleId.sol";
+import {TokenHandler} from "../../shared/TokenHandler.sol";
+import {UFixed} from "../../types/UFixed.sol";
+
+interface ISetup {
+
+    struct ProductSetupInfo {
+        IERC20Metadata token;
+        TokenHandler tokenHandler;
+        NftId distributionNftId;
+        NftId poolNftId;
+        Fee productFee; // product fee on net premium
+        Fee processingFee; // product fee on payout amounts        
+        bool isIntercepting; // intercepts nft transfers (for products)
+        address wallet;
+    }
+
+    struct DistributionSetupInfo {
+        NftId productNftId;
+        TokenHandler tokenHandler;
+        Fee minDistributionOwnerFee;
+        Fee distributionFee; // recalculated whenever any fee on the product/pool/dist/disttype is changed
+        address wallet;
+        uint256 sumDistributionOwnerFees;
+    }
+}

package/contracts/instance/module/ITreasury.sol

@@ -0,0 +1,23 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+
+import {Fee} from "../../types/Fee.sol";
+import {NftId} from "../../types/NftId.sol";
+import {TokenHandler} from "../../shared/TokenHandler.sol";
+
+interface ITreasury {
+    struct TreasuryInfo {
+        IERC20Metadata token;
+        TokenHandler tokenHandler;
+        NftId distributionNftId;
+        NftId poolNftId;
+        Fee distributionFee; // default distribution fee (no referral id)
+        Fee productFee; // product fee on net premium
+        Fee processingFee; // product fee on payout amounts
+        Fee poolFee; // pool fee on net premium
+        Fee stakingFee; // pool fee on staked capital from investor
+        Fee performanceFee; // pool fee on profits from capital investors
+    }
+}

package/contracts/instance/service/ApplicationService.sol

@@ -0,0 +1,350 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IRisk} from "../module/IRisk.sol";
+import {IService} from "./IApplicationService.sol";
+
+import {IRegistry} from "../../registry/IRegistry.sol";
+import {IProductComponent} from "../../components/IProductComponent.sol";
+import {Product} from "../../components/Product.sol";
+import {IPoolComponent} from "../../components/IPoolComponent.sol";
+import {IDistributionComponent} from "../../components/IDistributionComponent.sol";
+import {IInstance} from "../IInstance.sol";
+import {IComponents} from "../module/IComponents.sol";
+import {IPolicy} from "../module/IPolicy.sol";
+import {IRisk} from "../module/IRisk.sol";
+import {IBundle} from "../module/IBundle.sol";
+import {IProductService} from "./IProductService.sol";
+import {ITreasury} from "../module/ITreasury.sol";
+import {ISetup} from "../module/ISetup.sol";
+
+import {TokenHandler} from "../../shared/TokenHandler.sol";
+
+import {IVersionable} from "../../shared/IVersionable.sol";
+import {Versionable} from "../../shared/Versionable.sol";
+
+import {Seconds} from "../../types/Seconds.sol";
+import {Timestamp, TimestampLib, zeroTimestamp} from "../../types/Timestamp.sol";
+import {UFixed, UFixedLib} from "../../types/UFixed.sol";
+import {Blocknumber, blockNumber} from "../../types/Blocknumber.sol";
+import {ObjectType, DISTRIBUTION, INSTANCE, PRODUCT, POOL, APPLICATION, POLICY, BUNDLE} from "../../types/ObjectType.sol";
+import {APPLIED, REVOKED, UNDERWRITTEN, ACTIVE, KEEP_STATE, CLOSED} from "../../types/StateId.sol";
+import {NftId, NftIdLib, zeroNftId} from "../../types/NftId.sol";
+import {Fee, FeeLib} from "../../types/Fee.sol";
+import {ReferralId} from "../../types/Referral.sol";
+import {RiskId} from "../../types/RiskId.sol";
+import {StateId} from "../../types/StateId.sol";
+import {Version, VersionLib} from "../../types/Version.sol";
+
+import {ComponentService} from "../base/ComponentService.sol";
+import {InstanceReader} from "../InstanceReader.sol";
+import {IApplicationService} from "./IApplicationService.sol";
+import {IBundleService} from "./IBundleService.sol";
+import {IDistributionService} from "./IDistributionService.sol";
+import {IPoolService} from "./IPoolService.sol";
+import {IService} from "../../shared/IService.sol";
+import {Service} from "../../shared/Service.sol";
+
+
+contract ApplicationService is 
+    ComponentService, 
+    IApplicationService
+{
+    IDistributionService internal _distributionService;
+
+    function _initialize(
+        address owner, 
+        bytes memory data
+    )
+        internal
+        virtual override
+        initializer()
+    {
+        // TODO check this, might no longer be the way, refactor if necessary
+        address registryAddress;
+        address initialOwner;
+        (registryAddress, initialOwner) = abi.decode(data, (address, address));
+
+        initializeService(registryAddress, address(0), owner);
+        registerInterface(type(IApplicationService).interfaceId);
+
+        _distributionService = IDistributionService(getRegistry().getServiceAddress(DISTRIBUTION(), getVersion().toMajorPart()));
+    }
+
+
+    function getDomain() public pure override returns(ObjectType) {
+        return APPLICATION();
+    }
+
+
+    function create(
+        address applicationOwner,
+        RiskId riskId,
+        uint256 sumInsuredAmount,
+        Seconds lifetime,
+        NftId bundleNftId,
+        ReferralId referralId,
+        bytes memory applicationData
+    )
+        external
+        virtual
+        returns (NftId applicationNftId)
+    {
+        (NftId productNftId,, IInstance instance) = _getAndVerifyComponentInfoAndInstance(PRODUCT());
+        // TODO: add validations (see create bundle in pool service)
+
+        applicationNftId = getRegistryService().registerPolicy(
+            IRegistry.ObjectInfo(
+                zeroNftId(),
+                productNftId,
+                POLICY(),
+                false, // intercepting property for policies is defined on product
+                address(0),
+                applicationOwner,
+                ""
+            )
+        );
+
+        // (uint256 premiumAmount,,,,,) = calculatePremium(
+        IPolicy.Premium memory premium = calculatePremium(
+            productNftId,
+            riskId,
+            sumInsuredAmount,
+            lifetime,
+            applicationData,
+            bundleNftId,
+            referralId
+        );
+
+        IPolicy.PolicyInfo memory policyInfo = IPolicy.PolicyInfo(
+            productNftId,
+            bundleNftId,
+            referralId,
+            riskId,
+            sumInsuredAmount,
+            premium.premiumAmount,
+            0,
+            lifetime,
+            applicationData,
+            "",
+            0,
+            0,
+            0,
+            zeroTimestamp(),
+            zeroTimestamp(),
+            zeroTimestamp()
+        );
+        
+        instance.createApplication(applicationNftId, policyInfo);
+
+        // TODO: add logging
+    }
+
+
+    function renew(
+        NftId policyNftId, // policy to be renewd (renewal inherits policy attributes)
+        NftId bundleNftId // will likely need a newer bundle for underwriting
+    )
+        external
+        virtual override
+        returns (NftId applicationNftId)
+    {
+
+    }
+
+
+    function adjust(
+        NftId applicationNftId,
+        RiskId riskId,
+        NftId bundleNftId,
+        ReferralId referralId,
+        uint256 sumInsuredAmount,
+        uint256 lifetime,
+        bytes memory applicationData
+    )
+        external
+        virtual override
+    {
+
+    }
+
+    function revoke(NftId applicationNftId)
+        external
+        virtual override
+    {
+        (,, IInstance instance) = _getAndVerifyComponentInfoAndInstance(PRODUCT());
+        instance.updateApplicationState(applicationNftId, REVOKED());
+    }
+
+    // TODO: maybe move this to a pricing service later
+    function calculatePremium(
+        NftId productNftId,
+        RiskId riskId,
+        uint256 sumInsuredAmount,
+        Seconds lifetime,
+        bytes memory applicationData,
+        NftId bundleNftId,
+        ReferralId referralId
+    )
+        public
+        view
+        virtual override
+        returns (
+            IPolicy.Premium memory premium
+        )
+    {
+        uint256 netPremiumAmount = _getAndVerifyProduct(productNftId).calculateNetPremium(
+            sumInsuredAmount,
+            riskId,
+            lifetime,
+            applicationData
+        );
+
+        premium = _getFixedFeeAmounts(
+            netPremiumAmount,
+            _getAndVerifyProduct(productNftId),
+            bundleNftId,
+            referralId
+        );
+
+        (
+            premium
+        ) = _calculateVariableFeeAmounts(
+            premium,
+            _getAndVerifyProduct(productNftId),
+            bundleNftId,
+            referralId
+        );
+    }
+
+
+    // internal functions
+    function _getFixedFeeAmounts(
+        uint256 netPremiumAmount,
+        Product product,
+        NftId bundleNftId,
+        ReferralId referralId
+    )
+        internal
+        view
+        returns (
+            IPolicy.Premium memory premium
+        )
+    {
+        InstanceReader instanceReader;
+        {
+            IInstance instance = product.getInstance();
+            instanceReader = instance.getInstanceReader();
+        }
+        
+        NftId poolNftId = product.getPoolNftId();
+        premium = IPolicy.Premium(
+            netPremiumAmount, // net premium
+            netPremiumAmount, // full premium
+            0, // premium
+            0, 0, 0, 0, // fix fees
+            0, 0, 0, 0, // variable fees
+            0, 0, 0, 0); // distribution owner fee/commission/discount
+
+        {
+            {
+                ISetup.ProductSetupInfo memory productSetupInfo = instanceReader.getProductSetupInfo(product.getProductNftId());
+                uint256 t = productSetupInfo.productFee.fixedFee;
+                premium.productFeeFixAmount = t;
+                premium.fullPremiumAmount += t;
+            }
+            {
+                bytes memory componentData = instanceReader.getComponentInfo(poolNftId).data;
+                uint256 t = abi.decode(componentData, (IComponents.PoolInfo)).poolFee.fixedFee;
+                premium.poolFeeFixAmount = t;
+                premium.fullPremiumAmount += t;
+            }
+            {
+                IBundle.BundleInfo memory bundleInfo = instanceReader.getBundleInfo(bundleNftId);
+                if(bundleInfo.poolNftId != poolNftId) {
+                    revert IApplicationServiceBundlePoolMismatch(bundleNftId, bundleInfo.poolNftId, poolNftId);
+                }
+                uint256 t = bundleInfo.fee.fixedFee;
+                premium.bundleFeeFixAmount = t;
+                premium.fullPremiumAmount += t;
+            }
+            {
+                ISetup.DistributionSetupInfo memory distInto = instanceReader.getDistributionSetupInfo(product.getDistributionNftId());
+                uint256 t = distInto.distributionFee.fixedFee;
+                premium.distributionFeeFixAmount = t;
+                premium.fullPremiumAmount += t;
+            }
+        }
+        
+    }
+
+    function _calculateVariableFeeAmounts(
+        IPolicy.Premium memory premium,
+        Product product,
+        NftId bundleNftId,
+        ReferralId referralId
+    )
+        internal
+        view
+        returns (
+            IPolicy.Premium memory finalPremium
+        )
+    {
+        InstanceReader instanceReader;
+        {
+            IInstance instance = product.getInstance();
+            instanceReader = instance.getInstanceReader();
+        }
+        
+        NftId poolNftId = product.getPoolNftId();
+        uint256 netPremiumAmount = premium.netPremiumAmount;
+
+        {
+            {
+                ISetup.ProductSetupInfo memory productSetupInfo = instanceReader.getProductSetupInfo(product.getProductNftId());
+                uint256 t = (UFixedLib.toUFixed(netPremiumAmount) * productSetupInfo.productFee.fractionalFee).toInt();
+                premium.productFeeVarAmount = t;
+                premium.fullPremiumAmount += t;
+            }
+            {
+                bytes memory componentData = instanceReader.getComponentInfo(poolNftId).data;
+                UFixed poolFractionalFee = abi.decode(componentData, (IComponents.PoolInfo)).poolFee.fractionalFee;
+                uint256 t = (UFixedLib.toUFixed(netPremiumAmount) * poolFractionalFee).toInt();
+                premium.poolFeeVarAmount = t;
+                premium.fullPremiumAmount += t;
+            }
+            {
+                IBundle.BundleInfo memory bundleInfo = instanceReader.getBundleInfo(bundleNftId);
+                if(bundleInfo.poolNftId != poolNftId) {
+                    revert IApplicationServiceBundlePoolMismatch(bundleNftId, bundleInfo.poolNftId, poolNftId);
+                }
+                uint256 t = (UFixedLib.toUFixed(netPremiumAmount) * bundleInfo.fee.fractionalFee).toInt();
+                premium.bundleFeeVarAmount = t;
+                premium.fullPremiumAmount += t;
+            }
+            {
+                premium = _distributionService.calculateFeeAmount(
+                    product.getDistributionNftId(),
+                    referralId,
+                    premium
+                );
+            }
+        }
+
+        return premium;
+    }
+
+
+    function _getAndVerifyInstanceAndProduct() internal view returns (Product product) {
+        IRegistry.ObjectInfo memory productInfo;
+        (, productInfo,) = _getAndVerifyComponentInfoAndInstance(PRODUCT());
+        product = Product(productInfo.objectAddress);
+    }
+
+    function _getAndVerifyProduct(NftId productNftId) internal view returns (Product product) {
+        IRegistry registry = getRegistry();        
+        IRegistry.ObjectInfo memory productInfo = registry.getObjectInfo(productNftId);
+        require(productInfo.objectType == PRODUCT(), "OBJECT_TYPE_INVALID");
+        product = Product(productInfo.objectAddress);
+    }
+}

package/contracts/instance/service/ApplicationServiceManager.sol

@@ -0,0 +1,35 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IVersionable} from "../../shared/IVersionable.sol";
+import {ProxyManager} from "../../shared/ProxyManager.sol";
+import {ApplicationService} from "./ApplicationService.sol";
+
+contract ApplicationServiceManager is ProxyManager {
+
+    ApplicationService private _applicationService;
+
+    /// @dev initializes proxy manager with service implementation 
+    constructor(
+        address registryAddress
+    )
+        ProxyManager(registryAddress)
+    {
+        ApplicationService svc = new ApplicationService();
+        bytes memory data = abi.encode(registryAddress, address(this));
+        IVersionable versionable = deploy(
+            address(svc), 
+            data);
+
+        _applicationService = ApplicationService(address(versionable));
+    }
+
+    //--- view functions ----------------------------------------------------//
+    function getApplicationService()
+        external
+        view
+        returns (ApplicationService)
+    {
+        return _applicationService;
+    }
+}