@etherisc/gif-next 0.0.2-e0ff180-766 → 0.0.2-e14821a-976

package/contracts/examples/unpermissioned/SimpleProduct.sol

@@ -0,0 +1,437 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+
+import {Amount, AmountLib} from "../../type/Amount.sol";
+import {BasicProduct} from "../../product/BasicProduct.sol";
+import {ClaimId} from "../../type/ClaimId.sol";
+import {IAuthorization} from "../../authorization/IAuthorization.sol";
+import {IComponents} from "../../instance/module/IComponents.sol";
+import {IOracleService} from "../../oracle/IOracleService.sol";
+import {ORACLE} from "../../type/ObjectType.sol";
+import {NftId} from "../../type/NftId.sol";
+import {PayoutId} from "../../type/PayoutId.sol";
+import {ReferralId} from "../../type/Referral.sol";
+import {RequestId} from "../../type/RequestId.sol";
+import {RiskId} from "../../type/RiskId.sol";
+import {Seconds} from "../../type/Seconds.sol";
+import {SimpleOracle} from "./SimpleOracle.sol";
+import {StateId} from "../../type/StateId.sol";
+import {Timestamp, TimestampLib} from "../../type/Timestamp.sol";
+
+uint64 constant SPECIAL_ROLE_INT = 11111;
+
+contract SimpleProduct is 
+    BasicProduct
+{
+
+    event LogSimpleProductRequestAsyncFulfilled(RequestId requestId, string responseText, uint256 responseDataLength);
+    event LogSimpleProductRequestSyncFulfilled(RequestId requestId, string responseText, uint256 responseDataLength);
+
+    error ErrorSimpleProductRevertedWhileProcessingResponse(RequestId requestId);
+
+    IOracleService private _oracleService;
+
+    constructor(
+        address registry,
+        NftId instanceNftId,
+        string memory name,
+        IComponents.ProductInfo memory productInfo,
+        IComponents.FeeInfo memory feeInfo,
+        IAuthorization authorization,
+        address initialOwner
+    )
+    {
+        initialize(
+            registry,
+            instanceNftId,
+            name,
+            productInfo,
+            feeInfo,
+            authorization,
+            initialOwner); 
+    }
+
+
+    function initialize(
+        address registry,
+        NftId instanceNftid,
+        string memory name,
+        IComponents.ProductInfo memory productInfo,
+        IComponents.FeeInfo memory feeInfo,
+        IAuthorization authorization,
+        address initialOwner
+    )
+        public
+        virtual
+        initializer()
+    {
+        _initializeBasicProduct(
+            registry,
+            instanceNftid,
+            name,
+            productInfo,
+            feeInfo,
+            authorization,
+            initialOwner); 
+
+        _oracleService = IOracleService(_getServiceAddress(ORACLE()));
+    }
+
+
+    function createRisk(
+        string memory id,
+        bytes memory data
+    ) public returns (RiskId) {
+        return _createRisk(
+            bytes32(abi.encodePacked(id)),
+            data
+        );
+    }
+
+    function updateRisk(
+        RiskId id,
+        bytes memory data
+    ) public {
+        _updateRisk(
+            id,
+            data
+        );
+    }
+
+    function setRiskLocked(
+        RiskId id,
+        bool locked
+    ) public {
+        _setRiskLocked(
+            id,
+            locked
+        );
+    }
+
+    function closeRisk(
+        RiskId id
+    ) public {
+        _closeRisk(id);
+    }
+
+    function createApplication(
+        address applicationOwner,
+        RiskId riskId,
+        uint256 sumInsured,
+        Seconds lifetime,
+        bytes memory applicationData,
+        NftId bundleNftId,
+        ReferralId referralId
+    )
+        public
+        returns (NftId nftId)
+    {
+        Amount sumInsuredAmount = AmountLib.toAmount(sumInsured);
+        Amount premiumAmount = calculatePremium(
+            sumInsuredAmount,
+            riskId,
+            lifetime,
+            applicationData,
+            bundleNftId,
+            referralId);
+
+        return _createApplication(
+            applicationOwner,
+            riskId,
+            sumInsuredAmount,
+            premiumAmount,
+            lifetime,
+            bundleNftId,
+            referralId,
+            applicationData
+        );
+    }
+
+    function createApplication2(
+        address applicationOwner,
+        RiskId riskId,
+        Amount sumInsuredAmount,
+        Amount premiumAmount,
+        Seconds lifetime,
+        bytes memory applicationData,
+        NftId bundleNftId,
+        ReferralId referralId
+    )
+        public
+        returns (NftId nftId)
+    {
+        return _createApplication(
+            applicationOwner,
+            riskId,
+            sumInsuredAmount,
+            premiumAmount,
+            lifetime,
+            bundleNftId,
+            referralId,
+            applicationData
+        );
+    }
+    
+    function revoke(
+        NftId applicationNftId
+    ) public {
+        _revoke(applicationNftId);
+    }
+
+    function createPolicy(
+        NftId applicationNftId,
+        bool requirePremiumPayment,
+        Timestamp activateAt
+    ) public {
+        _createPolicy(applicationNftId, activateAt, AmountLib.max());
+        if (requirePremiumPayment == true) {
+            _collectPremium(applicationNftId, activateAt);
+        }
+    }
+
+    function createPolicy2(
+        NftId applicationNftId,
+        bool requirePremiumPayment,
+        Timestamp activateAt,
+        Amount maxPremiumAmount
+    ) public {
+        _createPolicy(applicationNftId, activateAt, maxPremiumAmount);
+        if (requirePremiumPayment == true) {
+            _collectPremium(applicationNftId, activateAt);
+        }
+    }
+
+    function decline(
+        NftId policyNftId
+    ) public {
+        _decline(policyNftId);
+    }
+
+    function expire(
+        NftId policyNftId,
+        Timestamp expireAt
+    ) 
+        public 
+        returns (Timestamp)
+    {
+        return _expire(policyNftId, expireAt);
+    }
+
+    function collectPremium(
+        NftId policyNftId,
+        Timestamp activateAt
+    ) public {
+        _collectPremium(policyNftId, activateAt);
+    }
+
+    function activate(
+        NftId policyNftId,
+        Timestamp activateAt
+    ) public {
+        _activate(policyNftId, activateAt);
+    }
+
+    function adjustActivation(
+        NftId policyNftId,
+        Timestamp activateAt
+    ) public {
+        _adjustActivation(policyNftId, activateAt);
+    }
+
+    function close(
+        NftId policyNftId
+    ) public {
+        _close(policyNftId);
+    }
+
+    function submitClaim(
+        NftId policyNftId,
+        Amount claimAmount,
+        bytes memory submissionData
+    ) public returns (ClaimId) {
+        return _submitClaim(policyNftId, claimAmount, submissionData);
+    }
+
+    function revokeClaim(
+        NftId policyNftId,
+        ClaimId claimId
+    ) public {
+        _revokeClaim(policyNftId, claimId);
+    }
+
+    function confirmClaim(
+        NftId policyNftId,
+        ClaimId claimId,
+        Amount confirmedAmount,
+        bytes memory processData
+    ) public {
+        _confirmClaim(policyNftId, claimId, confirmedAmount, processData);
+    }
+
+    function declineClaim(
+        NftId policyNftId,
+        ClaimId claimId,
+        bytes memory processData
+    ) public {
+        _declineClaim(policyNftId, claimId, processData);
+    }
+
+    function cancelConfirmedClaim(
+        NftId policyNftId,
+        ClaimId claimId
+    ) public {
+        _cancelConfirmedClaim(policyNftId, claimId);
+    }
+
+    function createPayout(
+        NftId policyNftId,
+        ClaimId claimId,
+        Amount amount,
+        bytes memory data
+    ) public returns (PayoutId) {
+        return _createPayout(policyNftId, claimId, amount, data);
+    }
+
+    function cancelPayout(
+        NftId policyNftId,
+        PayoutId payoutId
+    ) public {
+        _cancelPayout(policyNftId, payoutId);
+    }
+
+    // TODO add test
+    function createPayoutForBeneficiary(
+        NftId policyNftId,
+        ClaimId claimId,
+        Amount amount,
+        address beneficiary,
+        bytes memory data
+    ) public returns (PayoutId) {
+        return _createPayoutForBeneficiary(policyNftId, claimId, amount, beneficiary, data);
+    }
+
+    function processPayout(
+        NftId policyNftId,
+        PayoutId payoutId
+    ) public returns (Amount netPayoutAmount, Amount processingFeeAmount) {
+        (netPayoutAmount, processingFeeAmount) = _processPayout(policyNftId, payoutId);
+    }
+
+    function createOracleRequest(
+        NftId oracleNftId,
+        string memory requestText,
+        Timestamp expiryAt,
+        bool synchronous
+    )
+        public
+        // restricted()
+        returns (RequestId)
+    {
+        bytes memory requestData = abi.encode(SimpleOracle.SimpleRequest(
+            synchronous,
+            requestText));
+
+        if (synchronous) {
+            return _oracleService.request(
+                oracleNftId, 
+                requestData, 
+                expiryAt, 
+                "fulfillOracleRequestSync");
+        } else {
+            return _oracleService.request(
+                oracleNftId, 
+                requestData, 
+                expiryAt, 
+                "fulfillOracleRequestAsync");
+        }
+    }
+
+    function createOracleRequest2(
+        NftId oracleNftId,
+        string memory requestText,
+        Timestamp expiryAt,
+        bool synchronous,
+        string memory callbackMethod
+    )
+        public
+        // restricted()
+        returns (RequestId)
+    {
+        bytes memory requestData = abi.encode(SimpleOracle.SimpleRequest(
+            synchronous,
+            requestText));
+
+        return _oracleService.request(
+            oracleNftId, 
+            requestData, 
+            expiryAt, 
+            callbackMethod);
+    }
+
+    function cancelOracleRequest(
+        RequestId requestId
+    )
+        public
+        // restricted() // 
+    {
+        _oracleService.cancel(requestId);
+    }
+
+    function fulfillOracleRequestSync(
+        RequestId requestId,
+        bytes memory responseData
+    )
+        public
+        // restricted() // only oracle service
+    {
+        string memory responseText = abi.decode(responseData, (string));
+        emit LogSimpleProductRequestSyncFulfilled(requestId, responseText, bytes(responseText).length);
+    }
+
+    function fulfillOracleRequestAsync(
+        RequestId requestId,
+        bytes memory responseData
+    )
+        public
+        // restricted() // only oracle service
+    {
+        SimpleOracle.SimpleResponse memory response = abi.decode(
+            responseData, (SimpleOracle.SimpleResponse));
+
+        if (response.revertInCall && response.revertUntil >= TimestampLib.current()) {
+            revert ErrorSimpleProductRevertedWhileProcessingResponse(requestId);
+        }
+
+        emit LogSimpleProductRequestAsyncFulfilled(requestId, response.text, bytes(response.text).length);
+    }
+
+
+    function resend(
+        RequestId requestId
+    )
+        public
+        // restricted() // 
+    {
+        _oracleService.resend(requestId);
+    }
+
+
+    function doSomethingOnlyWhenActive() 
+        public 
+        onlyActive()
+        returns (bool) 
+    {
+        return true;
+    }
+
+
+    function getOracleService() public view returns (IOracleService) {
+        return _oracleService;
+    }
+
+    function approveTokenHandler(IERC20Metadata token, Amount amount) external restricted() onlyOwner() { _approveTokenHandler(token, amount); }
+    function setLocked(bool locked) external onlyOwner() { _setLocked(locked); }
+    function setWallet(address newWallet) external restricted() onlyOwner() { _setWallet(newWallet); }
+}

