@etherisc/gif-next 0.0.2-e0ff180-766 → 0.0.2-e14821a-976

package/contracts/product/PolicyServiceLib.sol

@@ -0,0 +1,139 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {InstanceReader} from "../instance/InstanceReader.sol";
+import {IPolicy} from "../instance/module/IPolicy.sol";
+import {IPolicyService} from "../product/IPolicyService.sol";
+import {NftId} from "../type/NftId.sol";
+import {StateId, CLOSED, COLLATERALIZED} from "../type/StateId.sol";
+import {Timestamp, TimestampLib} from "../type/Timestamp.sol";
+
+library PolicyServiceLib {
+
+    function policyIsActive(InstanceReader instanceReader, NftId policyNftId)
+        external 
+        view
+        returns (bool isActive)
+    {
+        // policy not collateralized
+        if (instanceReader.getPolicyState(policyNftId) != COLLATERALIZED()) {
+            return false;
+        }
+
+        IPolicy.PolicyInfo memory info = instanceReader.getPolicyInfo(policyNftId);
+
+        if (info.productNftId.eqz()) { return false; } // not closeable: policy does not exist (or does not belong to this instance)
+        if (info.activatedAt.eqz()) { return false; } // not closeable: not yet activated
+        if (info.activatedAt > TimestampLib.current()) { return false; } // not yet active
+        if (info.expiredAt <= TimestampLib.current()) { return false; } // already expired
+
+        return true;
+    }
+
+    function activate(
+        NftId policyNftId, 
+        IPolicy.PolicyInfo memory policyInfo,
+        Timestamp activateAt
+    )
+        external
+        pure 
+        returns (IPolicy.PolicyInfo memory)
+    {
+        // fail if policy has already been activated and activateAt is different
+        if(! policyInfo.activatedAt.eqz() && activateAt != policyInfo.activatedAt) {
+            revert IPolicyService.ErrorPolicyServicePolicyAlreadyActivated(policyNftId);
+        }
+
+        // ignore if policy has already been activated and activateAt is the same
+        if (policyInfo.activatedAt == activateAt) {
+            return policyInfo;
+        }
+
+        policyInfo.activatedAt = activateAt;
+        policyInfo.expiredAt = activateAt.addSeconds(policyInfo.lifetime);
+
+        return policyInfo;
+    }
+
+    function expire(
+        InstanceReader instanceReader,
+        NftId policyNftId,
+        IPolicy.PolicyInfo memory policyInfo,
+        Timestamp expireAt
+    )
+        external
+        view
+        returns (IPolicy.PolicyInfo memory)
+    {
+        StateId policyState = instanceReader.getPolicyState(policyNftId);
+
+        checkExpiration(
+            expireAt,
+            policyNftId,
+            policyState,
+            policyInfo);
+
+        // effects
+        // update policyInfo with new expiredAt timestamp
+        if (expireAt.gtz()) {
+            policyInfo.expiredAt = expireAt;
+        } else {
+            policyInfo.expiredAt = TimestampLib.current();
+        }
+
+        return policyInfo;
+    }
+
+    function checkExpiration(
+        Timestamp newExpiredAt,
+        NftId policyNftId,
+        StateId policyState,
+        IPolicy.PolicyInfo memory policyInfo
+    )
+        public 
+        view
+    {
+        if (policyState != COLLATERALIZED()) { 
+            revert IPolicyService.ErrorPolicyServicePolicyNotActive(policyNftId, policyState);
+        } 
+        if (TimestampLib.current() < policyInfo.activatedAt) { 
+            revert IPolicyService.ErrorPolicyServicePolicyNotActive(policyNftId, policyState);
+        } 
+
+        // check expiredAt represents a valid expiry time
+        if (newExpiredAt >= policyInfo.expiredAt) {
+            revert IPolicyService.ErrorPolicyServicePolicyExpirationTooLate(policyNftId, policyInfo.expiredAt, newExpiredAt);
+        }
+
+        if (newExpiredAt.gtz() && newExpiredAt < TimestampLib.current()) {
+            revert IPolicyService.ErrorPolicyServicePolicyExpirationTooEarly(policyNftId, TimestampLib.current(), newExpiredAt);
+        }
+    }
+
+    function policyIsCloseable(InstanceReader instanceReader, NftId policyNftId)
+        external 
+        view
+        returns (bool isCloseable)
+    {
+        // policy already closed
+        if (instanceReader.getPolicyState(policyNftId) == CLOSED()) {
+            return false;
+        }
+
+        IPolicy.PolicyInfo memory info = instanceReader.getPolicyInfo(policyNftId);
+        
+        if (info.productNftId.eqz()) { return false; } // not closeable: policy does not exist (or does not belong to this instance)
+        if (info.activatedAt.eqz()) { return false; } // not closeable: not yet activated
+        if (info.openClaimsCount > 0) { return false; } // not closeable: has open claims
+
+        // closeable: if sum of claims matches sum insured a policy may be closed prior to the expiry date
+        if (info.claimAmount == info.sumInsuredAmount) { return true; }
+
+        // not closeable: not yet expired
+        if (TimestampLib.current() < info.expiredAt) { return false; }
+
+        // all conditions to close the policy are met
+        return true; 
+    }
+
+}

