@etherisc/gif-next 0.0.2-e0ff180-567 → 0.0.2-e14821a-976

package/contracts/staking/StakingLib.sol

@@ -0,0 +1,195 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IRegistry} from "../registry/IRegistry.sol";
+import {IStaking} from "./IStaking.sol";
+import {IStakingService} from "./IStakingService.sol";
+
+import {Amount} from "../type/Amount.sol";
+import {NftId} from "../type/NftId.sol";
+import {ReleaseRegistry} from "../registry/ReleaseRegistry.sol";
+import {Seconds, SecondsLib} from "../type/Seconds.sol";
+import {StakingReader} from "./StakingReader.sol";
+import {STAKING} from "../type/ObjectType.sol";
+import {Timestamp, TimestampLib} from "../type/Timestamp.sol";
+import {UFixed, UFixedLib} from "../type/UFixed.sol";
+import {VersionPart} from "../type/Version.sol";
+
+
+library StakingLib {
+
+    function checkCreateParameters(
+        StakingReader stakingReader,
+        NftId targetNftId, 
+        Amount dipAmount
+    )
+        external
+        view
+        returns (
+            Timestamp lockedUntil
+        )
+    {
+        return _checkCreateParameters(stakingReader, targetNftId, dipAmount);
+    }
+
+
+    function _checkCreateParameters(
+        StakingReader stakingReader,
+        NftId targetNftId, 
+        Amount dipAmount
+    )
+        internal view
+        returns (
+            Timestamp lockedUntil
+        )
+    {
+        Seconds lockingPeriod = checkTarget(stakingReader, targetNftId);
+        checkDipAmount(stakingReader, targetNftId, dipAmount);
+
+        Timestamp currentTime = TimestampLib.current();
+        lockedUntil = currentTime.addSeconds(lockingPeriod);
+    }
+
+
+    function checkStakeParameters(
+        StakingReader stakingReader,
+        NftId stakeNftId
+    )
+        public
+        view
+        returns (
+            UFixed rewardRate,
+            Seconds lockingPeriod
+        )
+    {
+        NftId targetNftId = stakingReader.getTargetNftId(stakeNftId);
+
+        // target nft id must be registered
+        if (!stakingReader.isTarget(targetNftId)) {
+            revert IStaking.ErrorStakingNotTarget(targetNftId);
+        }
+        
+        IStaking.TargetInfo memory info = stakingReader.getTargetInfo(targetNftId);
+        rewardRate = info.rewardRate;
+        lockingPeriod = info.lockingPeriod;
+    }
+
+
+    function checkUnstakeParameters(
+        StakingReader stakingReader,
+        NftId stakeNftId
+    )
+        public
+        view
+        returns (
+            Seconds lockingPeriod
+        )
+    {
+        IStaking.StakeInfo memory stakeInfo = stakingReader.getStakeInfo(stakeNftId);
+        
+        if (stakeInfo.lockedUntil > TimestampLib.current()) {
+            revert IStaking.ErrorStakingStakeLocked(stakeNftId, stakeInfo.lockedUntil);
+        }
+    }
+
+
+    function checkTarget(
+        StakingReader stakingReader,
+        NftId targetNftId
+    )
+        public
+        view
+        returns (Seconds lockingPeriod)
+    {
+        // target nft id must be registered
+        if (!stakingReader.isTarget(targetNftId)) {
+            revert IStaking.ErrorStakingNotTarget(targetNftId);
+        }
+
+        lockingPeriod = stakingReader.getTargetInfo(targetNftId).lockingPeriod;
+    }
+
+
+    function checkAndGetStakingService(
+        IRegistry registry,
+        VersionPart release
+    )
+        public
+        view
+        returns (IStakingService stakingService)
+    {
+        if (!ReleaseRegistry(registry.getReleaseRegistryAddress()).isActiveRelease(release)) {
+            revert IStaking.ErrorStakingReleaseNotActive(release);
+        }
+
+        address stakingServiceAddress = registry.getServiceAddress(STAKING(), release);
+        if (stakingServiceAddress == address(0)) {
+            revert IStaking.ErrorStakingServiceNotFound(release);
+        }
+
+        return IStakingService(stakingServiceAddress);
+    }
+
+
+    function checkDipAmount(
+        StakingReader stakingReader,
+        NftId targetNftId, 
+        Amount dipAmount
+    )
+        public 
+        view 
+    {
+        // check stake amount > 0
+        if (dipAmount.eqz()) {
+            revert IStaking.ErrorStakingStakeAmountZero(targetNftId);
+        }
+
+        Amount stakeLimitAmount = stakingReader.getTargetMaxStakedAmount(targetNftId);
+        if (dipAmount > stakeLimitAmount) {
+            revert IStaking.ErrorStakingTargetMaxStakedAmountExceeded(targetNftId, stakeLimitAmount, dipAmount);
+        }
+    }
+
+    function calculateRewardIncrease(
+        StakingReader stakingReader,
+        NftId stakeNftId,
+        UFixed rewardRate
+    )
+        public
+        view
+        returns (
+            Amount rewardIncreaseAmount
+        )
+    {
+        IStaking.StakeInfo memory stakeInfo = stakingReader.getStakeInfo(stakeNftId);
+
+        Seconds duration = SecondsLib.toSeconds(
+            block.timestamp - stakeInfo.lastUpdateAt.toInt());
+        
+        rewardIncreaseAmount = calculateRewardAmount(
+            rewardRate,
+            duration,
+            stakeInfo.stakedAmount);
+    }
+
+    function calculateRewardAmount(
+        UFixed rewardRate,
+        Seconds duration, 
+        Amount stakeAmount
+    )
+        public 
+        pure 
+        returns(
+            Amount rewardAmount
+        )
+    {
+        UFixed rewardRateFraction = getYearFraction(duration) * rewardRate;
+        rewardAmount = stakeAmount.multiplyWith(rewardRateFraction);
+    }
+
+
+    function getYearFraction(Seconds duration) public pure returns (UFixed yearFraction) {
+        return UFixedLib.toUFixed(duration.toInt()) / UFixedLib.toUFixed(SecondsLib.oneYear().toInt());
+    }
+
+}