package/contracts/examples/unpermissioned/SimpleProductAuthorization.sol

@@ -0,0 +1,28 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {BasicProductAuthorization} from "../../product/BasicProductAuthorization.sol";
+import {IAccess} from "../../authorization/IAccess.sol";
+import {PUBLIC_ROLE} from "../../type/RoleId.sol";
+import {SimpleProduct} from "./SimpleProduct.sol";
+
+contract SimpleProductAuthorization
+    is BasicProductAuthorization
+{
+    constructor(string memory componentName)
+        BasicProductAuthorization(componentName)
+    {}
+
+    function _setupTargetAuthorizations()
+        internal
+        virtual override
+    {
+        super._setupTargetAuthorizations();
+
+        // authorize public role (open access to any account, only allows to lock target)
+        IAccess.FunctionInfo[] storage functions;
+        functions = _authorizeForTarget(getMainTargetName(), PUBLIC_ROLE());
+        _authorize(functions, SimpleProduct.approveTokenHandler.selector, "approveTokenHandler");
+        _authorize(functions, SimpleProduct.setWallet.selector, "setWallet");
+    }
+}

package/contracts/instance/BaseStore.sol

@@ -0,0 +1,93 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IBaseStore} from "./IBaseStore.sol";
+
+import {Blocknumber, BlocknumberLib} from "../type/Blocknumber.sol";
+import {Key32, KeyId, Key32Lib} from "../type/Key32.sol";
+import {ObjectType} from "../type/ObjectType.sol";
+import {StateId, KEEP_STATE} from "../type/StateId.sol";
+import {Lifecycle} from "../shared/Lifecycle.sol";
+
+abstract contract BaseStore is
+    Lifecycle, 
+    IBaseStore
+{
+
+    mapping(Key32 key32 => IBaseStore.Metadata metadata) private _metadata;
+
+    function _createMetadata(
+        Key32 key32
+    )
+        internal
+    {
+        ObjectType objectType = key32.toObjectType();
+        if (objectType.eqz()) {
+            revert ErrorBaseStoreTypeUndefined(objectType);
+        }
+
+        Metadata storage metadata = _metadata[key32];
+        if (metadata.updatedIn.gtz()) {
+            revert ErrorBaseStoreAlreadyCreated(key32, objectType);
+        }
+
+        if(!hasLifecycle(objectType)) {
+            revert ErrorBaseStoreNoLifecycle(objectType);
+        }
+
+        Blocknumber blocknumber = BlocknumberLib.current();
+        StateId initialState = getInitialState(objectType);
+
+        // set metadata
+        metadata.objectType = objectType;
+        metadata.state = initialState;
+        metadata.updatedIn = blocknumber;
+    }
+
+    function _updateState(
+        Key32 key32, 
+        StateId state
+    )
+        internal
+        returns (Blocknumber lastUpdatedIn, StateId oldState)
+    {
+        if (state.eqz()) {
+            revert ErrorBaseStoreStateZero(key32);
+        }
+
+        Metadata storage metadata = _metadata[key32];
+        oldState = metadata.state;
+        lastUpdatedIn = metadata.updatedIn;
+
+        if (oldState.eqz()) {
+            revert ErrorBaseStoreNotExisting(key32);
+        }
+
+        // update state 
+        if(state != KEEP_STATE()) {
+            checkTransition(oldState, metadata.objectType, oldState, state);
+            metadata.state = state;
+
+            // solhint-disable-next-line avoid-tx-origin
+        }
+
+        // update metadata
+        metadata.updatedIn = BlocknumberLib.current();
+    }
+
+    function exists(Key32 key32) public view returns (bool) {
+        return _metadata[key32].state.gtz();
+    }
+
+    function getMetadata(Key32 key32) public view returns (Metadata memory metadata) {
+        return _metadata[key32];
+    }
+
+    function getState(Key32 key32) public view returns (StateId state) {
+        return _metadata[key32].state;
+    }
+
+    function toKey32(ObjectType objectType, KeyId id) external pure override returns(Key32) {
+        return Key32Lib.toKey32(objectType, id);
+    }
+}