package/contracts/product/PolicyServiceManager.sol

@@ -0,0 +1,39 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IVersionable} from "../upgradeability/IVersionable.sol";
+import {ProxyManager} from "../upgradeability/ProxyManager.sol";
+import {PolicyService} from "./PolicyService.sol";
+
+contract PolicyServiceManager is ProxyManager {
+
+    PolicyService private _policyService;
+
+    /// @dev initializes proxy manager with product service implementation 
+    constructor(
+        address authority, 
+        address registry,
+        bytes32 salt
+    ) 
+    {
+        PolicyService svc = new PolicyService{salt: salt}();
+        bytes memory data = abi.encode(authority, registry);
+        IVersionable versionable = initialize(
+            registry,
+            address(svc), 
+            data,
+            salt);
+
+        _policyService = PolicyService(address(versionable));
+    }
+
+    //--- view functions ----------------------------------------------------//
+    function getPolicyService()
+        external
+        view
+        returns (PolicyService policyService)
+    {
+        return _policyService;
+    }
+
+}

package/contracts/product/PricingService.sol

@@ -0,0 +1,318 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IBundle} from "../instance/module/IBundle.sol";
+import {IComponents} from "../instance/module/IComponents.sol";
+import {IDistribution} from "../instance/module/IDistribution.sol";
+import {IDistributionService} from "../distribution/IDistributionService.sol";
+import {IInstance} from "../instance/IInstance.sol";
+import {IPolicy} from "../instance/module/IPolicy.sol";
+import {IPricingService} from "./IPricingService.sol";
+import {IProductComponent} from "./IProductComponent.sol";
+import {IRegistry} from "../registry/IRegistry.sol";
+
+import {Amount} from "../type/Amount.sol";
+import {BUNDLE, DISTRIBUTION, PRICE, PRODUCT} from "../type/ObjectType.sol";
+import {ContractLib} from "../shared/ContractLib.sol";
+import {Fee} from "../type/Fee.sol";
+import {InstanceReader} from "../instance/InstanceReader.sol";
+import {NftId} from "../type/NftId.sol";
+import {ObjectType} from "../type/ObjectType.sol";
+import {ReferralId} from "../type/Referral.sol";
+import {RiskId} from "../type/RiskId.sol";
+import {Seconds} from "../type/Seconds.sol";
+import {Service} from "../shared/Service.sol";
+
+
+contract PricingService is 
+    Service, 
+    IPricingService
+{
+    // keccak256(abi.encode(uint256(keccak256("etherisc.gif.PricingService@3.0.0")) - 1)) & ~bytes32(uint256(0xff));
+    bytes32 public constant PRICING_SERVICE_STORAGE_LOCATION_V3_0 = 0x69339118ac24f243948ace3f64dcbea8699f7f0061492066c280ac597f7bd500;
+
+    struct PricingServiceStorage {
+        IDistributionService _distributionService;
+    }
+
+    function _initialize(
+        address owner, 
+        bytes memory data
+    )
+        internal
+        virtual override
+        initializer()
+    {
+        (
+            address authority,
+            address registry
+        ) = abi.decode(data, (address, address));
+
+        __Service_init(authority, registry, owner);
+
+        PricingServiceStorage storage $ = _getPricingServiceStorage();
+        $._distributionService = IDistributionService(_getServiceAddress(DISTRIBUTION()));
+
+        _registerInterface(type(IPricingService).interfaceId);
+    }
+
+    /// @dev calculates the premium amount for the specified attributes
+    /// also returns the various fee components involved with creating a policy
+    function calculatePremium(
+        NftId productNftId,
+        RiskId riskId,
+        Amount sumInsuredAmount,
+        Seconds lifetime,
+        bytes memory applicationData,
+        NftId bundleNftId,
+        ReferralId referralId
+    )
+        external
+        view
+        virtual override
+        returns (
+            IPolicy.PremiumInfo memory premium
+        )
+    {
+        _checkNftType(productNftId, PRODUCT());
+        _checkNftType(bundleNftId, BUNDLE());
+
+        InstanceReader reader;
+        Amount netPremiumAmount;
+
+        {
+            // verify product
+            (
+                IRegistry.ObjectInfo memory registryInfo, 
+                address instanceAddress
+            ) = ContractLib.getInfoAndInstance(getRegistry(), productNftId, false);
+
+            // get instance reader from local instance variable
+            reader = IInstance(instanceAddress).getInstanceReader();
+
+            NftId riskProductNftId = reader.getRiskInfo(riskId).productNftId;
+            if (productNftId != riskProductNftId) {
+                revert ErrorPricingServiceRiskProductMismatch(riskId, riskProductNftId, productNftId);
+            }
+
+            // calculate net premium
+            netPremiumAmount = IProductComponent(registryInfo.objectAddress).calculateNetPremium(
+                sumInsuredAmount,
+                riskId,
+                lifetime,
+                applicationData
+            );
+        }
+
+        {
+            // get configurations for all involed objects
+            IComponents.ProductInfo memory productInfo = reader.getProductInfo(productNftId);
+            IComponents.FeeInfo memory feeInfo = reader.getFeeInfo(productNftId);
+
+            IBundle.BundleInfo memory bundleInfo = reader.getBundleInfo(bundleNftId);
+            if(bundleInfo.poolNftId != productInfo.poolNftId) {
+                revert ErrorPricingServiceBundlePoolMismatch(bundleNftId, bundleInfo.poolNftId, productInfo.poolNftId);
+            }
+
+            // calculate fixed fees for product, pool, bundle
+            premium = _getFixedFeeAmounts(
+                netPremiumAmount,
+                feeInfo,
+                bundleInfo
+            );
+
+            // calculate variable fees for product, pool, bundle
+            premium = _calculateVariableFeeAmounts(
+                premium,
+                feeInfo,
+                bundleInfo
+            );
+
+            // calculate distribution fee and (if applicable) commission
+            premium = _calculateDistributionOwnerFeeAmount(
+                premium,
+                feeInfo,
+                productInfo.distributionNftId,
+                referralId,
+                reader
+            );
+
+            // calculate resulting amounts for product, pool, and distribution wallets
+            premium = _calculateTargetWalletAmounts(premium);
+
+            // sanity check to validate the fee calculation
+            if(premium.premiumAmount != premium.productFeeAmount 
+                + premium.distributionFeeAndCommissionAmount 
+                + premium.poolPremiumAndFeeAmount)
+            {
+                revert ErrorPricingServiceTargetWalletAmountsMismatch();
+            }
+
+            if (premium.distributionOwnerFeeFixAmount < feeInfo.minDistributionOwnerFee.fixedFee) {
+                revert ErrorPricingServiceFeeCalculationMismatch( 
+                    premium.distributionFeeFixAmount,
+                    premium.distributionFeeVarAmount,
+                    premium.distributionOwnerFeeFixAmount,
+                    premium.distributionOwnerFeeVarAmount,
+                    premium.commissionAmount,
+                    premium.discountAmount
+                );
+            }
+
+            if ((premium.distributionFeeVarAmount) != (premium.discountAmount + premium.distributionOwnerFeeVarAmount + premium.commissionAmount)) {
+                revert ErrorPricingServiceFeeCalculationMismatch(
+                    premium.distributionFeeFixAmount,
+                    premium.distributionFeeVarAmount,
+                    premium.distributionOwnerFeeFixAmount,
+                    premium.distributionOwnerFeeVarAmount,
+                    premium.commissionAmount,
+                    premium.discountAmount
+                );
+            }
+        }
+    }
+
+    // internal functions
+    function _getFixedFeeAmounts(
+        Amount netPremiumAmount,
+        IComponents.FeeInfo memory feeInfo,
+        IBundle.BundleInfo memory bundleInfo
+    )
+        internal
+        pure
+        returns (
+            IPolicy.PremiumInfo memory premium
+        )
+    {
+        // initial premium amount is the net premium
+        premium.netPremiumAmount = netPremiumAmount;
+        premium.fullPremiumAmount = netPremiumAmount;
+
+        Amount t = feeInfo.productFee.fixedFee;
+        premium.productFeeFixAmount = t;
+        premium.fullPremiumAmount = premium.fullPremiumAmount + t;
+
+        t = feeInfo.poolFee.fixedFee;
+        premium.poolFeeFixAmount = t;
+        premium.fullPremiumAmount = premium.fullPremiumAmount + t;
+
+        t = bundleInfo.fee.fixedFee;
+        premium.bundleFeeFixAmount = t;
+        premium.fullPremiumAmount = premium.fullPremiumAmount + t;
+
+        t = feeInfo.distributionFee.fixedFee;
+        premium.distributionFeeFixAmount = t;
+        premium.fullPremiumAmount = premium.fullPremiumAmount + t;
+    }
+
+    function _calculateVariableFeeAmounts(
+        IPolicy.PremiumInfo memory premium,
+        IComponents.FeeInfo memory feeInfo,
+        IBundle.BundleInfo memory bundleInfo
+    )
+        internal
+        pure
+        returns (
+            IPolicy.PremiumInfo memory intermadiatePremium
+        )
+    {
+        Amount netPremiumAmount = premium.netPremiumAmount;
+
+        Amount t = netPremiumAmount.multiplyWith(feeInfo.productFee.fractionalFee);
+        premium.productFeeVarAmount = t;
+        premium.fullPremiumAmount = premium.fullPremiumAmount + t;
+
+        t = netPremiumAmount.multiplyWith(feeInfo.poolFee.fractionalFee);
+        premium.poolFeeVarAmount = t;
+        premium.fullPremiumAmount = premium.fullPremiumAmount + t;
+
+        t = netPremiumAmount.multiplyWith(bundleInfo.fee.fractionalFee);
+        premium.bundleFeeVarAmount = t;
+        premium.fullPremiumAmount = premium.fullPremiumAmount + t;
+
+        t = netPremiumAmount.multiplyWith(feeInfo.distributionFee.fractionalFee);
+        premium.distributionFeeVarAmount = t;
+        premium.fullPremiumAmount = premium.fullPremiumAmount + t;
+
+        return premium;
+    }
+
+    function _calculateDistributionOwnerFeeAmount(
+        IPolicy.PremiumInfo memory premium,
+        IComponents.FeeInfo memory feeInfo,
+        NftId distributionNftId,
+        // ISetup.DistributionSetupInfo memory distInfo,
+        ReferralId referralId,
+        InstanceReader reader
+    )
+        internal
+        view 
+        returns (IPolicy.PremiumInfo memory finalPremium)
+    {
+        PricingServiceStorage storage $ = _getPricingServiceStorage();
+        // if the referral is not valid, then the distribution owner gets everything
+        if (distributionNftId.eqz() || ! $._distributionService.referralIsValid(distributionNftId, referralId)) {
+            premium.distributionOwnerFeeFixAmount = premium.distributionFeeFixAmount;
+            premium.distributionOwnerFeeVarAmount = premium.distributionFeeVarAmount;
+            premium.premiumAmount = premium.fullPremiumAmount;
+            return premium;
+        }
+
+        Fee memory minDistributionOwnerFee = feeInfo.minDistributionOwnerFee;
+
+        // if the referral is valid, then the commission and discount are calculated based in the full premium
+        // the remaing amount goes to the distribution owner
+        {
+            IDistribution.ReferralInfo memory referralInfo = reader.getReferralInfo(referralId);
+            IDistribution.DistributorInfo memory distributorInfo = reader.getDistributorInfo(referralInfo.distributorNftId);
+            IDistribution.DistributorTypeInfo memory distributorTypeInfo = reader.getDistributorTypeInfo(distributorInfo.distributorType);
+
+            Amount commissionAmount = premium.netPremiumAmount.multiplyWith(distributorTypeInfo.commissionPercentage);
+            premium.commissionAmount = commissionAmount;
+            premium.discountAmount = premium.fullPremiumAmount.multiplyWith(referralInfo.discountPercentage);
+            premium.distributionOwnerFeeFixAmount = minDistributionOwnerFee.fixedFee;
+            premium.distributionOwnerFeeVarAmount = premium.distributionFeeVarAmount - commissionAmount - premium.discountAmount;
+            premium.premiumAmount = premium.fullPremiumAmount - premium.discountAmount;
+        }
+
+        return premium; 
+    }
+
+
+    function _calculateTargetWalletAmounts(
+        IPolicy.PremiumInfo memory premium
+    )
+        internal
+        virtual
+        view
+        returns (
+            IPolicy.PremiumInfo memory premiumWithTargetWalletAmounts
+        )
+    {
+        // fees for product owner
+        premium.productFeeAmount = premium.productFeeFixAmount + premium.productFeeVarAmount;
+
+        // fees for distribution owner + distributor commission
+        premium.distributionFeeAndCommissionAmount = 
+            premium.distributionFeeFixAmount + premium.distributionOwnerFeeVarAmount 
+            + premium.commissionAmount;
+
+        // net premium + fees for pool owner + bundle owner
+        premium.poolPremiumAndFeeAmount = premium.netPremiumAmount 
+            + premium.poolFeeFixAmount + premium.poolFeeVarAmount 
+            + premium.bundleFeeFixAmount + premium.bundleFeeVarAmount;
+
+        premiumWithTargetWalletAmounts = premium;
+    }
+
+    function _getPricingServiceStorage() private pure returns (PricingServiceStorage storage $) {
+        // solhint-disable-next-line no-inline-assembly
+        assembly {
+            $.slot := PRICING_SERVICE_STORAGE_LOCATION_V3_0
+        }
+    }
+
+    function _getDomain() internal pure override returns(ObjectType) {
+        return PRICE();
+    }
+}

package/contracts/product/PricingServiceManager.sol

@@ -0,0 +1,39 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IVersionable} from "../upgradeability/IVersionable.sol";
+import {ProxyManager} from "../upgradeability/ProxyManager.sol";
+import {PricingService} from "./PricingService.sol";
+
+contract PricingServiceManager is ProxyManager {
+
+    PricingService private _pricingService;
+
+    /// @dev initializes proxy manager with pricing service implementation and deploys instance
+    constructor(
+        address authority, 
+        address registry,
+        bytes32 salt
+    )
+    {
+        PricingService pricingSrv = new PricingService{salt: salt}();
+        bytes memory data = abi.encode(authority, registry);
+        IVersionable versionable = initialize(
+            registry,
+            address(pricingSrv), 
+            data,
+            salt);
+
+        _pricingService = PricingService(address(versionable));
+    }
+
+    //--- view functions ----------------------------------------------------//
+    function getPricingService()
+        external
+        view
+        returns (PricingService)
+    {
+        return _pricingService;
+    }
+
+}