package/contracts/staking/StakingManager.sol

@@ -0,0 +1,53 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IVersionable} from "../upgradeability/IVersionable.sol";
+import {ProxyManager} from "../upgradeability/ProxyManager.sol";
+import {Staking} from "./Staking.sol";
+
+
+contract StakingManager is
+    ProxyManager
+{
+    Staking private _staking;
+    address private _initialImplementation;
+    bytes private _initializationData;
+
+    /// @dev initializes proxy manager with service implementation 
+    constructor(
+        address registry,
+        address targetHandler,
+        address stakingStore,
+        address tokenRegistry,
+        address initialOwner,
+        bytes32 salt
+    )
+    {
+        Staking stakingImplementation = new Staking();
+
+        _initialImplementation = address(stakingImplementation);
+        _initializationData = abi.encode(
+            registry,
+            targetHandler,
+            stakingStore,
+            tokenRegistry);
+        
+        IVersionable versionable = initialize(
+            registry,
+            _initialImplementation,
+            _initializationData,
+            salt);
+
+        _staking = Staking(address(versionable));
+    }
+
+    //--- view functions ----------------------------------------------------//
+
+    function getStaking()
+        external
+        view
+        returns (Staking)
+    {
+        return _staking;
+    }
+}

package/contracts/staking/StakingReader.sol