package/contracts/instance/BundleSet.sol

@@ -0,0 +1,130 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {LibNftIdSet} from "../type/NftIdSet.sol";
+import {NftId, NftIdLib} from "../type/NftId.sol";
+import {Key32} from "../type/Key32.sol";
+import {BUNDLE} from "../type/ObjectType.sol";
+
+import {ObjectSet} from "./base/ObjectSet.sol";
+import {ObjectSetHelperLib} from "./base/ObjectSetHelperLib.sol";
+
+contract BundleSet is 
+    ObjectSet
+{
+    using LibNftIdSet for LibNftIdSet.Set;
+
+    event LogBundleSetPolicyLinked(NftId bundleNftId, NftId policyNftId);
+    event LogBundleSetPolicyUnlinked(NftId bundleNftId, NftId policyNftId);
+
+    event LogBundleSetBundleAdded(NftId poolNftId, NftId bundleNftId);
+    event LogBundleSetBundleUnlocked(NftId poolNftId, NftId bundleNftId);
+    event LogBundleSetBundleLocked(NftId poolNftId, NftId bundleNftId);
+    event LogBundleSetBundleClosed(NftId poolNftId, NftId bundleNftId);
+
+    error ErrorBundleSetPolicyAlreadyActivated(NftId policyNftId);
+    error ErrorBundleSetBundleLocked(NftId bundleNftId, NftId policyNftId);
+    error ErrorBundleSetPolicyWithOpenClaims(NftId policyNftId, uint256 openClaimsCount);
+    error ErrorBundleSetPolicyNotCloseable(NftId policyNftId);
+    error ErrorBundleSetBundleUnknown(NftId bundleNftId);
+    error ErrorBundleSetBundleNotRegistered(NftId bundleNftId);
+
+    mapping(NftId bundleNftId => LibNftIdSet.Set policies) internal _activePolicies;
+
+    /// @dev links a policy to its bundle
+    function linkPolicy(NftId poolNftId, NftId bundleNftId, NftId policyNftId) external restricted() {
+
+        // ensure bundle is unlocked (in active set) and registered with this instance
+        if (!_isActive(poolNftId, _toBundleKey32(bundleNftId))) {
+            revert ErrorBundleSetBundleLocked(bundleNftId, policyNftId);
+        }
+
+        _activePolicies[bundleNftId].add(policyNftId);
+        emit LogBundleSetPolicyLinked(bundleNftId, policyNftId);
+    }
+
+
+    /// @dev unlinks a policy from its bundle
+    function unlinkPolicy(NftId poolNftId, NftId bundleNftId, NftId policyNftId) external restricted() {
+
+        // ensure bundle is registered with this instance
+        if (!_contains(poolNftId, _toBundleKey32(bundleNftId))) {
+            revert ErrorBundleSetBundleUnknown(bundleNftId);
+        }
+
+        _activePolicies[bundleNftId].remove(policyNftId);
+        emit LogBundleSetPolicyUnlinked(bundleNftId, policyNftId);
+    }
+
+
+    /// @dev add a new bundle to a pool registerd with this instance
+    // the corresponding pool is fetched via instance reader
+    function add(NftId bundleNftId) external restricted() {
+        NftId poolNftId = ObjectSetHelperLib.getPoolNftId(_instanceAddress, bundleNftId);
+
+        // ensure pool is registered with instance
+        if(poolNftId.eqz()) {
+            revert ErrorBundleSetBundleNotRegistered(bundleNftId);
+        }
+
+        _add(poolNftId, _toBundleKey32(bundleNftId));
+        emit LogBundleSetBundleAdded(poolNftId, bundleNftId);
+    }
+
+
+    /// @dev unlocked (active) bundles are available to collateralize new policies
+    function unlock(NftId bundleNftId) external restricted() {
+        NftId poolNftId = ObjectSetHelperLib.getPoolNftId(_instanceAddress, bundleNftId);
+        _activate(poolNftId, _toBundleKey32(bundleNftId));
+        emit LogBundleSetBundleUnlocked(poolNftId, bundleNftId);
+    }
+
+    /// @dev locked (deactivated) bundles may not collateralize any new policies
+    function lock(NftId bundleNftId) external restricted() {
+        NftId poolNftId = ObjectSetHelperLib.getPoolNftId(_instanceAddress, bundleNftId);
+        _deactivate(poolNftId, _toBundleKey32(bundleNftId));
+        emit LogBundleSetBundleLocked(poolNftId, bundleNftId);
+    }
+
+
+    function checkBundle(NftId productNftId, NftId bundleId)
+        public
+        view 
+        returns (bool exists, bool active)
+    {
+        Key32 bundleKey32 = bundleId.toKey32(BUNDLE());
+        exists = _contains(productNftId, bundleKey32);
+
+        if (exists) {
+            active = _isActive(productNftId, bundleKey32);
+        }
+    }
+
+    function bundles(NftId poolNftId) external view returns(uint256) {
+        return _objects(poolNftId);
+    }
+
+    function getBundleNftId(NftId poolNftId, uint256 idx) external view returns(NftId) {
+        return NftIdLib.toNftId(_getObject(poolNftId, idx).toKeyId());
+    }
+
+    function activeBundles(NftId poolNftId) external view returns(uint256) {
+        return _activeObjs(poolNftId);
+    }
+
+    function getActiveBundleNftId(NftId poolNftId, uint256 idx) external view returns(NftId) {
+        return NftIdLib.toNftId(_getActiveObject(poolNftId, idx).toKeyId());
+    }
+
+    function activePolicies(NftId bundleNftId) external view returns(uint256) {
+        return _activePolicies[bundleNftId].size();
+    }
+
+    function getActivePolicy(NftId bundleNftId, uint256 idx) external view returns(NftId policyNftId) {
+        return _activePolicies[bundleNftId].getElementAt(idx);
+    }
+
+    function _toBundleKey32(NftId nftId) private pure returns (Key32) {
+        return nftId.toKey32(BUNDLE());
+    }
+}