@@ -0,0 +1,171 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Initializable} from "@openzeppelin/contracts-upgradeable/proxy/utils/Initializable.sol"; 
+
+import {IRegistry} from "../registry/IRegistry.sol";
+import {IRegistryLinked} from "../shared/IRegistryLinked.sol";
+import {IStaking} from "../staking/IStaking.sol";
+
+import {Amount, AmountLib} from "../type/Amount.sol";
+import {Blocknumber}  from "../type/Blocknumber.sol";
+import {ChainId}  from "../type/ChainId.sol";
+import {NftId} from "../type/NftId.sol";
+import {ObjectType} from "../type/ObjectType.sol";
+import {Seconds} from "../type/Seconds.sol";
+import {StakingStore} from "./StakingStore.sol";
+import {STAKE, TARGET} from "../type/ObjectType.sol";
+import {Timestamp} from "../type/Timestamp.sol";
+import {UFixed} from "../type/UFixed.sol";
+
+
+contract StakingReader is
+    IRegistryLinked,
+    Initializable
+{
+
+    error ErrorStakingReaderUnauthorizedCaler();
+
+    address private _initializeOwner;
+    IRegistry private _registry;
+    IStaking private _staking;
+    StakingStore private _store;
+
+    constructor(IRegistry registry) {
+        _initializeOwner = msg.sender;
+        _registry = registry;
+    }
+
+    function initialize(
+        address stakingAddress,
+        address stakingStoreAddress
+    )
+        external
+        initializer()
+    {
+        if (msg.sender != _initializeOwner) {
+            revert ErrorStakingReaderUnauthorizedCaler();
+        }
+
+        _staking = IStaking(stakingAddress);
+        _store = StakingStore(stakingStoreAddress);
+    }
+
+    // view and pure functions 
+
+    function getRegistry() external view returns (IRegistry registry) {
+        return _registry;
+    }
+
+    function getStaking() external view returns (IStaking staking) {
+        return _staking;
+    }
+
+    function getProtocolNftId() external view returns (NftId protocolNftId) {
+        return _registry.getProtocolNftId();
+    }
+
+
+    function isTarget(NftId targetNftId) external view returns (bool) {
+        return _store.getTargetSet().exists(targetNftId);
+    }
+
+
+    function targets() external view returns (uint256) {
+        return _store.getTargetSet().nftIds();
+    }
+
+
+    function getTargetNftId(uint256 idx) external view returns (NftId) {
+        return _store.getTargetSet().getNftId(idx);
+    }
+
+
+    function getTargetNftId(NftId stakeNftId) public view returns (NftId targetNftId) {
+        return _registry.getParentNftId(stakeNftId);
+    }
+
+
+    function getStakeInfo(NftId stakeNftId) external view returns (IStaking.StakeInfo memory stakeInfo) {
+        return _store.getStakeInfo(stakeNftId);
+    }
+
+
+    function getTargetInfo(NftId targetNftId) public view returns (IStaking.TargetInfo memory info) {
+        return _store.getTargetInfo(targetNftId);
+    }
+
+
+    function getLimitInfo(NftId targetNftId) public view returns (IStaking.LimitInfo memory info) {
+        return _store.getLimitInfo(targetNftId);
+    }
+
+
+    function getTvlInfo(NftId targetNftId, address token) public view returns (IStaking.TvlInfo memory info) {
+        return _store.getTvlInfo(targetNftId, token);
+    }
+
+
+    function getTokenInfo(ChainId chainId, address token) public view returns (IStaking.TokenInfo memory info) {
+        return _store.getTokenInfo(chainId, token);
+    }
+
+
+    function isSupportedTargetType(ObjectType targetType) public view returns (bool) {
+        return _store.getSupportInfo(targetType).isSupported;
+    }
+
+
+    function getSupportInfo(ObjectType targetType) public view returns (IStaking.SupportInfo memory info) {
+        return _store.getSupportInfo(targetType);
+    }
+
+
+    /// @dev Get the locking period that applies to the specified stake NFT ID.
+    function getTargetLockingPeriod(NftId stakeNftId) external view returns (NftId targetNftId, Seconds lockingPeriod) {
+        targetNftId = getTargetNftId(stakeNftId);
+        lockingPeriod = getTargetInfo(targetNftId).lockingPeriod;
+    }
+
+
+    /// @dev Get the reward rate that applies to the specified stake NFT ID.
+    function getTargetRewardRate(NftId stakeNftId) external view returns (NftId targetNftId, UFixed rewardRate) {
+        targetNftId = getTargetNftId(stakeNftId);
+        rewardRate = getTargetInfo(targetNftId).rewardRate;
+    }
+
+
+    /// @dev Get the max staked amount allowed for the specified target NFT ID.
+    function getTargetMaxStakedAmount(NftId targetNftId) external view returns (Amount maxStakedAmount) {
+        return getTargetInfo(targetNftId).limitAmount;
+    }
+
+
+    /// @dev Get the reward rate for the specified target NFT ID.
+    function getLockingPeriod(NftId targetNftId) external view returns (Seconds lockingPeriod) {
+        return getTargetInfo(targetNftId).lockingPeriod;
+    }
+
+
+    /// @dev Get the reward rate for the specified target NFT ID.
+    function getRewardRate(NftId targetNftId) external view returns (UFixed rewardRate) {
+        return getTargetInfo(targetNftId).rewardRate;
+    }
+
+    /// @dev returns the current reward reserve balance for the specified target.
+    function getReserveBalance(NftId targetNftId) external view returns (Amount rewardReserveBalance) {
+        return getTargetInfo(targetNftId).reserveAmount;
+    }
+
+    function getTotalValueLocked(NftId targetNftId, address token) external view returns (Amount totalValueLocked) {
+        return _store.getTvlInfo(targetNftId, token).tvlAmount;
+    }
+
+    function getRequiredStakeBalance(NftId targetNftId) external view returns (Amount requiredStakedAmount) {
+        return _store.getRequiredStakeBalance(targetNftId, true);
+    }
+
+    function getRequiredStakeBalance(NftId targetNftId, bool includeTargetTypeRequirements) external view returns (Amount requiredStakedAmount) {
+        return _store.getRequiredStakeBalance(targetNftId, includeTargetTypeRequirements);
+    }
+}